ncurses 5.9 - patch 20130720
[ncurses.git] / configure.in
1 dnl***************************************************************************
2 dnl Copyright (c) 1998-2012,2013 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey 1995-on
30 dnl
31 dnl $Id: configure.in,v 1.571 2013/07/06 21:43:56 tom Exp $
32 dnl Process this file with autoconf to produce a configure script.
33 dnl
34 dnl See http://invisible-island.net/autoconf/ for additional information.
35 dnl
36 dnl ---------------------------------------------------------------------------
37 AC_PREREQ(2.52.20030208)
38 AC_REVISION($Revision: 1.571 $)
39 AC_INIT(ncurses/base/lib_initscr.c)
40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
41
42 CF_TOP_BUILDDIR
43 CF_SUBST_NCURSES_VERSION
44
45 CF_WITH_REL_VERSION(NCURSES)
46 CF_WITH_ABI_VERSION
47
48 CF_WITH_SYSTYPE
49
50 ###     Save the given $CFLAGS to allow user-override.
51 cf_user_CFLAGS="$CFLAGS"
52
53 ###     Default install-location
54 CF_CFG_DEFAULTS
55
56 ###     Checks for programs.
57 AC_ARG_WITH(ada,
58         [  --without-ada           suppress check for Ada95, don't build demo],
59         [cf_with_ada=$withval],
60         [cf_with_ada=yes])
61 if test "x$cf_with_ada" = xyes
62 then
63         cf_PROG_CC="gnatgcc gcc cc"
64 else
65         cf_PROG_CC="gcc cc"
66 fi
67
68 CF_PROG_CC($cf_PROG_CC)
69
70 AC_PROG_CPP
71 AC_PROG_GCC_TRADITIONAL
72 CF_PROG_CC_C_O(CC)
73 CF_PROG_LDCONFIG
74
75 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
76 dnl                             configure script by not letting us test if C++
77 dnl                             is present, making this option necessary.
78 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
79 AC_ARG_WITH(cxx,
80         [  --without-cxx           do not adjust ncurses bool to match C++],
81         [cf_with_cxx=$withval],
82         [cf_with_cxx=yes])
83 AC_MSG_RESULT($cf_with_cxx)
84 if test "X$cf_with_cxx" = Xno ; then
85         CXX=""
86         GXX=""
87 else
88         # with autoconf 2.13, we can change the error to a warning:
89         pushdef([AC_MSG_ERROR],
90                 [AC_MSG_RESULT(no)
91                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
92                 cf_with_cxx=no; CXX=""; GXX="";])dnl
93         AC_PROG_CXX
94         popdef([AC_MSG_ERROR])dnl
95         # autoconf 2.5x removed the error (hardcoding it to g++, or just blank)
96         if test "$CXX" = "g++" ; then
97                 AC_PATH_PROG(CXX,g++)
98         fi
99         case "x$CXX" in #(vi
100         x|xg++)
101                 AC_MSG_WARN([You don't have any C++ compiler, too bad])
102                 cf_with_cxx=no; CXX=""; GXX="";
103                 ;;
104         esac
105 fi
106
107 CF_GXX_VERSION
108 case $GXX_VERSION in
109 1*|2.[[0-6]]*)
110         # GXX=""; CXX=""; ac_cv_prog_gxx=no
111         # cf_cxx_library=no
112         AC_MSG_WARN(templates do not work)
113         ;;
114 esac
115
116 AC_MSG_CHECKING(if you want to build C++ binding and demo)
117 AC_ARG_WITH(cxx-binding,
118         [  --without-cxx-binding   do not build C++ binding and demo],
119         [cf_with_cxx_binding=$withval],
120         [cf_with_cxx_binding=$cf_with_cxx])
121 AC_MSG_RESULT($cf_with_cxx_binding)
122
123 AC_MSG_CHECKING(if you want to build with Ada95)
124 AC_MSG_RESULT($cf_with_ada)
125
126 AC_MSG_CHECKING(if you want to install manpages)
127 AC_ARG_WITH(manpages,
128         [  --without-manpages      suppress install of manpages],
129         [cf_with_manpages=$withval],
130         [cf_with_manpages=yes])
131 AC_MSG_RESULT($cf_with_manpages)
132
133 AC_MSG_CHECKING(if you want to build programs such as tic)
134 AC_ARG_WITH(progs,
135         [  --without-progs         suppress build with programs (e.g., tic)],
136         [cf_with_progs=$withval],
137         [cf_with_progs=yes])
138 AC_MSG_RESULT($cf_with_progs)
139
140 AC_MSG_CHECKING(if you want to build test-programs)
141 AC_ARG_WITH(tests,
142         [  --without-tests         suppress build with test-programs],
143         [cf_with_tests=$withval],
144         [cf_with_tests=yes])
145 AC_MSG_RESULT($cf_with_tests)
146
147 AC_MSG_CHECKING(if you wish to install curses.h)
148 AC_ARG_WITH(curses-h,
149         [  --without-curses-h      install curses.h as ncurses.h only],
150         [with_curses_h=$withval],
151         [with_curses_h=yes])
152 AC_MSG_RESULT($with_curses_h)
153
154 modules_to_build="ncurses"
155 if test "X$cf_with_progs" != Xno ; then
156 modules_to_build="$modules_to_build progs tack"
157 fi
158 modules_to_build="$modules_to_build panel menu form"
159
160 AC_ARG_PROGRAM
161
162 CF_PROG_AWK
163 CF_PROG_EGREP
164 CF_PROG_INSTALL
165 CF_PROG_LINT
166 CF_PROG_LN_S
167
168 AC_SYS_LONG_FILE_NAMES
169
170 # if we find pkg-config, check if we should install the ".pc" files.
171 CF_PKG_CONFIG
172 CF_WITH_PKG_CONFIG_LIBDIR
173 CF_ENABLE_PC_FILES
174
175 AC_MSG_CHECKING(if we should assume mixed-case filenames)
176 AC_ARG_ENABLE(mixed-case,
177         [  --enable-mixed-case     tic should assume mixed-case filenames],
178         [enable_mixedcase=$enableval],
179         [enable_mixedcase=auto])
180 AC_MSG_RESULT($enable_mixedcase)
181 if test "$enable_mixedcase" = "auto" ; then
182     CF_MIXEDCASE_FILENAMES
183 else
184     cf_cv_mixedcase=$enable_mixedcase
185     if test "x$enable_mixedcase" = "xyes" ; then
186         AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if tic should assume mixed-case filenames])
187     fi
188 fi
189
190 # do this after mixed-case option (tags/TAGS is not as important as tic).
191 AC_PROG_MAKE_SET
192 CF_MAKE_TAGS
193 CF_MAKEFLAGS
194
195 dnl These are standard among *NIX systems, but not when cross-compiling
196 AC_CHECK_TOOL(RANLIB, ranlib, ':')
197 AC_CHECK_TOOL(LD, ld, ld)
198 AC_CHECK_TOOL(AR, ar, ar)
199 AC_CHECK_TOOL(NM, nm, nm)
200 CF_AR_FLAGS
201
202 dnl Special option for use by system-builders: the install-prefix is used to
203 dnl adjust the location into which the actual install is done, so that an
204 dnl archive can be built without modifying the host system's configuration.
205 AC_MSG_CHECKING(if you have specified an install-prefix)
206 AC_ARG_WITH(install-prefix,
207         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
208         [case "x$withval" in #(vi
209         xyes|xno) #(vi
210                 ;;
211         *)      DESTDIR="$withval"
212                 ;;
213         esac])
214 AC_MSG_RESULT($DESTDIR)
215 AC_SUBST(DESTDIR)
216
217 ###############################################################################
218 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
219 # If we're cross-compiling, allow the user to override the tools and their
220 # options.  The configure script is oriented toward identifying the host
221 # compiler, etc., but we need a build compiler to generate parts of the source.
222 CF_BUILD_CC
223
224 ###############################################################################
225 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
226
227 ### Options to allow the user to specify the set of libraries which are used.
228 ### Use "--without-normal --with-shared" to allow the default model to be
229 ### shared, for example.
230 cf_list_models=""
231 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
232
233 CF_WITH_LIBTOOL
234 if test "$with_libtool" != "no" ; then
235
236 cf_list_models="$cf_list_models libtool"
237
238 else
239
240 AC_MSG_CHECKING(if you want to build shared libraries)
241 AC_ARG_WITH(shared,
242         [  --with-shared           generate shared-libraries],
243         [with_shared=$withval],
244         [with_shared=no])
245 AC_MSG_RESULT($with_shared)
246 test "x$with_shared" = "xyes" && cf_list_models="$cf_list_models shared"
247
248 AC_MSG_CHECKING(if you want to build static libraries)
249 AC_ARG_WITH(normal,
250         [  --with-normal           generate normal-libraries (default)],
251         [with_normal=$withval],
252         [with_normal=yes])
253 AC_MSG_RESULT($with_normal)
254 test "x$with_normal" = "xyes" && cf_list_models="$cf_list_models normal"
255
256 AC_MSG_CHECKING(if you want to build debug libraries)
257 AC_ARG_WITH(debug,
258         [  --with-debug            generate debug-libraries (default)],
259         [with_debug=$withval],
260         [with_debug=yes])
261 AC_MSG_RESULT($with_debug)
262 test "x$with_debug" = "xyes" && cf_list_models="$cf_list_models debug"
263
264 AC_MSG_CHECKING(if you want to build profiling libraries)
265 AC_ARG_WITH(profile,
266         [  --with-profile          generate profile-libraries],
267         [with_profile=$withval],
268         [with_profile=no])
269 AC_MSG_RESULT($with_profile)
270 test "x$with_profile" = "xyes" && cf_list_models="$cf_list_models profile"
271
272 fi
273
274 if test "X$cf_with_cxx_binding" != Xno; then
275 if test "x$with_shared" = "xyes"; then
276 AC_MSG_CHECKING(if you want to build C++ shared libraries)
277 AC_ARG_WITH(cxx-shared,
278         [  --with-cxx-shared       generate C++ shared-libraries],
279         [with_shared_cxx=$withval],
280         [with_shared_cxx=no])
281 AC_MSG_RESULT($with_shared_cxx)
282 fi
283 fi
284
285 ###############################################################################
286
287 AC_MSG_CHECKING(for specified models)
288 test -z "$cf_list_models" && cf_list_models=normal
289 dnl If we use libtool to generate libraries, then it must be the only
290 dnl specified model.
291 test "$with_libtool" != "no" && cf_list_models=libtool
292 AC_MSG_RESULT($cf_list_models)
293
294 ### Use the first model as the default, and save its suffix for use in building
295 ### up test-applications.
296 AC_MSG_CHECKING(for default model)
297 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
298 AC_MSG_RESULT($DFT_LWR_MODEL)
299
300 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
301
302 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
303 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
304
305 TICS_NAME=tic
306 AC_SUBST(TICS_NAME)
307
308 TINFO_NAME=tinfo
309 AC_SUBST(TINFO_NAME)
310
311 LIB_NAME=ncurses
312 AC_SUBST(LIB_NAME)
313
314 LIB_DIR=../lib
315 LIB_2ND=../../lib
316
317 CF_WITH_LIB_PREFIX(cf_prefix)
318
319 LIB_SUFFIX=
320 AC_SUBST(LIB_SUFFIX)
321 CF_PATHSEP
322
323 ###############################################################################
324
325 AC_MSG_CHECKING(if you want to build a separate terminfo library)
326 AC_ARG_WITH(termlib,
327         [  --with-termlib          generate separate terminfo library],
328         [with_termlib=$withval],
329         [with_termlib=no])
330 AC_MSG_RESULT($with_termlib)
331
332 AC_MSG_CHECKING(if you want to build a separate tic library)
333 AC_ARG_WITH(ticlib,
334         [  --with-ticlib           generate separate tic library],
335         [with_ticlib=$withval],
336         [with_ticlib=no])
337 AC_MSG_RESULT($with_ticlib)
338
339 ### Checks for special libraries, must be done up-front.
340 SHLIB_LIST=""
341 CF_WITH_GPM
342 if test "$with_gpm" != no ; then
343         AC_MSG_CHECKING(if you want to load GPM dynamically)
344         AC_ARG_WITH(dlsym,
345                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
346                 [with_dlsym=$withval],
347                 [with_dlsym=yes])
348         AC_MSG_RESULT($with_dlsym)
349         if test "x$with_dlsym" = xyes ; then
350                 CF_FUNC_DLSYM
351                 if test "x$with_gpm" != xyes ; then
352                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
353                         cf_cv_gpm_soname="$with_gpm"
354                 else
355                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
356                 fi
357                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname",[Define as needed to set the gpm share library soname])
358                 SHLIB_LIST="-ldl $SHLIB_LIST"
359         else
360                 SHLIB_LIST="-lgpm $SHLIB_LIST"
361                 CF_ADD_LIB(gpm,TEST_LIBS)
362         fi
363         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
364         CF_CHECK_GPM_WGETCH
365 fi
366
367 CF_WITH_SYSMOUSE
368
369 dnl Not all ports of gcc support the -g option
370
371 if test X"$CC_G_OPT" = X"" ; then
372         CC_G_OPT='-g'
373         test -n "$GCC" && test "x${ac_cv_prog_cc_g}" != xyes && CC_G_OPT=''
374 fi
375 AC_SUBST(CC_G_OPT)
376
377 if test X"$CXX_G_OPT" = X"" ; then
378         CXX_G_OPT='-g'
379         test -n "$GXX" && test "x${ac_cv_prog_cxx_g}" != xyes && CXX_G_OPT=''
380 fi
381 AC_SUBST(CXX_G_OPT)
382
383 AC_MSG_CHECKING(for default loader flags)
384 case $DFT_LWR_MODEL in
385 libtool) LD_MODEL=''   ;;
386 normal)  LD_MODEL=''   ;;
387 debug)   LD_MODEL=$CC_G_OPT ;;
388 profile) LD_MODEL='-pg';;
389 shared)  LD_MODEL=''   ;;
390 esac
391 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
392 AC_MSG_RESULT($LD_MODEL)
393
394 case $DFT_LWR_MODEL in
395 shared)
396 CF_ENABLE_RPATH
397 AC_MSG_CHECKING(if shared libraries should be relinked during install)
398 AC_ARG_ENABLE(relink,
399 [  --disable-relink        relink shared libraries during install],
400 [cf_cv_do_relink=$enableval],
401 [cf_cv_do_relink=yes])
402 AC_MSG_RESULT($cf_cv_do_relink)
403         ;;
404 esac
405
406 CF_SHARED_OPTS
407 if test "$CC_SHARED_OPTS" = "unknown"; then
408         for model in $cf_list_models; do
409                 if test "$model" = "shared"; then
410                         AC_ERROR(Shared libraries are not supported in this version)
411                 fi
412         done
413 fi
414
415 ### If we're building with rpath, try to link non-standard libs that way too.
416 if test "$DFT_LWR_MODEL" = "shared"; then
417         CF_DISABLE_RPATH_HACK
418 fi
419
420 ###############################################################################
421 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
422
423 ###     use option --disable-overwrite to leave out the link to -lcurses
424 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
425 AC_ARG_ENABLE(overwrite,
426         [  --disable-overwrite     leave out the link to -lcurses],
427         [with_overwrite=$enableval],
428         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
429 AC_MSG_RESULT($with_overwrite)
430
431 AC_MSG_CHECKING(if external terminfo-database is used)
432 AC_ARG_ENABLE(database,
433         [  --disable-database      do not use terminfo, only fallbacks/termcap],
434         [use_database=$enableval],
435         [use_database=yes])
436 AC_MSG_RESULT($use_database)
437
438 case $host_os in #(vi
439 os2*) #(vi
440         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
441         ;;
442 *) #(vi
443         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
444         ;;
445 esac
446 AC_SUBST(TERMINFO_SRC)
447
448 NCURSES_USE_DATABASE=0
449 if test "$use_database" != no ; then
450         NCURSES_USE_DATABASE=1
451
452         AC_MSG_CHECKING(which terminfo source-file will be installed)
453         AC_ARG_WITH(database,
454                 [  --with-database=XXX     specify terminfo source to install],
455                 [TERMINFO_SRC=$withval])
456         AC_MSG_RESULT($TERMINFO_SRC)
457
458         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
459         AC_ARG_WITH(hashed-db,
460                 [  --with-hashed-db        specify hashed-database library],,
461                 [with_hashed_db=no])
462         AC_MSG_RESULT($with_hashed_db)
463 else
464         with_hashed_db=no
465 fi
466 AC_SUBST(NCURSES_USE_DATABASE)
467
468 AC_MSG_CHECKING(for list of fallback descriptions)
469 AC_ARG_WITH(fallbacks,
470         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
471         [with_fallback=$withval],
472         [with_fallback=])
473 AC_MSG_RESULT($with_fallback)
474 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
475 AC_SUBST(FALLBACK_LIST)
476
477 AC_MSG_CHECKING(if you want modern xterm or antique)
478 AC_ARG_WITH(xterm-new,
479         [  --without-xterm-new     specify if xterm terminfo should be old version],
480         [with_xterm_new=$withval],
481         [with_xterm_new=yes])
482 case $with_xterm_new in
483 no)     with_xterm_new=xterm-old;;
484 *)      with_xterm_new=xterm-new;;
485 esac
486 AC_MSG_RESULT($with_xterm_new)
487 WHICH_XTERM=$with_xterm_new
488 AC_SUBST(WHICH_XTERM)
489
490 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
491 AC_ARG_WITH(xterm-kbs,
492         [  --with-xterm-kbs=XXX    specify if xterm backspace sends BS or DEL],
493         [with_xterm_kbs=$withval],
494         [with_xterm_kbs=BS])
495 case x$with_xterm_kbs in
496 xyes|xno|xBS|xbs|x8)
497         with_xterm_kbs=BS
498         ;;
499 xDEL|xdel|x127)
500         with_xterm_kbs=DEL
501         ;;
502 *)
503         with_xterm_kbs=$withval
504         ;;
505 esac
506 AC_MSG_RESULT($with_xterm_kbs)
507 XTERM_KBS=$with_xterm_kbs
508 AC_SUBST(XTERM_KBS)
509
510 MAKE_TERMINFO=
511 if test "$use_database" = no ; then
512         TERMINFO="${datadir}/terminfo"
513         MAKE_TERMINFO="#"
514 else
515
516 AC_MSG_CHECKING(for list of terminfo directories)
517 CF_WITH_PATHLIST(terminfo-dirs,
518         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
519         TERMINFO_DIRS,
520         DATADIR/terminfo,
521         ${datadir}/terminfo)
522 AC_MSG_RESULT($TERMINFO_DIRS)
523 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS",[Define as needed to predefine the TERMINFO_DIR searchlist])
524
525 AC_MSG_CHECKING(for default terminfo directory)
526 CF_WITH_PATH(default-terminfo-dir,
527         [  --with-default-terminfo-dir=DIR default terminfo directory],
528         TERMINFO,
529         DATADIR/terminfo,
530         ${datadir}/terminfo)
531 AC_MSG_RESULT($TERMINFO)
532 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO",[Define to set the default terminal database path])
533
534 fi
535
536 AC_SUBST(TERMINFO)
537 AC_SUBST(MAKE_TERMINFO)
538
539 ###     use option --disable-big-core to make tic run on small machines
540 ###     We need 4Mb, check if we can allocate 50% more than that.
541 AC_MSG_CHECKING(if big-core option selected)
542 AC_ARG_ENABLE(big-core,
543         [  --disable-big-core      assume machine has little memory],
544         [with_big_core=$enableval],
545         [AC_TRY_RUN([
546 #include <stdlib.h>
547 #include <string.h>
548 int main() {
549         unsigned long n = 6000000L;
550         char *s = malloc(n);
551         if (s != 0)
552                 s[0] = s[n-1] = 0;
553         ${cf_cv_main_return:-return}(s == 0);
554 }],
555         [with_big_core=yes],
556         [with_big_core=no],
557         [with_big_core=no])])
558 AC_MSG_RESULT($with_big_core)
559 test "x$with_big_core" = "xyes" && AC_DEFINE(HAVE_BIG_CORE,1,[Define to 1 if machine has ample memory for tic])
560
561 ### ISO C only guarantees 512-char strings, we have tables which load faster
562 ### when constructed using "big" strings.  More than the C compiler, the awk
563 ### program is a limit on most vendor UNIX systems.  Check that we can build.
564 AC_MSG_CHECKING(if big-strings option selected)
565 AC_ARG_ENABLE(big-strings,
566         [  --disable-big-strings   assume compiler has only standard-size strings],
567         [with_big_strings=$enableval],
568         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
569 AC_MSG_RESULT($with_big_strings)
570
571 USE_BIG_STRINGS=0
572 test "x$with_big_strings" = "xyes" && USE_BIG_STRINGS=1
573 AC_SUBST(USE_BIG_STRINGS)
574
575 ###     use option --enable-termcap to compile in the termcap fallback support
576 AC_MSG_CHECKING(if you want termcap-fallback support)
577 AC_ARG_ENABLE(termcap,
578         [  --enable-termcap        compile in termcap fallback support],
579         [with_termcap=$enableval],
580         [with_termcap=no])
581 AC_MSG_RESULT($with_termcap)
582
583 NCURSES_USE_TERMCAP=0
584 if test "x$with_termcap" != "xyes" ; then
585         if test "$use_database" = no ; then
586                 if test -z "$with_fallback" ; then
587                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
588                 fi
589         fi
590         AC_DEFINE(PURE_TERMINFO,1,[Define to 1 if we should support only terminfo])
591 else
592
593         if test "$with_ticlib" != no ; then
594                 AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
595         fi
596
597         NCURSES_USE_TERMCAP=1
598         AC_MSG_CHECKING(for list of termcap files)
599         CF_WITH_PATHLIST(termpath,
600                 [  --with-termpath=XXX     specify list of termcap files],
601                 TERMPATH,
602                 /etc/termcap:/usr/share/misc/termcap)
603         AC_MSG_RESULT($TERMPATH)
604         test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH",[Define to set the termcap searchlist])
605
606         ###     use option --enable-getcap to use a hacked getcap for reading termcaps
607         AC_MSG_CHECKING(if fast termcap-loader is needed)
608         AC_ARG_ENABLE(getcap,
609                 [  --enable-getcap         fast termcap load, no xrefs to terminfo],
610                 [with_getcap=$enableval],
611                 [with_getcap=no])
612         AC_MSG_RESULT($with_getcap)
613         test "x$with_getcap" = "xyes" && AC_DEFINE(USE_GETCAP,1,[Define to 1 to use fast termcap-loader])
614
615         AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
616         AC_ARG_ENABLE(getcap-cache,
617                 [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
618                 [with_getcap_cache=$enableval],
619                 [with_getcap_cache=no])
620         AC_MSG_RESULT($with_getcap_cache)
621         test "x$with_getcap_cache" = "xyes" && AC_DEFINE(USE_GETCAP_CACHE,1,[Define to 1 if translated termcap should be stored in $HOME/.terminfo])
622
623 fi
624 AC_SUBST(NCURSES_USE_TERMCAP)
625
626 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
627 AC_MSG_CHECKING(if ~/.terminfo is wanted)
628 AC_ARG_ENABLE(home-terminfo,
629         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
630         [with_home_terminfo=$enableval],
631         [with_home_terminfo=yes])
632 AC_MSG_RESULT($with_home_terminfo)
633 test "x$with_home_terminfo" = "xyes" && AC_DEFINE(USE_HOME_TERMINFO,1,[Define to 1 if $HOME/.terminfo feature is wanted])
634
635 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
636 AC_ARG_ENABLE(root-environ,
637         [  --disable-root-environ  restrict environment when running as root],
638         [with_root_environ=$enableval],
639         [with_root_environ=yes])
640 AC_MSG_RESULT($with_root_environ)
641 test "x$with_root_environ" = xyes && AC_DEFINE(USE_ROOT_ENVIRON,1,[Define to 1 if environment should be restricted for root user])
642
643 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
644 ###   to reduce storage requirements for the terminfo database.
645 CF_LINK_FUNCS
646
647 with_links=no
648 with_symlinks=no
649
650 # soft links (symbolic links) are useful for some systems where hard links do
651 # not work, or to make it simpler to copy terminfo trees around.
652 if test "x$ac_cv_func_symlink" = xyes ; then
653     AC_MSG_CHECKING(if tic should use symbolic links)
654     AC_ARG_ENABLE(symlinks,
655         [  --enable-symlinks       make tic use symbolic links not hard links],
656         [with_symlinks=$enableval],
657         [with_symlinks=no])
658     AC_MSG_RESULT($with_symlinks)
659 fi
660
661 # If we have hard links and did not choose to use soft links instead, there is
662 # no reason to make this choice optional - use the hard links.
663 if test "$with_symlinks" = no ; then
664     AC_MSG_CHECKING(if tic should use hard links)
665     if test "x$ac_cv_func_link" = xyes ; then
666         with_links=yes
667     else
668         with_links=no
669     fi
670     AC_MSG_RESULT($with_links)
671 fi
672
673 test "x$with_links" = xyes && AC_DEFINE(USE_LINKS,1,[Define to 1 if hardlinks should be used in terminfo database])
674 test "x$with_symlinks" = xyes && AC_DEFINE(USE_SYMLINKS,1,[Define to 1 if symbolic links should be used in terminfo database])
675
676 ###   use option --enable-broken-linker to force on use of broken-linker support
677 AC_MSG_CHECKING(if you want broken-linker support code)
678 AC_ARG_ENABLE(broken_linker,
679         [  --enable-broken_linker  compile with broken-linker support code],
680         [with_broken_linker=$enableval],
681         [with_broken_linker=${BROKEN_LINKER:-no}])
682 AC_MSG_RESULT($with_broken_linker)
683
684 BROKEN_LINKER=0
685 if test "x$with_broken_linker" = xyes ; then
686         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
687         BROKEN_LINKER=1
688 elif test "$DFT_LWR_MODEL" = shared ; then
689         case $cf_cv_system_name in #(vi
690         cygwin*)
691                 AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
692                 BROKEN_LINKER=1
693                 CF_VERBOSE(cygwin linker is broken anyway)
694                 ;;
695         esac
696 fi
697 AC_SUBST(BROKEN_LINKER)
698
699 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
700 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
701 AC_ARG_ENABLE(bsdpad,
702         [  --enable-bsdpad         recognize BSD-style prefix padding],
703         [with_bsdpad=$enableval],
704         [with_bsdpad=no])
705 AC_MSG_RESULT($with_bsdpad)
706 test "x$with_bsdpad" = xyes && AC_DEFINE(BSD_TPUTS,1,[Define to 1 to recognize BSD-style prefix padding])
707
708 ###   use option --enable-widec to turn on use of wide-character support
709 NCURSES_CH_T=chtype
710 NCURSES_LIBUTF8=0
711
712 NEED_WCHAR_H=0
713 NCURSES_MBSTATE_T=0
714 NCURSES_WCHAR_T=0
715 NCURSES_WINT_T=0
716
717 # Check to define _XOPEN_SOURCE "automatically"
718 CF_XOPEN_SOURCE(500)
719
720 # Work around breakage on OS X
721 CF_SIGWINCH
722
723 # Checks for CODESET support.
724 AM_LANGINFO_CODESET
725
726 # use these variables to work around a defect in gcc's fixincludes.
727 NCURSES_OK_WCHAR_T=
728 NCURSES_OK_WINT_T=
729
730 AC_MSG_CHECKING(if you want wide-character code)
731 AC_ARG_ENABLE(widec,
732         [  --enable-widec          compile with wide-char/UTF-8 code],
733         [with_widec=$enableval],
734         [with_widec=no])
735 AC_MSG_RESULT($with_widec)
736 if test "x$with_widec" = xyes ; then
737         LIB_SUFFIX="w${LIB_SUFFIX}"
738         AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to compile with wide-char/UTF-8 code])
739         AC_DEFINE(NCURSES_WIDECHAR,1,[Define to 1 to compile with wide-char/UTF-8 code])
740
741         CF_CHECK_WCHAR_H
742
743         # with_overwrite=no
744         NCURSES_CH_T=cchar_t
745         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
746         if test "x$ac_cv_func_putwc" != xyes ; then
747                 CF_UTF8_LIB
748                 if test "$cf_cv_utf8_lib" != no ; then
749                         NCURSES_LIBUTF8=1
750                 fi
751         fi
752         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
753         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
754         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
755
756         if test "$NCURSES_MBSTATE_T" != 0; then
757                 AC_DEFINE(NEED_MBSTATE_T_DEF,1,[Define to 1 if we must declare mbstate_t])
758         fi
759 fi
760 AC_SUBST(NCURSES_CH_T)
761 AC_SUBST(NCURSES_LIBUTF8)
762
763 AC_SUBST(NEED_WCHAR_H)
764 AC_SUBST(NCURSES_MBSTATE_T)
765 AC_SUBST(NCURSES_WCHAR_T)
766 AC_SUBST(NCURSES_WINT_T)
767
768 AC_SUBST(NCURSES_OK_WCHAR_T)
769 AC_SUBST(NCURSES_OK_WINT_T)
770
771 ###   use option --disable-lp64 to allow long chtype
772 case $cf_cv_abi_version in
773 [[345]]*)
774         default_with_lp64=no
775         ;;
776 *)
777         default_with_lp64=yes
778         ;;
779 esac
780
781 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
782 AC_ARG_ENABLE(lp64,
783         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
784         [with_lp64=$enableval],
785         [with_lp64=$default_with_lp64])
786 AC_MSG_RESULT($with_lp64)
787
788 if test "x$with_lp64" = xyes ; then
789         cf_cv_enable_lp64=1
790 else
791         cf_cv_enable_lp64=0
792 fi
793 AC_SUBST(cf_cv_enable_lp64)
794
795 CF_LARGEFILE
796
797 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
798 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
799 AC_ARG_ENABLE(tparm-varargs,
800         [  --disable-tparm-varargs compile tparm() without varargs interface],
801         [with_tparm_varargs=$enableval],
802         [with_tparm_varargs=yes])
803 AC_MSG_RESULT($with_tparm_varargs)
804 NCURSES_TPARM_VARARGS=0
805 test "x$with_tparm_varargs" = xyes && NCURSES_TPARM_VARARGS=1
806 AC_SUBST(NCURSES_TPARM_VARARGS)
807
808 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
809 if test "$with_ticlib" != no ; then
810 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
811 AC_ARG_ENABLE(tic-depends,
812         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
813         [with_tic_depends=$enableval],
814         [with_tic_depends=yes])
815 AC_MSG_RESULT($with_tic_depends)
816 else
817         with_tic_depends=no
818 fi
819
820 ###   use option --with-bool to override bool's type
821 AC_MSG_CHECKING(for type of bool)
822 AC_ARG_WITH(bool,
823         [  --with-bool=TYPE        override fallback type of bool variable],
824         [NCURSES_BOOL="$withval"],
825         [NCURSES_BOOL=auto])
826 AC_MSG_RESULT($NCURSES_BOOL)
827 AC_SUBST(NCURSES_BOOL)
828
829 AC_MSG_CHECKING(for alternate terminal capabilities file)
830 AC_ARG_WITH(caps,
831         [  --with-caps=alt         compile with alternate Caps file],
832         [TERMINFO_CAPS=Caps.$withval],
833         [TERMINFO_CAPS=Caps])
834 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
835 AC_MSG_RESULT($TERMINFO_CAPS)
836 AC_SUBST(TERMINFO_CAPS)
837
838 ###   use option --with-chtype to override chtype's type
839 AC_MSG_CHECKING(for type of chtype)
840 AC_ARG_WITH(chtype,
841         [  --with-chtype=TYPE      override type of chtype],
842         [NCURSES_CHTYPE="$withval"],
843         [NCURSES_CHTYPE=auto])
844 AC_MSG_RESULT($NCURSES_CHTYPE)
845
846 ###   use option --with-ospeed to override ospeed's type
847 AC_MSG_CHECKING(for type of ospeed)
848 AC_ARG_WITH(ospeed,
849         [  --with-ospeed=TYPE      override type of ospeed variable],
850         [NCURSES_OSPEED="$withval"],
851         [NCURSES_OSPEED=short])
852 AC_MSG_RESULT($NCURSES_OSPEED)
853 AC_SUBST(NCURSES_OSPEED)
854
855 ###   use option --with-mmask-t to override mmask_t's type
856 AC_MSG_CHECKING(for type of mmask_t)
857 AC_ARG_WITH(mmask-t,
858         [  --with-mmask-t=TYPE     override type of mmask_t],
859         [NCURSES_MMASK_T="$withval"],
860         [NCURSES_MMASK_T=auto])
861 AC_MSG_RESULT($NCURSES_MMASK_T)
862
863 ###   use option --with-ccharw-max to override CCHARW_MAX size
864 AC_MSG_CHECKING(for size CCHARW_MAX)
865 AC_ARG_WITH(ccharw-max,
866         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
867         [NCURSES_CCHARW_MAX="$withval"],
868         [NCURSES_CCHARW_MAX=5])
869 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
870 AC_SUBST(NCURSES_CCHARW_MAX)
871
872 ###   use option --with-tparm-arg to override tparm's argument type
873 AC_MSG_CHECKING(for type of tparm args)
874 AC_ARG_WITH(tparm-arg,
875         [  --with-tparm-arg=TYPE   override parameter type of tparm],
876         [NCURSES_TPARM_ARG="$withval"],
877         [NCURSES_TPARM_ARG=long])
878 AC_MSG_RESULT($NCURSES_TPARM_ARG)
879 AC_SUBST(NCURSES_TPARM_ARG)
880
881 ### Enable compiling-in rcs id's
882 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
883 AC_ARG_WITH(rcs-ids,
884         [  --with-rcs-ids          compile-in RCS identifiers],
885         [with_rcs_ids=$withval],
886         [with_rcs_ids=no])
887 AC_MSG_RESULT($with_rcs_ids)
888 test "x$with_rcs_ids" = xyes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 to compile-in RCS identifiers])
889
890 ###############################################################################
891 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tabs tic toe tput tset ])
892
893 ###############################################################################
894 CF_HELP_MESSAGE(Extensions:)
895
896 ### Note that some functions (such as const) are normally disabled anyway.
897 AC_MSG_CHECKING(if you want to build with function extensions)
898 AC_ARG_ENABLE(ext-funcs,
899         [  --disable-ext-funcs     disable function-extensions],
900         [with_ext_funcs=$enableval],
901         [with_ext_funcs=yes])
902 AC_MSG_RESULT($with_ext_funcs)
903 if test "x$with_ext_funcs" = xyes ; then
904         NCURSES_EXT_FUNCS=1
905         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS,1,[Define to 1 to enable assume_default_colors() function])
906         AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 to enable curses_version() function])
907         AC_DEFINE(HAVE_HAS_KEY,1,[Define to 1 to enable has_key() function])
908         AC_DEFINE(HAVE_RESIZETERM,1,[Define to 1 to enable resizeterm() function])
909         AC_DEFINE(HAVE_RESIZE_TERM,1,[Define to 1 to enable resize_term() function])
910         AC_DEFINE(HAVE_TERM_ENTRY_H,1,[Define to 1 to enable term_entry() function])
911         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 to enable use_default_colors() function])
912         AC_DEFINE(HAVE_USE_SCREEN,1,[Define to 1 to enable use_screen() function])
913         AC_DEFINE(HAVE_USE_WINDOW,1,[Define to 1 to enable use_window() function])
914         AC_DEFINE(HAVE_WRESIZE,1,[Define to 1 to enable wresize() function])
915         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 to enable ncurses extended functions])
916         GENERATED_EXT_FUNCS=generated
917 else
918         NCURSES_EXT_FUNCS=0
919         GENERATED_EXT_FUNCS=
920 fi
921 AC_SUBST(NCURSES_EXT_FUNCS)
922 AC_SUBST(GENERATED_EXT_FUNCS)
923
924 AC_MSG_CHECKING(if you want to build with experimental SCREEN extensions)
925 AC_ARG_ENABLE(sp-funcs,
926         [  --enable-sp-funcs       enable experimental SCREEN-extensions],
927         [with_sp_funcs=$enableval],
928         [with_sp_funcs=no])
929 AC_MSG_RESULT($with_sp_funcs)
930 if test "x$with_sp_funcs" = xyes ; then
931         NCURSES_SP_FUNCS=1
932         AC_DEFINE(NCURSES_SP_FUNCS,1,[Define to 1 to enable experimental SCREEN-extensions])
933         GENERATED_SP_FUNCS=generated
934 else
935         NCURSES_SP_FUNCS=0
936         GENERATED_SP_FUNCS=
937 fi
938 AC_SUBST(NCURSES_SP_FUNCS)
939 AC_SUBST(GENERATED_SP_FUNCS)
940
941 AC_MSG_CHECKING(if you want to build with experimental terminal-driver)
942 AC_ARG_ENABLE(term-driver,
943         [  --enable-term-driver    enable experimental terminal-driver],
944         [with_term_driver=$enableval],
945         [with_term_driver=no])
946 AC_MSG_RESULT($with_term_driver)
947 if test "x$with_term_driver" = xyes ; then
948         AC_DEFINE(USE_TERM_DRIVER,1,[Define to 1 to enable experimental terminal-driver])
949         if test "x$with_sp_funcs" != xyes ; then
950                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
951         fi
952 fi
953
954 ###   use option --enable-const to turn on use of const beyond that in XSI.
955 AC_MSG_CHECKING(for extended use of const keyword)
956 AC_ARG_ENABLE(const,
957         [  --enable-const          compile with extra/non-standard const],
958         [with_ext_const=$enableval],
959         [with_ext_const=no])
960 AC_MSG_RESULT($with_ext_const)
961 NCURSES_CONST='/*nothing*/'
962 if test "x$with_ext_const" = xyes ; then
963         NCURSES_CONST=const
964 fi
965 AC_SUBST(NCURSES_CONST)
966
967 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
968 AC_MSG_CHECKING(if you want to use extended colors)
969 AC_ARG_ENABLE(ext-colors,
970         [  --enable-ext-colors     compile for 256-color support],
971         [with_ext_colors=$enableval],
972         [with_ext_colors=no])
973 AC_MSG_RESULT($with_ext_colors)
974 NCURSES_EXT_COLORS=0
975 if test "x$with_ext_colors" = xyes ; then
976         if test "x$with_widec" != xyes ; then
977                 AC_MSG_ERROR(This option applies only to wide-character library)
978         else
979                 # cannot be ABI 5 since it changes sizeof(cchar_t)
980                 CF_NCURSES_ABI_6
981         fi
982         NCURSES_EXT_COLORS=1
983         AC_DEFINE(NCURSES_EXT_COLORS,1,[Define to 1 to compile for 256-color support])
984 fi
985 AC_SUBST(NCURSES_EXT_COLORS)
986
987 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
988 AC_MSG_CHECKING(if you want to use extended mouse encoding)
989 AC_ARG_ENABLE(ext-mouse,
990         [  --enable-ext-mouse      compile for extended mouse-encoding],
991         [with_ext_mouse=$enableval],
992         [with_ext_mouse=no])
993 AC_MSG_RESULT($with_ext_mouse)
994 NCURSES_MOUSE_VERSION=1
995 if test "x$with_ext_mouse" = xyes ; then
996         NCURSES_MOUSE_VERSION=2
997         CF_NCURSES_ABI_6
998 fi
999 AC_SUBST(NCURSES_MOUSE_VERSION)
1000
1001 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
1002 AC_ARG_ENABLE(no-padding,
1003         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
1004         [with_no_padding=$enableval],
1005         [with_no_padding=$with_ext_funcs])
1006 AC_MSG_RESULT($with_no_padding)
1007 test "x$with_no_padding" = xyes && AC_DEFINE(NCURSES_NO_PADDING,1,[Define to 1 to compile with $NCURSES_NO_PADDING code])
1008
1009 AC_CHECK_SIZEOF([signed char], 0)
1010 if test "$ac_cv_sizeof_signed_char" = 1 ; then
1011         NCURSES_SBOOL="signed char"
1012 else
1013         NCURSES_SBOOL="char"
1014 fi
1015 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
1016 AC_ARG_ENABLE(signed-char,
1017         [  --enable-signed-char    compile using signed Boolean's in term.h],
1018         [with_signed_char=$enableval],
1019         [with_signed_char=no])
1020 AC_MSG_RESULT($with_signed_char)
1021 test "x$with_signed_char" != xyes && NCURSES_SBOOL="char"
1022 AC_SUBST(NCURSES_SBOOL)
1023
1024 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1025 AC_MSG_CHECKING(if you want SIGWINCH handler)
1026 AC_ARG_ENABLE(sigwinch,
1027         [  --enable-sigwinch       compile with SIGWINCH handler],
1028         [with_sigwinch=$enableval],
1029         [with_sigwinch=$with_ext_funcs])
1030 AC_MSG_RESULT($with_sigwinch)
1031 test "x$with_sigwinch" = xyes && AC_DEFINE(USE_SIGWINCH,1,[Define to 1 to compile with SIGWINCH handler])
1032
1033 ###   use option --enable-tcap-names to allow user to define new capabilities
1034 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1035 AC_ARG_ENABLE(tcap-names,
1036         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1037         [with_tcap_names=$enableval],
1038         [with_tcap_names=$with_ext_funcs])
1039 AC_MSG_RESULT($with_tcap_names)
1040 NCURSES_XNAMES=0
1041 test "x$with_tcap_names" = xyes && NCURSES_XNAMES=1
1042 AC_SUBST(NCURSES_XNAMES)
1043
1044 ###############################################################################
1045 # These options are relatively safe to experiment with.
1046 CF_HELP_MESSAGE(Development Code:)
1047 AC_MSG_CHECKING(if you want all development code)
1048 AC_ARG_WITH(develop,
1049         [  --without-develop       disable development options],
1050         [with_develop=$withval],
1051         [with_develop=no])
1052 AC_MSG_RESULT($with_develop)
1053
1054 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1055 AC_MSG_CHECKING(if you want hard-tabs code)
1056 AC_ARG_ENABLE(hard-tabs,
1057         [  --enable-hard-tabs      compile with hard-tabs code],,
1058         [enable_hard_tabs=$with_develop])
1059 AC_MSG_RESULT($enable_hard_tabs)
1060 test "x$enable_hard_tabs" = xyes && AC_DEFINE(USE_HARD_TABS,1,[Define to 1 to compile with hard-tabs code])
1061
1062 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1063 AC_MSG_CHECKING(if you want limited support for xmc)
1064 AC_ARG_ENABLE(xmc-glitch,
1065         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1066         [enable_xmc_glitch=$with_develop])
1067 AC_MSG_RESULT($enable_xmc_glitch)
1068 test "x$enable_xmc_glitch" = xyes && AC_DEFINE(USE_XMC_SUPPORT,1,[Define to 1 to compile with support for xmc (magic-cookie)])
1069
1070 ###############################################################################
1071 # These are just experimental, probably should not be in a package:
1072 CF_HELP_MESSAGE(Experimental Code:)
1073
1074 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1075 AC_ARG_ENABLE(assumed-color,
1076         [  --disable-assumed-color do not assume anything about default-colors],
1077         [with_assumed_color=$enableval],
1078         [with_assumed_color=yes])
1079 AC_MSG_RESULT($with_assumed_color)
1080 test "x$with_assumed_color" = xyes && AC_DEFINE(USE_ASSUMED_COLOR,1,[Define to 1 to assume things about default-colors])
1081
1082 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1083 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1084 AC_ARG_ENABLE(hashmap,
1085         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1086         [with_hashmap=$enableval],
1087         [with_hashmap=yes])
1088 AC_MSG_RESULT($with_hashmap)
1089 test "x$with_hashmap" = xyes && AC_DEFINE(USE_HASHMAP,1,[Define to 1 to compile with hashmap scrolling-optimization])
1090
1091 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1092 AC_MSG_CHECKING(if you want colorfgbg code)
1093 AC_ARG_ENABLE(colorfgbg,
1094         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1095         [with_colorfgbg=$enableval],
1096         [with_colorfgbg=no])
1097 AC_MSG_RESULT($with_colorfgbg)
1098 test "x$with_colorfgbg" = xyes && AC_DEFINE(USE_COLORFGBG,1,[Define to 1 to compile-in experimental $COLORFGBG code])
1099
1100 ###   use option --enable-interop to turn on use of bindings used for interop
1101 AC_MSG_CHECKING(if you want interop bindings)
1102 AC_ARG_ENABLE(interop,
1103         [  --enable-interop        compile-in experimental interop bindings],
1104         [with_exp_interop=$enableval],
1105         [with_exp_interop=no])
1106 AC_MSG_RESULT($with_exp_interop)
1107
1108 NCURSES_INTEROP_FUNCS=0
1109 test "x$with_exp_interop" = xyes && NCURSES_INTEROP_FUNCS=1
1110 AC_SUBST(NCURSES_INTEROP_FUNCS)
1111
1112 # This is still experimental (20080329), but should ultimately be moved to
1113 # the script-block --with-normal, etc.
1114 CF_WITH_PTHREAD
1115
1116 if test "x$with_pthread" != xno; then
1117         AC_CHECK_FUNC(pthread_kill,[
1118                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1119                 AC_ARG_ENABLE(pthreads-eintr,
1120                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1121                         [use_pthreads_eintr=$enableval],
1122                         [use_pthreads_eintr=no])
1123                 AC_MSG_RESULT($use_pthreads_eintr)
1124                 if test "x$use_pthreads_eintr" = xyes ; then
1125                         AC_DEFINE(USE_PTHREADS_EINTR,1,[Define to 1 to enable EINTR in wgetch with pthreads])
1126                 fi])
1127
1128         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1129         AC_ARG_ENABLE(weak-symbols,
1130                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1131                 [use_weak_symbols=$enableval],
1132                 [use_weak_symbols=no])
1133         AC_MSG_RESULT($use_weak_symbols)
1134         if test "x$use_weak_symbols" = xyes ; then
1135                 CF_WEAK_SYMBOLS
1136         else
1137                 cf_cv_weak_symbols=no
1138         fi
1139
1140         if test "x$cf_cv_weak_symbols" = xyes ; then
1141                 AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
1142         fi
1143 fi
1144
1145 PTHREAD=
1146 if test "x$with_pthread" = "xyes" ; then
1147     AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use pthreads feature])
1148     enable_reentrant=yes
1149     if test "x$cf_cv_weak_symbols" = xyes ; then
1150         PTHREAD=-lpthread
1151     fi
1152 fi
1153 AC_SUBST(PTHREAD)
1154
1155 # Reentrant code has to be opaque; there's little advantage to making ncurses
1156 # opaque outside of that, so there is no --enable-opaque option.  We can use
1157 # this option without --with-pthreads, but this will be always set for
1158 # pthreads.
1159 AC_MSG_CHECKING(if you want experimental reentrant code)
1160 AC_ARG_ENABLE(reentrant,
1161         [  --enable-reentrant      compile with experimental reentrant code],
1162         [with_reentrant=$enableval],
1163         [with_reentrant=no])
1164 AC_MSG_RESULT($with_reentrant)
1165 if test "x$with_reentrant" = xyes ; then
1166         cf_cv_enable_reentrant=1
1167         cf_cv_enable_opaque="NCURSES_INTERNALS"
1168         NCURSES_OPAQUE=1
1169         NCURSES_SIZE_T=int
1170         if test "x$cf_cv_weak_symbols" = xyes ; then
1171                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1172                 CF_ADD_LIB(pthread,TEST_LIBS)
1173                 CF_ADD_LIB(pthread,TEST_LIBS2)
1174         else
1175                 LIB_SUFFIX="t${LIB_SUFFIX}"
1176         fi
1177         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to use experimental reentrant feature])
1178         CF_NCURSES_ABI_6
1179 else
1180         cf_cv_enable_reentrant=0
1181         cf_cv_enable_opaque="NCURSES_OPAQUE"
1182         NCURSES_OPAQUE=0
1183         NCURSES_SIZE_T=short
1184 fi
1185 AC_SUBST(cf_cv_enable_reentrant)
1186 AC_SUBST(cf_cv_enable_opaque)
1187 AC_SUBST(NCURSES_OPAQUE)
1188 AC_SUBST(NCURSES_SIZE_T)
1189
1190 ### Allow using a different wrap-prefix
1191 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1192         AC_MSG_CHECKING(for prefix used to wrap public variables)
1193         AC_ARG_WITH(wrap-prefix,
1194                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1195                 [NCURSES_WRAP_PREFIX=$withval],
1196                 [NCURSES_WRAP_PREFIX=_nc_])
1197         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1198 else
1199         NCURSES_WRAP_PREFIX=_nc_
1200 fi
1201 AC_SUBST(NCURSES_WRAP_PREFIX)
1202 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ prefix])
1203
1204 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1205 AC_ARG_ENABLE(safe-sprintf,
1206         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1207         [with_safe_sprintf=$enableval],
1208         [with_safe_sprintf=no])
1209 AC_MSG_RESULT($with_safe_sprintf)
1210 test "x$with_safe_sprintf" = xyes && AC_DEFINE(USE_SAFE_SPRINTF,1,[Define to 1 to compile with experimental safe-sprintf code])
1211
1212 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1213 # when hashmap is used scroll hints are useless
1214 if test "$with_hashmap" = no ; then
1215 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1216 AC_ARG_ENABLE(scroll-hints,
1217         [  --disable-scroll-hints  compile without scroll-hints code],
1218         [with_scroll_hints=$enableval],
1219         [with_scroll_hints=yes])
1220 AC_MSG_RESULT($with_scroll_hints)
1221 test "x$with_scroll_hints" = xyes && AC_DEFINE(USE_SCROLL_HINTS,1,[Define to 1 to compile without scroll-hints code])
1222 fi
1223
1224 AC_MSG_CHECKING(if you want experimental wgetch-events code)
1225 AC_ARG_ENABLE(wgetch-events,
1226         [  --enable-wgetch-events  compile with experimental wgetch-events code],
1227         [with_wgetch_events=$enableval],
1228         [with_wgetch_events=no])
1229 AC_MSG_RESULT($with_wgetch_events)
1230 test "x$with_wgetch_events" = xyes && AC_DEFINE(NCURSES_WGETCH_EVENTS,1,[Define to 1 to compile with experimental wgetch-events code])
1231
1232 ###############################################################################
1233 CF_HELP_MESSAGE(Testing/development Options:)
1234
1235 ###     use option --disable-echo to suppress full display compiling commands
1236 CF_DISABLE_ECHO
1237 if test "x$enable_echo" = xyes; then
1238         ECHO_LINK=
1239 else
1240         ECHO_LINK='@ echo linking $@ ... ;'
1241         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1242         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1243 fi
1244 AC_SUBST(ECHO_LINK)
1245
1246 ###     use option --enable-warnings to turn on all gcc warnings
1247 AC_MSG_CHECKING(if you want to see compiler warnings)
1248 AC_ARG_ENABLE(warnings,
1249         [  --enable-warnings       build: turn on GCC compiler warnings],
1250         [with_warnings=$enableval])
1251 AC_MSG_RESULT($with_warnings)
1252
1253 if test "x$with_warnings" = "xyes"; then
1254         CF_ADD_ADAFLAGS(-gnatg)
1255         CF_GCC_WARNINGS(Wdeclaration-after-statement Wextra Wno-unknown-pragmas Wswitch-enum)
1256         if test "x$cf_with_cxx" = xyes ; then
1257                 CF_GXX_WARNINGS(Wno-unused)
1258         fi
1259 fi
1260 CF_GCC_ATTRIBUTES
1261 CF_ENABLE_STRING_HACKS
1262
1263 ###     use option --enable-assertions to turn on generation of assertion code
1264 AC_MSG_CHECKING(if you want to enable runtime assertions)
1265 AC_ARG_ENABLE(assertions,
1266         [  --enable-assertions     test: turn on generation of assertion code],
1267         [with_assertions=$enableval],
1268         [with_assertions=no])
1269 AC_MSG_RESULT($with_assertions)
1270 if test -n "$GCC"
1271 then
1272         if test "$with_assertions" = no
1273         then
1274                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1275         else
1276                 CF_ADD_ADAFLAGS(-gnata)
1277         fi
1278 fi
1279
1280 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1281 CF_DISABLE_LEAKS
1282 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
1283
1284 ###     use option --enable-expanded to generate certain macros as functions
1285 AC_ARG_ENABLE(expanded,
1286         [  --enable-expanded       test: generate functions for certain macros],
1287         [test "x$enableval" = xyes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 to generate functions for certain macros])])
1288
1289 ###     use option --disable-macros to suppress macros in favor of functions
1290 AC_ARG_ENABLE(macros,
1291         [  --disable-macros        test: use functions rather than macros],
1292         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 to use functions rather than macros])])
1293
1294 # Normally we only add trace() to the debug-library.  Allow this to be
1295 # extended to all models of the ncurses library:
1296 cf_all_traces=no
1297 case "$CFLAGS $CPPFLAGS" in
1298 *-DTRACE*)
1299         cf_all_traces=yes
1300         ;;
1301 esac
1302
1303 AC_MSG_CHECKING(whether to add trace feature to all models)
1304 AC_ARG_WITH(trace,
1305 [  --with-trace            test: add trace() function to all models of ncurses],
1306 [cf_with_trace=$withval],
1307 [cf_with_trace=$cf_all_traces])
1308 AC_MSG_RESULT($cf_with_trace)
1309
1310 if test "x$cf_with_trace" = xyes ; then
1311         LIB_TRACING=all
1312         ADA_TRACE=TRUE
1313         CF_ADD_CFLAGS(-DTRACE)
1314 else
1315         LIB_TRACING=DEBUG
1316         ADA_TRACE=FALSE
1317 fi
1318
1319 AC_SUBST(ADA_TRACE)
1320
1321 ###     Checks for libraries.
1322 case $cf_cv_system_name in #(vi
1323 *mingw32*) #(vi
1324         ;;
1325 *)
1326 AC_CHECK_FUNC(gettimeofday,
1327         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function]),[
1328
1329 AC_CHECK_LIB(bsd, gettimeofday,
1330         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function])
1331         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1332         ;;
1333 esac
1334
1335 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
1336 AC_SUBST(MATH_LIB)
1337
1338 ###     Checks for header files.
1339 AC_STDC_HEADERS
1340 AC_HEADER_DIRENT
1341 AC_HEADER_TIME
1342 CF_REGEX
1343
1344 dnl These are some other potentially nonportable headers.
1345 AC_CHECK_HEADERS( \
1346 fcntl.h \
1347 getopt.h \
1348 limits.h \
1349 locale.h \
1350 math.h \
1351 poll.h \
1352 sys/bsdtypes.h \
1353 sys/ioctl.h \
1354 sys/param.h \
1355 sys/poll.h \
1356 sys/select.h \
1357 sys/time.h \
1358 sys/times.h \
1359 ttyent.h \
1360 unistd.h \
1361 wctype.h \
1362 )
1363
1364 CF_GETOPT_HEADER
1365
1366 # check for ISC (this may also define _POSIX_SOURCE)
1367 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1368 if test "x$ISC" = xyes ; then
1369         AC_CHECK_LIB(cposix,main)
1370         AC_CHECK_LIB(inet,bzero,CF_ADD_LIB(inet))dnl also 'select()'
1371 fi
1372
1373 CF_SYS_TIME_SELECT
1374
1375 ###     checks for compiler characteristics
1376 AC_LANG_C
1377 AC_C_CONST
1378 CF_C_INLINE(NCURSES_INLINE,1200)
1379 CF_SIG_ATOMIC_T
1380
1381 if test $NCURSES_CHTYPE = auto ; then
1382         CF_TYPEOF_CHTYPE
1383 else
1384         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1385 fi
1386 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1387 AC_SUBST(cf_cv_typeof_chtype)
1388
1389 CF_UNSIGNED_LITERALS
1390 cf_cv_1UL="1"
1391 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1392 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1393 AC_SUBST(cf_cv_1UL)
1394
1395 if test $NCURSES_MMASK_T = auto ; then
1396         cf_cv_typeof_mmask_t=long
1397 else
1398         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1399 fi
1400 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1401 AC_SUBST(cf_cv_typeof_mmask_t)
1402
1403 ###     Checks for external-data
1404 CF_ERRNO
1405 CF_LINK_DATAONLY
1406
1407 ###     Checks for library functions.
1408 AC_CHECK_FUNCS( \
1409 getcwd \
1410 getegid \
1411 geteuid \
1412 getttynam \
1413 issetugid \
1414 poll \
1415 putenv \
1416 remove \
1417 select \
1418 setbuf \
1419 setbuffer \
1420 setenv \
1421 setvbuf \
1422 sigaction \
1423 sigvec \
1424 strdup \
1425 strstr \
1426 tcgetpgrp \
1427 times \
1428 vsnprintf \
1429 )
1430 if test "x$with_getcap" = "xyes" ; then
1431         CF_CGETENT
1432 fi
1433
1434 CF_ISASCII
1435 CF_STRUCT_SIGACTION
1436 CF_FUNC_NANOSLEEP
1437 CF_FUNC_TERMIOS
1438 CF_FUNC_VSSCANF
1439 CF_MKSTEMP
1440
1441 # setup for prototype of fallback for vsscanf()
1442 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1443
1444 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1445 if test "x$cross_compiling" = xyes ; then
1446         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1447 else
1448         AC_FUNC_SETVBUF_REVERSED
1449 fi
1450 AC_CHECK_TYPE(intptr_t, long)
1451 CF_TYPE_SIGACTION
1452 CF_SIZECHANGE
1453 CF_FUNC_MEMMOVE
1454 CF_FUNC_POLL
1455 CF_VA_COPY
1456 AC_FUNC_VFORK
1457
1458 # special check for test/ditto.c
1459 CF_FUNC_OPENPTY
1460 if test "$cf_cv_func_openpty" != no ; then
1461     AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
1462     AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
1463     if test "x$cf_cv_lib_util" = xyes ; then
1464         CF_ADD_LIB(util,TEST_LIBS)
1465     fi
1466 fi
1467 AC_SUBST(TEST_LIBS)
1468 AC_SUBST(TEST_LIBS2)
1469
1470 if test "$with_hashed_db" != no ; then
1471         AC_DEFINE(USE_HASHED_DB,1,[Define to 1 if we should build terminfo in hashed database])
1472         CF_HASHED_DB($with_hashed_db)
1473 fi
1474
1475 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1476 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1477         CF_STRIP_G_OPT(CFLAGS)
1478         CF_STRIP_G_OPT(CXXFLAGS)
1479 fi
1480
1481 # Just in case, check if the C compiler has a bool type.
1482 CF_BOOL_DECL(cf_cv_cc_bool_type)
1483
1484 # Check for C++ compiler characteristics (and ensure that it's there!)
1485 if test -n "$CXX" ; then
1486         AC_LANG_CPLUSPLUS
1487         CF_STDCPP_LIBRARY
1488         CF_PROG_CC_C_O(CXX)
1489
1490         case $GXX_VERSION in
1491         1*|2.[0-6]*)
1492                 cf_cxx_library=yes
1493                 ;;
1494         *-2.7*|2.7*)
1495                 CF_GPP_LIBRARY
1496                 ;;
1497         *)
1498                 cf_cxx_library=no
1499                 ;;
1500         esac
1501
1502         AC_CHECK_HEADERS(typeinfo)
1503         CF_CXX_IOSTREAM_NAMESPACE
1504         CF_BOOL_DECL
1505         CF_BOOL_SIZE
1506         CF_ETIP_DEFINES
1507         CF_CPP_PARAM_INIT
1508         CF_CPP_STATIC_CAST
1509         CF_CXX_AR_FLAGS
1510 else
1511         cf_cxx_library=no
1512         cf_cv_builtin_bool=1
1513
1514         # Just because we are not configuring against C++ right now does not
1515         # mean that a user will not want to use C++.  Some distributors disable
1516         # the C++ portion of this configuration as a shortcut (or just to avoid
1517         # compiling the demo in the c++ directory).  So we need a reasonable
1518         # default for the 'bool' type.
1519         #
1520         # Caveat: since the storage of the bool type is not standardized, it
1521         # may change.
1522
1523         if test "$NCURSES_BOOL" != auto ; then
1524                 cf_cv_type_of_bool=$NCURSES_BOOL
1525                 cf_cv_header_stdbool_h=0
1526         else
1527                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1528                         CF_BOOL_SIZE
1529                 else
1530                         AC_MSG_CHECKING(for fallback type of bool)
1531                         case "$host_cpu" in #(vi
1532                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1533                         *)      cf_cv_type_of_bool=int  ;;
1534                         esac
1535                         AC_MSG_RESULT($cf_cv_type_of_bool)
1536                 fi
1537         fi
1538 fi
1539 AC_SUBST(CXXLIBS)
1540
1541 # If the C compiler did not declare bool, and we did not determine that the C++
1542 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1543 # ncurses library use the same type as C++ bool.  Note that this allows one to
1544 # specify the type of bool in a configure-script option and postpone
1545 # integration with the C++ compiler provided that the types are compatible.
1546 USE_CXX_BOOL=1
1547 if test $cf_cv_cc_bool_type = 1
1548 then
1549         # oops: C has a bool.  Unlikely, but C++ could differ.
1550         USE_CXX_BOOL=0
1551 elif test $cf_cv_builtin_bool = 0
1552 then
1553         # C++ has no bool
1554         USE_CXX_BOOL=0
1555 else
1556         # this is the normal case
1557         USE_CXX_BOOL='defined(__cplusplus)'
1558 fi
1559 AC_SUBST(USE_CXX_BOOL)
1560
1561 CF_HELP_MESSAGE(Ada95 Binding Options:)
1562
1563 dnl If the Ada95 source-tree is present, add that to the build unless it will
1564 dnl not work, or was not requested.
1565 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1566
1567 dnl libtool does not know anything about GNAT, though a change made in 1998
1568 dnl provided for it "someday".  Disable the ada subtree if we are using
1569 dnl libtool -TD 20070714
1570         if test "$cf_with_ada" != "no" ; then
1571                 if test "$with_libtool" != "no"; then
1572                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1573                         cf_with_ada=no
1574                 fi
1575         fi
1576
1577 dnl Check for availability of GNU Ada Translator (GNAT).
1578 dnl At the moment we support no other Ada95 compiler.
1579         if test "$cf_with_ada" != "no" ; then
1580                 CF_PROG_GNAT
1581                 if test "x$cf_cv_prog_gnat_correct" = xyes; then
1582                         CF_ADD_ADAFLAGS(-gnatpn)
1583                         CF_FIXUP_ADAFLAGS
1584
1585                         CF_GNAT_GENERICS
1586                         CF_GNAT_SIGINT
1587                         CF_GNAT_PRAGMA_UNREF
1588                         CF_GNAT_PROJECTS
1589
1590                         CF_WITH_ADA_COMPILER
1591
1592                         cf_ada_package=terminal_interface
1593                         AC_SUBST(cf_ada_package)
1594
1595                         CF_WITH_ADA_INCLUDE
1596                         CF_WITH_ADA_OBJECTS
1597                         CF_WITH_ADA_SHAREDLIB
1598                 fi
1599         fi
1600 else
1601         cf_with_ada=no
1602 fi
1603
1604 # do this "late" to avoid conflict with header-checks
1605 if test "x$with_widec" = xyes ; then
1606         AC_CHECK_SIZEOF(wchar_t)
1607 fi
1608
1609 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1610 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1611 ###
1612 ### ticlib modules may be a separate library, otherwise contained in termlib.
1613 ### termlib modules may be a separate library, otherwise contained in ncurses.
1614 ###
1615 ### The of "+" or " " between the tokens controls the way the script
1616 ### chooses to split module lists into libraries.
1617 ###
1618 ### (see CF_LIB_RULES).
1619 AC_MSG_CHECKING(for library subsets)
1620 LIB_SUBSETS=
1621
1622 if test "x$cf_with_progs" = xyes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1623         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1624         if test "$with_ticlib" != no ; then
1625                 LIB_SUBSETS="${LIB_SUBSETS} "
1626         else
1627                 LIB_SUBSETS="${LIB_SUBSETS}+"
1628         fi
1629 fi
1630
1631 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1632 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1633
1634 if test "$with_termlib" != no ; then
1635         LIB_SUBSETS="${LIB_SUBSETS} "
1636 else
1637         LIB_SUBSETS="${LIB_SUBSETS}+"
1638 fi
1639
1640 LIB_SUBSETS="${LIB_SUBSETS}base"
1641
1642 # Most term-driver calls are to tinfo, but some like init_pair are to the
1643 # base library (so it resides in base).
1644 if test "$with_term_driver" != no ; then
1645         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
1646         case $cf_cv_system_name in #(vi
1647         *mingw32*) #(vi
1648                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1649                 ;;
1650         *) #(vi
1651                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1652                 ;;
1653         esac
1654 fi
1655
1656 test "x$with_widec"     = xyes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1657 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1658
1659 AC_MSG_RESULT($LIB_SUBSETS)
1660
1661 ### Construct the list of include-directories to be generated
1662 CF_INCLUDE_DIRS
1663 CF_ADA_INCLUDE_DIRS
1664
1665 ### Build up pieces for makefile rules
1666 AC_MSG_CHECKING(default library suffix)
1667 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1668 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1669 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1670
1671 AC_MSG_CHECKING(default library-dependency suffix)
1672 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1673 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1674 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1675
1676 AC_MSG_CHECKING(default object directory)
1677 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1678 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1679 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1680
1681 if test "x$cf_with_cxx" = xyes ; then
1682 AC_MSG_CHECKING(c++ library-dependency suffix)
1683 if test "$with_libtool" != "no"; then
1684         # libtool thinks it can make c++ shared libraries (perhaps only g++)
1685         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1686 elif test "$with_shared_cxx" != "no"; then
1687         # also for g++ users...
1688         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1689 else
1690         # we normally make a static library because C/C++ library rules differ
1691         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)
1692 fi
1693 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1694 AC_SUBST(CXX_LIB_SUFFIX)
1695 fi
1696
1697 # do not want -ldl in build except as needed for -lncurses dependency
1698 if test "x$with_dlsym" = xyes ; then
1699 if test $DFT_LWR_MODEL = shared || \
1700    test $DFT_LWR_MODEL = libtool ; then
1701         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1702 fi
1703 fi
1704 ### Set up low-level terminfo dependencies for makefiles.
1705
1706 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1707 # do not need libdl
1708 TICS_LIST=
1709 if test "x$with_dlsym" = xyes ; then
1710         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1711 fi
1712
1713 if test "$with_ticlib" != no ; then
1714
1715         if test "x$with_ticlib" != xyes ; then
1716                 TICS_NAME=$with_ticlib
1717                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1718                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1719                 TICS_LIB_SUFFIX="${with_ticlib}"
1720         else
1721                 TICS_ARG_SUFFIX="${TICS_NAME}${DFT_ARG_SUFFIX}"
1722                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1723                 TICS_LIB_SUFFIX="${TICS_NAME}${LIB_SUFFIX}"
1724         fi
1725         TICS_LDFLAGS="-L${LIB_DIR}"
1726         TICS_LIBS="-l${TICS_LIB_SUFFIX}"
1727 else
1728         TICS_LDFLAGS="-L${LIB_DIR}"
1729         TICS_LIBS="-l${LIB_NAME}${DFT_ARG_SUFFIX}"
1730 fi
1731 AC_SUBST(TICS_ARG_SUFFIX)
1732 AC_SUBST(TICS_DEP_SUFFIX)
1733 AC_SUBST(TICS_LIB_SUFFIX)
1734 AC_SUBST(TICS_LDFLAGS)
1735 AC_SUBST(TICS_LIBS)
1736
1737 if test "$with_termlib" != no ; then
1738
1739         if test "x$with_termlib" != xyes ; then
1740                 TINFO_NAME=$with_termlib
1741                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1742                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1743                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1744                 TINFO_LIB_SUFFIX="${with_termlib}"
1745         else
1746                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1747                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1748                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1749                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1750         fi
1751
1752         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1753         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1754         if test "$DFT_LWR_MODEL" = "libtool"; then
1755                 TEST_ARGS="${TEST_DEPS}"
1756                 TEST_ARG2="${TEST_DEP2}"
1757                 TINFO_LDFLAGS="-L${LIB_DIR}"
1758                 TINFO_LIBS="$TEST_ARGS"
1759                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
1760                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
1761         else
1762                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1763                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1764                 if test "x$with_term_driver" != xno ; then
1765                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1766                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1767                         TINFO_LIBS="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARGS"
1768                 else
1769                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1770                         TINFO_LIBS="$TEST_ARGS"
1771                 fi
1772                 TINFO_LDFLAGS="-L${LIB_DIR}"
1773                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1774         fi
1775 else
1776         # the next lines are needed for linking libtic over libncurses
1777         TINFO_NAME=${LIB_NAME}
1778         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1779         TINFO_ARG_SUFFIX=${LIB_NAME}${DFT_ARG_SUFFIX}
1780         if test "x$with_tic_depends" = xyes ; then
1781                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1782         else
1783                 TICS_LIST="$SHLIB_LIST"
1784         fi
1785
1786         TINFO_LDFLAGS="-L${LIB_DIR}"
1787         TINFO_LIBS="-l${LIB_NAME}${DFT_ARG_SUFFIX}"
1788 fi
1789
1790 if test "$DFT_LWR_MODEL" = shared ; then
1791         case $cf_cv_system_name in #(vi
1792         cygwin*)
1793                 # "lib" files have ".dll.a" suffix, "cyg" files have ".dll"
1794                 TINFO_SUFFIX=.dll
1795                 ;;
1796         esac
1797 fi
1798
1799 AC_SUBST(TINFO_ARG_SUFFIX)
1800 AC_SUBST(TINFO_DEP_SUFFIX)
1801 AC_SUBST(TINFO_LIB_SUFFIX)
1802 AC_SUBST(TINFO_LDFLAGS)
1803 AC_SUBST(TINFO_LIBS)
1804
1805 if test "x$with_dlsym" = xyes ; then
1806         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
1807 fi
1808
1809 if test "$DFT_LWR_MODEL" = "libtool"; then
1810     OBJEXT=lo
1811 fi
1812
1813 # needed for Ada95
1814 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
1815 AC_SUBST(TINFO_LDFLAGS2)
1816
1817 case $DFT_LWR_MODEL in
1818 normal|debug|profile)
1819         CF_LDFLAGS_STATIC
1820         ;;
1821 esac
1822
1823 AC_MSG_CHECKING(where we will install curses.h)
1824 test "$with_overwrite" = no && \
1825 test "x$includedir" = 'x${prefix}/include' && \
1826         includedir='${prefix}/include/ncurses'${LIB_SUFFIX}
1827 AC_MSG_RESULT($includedir)
1828
1829 ### Resolve a conflict between normal and wide-curses by forcing applications
1830 ### that will need libutf8 to add it to their configure script.
1831 if test "$with_overwrite" != no ; then
1832 if test "$NCURSES_LIBUTF8" = 1 ; then
1833         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1834         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1835 fi
1836 fi
1837 WITH_OVERWRITE=$with_overwrite
1838
1839 AC_SUBST(WITH_OVERWRITE)
1840 AC_SUBST(TICS_LIST)
1841 AC_SUBST(TINFO_LIST)
1842 AC_SUBST(SHLIB_LIST)
1843
1844 # used to separate tack out of the tree
1845 NCURSES_TREE=
1846 AC_SUBST(NCURSES_TREE)
1847
1848 ### predefined stuff for the test programs
1849 AC_DEFINE(HAVE_SLK_COLOR,1,[Define to 1 if we have slk_color for test-programs])
1850
1851 ### Construct the list of subdirectories for which we'll customize makefiles
1852 ### with the appropriate compile-rules.
1853
1854 CF_SRC_MODULES($modules_to_build)
1855
1856 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
1857    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${DFT_ARG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
1858    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${DFT_ARG_SUFFIX}-config.1:man/MKada_config.in"
1859 fi
1860
1861 CF_DIRS_TO_MAKE
1862
1863 # symbols that differ when compiling Ada95 by itself.
1864 NCURSES_SHLIB2='sh $(top_srcdir)/misc/shlib'
1865 AC_SUBST(NCURSES_SHLIB2)
1866
1867 # values to use as strings
1868 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as library path-separator])
1869
1870 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}",[Define to 1 if machine has ample memory for tic])
1871
1872 ### Now that we're done running tests, add the compiler-warnings, if any
1873 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1874
1875 ### Define substitutions for header files to avoid name-pollution
1876 CF_SUBST_IF(["x$cf_cv_have_tcgetattr" = xyes], HAVE_TCGETATTR, 1, 0)
1877 CF_SUBST_IF(["x$ac_cv_header_termio_h" = xyes], HAVE_TERMIO_H, 1, 0)
1878 CF_SUBST_IF(["x$ac_cv_header_termios_h" = xyes], HAVE_TERMIOS_H, 1, 0)
1879
1880 ################################################################################
1881 test "x$use_database" = xyes && \
1882 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1883
1884 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1885 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${DFT_ARG_SUFFIX}${cf_cv_abi_version}-config.1:man/MKncu_config.in"
1886
1887 if test "x$enable_pc_files" = xyes ; then \
1888 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
1889 MAKE_PC_FILES=
1890 else
1891 MAKE_PC_FILES="#"
1892 fi
1893 AC_SUBST(MAKE_PC_FILES)
1894 AC_SUBST(cross_compiling)
1895
1896 AC_PATH_PROG(TIC_PATH,tic,unknown,$PATH:/usr/local/ncurses/bin)
1897 if test -n "$FALLBACK_LIST"
1898 then
1899         if test "$TIC_PATH" = unknown
1900         then
1901                 AC_MSG_WARN(no tic program found for fallbacks)
1902         fi
1903 fi
1904 AC_SUBST(TIC_PATH)
1905
1906 if test "x$cf_with_tests" != xno ; then
1907         MAKE_TESTS=
1908 else
1909         MAKE_TESTS="#"
1910 fi
1911 AC_SUBST(MAKE_TESTS)
1912
1913 ADAHTML_DIR=../../doc/html/ada
1914 AC_SUBST(ADAHTML_DIR)
1915
1916 # these could be configurable, but are not currently
1917 PANEL_NAME=panel
1918 MENU_NAME=menu
1919 FORM_NAME=form
1920 CXX_NAME=ncurses++
1921
1922 AC_SUBST(PANEL_NAME)
1923 AC_SUBST(MENU_NAME)
1924 AC_SUBST(FORM_NAME)
1925 AC_SUBST(CXX_NAME)
1926
1927 SUB_SCRIPTS=
1928
1929 AC_OUTPUT( \
1930         include/MKterm.h.awk \
1931         include/curses.head:include/curses.h.in \
1932         include/ncurses_dll.h \
1933         include/termcap.h \
1934         include/unctrl.h \
1935         $SUB_SCRIPTS \
1936         $SUB_MAKEFILES \
1937         Makefile,[
1938 if test "x$cf_with_tests" != xno ; then
1939         CF_PRG_RULES([$srcdir/test/mk-test.awk INSTALL=no ECHO_LINK="$ECHO_LD"], test)
1940 fi
1941 CF_LIB_RULES($SRC_SUBDIRS)
1942
1943 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
1944 if test -z "$USE_OLD_MAKERULES" ; then
1945         $AWK -f $srcdir/Ada95/mk-1st.awk <$srcdir/Ada95/src/modules >>Ada95/src/Makefile
1946 fi
1947 fi
1948 ],[
1949 ### Special initialization commands, used to pass information from the
1950 ### configuration-run into config.status
1951
1952 AWK="$AWK"
1953 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
1954 DFT_LWR_MODEL="$DFT_LWR_MODEL"
1955 ECHO_LD="$ECHO_LD"
1956 LDCONFIG="$LDCONFIG"
1957 LIBTOOL_VERSION="$LIBTOOL_VERSION"
1958 LIB_NAME="$LIB_NAME"
1959 LIB_PREFIX="$LIB_PREFIX"
1960 LIB_SUBSETS="$LIB_SUBSETS"
1961 LIB_SUFFIX="$LIB_SUFFIX"
1962 LIB_TRACING="$LIB_TRACING"
1963 LN_S="$LN_S"
1964 MAKE_TERMINFO="$MAKE_TERMINFO"
1965 NCURSES_MAJOR="$NCURSES_MAJOR"
1966 NCURSES_MINOR="$NCURSES_MINOR"
1967 NCURSES_OSPEED="$NCURSES_OSPEED"
1968 NCURSES_PATCH="$NCURSES_PATCH"
1969 SRC_SUBDIRS="$SRC_SUBDIRS"
1970 TERMINFO="$TERMINFO"
1971 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
1972 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
1973 TICS_NAME="$TICS_NAME"
1974 TIC_PATH="$TIC_PATH"
1975 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
1976 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
1977 TINFO_NAME="$TINFO_NAME"
1978 TINFO_SUFFIX="$TINFO_SUFFIX"
1979 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
1980 WITH_CURSES_H="$with_curses_h"
1981 WITH_ECHO="${enable_echo:=yes}"
1982 WITH_OVERWRITE="$with_overwrite"
1983 cf_LIST_MODELS="$cf_list_models"
1984 cf_cv_abi_version="$cf_cv_abi_version"
1985 cf_cv_do_relink="$cf_cv_do_relink"
1986 cf_cv_do_symlinks="$cf_cv_do_symlinks"
1987 cf_cv_enable_lp64="$cf_cv_enable_lp64"
1988 cf_cv_enable_opaque="$cf_cv_enable_opaque"
1989 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
1990 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
1991 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
1992 cf_cv_rel_version="$cf_cv_rel_version"
1993 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
1994 cf_cv_shared_soname='$cf_cv_shared_soname'
1995 cf_cv_shlib_version="$cf_cv_shlib_version"
1996 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
1997 cf_cv_system_name="$cf_cv_system_name"
1998 cf_cv_term_driver="$with_term_driver"
1999 cf_with_ada="$cf_with_ada"
2000 cf_with_cxx_binding="$cf_with_cxx_binding"
2001 cf_with_manpages="$cf_with_manpages"
2002 cf_with_tests="$cf_with_tests"
2003 with_shared_cxx="$with_shared_cxx"
2004 host="$host"
2005 target="$target"
2006
2007 ],cat)dnl
2008 ${MAKE:-make} preinstall