fe9f518493e1df759b778e3c7dc40a708248158f
[ncurses.git] / configure.in
1 dnl***************************************************************************
2 dnl Copyright (c) 1998-2011,2012 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey 1995-on
30 dnl
31 dnl $Id: configure.in,v 1.562 2013/01/26 20:59:15 tom Exp $
32 dnl Process this file with autoconf to produce a configure script.
33 dnl
34 dnl See http://invisible-island.net/autoconf/ for additional information.
35 dnl
36 dnl ---------------------------------------------------------------------------
37 AC_PREREQ(2.52.20030208)
38 AC_REVISION($Revision: 1.562 $)
39 AC_INIT(ncurses/base/lib_initscr.c)
40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
41
42 CF_TOP_BUILDDIR
43 CF_SUBST_NCURSES_VERSION
44
45 CF_WITH_REL_VERSION(NCURSES)
46 CF_WITH_ABI_VERSION
47
48 CF_WITH_SYSTYPE
49
50 ###     Save the given $CFLAGS to allow user-override.
51 cf_user_CFLAGS="$CFLAGS"
52
53 ###     Default install-location
54 CF_CFG_DEFAULTS
55
56 ###     Checks for programs.
57 AC_ARG_WITH(ada,
58         [  --without-ada           suppress check for Ada95, don't build demo],
59         [cf_with_ada=$withval],
60         [cf_with_ada=yes])
61 if test "x$cf_with_ada" = xyes
62 then
63         cf_PROG_CC="gnatgcc gcc cc"
64 else
65         cf_PROG_CC="gcc cc"
66 fi
67
68 CF_PROG_CC($cf_PROG_CC)
69
70 AC_PROG_CPP
71 AC_PROG_GCC_TRADITIONAL
72 CF_PROG_CC_C_O(CC)
73 CF_PROG_LDCONFIG
74
75 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
76 dnl                             configure script by not letting us test if C++
77 dnl                             is present, making this option necessary.
78 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
79 AC_ARG_WITH(cxx,
80         [  --without-cxx           do not adjust ncurses bool to match C++],
81         [cf_with_cxx=$withval],
82         [cf_with_cxx=yes])
83 AC_MSG_RESULT($cf_with_cxx)
84 if test "X$cf_with_cxx" = Xno ; then
85         CXX=""
86         GXX=""
87 else
88         # with autoconf 2.13, we can change the error to a warning:
89         pushdef([AC_MSG_ERROR],
90                 [AC_MSG_RESULT(no)
91                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
92                 cf_with_cxx=no; CXX=""; GXX="";])dnl
93         AC_PROG_CXX
94         popdef([AC_MSG_ERROR])dnl
95         # autoconf 2.5x removed the error (hardcoding it to g++, or just blank)
96         if test "$CXX" = "g++" ; then
97                 AC_PATH_PROG(CXX,g++)
98         fi
99         case "x$CXX" in #(vi
100         x|xg++)
101                 AC_MSG_WARN([You don't have any C++ compiler, too bad])
102                 cf_with_cxx=no; CXX=""; GXX="";
103                 ;;
104         esac
105 fi
106
107 CF_GXX_VERSION
108 case $GXX_VERSION in
109 1*|2.[[0-6]]*)
110         # GXX=""; CXX=""; ac_cv_prog_gxx=no
111         # cf_cxx_library=no
112         AC_MSG_WARN(templates do not work)
113         ;;
114 esac
115
116 AC_MSG_CHECKING(if you want to build C++ binding and demo)
117 AC_ARG_WITH(cxx-binding,
118         [  --without-cxx-binding   do not build C++ binding and demo],
119         [cf_with_cxx_binding=$withval],
120         [cf_with_cxx_binding=$cf_with_cxx])
121 AC_MSG_RESULT($cf_with_cxx_binding)
122
123 AC_MSG_CHECKING(if you want to build with Ada95)
124 AC_MSG_RESULT($cf_with_ada)
125
126 AC_MSG_CHECKING(if you want to install manpages)
127 AC_ARG_WITH(manpages,
128         [  --without-manpages      suppress install of manpages],
129         [cf_with_manpages=$withval],
130         [cf_with_manpages=yes])
131 AC_MSG_RESULT($cf_with_manpages)
132
133 AC_MSG_CHECKING(if you want to build programs such as tic)
134 AC_ARG_WITH(progs,
135         [  --without-progs         suppress build with programs (e.g., tic)],
136         [cf_with_progs=$withval],
137         [cf_with_progs=yes])
138 AC_MSG_RESULT($cf_with_progs)
139
140 AC_MSG_CHECKING(if you want to build test-programs)
141 AC_ARG_WITH(tests,
142         [  --without-tests         suppress build with test-programs],
143         [cf_with_tests=$withval],
144         [cf_with_tests=yes])
145 AC_MSG_RESULT($cf_with_tests)
146
147 AC_MSG_CHECKING(if you wish to install curses.h)
148 AC_ARG_WITH(curses-h,
149         [  --without-curses-h      install curses.h as ncurses.h only],
150         [with_curses_h=$withval],
151         [with_curses_h=yes])
152 AC_MSG_RESULT($with_curses_h)
153
154 modules_to_build="ncurses"
155 if test "X$cf_with_progs" != Xno ; then
156 modules_to_build="$modules_to_build progs tack"
157 fi
158 modules_to_build="$modules_to_build panel menu form"
159
160 AC_ARG_PROGRAM
161
162 CF_PROG_AWK
163 CF_PROG_EGREP
164 CF_PROG_INSTALL
165 CF_PROG_LINT
166 CF_PROG_LN_S
167
168 AC_SYS_LONG_FILE_NAMES
169
170 # if we find pkg-config, check if we should install the ".pc" files.
171 CF_PKG_CONFIG
172 CF_WITH_PKG_CONFIG_LIBDIR
173 CF_ENABLE_PC_FILES
174
175 AC_MSG_CHECKING(if we should assume mixed-case filenames)
176 AC_ARG_ENABLE(mixed-case,
177         [  --enable-mixed-case     tic should assume mixed-case filenames],
178         [enable_mixedcase=$enableval],
179         [enable_mixedcase=auto])
180 AC_MSG_RESULT($enable_mixedcase)
181 if test "$enable_mixedcase" = "auto" ; then
182     CF_MIXEDCASE_FILENAMES
183 else
184     cf_cv_mixedcase=$enable_mixedcase
185     if test "x$enable_mixedcase" = "xyes" ; then
186         AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if tic should assume mixed-case filenames])
187     fi
188 fi
189
190 # do this after mixed-case option (tags/TAGS is not as important as tic).
191 AC_PROG_MAKE_SET
192 CF_MAKE_TAGS
193 CF_MAKEFLAGS
194
195 dnl These are standard among *NIX systems, but not when cross-compiling
196 AC_CHECK_TOOL(RANLIB, ranlib, ':')
197 AC_CHECK_TOOL(LD, ld, ld)
198 AC_CHECK_TOOL(AR, ar, ar)
199 CF_AR_FLAGS
200
201 dnl Special option for use by system-builders: the install-prefix is used to
202 dnl adjust the location into which the actual install is done, so that an
203 dnl archive can be built without modifying the host system's configuration.
204 AC_MSG_CHECKING(if you have specified an install-prefix)
205 AC_ARG_WITH(install-prefix,
206         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
207         [case "x$withval" in #(vi
208         xyes|xno) #(vi
209                 ;;
210         *)      DESTDIR="$withval"
211                 ;;
212         esac])
213 AC_MSG_RESULT($DESTDIR)
214 AC_SUBST(DESTDIR)
215
216 ###############################################################################
217 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
218 # If we're cross-compiling, allow the user to override the tools and their
219 # options.  The configure script is oriented toward identifying the host
220 # compiler, etc., but we need a build compiler to generate parts of the source.
221 CF_BUILD_CC
222
223 ###############################################################################
224 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
225
226 ### Options to allow the user to specify the set of libraries which are used.
227 ### Use "--without-normal --with-shared" to allow the default model to be
228 ### shared, for example.
229 cf_list_models=""
230 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
231
232 CF_WITH_LIBTOOL
233 if test "$with_libtool" != "no" ; then
234
235 cf_list_models="$cf_list_models libtool"
236
237 else
238
239 AC_MSG_CHECKING(if you want to build shared libraries)
240 AC_ARG_WITH(shared,
241         [  --with-shared           generate shared-libraries],
242         [with_shared=$withval],
243         [with_shared=no])
244 AC_MSG_RESULT($with_shared)
245 test "x$with_shared" = "xyes" && cf_list_models="$cf_list_models shared"
246
247 AC_MSG_CHECKING(if you want to build static libraries)
248 AC_ARG_WITH(normal,
249         [  --with-normal           generate normal-libraries (default)],
250         [with_normal=$withval],
251         [with_normal=yes])
252 AC_MSG_RESULT($with_normal)
253 test "x$with_normal" = "xyes" && cf_list_models="$cf_list_models normal"
254
255 AC_MSG_CHECKING(if you want to build debug libraries)
256 AC_ARG_WITH(debug,
257         [  --with-debug            generate debug-libraries (default)],
258         [with_debug=$withval],
259         [with_debug=yes])
260 AC_MSG_RESULT($with_debug)
261 test "x$with_debug" = "xyes" && cf_list_models="$cf_list_models debug"
262
263 AC_MSG_CHECKING(if you want to build profiling libraries)
264 AC_ARG_WITH(profile,
265         [  --with-profile          generate profile-libraries],
266         [with_profile=$withval],
267         [with_profile=no])
268 AC_MSG_RESULT($with_profile)
269 test "x$with_profile" = "xyes" && cf_list_models="$cf_list_models profile"
270
271 fi
272
273 ###############################################################################
274
275 AC_MSG_CHECKING(for specified models)
276 test -z "$cf_list_models" && cf_list_models=normal
277 dnl If we use libtool to generate libraries, then it must be the only
278 dnl specified model.
279 test "$with_libtool" != "no" && cf_list_models=libtool
280 AC_MSG_RESULT($cf_list_models)
281
282 ### Use the first model as the default, and save its suffix for use in building
283 ### up test-applications.
284 AC_MSG_CHECKING(for default model)
285 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
286 AC_MSG_RESULT($DFT_LWR_MODEL)
287
288 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
289
290 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
291 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
292
293 TICS_NAME=tic
294 AC_SUBST(TICS_NAME)
295
296 TINFO_NAME=tinfo
297 AC_SUBST(TINFO_NAME)
298
299 LIB_NAME=ncurses
300 AC_SUBST(LIB_NAME)
301
302 LIB_DIR=../lib
303 LIB_2ND=../../lib
304
305 CF_WITH_LIB_PREFIX(cf_prefix)
306
307 LIB_SUFFIX=
308 AC_SUBST(LIB_SUFFIX)
309 CF_PATHSEP
310
311 ###############################################################################
312
313 AC_MSG_CHECKING(if you want to build a separate terminfo library)
314 AC_ARG_WITH(termlib,
315         [  --with-termlib          generate separate terminfo library],
316         [with_termlib=$withval],
317         [with_termlib=no])
318 AC_MSG_RESULT($with_termlib)
319
320 AC_MSG_CHECKING(if you want to build a separate tic library)
321 AC_ARG_WITH(ticlib,
322         [  --with-ticlib           generate separate tic library],
323         [with_ticlib=$withval],
324         [with_ticlib=no])
325 AC_MSG_RESULT($with_ticlib)
326
327 ### Checks for special libraries, must be done up-front.
328 SHLIB_LIST=""
329 CF_WITH_GPM
330 if test "$with_gpm" != no ; then
331         AC_MSG_CHECKING(if you want to load GPM dynamically)
332         AC_ARG_WITH(dlsym,
333                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
334                 [with_dlsym=$withval],
335                 [with_dlsym=yes])
336         AC_MSG_RESULT($with_dlsym)
337         if test "x$with_dlsym" = xyes ; then
338                 CF_FUNC_DLSYM
339                 if test "x$with_gpm" != xyes ; then
340                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
341                         cf_cv_gpm_soname="$with_gpm"
342                 else
343                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
344                 fi
345                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname",[Define as needed to set the gpm share library soname])
346                 SHLIB_LIST="-ldl $SHLIB_LIST"
347         else
348                 SHLIB_LIST="-lgpm $SHLIB_LIST"
349                 CF_ADD_LIB(gpm,TEST_LIBS)
350         fi
351         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
352         CF_CHECK_GPM_WGETCH
353 fi
354
355 CF_WITH_SYSMOUSE
356
357 dnl Not all ports of gcc support the -g option
358
359 if test X"$CC_G_OPT" = X"" ; then
360         CC_G_OPT='-g'
361         test -n "$GCC" && test "x${ac_cv_prog_cc_g}" != xyes && CC_G_OPT=''
362 fi
363 AC_SUBST(CC_G_OPT)
364
365 if test X"$CXX_G_OPT" = X"" ; then
366         CXX_G_OPT='-g'
367         test -n "$GXX" && test "x${ac_cv_prog_cxx_g}" != xyes && CXX_G_OPT=''
368 fi
369 AC_SUBST(CXX_G_OPT)
370
371 AC_MSG_CHECKING(for default loader flags)
372 case $DFT_LWR_MODEL in
373 libtool) LD_MODEL=''   ;;
374 normal)  LD_MODEL=''   ;;
375 debug)   LD_MODEL=$CC_G_OPT ;;
376 profile) LD_MODEL='-pg';;
377 shared)  LD_MODEL=''   ;;
378 esac
379 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
380 AC_MSG_RESULT($LD_MODEL)
381
382 case $DFT_LWR_MODEL in
383 shared)
384 CF_ENABLE_RPATH
385 AC_MSG_CHECKING(if shared libraries should be relinked during install)
386 AC_ARG_ENABLE(relink,
387 [  --disable-relink        relink shared libraries during install],
388 [cf_cv_do_relink=$enableval],
389 [cf_cv_do_relink=yes])
390 AC_MSG_RESULT($cf_cv_do_relink)
391         ;;
392 esac
393
394 CF_SHARED_OPTS
395 if test "$CC_SHARED_OPTS" = "unknown"; then
396         for model in $cf_list_models; do
397                 if test "$model" = "shared"; then
398                         AC_ERROR(Shared libraries are not supported in this version)
399                 fi
400         done
401 fi
402
403 ### If we're building with rpath, try to link non-standard libs that way too.
404 if test "$DFT_LWR_MODEL" = "shared"; then
405         CF_DISABLE_RPATH_HACK
406 fi
407
408 ###############################################################################
409 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
410
411 ###     use option --disable-overwrite to leave out the link to -lcurses
412 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
413 AC_ARG_ENABLE(overwrite,
414         [  --disable-overwrite     leave out the link to -lcurses],
415         [with_overwrite=$enableval],
416         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
417 AC_MSG_RESULT($with_overwrite)
418
419 AC_MSG_CHECKING(if external terminfo-database is used)
420 AC_ARG_ENABLE(database,
421         [  --disable-database      do not use terminfo, only fallbacks/termcap],
422         [use_database=$enableval],
423         [use_database=yes])
424 AC_MSG_RESULT($use_database)
425
426 case $host_os in #(vi
427 os2*) #(vi
428         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
429         ;;
430 *) #(vi
431         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
432         ;;
433 esac
434 AC_SUBST(TERMINFO_SRC)
435
436 if test "$use_database" != no ; then
437         AC_DEFINE(USE_DATABASE,1,[Define to 1 if we should use the terminal database])
438
439         AC_MSG_CHECKING(which terminfo source-file will be installed)
440         AC_ARG_WITH(database,
441                 [  --with-database=XXX     specify terminfo source to install],
442                 [TERMINFO_SRC=$withval])
443         AC_MSG_RESULT($TERMINFO_SRC)
444
445         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
446         AC_ARG_WITH(hashed-db,
447                 [  --with-hashed-db        specify hashed-database library],,
448                 [with_hashed_db=no])
449         AC_MSG_RESULT($with_hashed_db)
450 else
451         with_hashed_db=no
452 fi
453
454 AC_MSG_CHECKING(for list of fallback descriptions)
455 AC_ARG_WITH(fallbacks,
456         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
457         [with_fallback=$withval],
458         [with_fallback=])
459 AC_MSG_RESULT($with_fallback)
460 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
461 AC_SUBST(FALLBACK_LIST)
462
463 AC_MSG_CHECKING(if you want modern xterm or antique)
464 AC_ARG_WITH(xterm-new,
465         [  --without-xterm-new     specify if xterm terminfo should be old version],
466         [with_xterm_new=$withval],
467         [with_xterm_new=yes])
468 case $with_xterm_new in
469 no)     with_xterm_new=xterm-old;;
470 *)      with_xterm_new=xterm-new;;
471 esac
472 AC_MSG_RESULT($with_xterm_new)
473 WHICH_XTERM=$with_xterm_new
474 AC_SUBST(WHICH_XTERM)
475
476 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
477 AC_ARG_WITH(xterm-kbs,
478         [  --with-xterm-kbs=XXX    specify if xterm backspace sends BS or DEL],
479         [with_xterm_kbs=$withval],
480         [with_xterm_kbs=BS])
481 case x$with_xterm_kbs in
482 xyes|xno|xBS|xbs|x8)
483         with_xterm_kbs=BS
484         ;;
485 xDEL|xdel|x127)
486         with_xterm_kbs=DEL
487         ;;
488 *)
489         with_xterm_kbs=$withval
490         ;;
491 esac
492 AC_MSG_RESULT($with_xterm_kbs)
493 XTERM_KBS=$with_xterm_kbs
494 AC_SUBST(XTERM_KBS)
495
496 MAKE_TERMINFO=
497 if test "$use_database" = no ; then
498         TERMINFO="${datadir}/terminfo"
499         MAKE_TERMINFO="#"
500 else
501
502 AC_MSG_CHECKING(for list of terminfo directories)
503 CF_WITH_PATHLIST(terminfo-dirs,
504         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
505         TERMINFO_DIRS,
506         DATADIR/terminfo,
507         ${datadir}/terminfo)
508 AC_MSG_RESULT($TERMINFO_DIRS)
509 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS",[Define as needed to predefine the TERMINFO_DIR searchlist])
510
511 AC_MSG_CHECKING(for default terminfo directory)
512 CF_WITH_PATH(default-terminfo-dir,
513         [  --with-default-terminfo-dir=DIR default terminfo directory],
514         TERMINFO,
515         DATADIR/terminfo,
516         ${datadir}/terminfo)
517 AC_MSG_RESULT($TERMINFO)
518 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO",[Define to set the default terminal database path])
519
520 fi
521
522 AC_SUBST(TERMINFO)
523 AC_SUBST(MAKE_TERMINFO)
524
525 ###     use option --disable-big-core to make tic run on small machines
526 ###     We need 4Mb, check if we can allocate 50% more than that.
527 AC_MSG_CHECKING(if big-core option selected)
528 AC_ARG_ENABLE(big-core,
529         [  --disable-big-core      assume machine has little memory],
530         [with_big_core=$enableval],
531         [AC_TRY_RUN([
532 #include <stdlib.h>
533 #include <string.h>
534 int main() {
535         unsigned long n = 6000000L;
536         char *s = malloc(n);
537         if (s != 0)
538                 s[0] = s[n-1] = 0;
539         ${cf_cv_main_return:-return}(s == 0);
540 }],
541         [with_big_core=yes],
542         [with_big_core=no],
543         [with_big_core=no])])
544 AC_MSG_RESULT($with_big_core)
545 test "x$with_big_core" = "xyes" && AC_DEFINE(HAVE_BIG_CORE,1,[Define to 1 if machine has ample memory for tic])
546
547 ### ISO C only guarantees 512-char strings, we have tables which load faster
548 ### when constructed using "big" strings.  More than the C compiler, the awk
549 ### program is a limit on most vendor UNIX systems.  Check that we can build.
550 AC_MSG_CHECKING(if big-strings option selected)
551 AC_ARG_ENABLE(big-strings,
552         [  --disable-big-strings   assume compiler has only standard-size strings],
553         [with_big_strings=$enableval],
554         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
555 AC_MSG_RESULT($with_big_strings)
556
557 USE_BIG_STRINGS=0
558 test "x$with_big_strings" = "xyes" && USE_BIG_STRINGS=1
559 AC_SUBST(USE_BIG_STRINGS)
560
561 ###     use option --enable-termcap to compile in the termcap fallback support
562 AC_MSG_CHECKING(if you want termcap-fallback support)
563 AC_ARG_ENABLE(termcap,
564         [  --enable-termcap        compile in termcap fallback support],
565         [with_termcap=$enableval],
566         [with_termcap=no])
567 AC_MSG_RESULT($with_termcap)
568
569 if test "x$with_termcap" != "xyes" ; then
570         if test "$use_database" = no ; then
571                 if test -z "$with_fallback" ; then
572                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
573                 fi
574         fi
575         AC_DEFINE(PURE_TERMINFO,1,[Define to 1 if we should support only terminfo])
576 else
577
578 if test "$with_ticlib" != no ; then
579         AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
580 fi
581
582 AC_DEFINE(USE_TERMCAP,1,[Define to 1 if we should support termcap])
583 AC_MSG_CHECKING(for list of termcap files)
584 CF_WITH_PATHLIST(termpath,
585         [  --with-termpath=XXX     specify list of termcap files],
586         TERMPATH,
587         /etc/termcap:/usr/share/misc/termcap)
588 AC_MSG_RESULT($TERMPATH)
589 test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH",[Define to set the termcap searchlist])
590
591 ###     use option --enable-getcap to use a hacked getcap for reading termcaps
592 AC_MSG_CHECKING(if fast termcap-loader is needed)
593 AC_ARG_ENABLE(getcap,
594         [  --enable-getcap         fast termcap load, no xrefs to terminfo],
595         [with_getcap=$enableval],
596         [with_getcap=no])
597 AC_MSG_RESULT($with_getcap)
598 test "x$with_getcap" = "xyes" && AC_DEFINE(USE_GETCAP,1,[Define to 1 to use fast termcap-loader])
599
600 AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
601 AC_ARG_ENABLE(getcap-cache,
602         [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
603         [with_getcap_cache=$enableval],
604         [with_getcap_cache=no])
605 AC_MSG_RESULT($with_getcap_cache)
606 test "x$with_getcap_cache" = "xyes" && AC_DEFINE(USE_GETCAP_CACHE,1,[Define to 1 if translated termcap should be stored in $HOME/.terminfo])
607
608 fi
609
610 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
611 AC_MSG_CHECKING(if ~/.terminfo is wanted)
612 AC_ARG_ENABLE(home-terminfo,
613         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
614         [with_home_terminfo=$enableval],
615         [with_home_terminfo=yes])
616 AC_MSG_RESULT($with_home_terminfo)
617 test "x$with_home_terminfo" = "xyes" && AC_DEFINE(USE_HOME_TERMINFO,1,[Define to 1 if $HOME/.terminfo feature is wanted])
618
619 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
620 AC_ARG_ENABLE(root-environ,
621         [  --disable-root-environ  restrict environment when running as root],
622         [with_root_environ=$enableval],
623         [with_root_environ=yes])
624 AC_MSG_RESULT($with_root_environ)
625 test "x$with_root_environ" = xyes && AC_DEFINE(USE_ROOT_ENVIRON,1,[Define to 1 if environment should be restricted for root user])
626
627 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
628 ###   to reduce storage requirements for the terminfo database.
629 CF_LINK_FUNCS
630
631 with_links=no
632 with_symlinks=no
633
634 # soft links (symbolic links) are useful for some systems where hard links do
635 # not work, or to make it simpler to copy terminfo trees around.
636 if test "x$ac_cv_func_symlink" = xyes ; then
637     AC_MSG_CHECKING(if tic should use symbolic links)
638     AC_ARG_ENABLE(symlinks,
639         [  --enable-symlinks       make tic use symbolic links not hard links],
640         [with_symlinks=$enableval],
641         [with_symlinks=no])
642     AC_MSG_RESULT($with_symlinks)
643 fi
644
645 # If we have hard links and did not choose to use soft links instead, there is
646 # no reason to make this choice optional - use the hard links.
647 if test "$with_symlinks" = no ; then
648     AC_MSG_CHECKING(if tic should use hard links)
649     if test "x$ac_cv_func_link" = xyes ; then
650         with_links=yes
651     else
652         with_links=no
653     fi
654     AC_MSG_RESULT($with_links)
655 fi
656
657 test "x$with_links" = xyes && AC_DEFINE(USE_LINKS,1,[Define to 1 if hardlinks should be used in terminfo database])
658 test "x$with_symlinks" = xyes && AC_DEFINE(USE_SYMLINKS,1,[Define to 1 if symbolic links should be used in terminfo database])
659
660 ###   use option --enable-broken-linker to force on use of broken-linker support
661 AC_MSG_CHECKING(if you want broken-linker support code)
662 AC_ARG_ENABLE(broken_linker,
663         [  --enable-broken_linker  compile with broken-linker support code],
664         [with_broken_linker=$enableval],
665         [with_broken_linker=${BROKEN_LINKER:-no}])
666 AC_MSG_RESULT($with_broken_linker)
667
668 BROKEN_LINKER=0
669 if test "x$with_broken_linker" = xyes ; then
670         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
671         BROKEN_LINKER=1
672 elif test "$DFT_LWR_MODEL" = shared ; then
673         case $cf_cv_system_name in #(vi
674         cygwin*)
675                 AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
676                 BROKEN_LINKER=1
677                 CF_VERBOSE(cygwin linker is broken anyway)
678                 ;;
679         esac
680 fi
681 AC_SUBST(BROKEN_LINKER)
682
683 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
684 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
685 AC_ARG_ENABLE(bsdpad,
686         [  --enable-bsdpad         recognize BSD-style prefix padding],
687         [with_bsdpad=$enableval],
688         [with_bsdpad=no])
689 AC_MSG_RESULT($with_bsdpad)
690 test "x$with_bsdpad" = xyes && AC_DEFINE(BSD_TPUTS,1,[Define to 1 to recognize BSD-style prefix padding])
691
692 ###   use option --enable-widec to turn on use of wide-character support
693 NCURSES_CH_T=chtype
694 NCURSES_LIBUTF8=0
695
696 NEED_WCHAR_H=0
697 NCURSES_MBSTATE_T=0
698 NCURSES_WCHAR_T=0
699 NCURSES_WINT_T=0
700
701 # Check to define _XOPEN_SOURCE "automatically"
702 CF_XOPEN_SOURCE(500)
703
704 # Work around breakage on OS X
705 CF_SIGWINCH
706
707 # Checks for CODESET support.
708 AM_LANGINFO_CODESET
709
710 # use these variables to work around a defect in gcc's fixincludes.
711 NCURSES_OK_WCHAR_T=
712 NCURSES_OK_WINT_T=
713
714 AC_MSG_CHECKING(if you want wide-character code)
715 AC_ARG_ENABLE(widec,
716         [  --enable-widec          compile with wide-char/UTF-8 code],
717         [with_widec=$enableval],
718         [with_widec=no])
719 AC_MSG_RESULT($with_widec)
720 if test "x$with_widec" = xyes ; then
721         LIB_SUFFIX="w${LIB_SUFFIX}"
722         AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to compile with wide-char/UTF-8 code])
723         AC_DEFINE(NCURSES_WIDECHAR,1,[Define to 1 to compile with wide-char/UTF-8 code])
724
725         CF_CHECK_WCHAR_H
726
727         # with_overwrite=no
728         NCURSES_CH_T=cchar_t
729         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
730         if test "x$ac_cv_func_putwc" != xyes ; then
731                 CF_UTF8_LIB
732                 if test "$cf_cv_utf8_lib" != no ; then
733                         NCURSES_LIBUTF8=1
734                 fi
735         fi
736         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
737         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
738         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
739
740         if test "$NCURSES_MBSTATE_T" != 0; then
741                 AC_DEFINE(NEED_MBSTATE_T_DEF,1,[Define to 1 if we must declare mbstate_t])
742         fi
743 fi
744 AC_SUBST(NCURSES_CH_T)
745 AC_SUBST(NCURSES_LIBUTF8)
746
747 AC_SUBST(NEED_WCHAR_H)
748 AC_SUBST(NCURSES_MBSTATE_T)
749 AC_SUBST(NCURSES_WCHAR_T)
750 AC_SUBST(NCURSES_WINT_T)
751
752 AC_SUBST(NCURSES_OK_WCHAR_T)
753 AC_SUBST(NCURSES_OK_WINT_T)
754
755 ###   use option --disable-lp64 to allow long chtype
756 case $cf_cv_abi_version in
757 [[345]]*)
758         default_with_lp64=no
759         ;;
760 *)
761         default_with_lp64=yes
762         ;;
763 esac
764
765 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
766 AC_ARG_ENABLE(lp64,
767         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
768         [with_lp64=$enableval],
769         [with_lp64=$default_with_lp64])
770 AC_MSG_RESULT($with_lp64)
771
772 if test "x$with_lp64" = xyes ; then
773         cf_cv_enable_lp64=1
774 else
775         cf_cv_enable_lp64=0
776 fi
777 AC_SUBST(cf_cv_enable_lp64)
778
779 CF_LARGEFILE
780
781 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
782 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
783 AC_ARG_ENABLE(tparm-varargs,
784         [  --disable-tparm-varargs compile tparm() without varargs interface],
785         [with_tparm_varargs=$enableval],
786         [with_tparm_varargs=yes])
787 AC_MSG_RESULT($with_tparm_varargs)
788 NCURSES_TPARM_VARARGS=0
789 test "x$with_tparm_varargs" = xyes && NCURSES_TPARM_VARARGS=1
790 AC_SUBST(NCURSES_TPARM_VARARGS)
791
792 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
793 if test "$with_ticlib" != no ; then
794 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
795 AC_ARG_ENABLE(tic-depends,
796         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
797         [with_tic_depends=$enableval],
798         [with_tic_depends=yes])
799 AC_MSG_RESULT($with_tic_depends)
800 else
801         with_tic_depends=no
802 fi
803
804 ###   use option --with-bool to override bool's type
805 AC_MSG_CHECKING(for type of bool)
806 AC_ARG_WITH(bool,
807         [  --with-bool=TYPE        override fallback type of bool variable],
808         [NCURSES_BOOL="$withval"],
809         [NCURSES_BOOL=auto])
810 AC_MSG_RESULT($NCURSES_BOOL)
811 AC_SUBST(NCURSES_BOOL)
812
813 AC_MSG_CHECKING(for alternate terminal capabilities file)
814 AC_ARG_WITH(caps,
815         [  --with-caps=alt         compile with alternate Caps file],
816         [TERMINFO_CAPS=Caps.$withval],
817         [TERMINFO_CAPS=Caps])
818 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
819 AC_MSG_RESULT($TERMINFO_CAPS)
820 AC_SUBST(TERMINFO_CAPS)
821
822 ###   use option --with-chtype to override chtype's type
823 AC_MSG_CHECKING(for type of chtype)
824 AC_ARG_WITH(chtype,
825         [  --with-chtype=TYPE      override type of chtype],
826         [NCURSES_CHTYPE="$withval"],
827         [NCURSES_CHTYPE=auto])
828 AC_MSG_RESULT($NCURSES_CHTYPE)
829
830 ###   use option --with-ospeed to override ospeed's type
831 AC_MSG_CHECKING(for type of ospeed)
832 AC_ARG_WITH(ospeed,
833         [  --with-ospeed=TYPE      override type of ospeed variable],
834         [NCURSES_OSPEED="$withval"],
835         [NCURSES_OSPEED=short])
836 AC_MSG_RESULT($NCURSES_OSPEED)
837 AC_SUBST(NCURSES_OSPEED)
838
839 ###   use option --with-mmask-t to override mmask_t's type
840 AC_MSG_CHECKING(for type of mmask_t)
841 AC_ARG_WITH(mmask-t,
842         [  --with-mmask-t=TYPE     override type of mmask_t],
843         [NCURSES_MMASK_T="$withval"],
844         [NCURSES_MMASK_T=auto])
845 AC_MSG_RESULT($NCURSES_MMASK_T)
846
847 ###   use option --with-ccharw-max to override CCHARW_MAX size
848 AC_MSG_CHECKING(for size CCHARW_MAX)
849 AC_ARG_WITH(ccharw-max,
850         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
851         [NCURSES_CCHARW_MAX="$withval"],
852         [NCURSES_CCHARW_MAX=5])
853 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
854 AC_SUBST(NCURSES_CCHARW_MAX)
855
856 ###   use option --with-tparm-arg to override tparm's argument type
857 AC_MSG_CHECKING(for type of tparm args)
858 AC_ARG_WITH(tparm-arg,
859         [  --with-tparm-arg=TYPE   override parameter type of tparm],
860         [NCURSES_TPARM_ARG="$withval"],
861         [NCURSES_TPARM_ARG=long])
862 AC_MSG_RESULT($NCURSES_TPARM_ARG)
863 AC_SUBST(NCURSES_TPARM_ARG)
864
865 ### Enable compiling-in rcs id's
866 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
867 AC_ARG_WITH(rcs-ids,
868         [  --with-rcs-ids          compile-in RCS identifiers],
869         [with_rcs_ids=$withval],
870         [with_rcs_ids=no])
871 AC_MSG_RESULT($with_rcs_ids)
872 test "x$with_rcs_ids" = xyes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 to compile-in RCS identifiers])
873
874 ###############################################################################
875 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tabs tic toe tput tset ])
876
877 ###############################################################################
878 CF_HELP_MESSAGE(Extensions:)
879
880 ### Note that some functions (such as const) are normally disabled anyway.
881 AC_MSG_CHECKING(if you want to build with function extensions)
882 AC_ARG_ENABLE(ext-funcs,
883         [  --disable-ext-funcs     disable function-extensions],
884         [with_ext_funcs=$enableval],
885         [with_ext_funcs=yes])
886 AC_MSG_RESULT($with_ext_funcs)
887 if test "x$with_ext_funcs" = xyes ; then
888         NCURSES_EXT_FUNCS=1
889         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS,1,[Define to 1 to enable assume_default_colors() function])
890         AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 to enable curses_version() function])
891         AC_DEFINE(HAVE_HAS_KEY,1,[Define to 1 to enable has_key() function])
892         AC_DEFINE(HAVE_RESIZETERM,1,[Define to 1 to enable resizeterm() function])
893         AC_DEFINE(HAVE_RESIZE_TERM,1,[Define to 1 to enable resize_term() function])
894         AC_DEFINE(HAVE_TERM_ENTRY_H,1,[Define to 1 to enable term_entry() function])
895         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 to enable use_default_colors() function])
896         AC_DEFINE(HAVE_USE_SCREEN,1,[Define to 1 to enable use_screen() function])
897         AC_DEFINE(HAVE_USE_WINDOW,1,[Define to 1 to enable use_window() function])
898         AC_DEFINE(HAVE_WRESIZE,1,[Define to 1 to enable wresize() function])
899         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 to enable ncurses extended functions])
900         GENERATED_EXT_FUNCS=generated
901 else
902         NCURSES_EXT_FUNCS=0
903         GENERATED_EXT_FUNCS=
904 fi
905 AC_SUBST(NCURSES_EXT_FUNCS)
906 AC_SUBST(GENERATED_EXT_FUNCS)
907
908 AC_MSG_CHECKING(if you want to build with experimental SCREEN extensions)
909 AC_ARG_ENABLE(sp-funcs,
910         [  --enable-sp-funcs       enable experimental SCREEN-extensions],
911         [with_sp_funcs=$enableval],
912         [with_sp_funcs=no])
913 AC_MSG_RESULT($with_sp_funcs)
914 if test "x$with_sp_funcs" = xyes ; then
915         NCURSES_SP_FUNCS=1
916         AC_DEFINE(NCURSES_SP_FUNCS,1,[Define to 1 to enable experimental SCREEN-extensions])
917         GENERATED_SP_FUNCS=generated
918 else
919         NCURSES_SP_FUNCS=0
920         GENERATED_SP_FUNCS=
921 fi
922 AC_SUBST(NCURSES_SP_FUNCS)
923 AC_SUBST(GENERATED_SP_FUNCS)
924
925 AC_MSG_CHECKING(if you want to build with experimental terminal-driver)
926 AC_ARG_ENABLE(term-driver,
927         [  --enable-term-driver    enable experimental terminal-driver],
928         [with_term_driver=$enableval],
929         [with_term_driver=no])
930 AC_MSG_RESULT($with_term_driver)
931 if test "x$with_term_driver" = xyes ; then
932         AC_DEFINE(USE_TERM_DRIVER,1,[Define to 1 to enable experimental terminal-driver])
933         if test "x$with_sp_funcs" != xyes ; then
934                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
935         fi
936 fi
937
938 ###   use option --enable-const to turn on use of const beyond that in XSI.
939 AC_MSG_CHECKING(for extended use of const keyword)
940 AC_ARG_ENABLE(const,
941         [  --enable-const          compile with extra/non-standard const],
942         [with_ext_const=$enableval],
943         [with_ext_const=no])
944 AC_MSG_RESULT($with_ext_const)
945 NCURSES_CONST='/*nothing*/'
946 if test "x$with_ext_const" = xyes ; then
947         NCURSES_CONST=const
948 fi
949 AC_SUBST(NCURSES_CONST)
950
951 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
952 AC_MSG_CHECKING(if you want to use extended colors)
953 AC_ARG_ENABLE(ext-colors,
954         [  --enable-ext-colors     compile for 256-color support],
955         [with_ext_colors=$enableval],
956         [with_ext_colors=no])
957 AC_MSG_RESULT($with_ext_colors)
958 NCURSES_EXT_COLORS=0
959 if test "x$with_ext_colors" = xyes ; then
960         if test "x$with_widec" != xyes ; then
961                 AC_MSG_ERROR(This option applies only to wide-character library)
962         else
963                 # cannot be ABI 5 since it changes sizeof(cchar_t)
964                 CF_NCURSES_ABI_6
965         fi
966         NCURSES_EXT_COLORS=1
967         AC_DEFINE(NCURSES_EXT_COLORS,1,[Define to 1 to compile for 256-color support])
968 fi
969 AC_SUBST(NCURSES_EXT_COLORS)
970
971 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
972 AC_MSG_CHECKING(if you want to use extended mouse encoding)
973 AC_ARG_ENABLE(ext-mouse,
974         [  --enable-ext-mouse      compile for extended mouse-encoding],
975         [with_ext_mouse=$enableval],
976         [with_ext_mouse=no])
977 AC_MSG_RESULT($with_ext_mouse)
978 NCURSES_MOUSE_VERSION=1
979 if test "x$with_ext_mouse" = xyes ; then
980         NCURSES_MOUSE_VERSION=2
981         CF_NCURSES_ABI_6
982 fi
983 AC_SUBST(NCURSES_MOUSE_VERSION)
984
985 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
986 AC_ARG_ENABLE(no-padding,
987         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
988         [with_no_padding=$enableval],
989         [with_no_padding=$with_ext_funcs])
990 AC_MSG_RESULT($with_no_padding)
991 test "x$with_no_padding" = xyes && AC_DEFINE(NCURSES_NO_PADDING,1,[Define to 1 to compile with $NCURSES_NO_PADDING code])
992
993 AC_CHECK_SIZEOF([signed char], 0)
994 if test "$ac_cv_sizeof_signed_char" = 1 ; then
995         NCURSES_SBOOL="signed char"
996 else
997         NCURSES_SBOOL="char"
998 fi
999 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
1000 AC_ARG_ENABLE(signed-char,
1001         [  --enable-signed-char    compile using signed Boolean's in term.h],
1002         [with_signed_char=$enableval],
1003         [with_signed_char=no])
1004 AC_MSG_RESULT($with_signed_char)
1005 test "x$with_signed_char" != xyes && NCURSES_SBOOL="char"
1006 AC_SUBST(NCURSES_SBOOL)
1007
1008 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1009 AC_MSG_CHECKING(if you want SIGWINCH handler)
1010 AC_ARG_ENABLE(sigwinch,
1011         [  --enable-sigwinch       compile with SIGWINCH handler],
1012         [with_sigwinch=$enableval],
1013         [with_sigwinch=$with_ext_funcs])
1014 AC_MSG_RESULT($with_sigwinch)
1015 test "x$with_sigwinch" = xyes && AC_DEFINE(USE_SIGWINCH,1,[Define to 1 to compile with SIGWINCH handler])
1016
1017 ###   use option --enable-tcap-names to allow user to define new capabilities
1018 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1019 AC_ARG_ENABLE(tcap-names,
1020         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1021         [with_tcap_names=$enableval],
1022         [with_tcap_names=$with_ext_funcs])
1023 AC_MSG_RESULT($with_tcap_names)
1024 NCURSES_XNAMES=0
1025 test "x$with_tcap_names" = xyes && NCURSES_XNAMES=1
1026 AC_SUBST(NCURSES_XNAMES)
1027
1028 ###############################################################################
1029 # These options are relatively safe to experiment with.
1030 CF_HELP_MESSAGE(Development Code:)
1031 AC_MSG_CHECKING(if you want all development code)
1032 AC_ARG_WITH(develop,
1033         [  --without-develop       disable development options],
1034         [with_develop=$withval],
1035         [with_develop=no])
1036 AC_MSG_RESULT($with_develop)
1037
1038 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1039 AC_MSG_CHECKING(if you want hard-tabs code)
1040 AC_ARG_ENABLE(hard-tabs,
1041         [  --enable-hard-tabs      compile with hard-tabs code],,
1042         [enable_hard_tabs=$with_develop])
1043 AC_MSG_RESULT($enable_hard_tabs)
1044 test "x$enable_hard_tabs" = xyes && AC_DEFINE(USE_HARD_TABS,1,[Define to 1 to compile with hard-tabs code])
1045
1046 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1047 AC_MSG_CHECKING(if you want limited support for xmc)
1048 AC_ARG_ENABLE(xmc-glitch,
1049         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1050         [enable_xmc_glitch=$with_develop])
1051 AC_MSG_RESULT($enable_xmc_glitch)
1052 test "x$enable_xmc_glitch" = xyes && AC_DEFINE(USE_XMC_SUPPORT,1,[Define to 1 to compile with support for xmc (magic-cookie)])
1053
1054 ###############################################################################
1055 # These are just experimental, probably should not be in a package:
1056 CF_HELP_MESSAGE(Experimental Code:)
1057
1058 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1059 AC_ARG_ENABLE(assumed-color,
1060         [  --disable-assumed-color do not assume anything about default-colors],
1061         [with_assumed_color=$enableval],
1062         [with_assumed_color=yes])
1063 AC_MSG_RESULT($with_assumed_color)
1064 test "x$with_assumed_color" = xyes && AC_DEFINE(USE_ASSUMED_COLOR,1,[Define to 1 to assume things about default-colors])
1065
1066 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1067 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1068 AC_ARG_ENABLE(hashmap,
1069         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1070         [with_hashmap=$enableval],
1071         [with_hashmap=yes])
1072 AC_MSG_RESULT($with_hashmap)
1073 test "x$with_hashmap" = xyes && AC_DEFINE(USE_HASHMAP,1,[Define to 1 to compile with hashmap scrolling-optimization])
1074
1075 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1076 AC_MSG_CHECKING(if you want colorfgbg code)
1077 AC_ARG_ENABLE(colorfgbg,
1078         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1079         [with_colorfgbg=$enableval],
1080         [with_colorfgbg=no])
1081 AC_MSG_RESULT($with_colorfgbg)
1082 test "x$with_colorfgbg" = xyes && AC_DEFINE(USE_COLORFGBG,1,[Define to 1 to compile-in experimental $COLORFGBG code])
1083
1084 ###   use option --enable-interop to turn on use of bindings used for interop
1085 AC_MSG_CHECKING(if you want interop bindings)
1086 AC_ARG_ENABLE(interop,
1087         [  --enable-interop        compile-in experimental interop bindings],
1088         [with_exp_interop=$enableval],
1089         [with_exp_interop=no])
1090 AC_MSG_RESULT($with_exp_interop)
1091
1092 NCURSES_INTEROP_FUNCS=0
1093 test "x$with_exp_interop" = xyes && NCURSES_INTEROP_FUNCS=1
1094 AC_SUBST(NCURSES_INTEROP_FUNCS)
1095
1096 # This is still experimental (20080329), but should ultimately be moved to
1097 # the script-block --with-normal, etc.
1098 CF_WITH_PTHREAD
1099
1100 if test "x$with_pthread" != xno; then
1101         AC_CHECK_FUNC(pthread_kill,[
1102                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1103                 AC_ARG_ENABLE(pthreads-eintr,
1104                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1105                         [use_pthreads_eintr=$enableval],
1106                         [use_pthreads_eintr=no])
1107                 AC_MSG_RESULT($use_pthreads_eintr)
1108                 if test "x$use_pthreads_eintr" = xyes ; then
1109                         AC_DEFINE(USE_PTHREADS_EINTR,1,[Define to 1 to enable EINTR in wgetch with pthreads])
1110                 fi])
1111
1112         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1113         AC_ARG_ENABLE(weak-symbols,
1114                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1115                 [use_weak_symbols=$enableval],
1116                 [use_weak_symbols=no])
1117         AC_MSG_RESULT($use_weak_symbols)
1118         if test "x$use_weak_symbols" = xyes ; then
1119                 CF_WEAK_SYMBOLS
1120         else
1121                 cf_cv_weak_symbols=no
1122         fi
1123
1124         if test "x$cf_cv_weak_symbols" = xyes ; then
1125                 AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
1126         fi
1127 fi
1128
1129 PTHREAD=
1130 if test "x$with_pthread" = "xyes" ; then
1131     AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use pthreads feature])
1132     enable_reentrant=yes
1133     if test "x$cf_cv_weak_symbols" = xyes ; then
1134         PTHREAD=-lpthread
1135     fi
1136 fi
1137 AC_SUBST(PTHREAD)
1138
1139 # Reentrant code has to be opaque; there's little advantage to making ncurses
1140 # opaque outside of that, so there is no --enable-opaque option.  We can use
1141 # this option without --with-pthreads, but this will be always set for
1142 # pthreads.
1143 AC_MSG_CHECKING(if you want experimental reentrant code)
1144 AC_ARG_ENABLE(reentrant,
1145         [  --enable-reentrant      compile with experimental reentrant code],
1146         [with_reentrant=$enableval],
1147         [with_reentrant=no])
1148 AC_MSG_RESULT($with_reentrant)
1149 if test "x$with_reentrant" = xyes ; then
1150         cf_cv_enable_reentrant=1
1151         cf_cv_enable_opaque="NCURSES_INTERNALS"
1152         NCURSES_OPAQUE=1
1153         NCURSES_SIZE_T=int
1154         if test "x$cf_cv_weak_symbols" = xyes ; then
1155                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1156                 CF_ADD_LIB(pthread,TEST_LIBS)
1157                 CF_ADD_LIB(pthread,TEST_LIBS2)
1158         else
1159                 LIB_SUFFIX="t${LIB_SUFFIX}"
1160         fi
1161         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to use experimental reentrant feature])
1162         CF_NCURSES_ABI_6
1163 else
1164         cf_cv_enable_reentrant=0
1165         cf_cv_enable_opaque="NCURSES_OPAQUE"
1166         NCURSES_OPAQUE=0
1167         NCURSES_SIZE_T=short
1168 fi
1169 AC_SUBST(cf_cv_enable_reentrant)
1170 AC_SUBST(cf_cv_enable_opaque)
1171 AC_SUBST(NCURSES_OPAQUE)
1172 AC_SUBST(NCURSES_SIZE_T)
1173
1174 ### Allow using a different wrap-prefix
1175 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1176         AC_MSG_CHECKING(for prefix used to wrap public variables)
1177         AC_ARG_WITH(wrap-prefix,
1178                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1179                 [NCURSES_WRAP_PREFIX=$withval],
1180                 [NCURSES_WRAP_PREFIX=_nc_])
1181         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1182 else
1183         NCURSES_WRAP_PREFIX=_nc_
1184 fi
1185 AC_SUBST(NCURSES_WRAP_PREFIX)
1186 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ prefix])
1187
1188 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1189 AC_ARG_ENABLE(safe-sprintf,
1190         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1191         [with_safe_sprintf=$enableval],
1192         [with_safe_sprintf=no])
1193 AC_MSG_RESULT($with_safe_sprintf)
1194 test "x$with_safe_sprintf" = xyes && AC_DEFINE(USE_SAFE_SPRINTF,1,[Define to 1 to compile with experimental safe-sprintf code])
1195
1196 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1197 # when hashmap is used scroll hints are useless
1198 if test "$with_hashmap" = no ; then
1199 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1200 AC_ARG_ENABLE(scroll-hints,
1201         [  --disable-scroll-hints  compile without scroll-hints code],
1202         [with_scroll_hints=$enableval],
1203         [with_scroll_hints=yes])
1204 AC_MSG_RESULT($with_scroll_hints)
1205 test "x$with_scroll_hints" = xyes && AC_DEFINE(USE_SCROLL_HINTS,1,[Define to 1 to compile without scroll-hints code])
1206 fi
1207
1208 AC_MSG_CHECKING(if you want experimental wgetch-events code)
1209 AC_ARG_ENABLE(wgetch-events,
1210         [  --enable-wgetch-events  compile with experimental wgetch-events code],
1211         [with_wgetch_events=$enableval],
1212         [with_wgetch_events=no])
1213 AC_MSG_RESULT($with_wgetch_events)
1214 test "x$with_wgetch_events" = xyes && AC_DEFINE(NCURSES_WGETCH_EVENTS,1,[Define to 1 to compile with experimental wgetch-events code])
1215
1216 ###############################################################################
1217 CF_HELP_MESSAGE(Testing/development Options:)
1218
1219 ###     use option --disable-echo to suppress full display compiling commands
1220 CF_DISABLE_ECHO
1221 if test "x$enable_echo" = xyes; then
1222         ECHO_LINK=
1223 else
1224         ECHO_LINK='@ echo linking $@ ... ;'
1225         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1226         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1227 fi
1228 AC_SUBST(ECHO_LINK)
1229
1230 ###     use option --enable-warnings to turn on all gcc warnings
1231 AC_MSG_CHECKING(if you want to see compiler warnings)
1232 AC_ARG_ENABLE(warnings,
1233         [  --enable-warnings       build: turn on GCC compiler warnings],
1234         [with_warnings=$enableval])
1235 AC_MSG_RESULT($with_warnings)
1236
1237 if test "x$with_warnings" = "xyes"; then
1238         CF_ADD_ADAFLAGS(-gnatg)
1239         CF_GCC_WARNINGS(Wdeclaration-after-statement Wextra Wno-unknown-pragmas Wswitch-enum)
1240         if test "x$cf_with_cxx" = xyes ; then
1241                 CF_GXX_WARNINGS(Wno-unused)
1242         fi
1243 fi
1244 CF_GCC_ATTRIBUTES
1245 CF_ENABLE_STRING_HACKS
1246
1247 ###     use option --enable-assertions to turn on generation of assertion code
1248 AC_MSG_CHECKING(if you want to enable runtime assertions)
1249 AC_ARG_ENABLE(assertions,
1250         [  --enable-assertions     test: turn on generation of assertion code],
1251         [with_assertions=$enableval],
1252         [with_assertions=no])
1253 AC_MSG_RESULT($with_assertions)
1254 if test -n "$GCC"
1255 then
1256         if test "$with_assertions" = no
1257         then
1258                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1259         else
1260                 CF_ADD_ADAFLAGS(-gnata)
1261         fi
1262 fi
1263
1264 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1265 CF_DISABLE_LEAKS
1266 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
1267
1268 ###     use option --enable-expanded to generate certain macros as functions
1269 AC_ARG_ENABLE(expanded,
1270         [  --enable-expanded       test: generate functions for certain macros],
1271         [test "x$enableval" = xyes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 to generate functions for certain macros])])
1272
1273 ###     use option --disable-macros to suppress macros in favor of functions
1274 AC_ARG_ENABLE(macros,
1275         [  --disable-macros        test: use functions rather than macros],
1276         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 to use functions rather than macros])])
1277
1278 # Normally we only add trace() to the debug-library.  Allow this to be
1279 # extended to all models of the ncurses library:
1280 cf_all_traces=no
1281 case "$CFLAGS $CPPFLAGS" in
1282 *-DTRACE*)
1283         cf_all_traces=yes
1284         ;;
1285 esac
1286
1287 AC_MSG_CHECKING(whether to add trace feature to all models)
1288 AC_ARG_WITH(trace,
1289 [  --with-trace            test: add trace() function to all models of ncurses],
1290 [cf_with_trace=$withval],
1291 [cf_with_trace=$cf_all_traces])
1292 AC_MSG_RESULT($cf_with_trace)
1293
1294 if test "x$cf_with_trace" = xyes ; then
1295         LIB_TRACING=all
1296         ADA_TRACE=TRUE
1297         CF_ADD_CFLAGS(-DTRACE)
1298 else
1299         LIB_TRACING=DEBUG
1300         ADA_TRACE=FALSE
1301 fi
1302
1303 AC_SUBST(ADA_TRACE)
1304
1305 ###     Checks for libraries.
1306 case $cf_cv_system_name in #(vi
1307 *mingw32*) #(vi
1308         ;;
1309 *)
1310 AC_CHECK_FUNC(gettimeofday,
1311         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function]),[
1312
1313 AC_CHECK_LIB(bsd, gettimeofday,
1314         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function])
1315         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1316         ;;
1317 esac
1318
1319 CF_MATH_LIB(MATH_LIB,sin(x))
1320 AC_SUBST(MATH_LIB)
1321
1322 ###     Checks for header files.
1323 AC_STDC_HEADERS
1324 AC_HEADER_DIRENT
1325 AC_HEADER_TIME
1326 CF_REGEX
1327
1328 dnl These are some other potentially nonportable headers.
1329 AC_CHECK_HEADERS( \
1330 fcntl.h \
1331 getopt.h \
1332 limits.h \
1333 locale.h \
1334 math.h \
1335 poll.h \
1336 sys/bsdtypes.h \
1337 sys/ioctl.h \
1338 sys/param.h \
1339 sys/poll.h \
1340 sys/select.h \
1341 sys/time.h \
1342 sys/times.h \
1343 ttyent.h \
1344 unistd.h \
1345 wctype.h \
1346 )
1347
1348 CF_GETOPT_HEADER
1349
1350 # check for ISC (this may also define _POSIX_SOURCE)
1351 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1352 if test "x$ISC" = xyes ; then
1353         AC_CHECK_LIB(cposix,main)
1354         AC_CHECK_LIB(inet,bzero,CF_ADD_LIB(inet))dnl also 'select()'
1355 fi
1356
1357 CF_SYS_TIME_SELECT
1358
1359 ###     checks for compiler characteristics
1360 AC_LANG_C
1361 AC_C_CONST
1362 CF_C_INLINE(NCURSES_INLINE,1200)
1363 CF_SIG_ATOMIC_T
1364
1365 if test $NCURSES_CHTYPE = auto ; then
1366         CF_TYPEOF_CHTYPE
1367 else
1368         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1369 fi
1370 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1371 AC_SUBST(cf_cv_typeof_chtype)
1372
1373 CF_UNSIGNED_LITERALS
1374 cf_cv_1UL="1"
1375 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1376 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1377 AC_SUBST(cf_cv_1UL)
1378
1379 if test $NCURSES_MMASK_T = auto ; then
1380         cf_cv_typeof_mmask_t=long
1381 else
1382         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1383 fi
1384 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1385 AC_SUBST(cf_cv_typeof_mmask_t)
1386
1387 ###     Checks for external-data
1388 CF_ERRNO
1389 CF_LINK_DATAONLY
1390
1391 ###     Checks for library functions.
1392 AC_CHECK_FUNCS( \
1393 getcwd \
1394 getegid \
1395 geteuid \
1396 getttynam \
1397 issetugid \
1398 poll \
1399 putenv \
1400 remove \
1401 select \
1402 setbuf \
1403 setbuffer \
1404 setenv \
1405 setvbuf \
1406 sigaction \
1407 sigvec \
1408 strdup \
1409 strstr \
1410 tcgetpgrp \
1411 times \
1412 vsnprintf \
1413 )
1414 if test "x$with_getcap" = "xyes" ; then
1415         CF_CGETENT
1416 fi
1417
1418 CF_ISASCII
1419 CF_STRUCT_SIGACTION
1420 CF_FUNC_NANOSLEEP
1421 CF_FUNC_TERMIOS
1422 CF_FUNC_VSSCANF
1423 CF_MKSTEMP
1424
1425 # setup for prototype of fallback for vsscanf()
1426 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1427
1428 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1429 if test "x$cross_compiling" = xyes ; then
1430         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1431 else
1432         AC_FUNC_SETVBUF_REVERSED
1433 fi
1434 AC_TYPE_SIGNAL
1435 AC_CHECK_TYPE(intptr_t, long)
1436 CF_TYPE_SIGACTION
1437 CF_SIZECHANGE
1438 CF_FUNC_MEMMOVE
1439 CF_FUNC_POLL
1440 CF_VA_COPY
1441 AC_FUNC_VFORK
1442
1443 # special check for test/ditto.c
1444 CF_FUNC_OPENPTY
1445 if test "$cf_cv_func_openpty" != no ; then
1446     AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
1447     AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
1448     if test "x$cf_cv_lib_util" = xyes ; then
1449         CF_ADD_LIB(util,TEST_LIBS)
1450     fi
1451 fi
1452 AC_SUBST(TEST_LIBS)
1453 AC_SUBST(TEST_LIBS2)
1454
1455 if test "$with_hashed_db" != no ; then
1456         AC_DEFINE(USE_HASHED_DB,1,[Define to 1 if we should build terminfo in hashed database])
1457         CF_HASHED_DB($with_hashed_db)
1458 fi
1459
1460 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1461 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1462         CF_STRIP_G_OPT(CFLAGS)
1463         CF_STRIP_G_OPT(CXXFLAGS)
1464 fi
1465
1466 # Just in case, check if the C compiler has a bool type.
1467 CF_BOOL_DECL(cf_cv_cc_bool_type)
1468
1469 # Check for C++ compiler characteristics (and ensure that it's there!)
1470 if test -n "$CXX" ; then
1471         AC_LANG_CPLUSPLUS
1472         CF_STDCPP_LIBRARY
1473         CF_PROG_CC_C_O(CXX)
1474
1475         case $GXX_VERSION in
1476         1*|2.[0-6]*)
1477                 cf_cxx_library=yes
1478                 ;;
1479         *-2.7*|2.7*)
1480                 CF_GPP_LIBRARY
1481                 ;;
1482         *)
1483                 cf_cxx_library=no
1484                 ;;
1485         esac
1486
1487         AC_CHECK_HEADERS(typeinfo)
1488         CF_CXX_IOSTREAM_NAMESPACE
1489         CF_BOOL_DECL
1490         CF_BOOL_SIZE
1491         CF_ETIP_DEFINES
1492         CF_CPP_PARAM_INIT
1493         CF_CPP_STATIC_CAST
1494         CF_CXX_AR_FLAGS
1495 else
1496         cf_cxx_library=no
1497         cf_cv_builtin_bool=1
1498
1499         # Just because we are not configuring against C++ right now does not
1500         # mean that a user will not want to use C++.  Some distributors disable
1501         # the C++ portion of this configuration as a shortcut (or just to avoid
1502         # compiling the demo in the c++ directory).  So we need a reasonable
1503         # default for the 'bool' type.
1504         #
1505         # Caveat: since the storage of the bool type is not standardized, it
1506         # may change.
1507
1508         if test "$NCURSES_BOOL" != auto ; then
1509                 cf_cv_type_of_bool=$NCURSES_BOOL
1510                 cf_cv_header_stdbool_h=0
1511         else
1512                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1513                         CF_BOOL_SIZE
1514                 else
1515                         AC_MSG_CHECKING(for fallback type of bool)
1516                         case "$host_cpu" in #(vi
1517                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1518                         *)      cf_cv_type_of_bool=int  ;;
1519                         esac
1520                         AC_MSG_RESULT($cf_cv_type_of_bool)
1521                 fi
1522         fi
1523 fi
1524 AC_SUBST(CXXLIBS)
1525
1526 # If the C compiler did not declare bool, and we did not determine that the C++
1527 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1528 # ncurses library use the same type as C++ bool.  Note that this allows one to
1529 # specify the type of bool in a configure-script option and postpone
1530 # integration with the C++ compiler provided that the types are compatible.
1531 USE_CXX_BOOL=1
1532 if test $cf_cv_cc_bool_type = 1
1533 then
1534         # oops: C has a bool.  Unlikely, but C++ could differ.
1535         USE_CXX_BOOL=0
1536 elif test $cf_cv_builtin_bool = 0
1537 then
1538         # C++ has no bool
1539         USE_CXX_BOOL=0
1540 else
1541         # this is the normal case
1542         USE_CXX_BOOL='defined(__cplusplus)'
1543 fi
1544 AC_SUBST(USE_CXX_BOOL)
1545
1546 CF_HELP_MESSAGE(Ada95 Binding Options:)
1547
1548 dnl If the Ada95 source-tree is present, add that to the build unless it will
1549 dnl not work, or was not requested.
1550 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1551
1552 dnl libtool does not know anything about GNAT, though a change made in 1998
1553 dnl provided for it "someday".  Disable the ada subtree if we are using
1554 dnl libtool -TD 20070714
1555         if test "$cf_with_ada" != "no" ; then
1556                 if test "$with_libtool" != "no"; then
1557                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1558                         cf_with_ada=no
1559                 fi
1560         fi
1561
1562 dnl Check for availability of GNU Ada Translator (GNAT).
1563 dnl At the moment we support no other Ada95 compiler.
1564         if test "$cf_with_ada" != "no" ; then
1565                 CF_PROG_GNAT
1566                 if test "x$cf_cv_prog_gnat_correct" = xyes; then
1567                         CF_ADD_ADAFLAGS(-gnatpn)
1568                         CF_FIXUP_ADAFLAGS
1569
1570                         CF_GNAT_GENERICS
1571                         CF_GNAT_SIGINT
1572                         CF_GNAT_PRAGMA_UNREF
1573                         CF_GNAT_PROJECTS
1574
1575                         CF_WITH_ADA_COMPILER
1576
1577                         cf_ada_package=terminal_interface
1578                         AC_SUBST(cf_ada_package)
1579
1580                         CF_WITH_ADA_INCLUDE
1581                         CF_WITH_ADA_OBJECTS
1582                         CF_WITH_ADA_SHAREDLIB
1583                 fi
1584         fi
1585 else
1586         cf_with_ada=no
1587 fi
1588
1589 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1590 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1591 ###
1592 ### ticlib modules may be a separate library, otherwise contained in termlib.
1593 ### termlib modules may be a separate library, otherwise contained in ncurses.
1594 ###
1595 ### The of "+" or " " between the tokens controls the way the script
1596 ### chooses to split module lists into libraries.
1597 ###
1598 ### (see CF_LIB_RULES).
1599 AC_MSG_CHECKING(for library subsets)
1600 LIB_SUBSETS=
1601
1602 if test "x$cf_with_progs" = xyes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1603         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1604         if test "$with_ticlib" != no ; then
1605                 LIB_SUBSETS="${LIB_SUBSETS} "
1606         else
1607                 LIB_SUBSETS="${LIB_SUBSETS}+"
1608         fi
1609 fi
1610
1611 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1612 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1613
1614 if test "$with_termlib" != no ; then
1615         LIB_SUBSETS="${LIB_SUBSETS} "
1616 else
1617         LIB_SUBSETS="${LIB_SUBSETS}+"
1618 fi
1619
1620 LIB_SUBSETS="${LIB_SUBSETS}base"
1621
1622 # Most term-driver calls are to tinfo, but some like init_pair are to the
1623 # base library (so it resides in base).
1624 if test "$with_term_driver" != no ; then
1625         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
1626         case $cf_cv_system_name in #(vi
1627         *mingw32*) #(vi
1628                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1629                 ;;
1630         *) #(vi
1631                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1632                 ;;
1633         esac
1634 fi
1635
1636 test "x$with_widec"     = xyes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1637 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1638
1639 AC_MSG_RESULT($LIB_SUBSETS)
1640
1641 ### Construct the list of include-directories to be generated
1642 CF_INCLUDE_DIRS
1643 CF_ADA_INCLUDE_DIRS
1644
1645 ### Build up pieces for makefile rules
1646 AC_MSG_CHECKING(default library suffix)
1647 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1648 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1649 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1650
1651 AC_MSG_CHECKING(default library-dependency suffix)
1652 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1653 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1654 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1655
1656 AC_MSG_CHECKING(default object directory)
1657 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1658 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1659 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1660
1661 # libtool thinks it can make c++ shared libraries (perhaps only g++)
1662 if test "x$cf_with_cxx" = xyes ; then
1663 AC_MSG_CHECKING(c++ library-dependency suffix)
1664 if test "$with_libtool" != "no"; then
1665         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1666 else
1667         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)dnl we normally make a static library
1668 fi
1669 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1670 AC_SUBST(CXX_LIB_SUFFIX)
1671 fi
1672
1673 # do not want -ldl in build except as needed for -lncurses dependency
1674 if test "x$with_dlsym" = xyes ; then
1675 if test $DFT_LWR_MODEL = shared || \
1676    test $DFT_LWR_MODEL = libtool ; then
1677         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1678 fi
1679 fi
1680 ### Set up low-level terminfo dependencies for makefiles.
1681
1682 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1683 # do not need libdl
1684 TICS_LIST=
1685 if test "x$with_dlsym" = xyes ; then
1686         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1687 fi
1688
1689 if test "$with_ticlib" != no ; then
1690
1691         if test "x$with_ticlib" != xyes ; then
1692                 TICS_NAME=$with_ticlib
1693                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1694                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1695                 TICS_LIB_SUFFIX="${with_ticlib}"
1696         else
1697                 TICS_ARG_SUFFIX="${TICS_NAME}${DFT_ARG_SUFFIX}"
1698                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1699                 TICS_LIB_SUFFIX="${TICS_NAME}${LIB_SUFFIX}"
1700         fi
1701         TICS_LDFLAGS="-L${LIB_DIR}"
1702         TICS_LIBS="-l${TICS_LIB_SUFFIX}"
1703 else
1704         TICS_LDFLAGS="-L${LIB_DIR}"
1705         TICS_LIBS="-l${LIB_NAME}${DFT_ARG_SUFFIX}"
1706 fi
1707 AC_SUBST(TICS_ARG_SUFFIX)
1708 AC_SUBST(TICS_DEP_SUFFIX)
1709 AC_SUBST(TICS_LIB_SUFFIX)
1710 AC_SUBST(TICS_LDFLAGS)
1711 AC_SUBST(TICS_LIBS)
1712
1713 if test "$with_termlib" != no ; then
1714
1715         if test "x$with_termlib" != xyes ; then
1716                 TINFO_NAME=$with_termlib
1717                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1718                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1719                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1720                 TINFO_LIB_SUFFIX="${with_termlib}"
1721         else
1722                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1723                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1724                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1725                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1726         fi
1727
1728         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1729         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1730         if test "$DFT_LWR_MODEL" = "libtool"; then
1731                 TEST_ARGS="${TEST_DEPS}"
1732                 TEST_ARG2="${TEST_DEP2}"
1733                 TINFO_LDFLAGS="-L${LIB_DIR}"
1734                 TINFO_LIBS="$TEST_ARGS"
1735                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
1736                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
1737         else
1738                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1739                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1740                 if test "x$with_term_driver" != xno ; then
1741                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1742                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1743                         TINFO_LIBS="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARGS"
1744                 else
1745                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1746                         TINFO_LIBS="$TEST_ARGS"
1747                 fi
1748                 TINFO_LDFLAGS="-L${LIB_DIR}"
1749                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1750         fi
1751 else
1752         # the next lines are needed for linking libtic over libncurses
1753         TINFO_NAME=${LIB_NAME}
1754         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1755         TINFO_ARG_SUFFIX=${LIB_NAME}${DFT_ARG_SUFFIX}
1756         if test "x$with_tic_depends" = xyes ; then
1757                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1758         else
1759                 TICS_LIST="$SHLIB_LIST"
1760         fi
1761
1762         TINFO_LDFLAGS="-L${LIB_DIR}"
1763         TINFO_LIBS="-l${LIB_NAME}${DFT_ARG_SUFFIX}"
1764 fi
1765
1766 if test "$DFT_LWR_MODEL" = shared ; then
1767         case $cf_cv_system_name in #(vi
1768         cygwin*)
1769                 # "lib" files have ".dll.a" suffix, "cyg" files have ".dll"
1770                 TINFO_SUFFIX=.dll
1771                 ;;
1772         esac
1773 fi
1774
1775 AC_SUBST(TINFO_ARG_SUFFIX)
1776 AC_SUBST(TINFO_DEP_SUFFIX)
1777 AC_SUBST(TINFO_LIB_SUFFIX)
1778 AC_SUBST(TINFO_LDFLAGS)
1779 AC_SUBST(TINFO_LIBS)
1780
1781 if test "x$with_dlsym" = xyes ; then
1782         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
1783 fi
1784
1785 if test "$DFT_LWR_MODEL" = "libtool"; then
1786     OBJEXT=lo
1787 fi
1788
1789 # needed for Ada95
1790 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
1791 AC_SUBST(TINFO_LDFLAGS2)
1792
1793 case $DFT_LWR_MODEL in
1794 normal|debug|profile)
1795         CF_LDFLAGS_STATIC
1796         ;;
1797 esac
1798
1799 AC_MSG_CHECKING(where we will install curses.h)
1800 test "$with_overwrite" = no && \
1801 test "x$includedir" = 'x${prefix}/include' && \
1802         includedir='${prefix}/include/ncurses'${LIB_SUFFIX}
1803 AC_MSG_RESULT($includedir)
1804
1805 ### Resolve a conflict between normal and wide-curses by forcing applications
1806 ### that will need libutf8 to add it to their configure script.
1807 if test "$with_overwrite" != no ; then
1808 if test "$NCURSES_LIBUTF8" = 1 ; then
1809         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1810         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1811 fi
1812 fi
1813 WITH_OVERWRITE=$with_overwrite
1814
1815 AC_SUBST(WITH_OVERWRITE)
1816 AC_SUBST(TICS_LIST)
1817 AC_SUBST(TINFO_LIST)
1818 AC_SUBST(SHLIB_LIST)
1819
1820 # used to separate tack out of the tree
1821 NCURSES_TREE=
1822 AC_SUBST(NCURSES_TREE)
1823
1824 ### predefined stuff for the test programs
1825 AC_DEFINE(HAVE_SLK_COLOR,1,[Define to 1 if we have slk_color for test-programs])
1826
1827 ### Construct the list of subdirectories for which we'll customize makefiles
1828 ### with the appropriate compile-rules.
1829
1830 CF_SRC_MODULES($modules_to_build)
1831
1832 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
1833    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${DFT_ARG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
1834    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${DFT_ARG_SUFFIX}-config.1:man/MKada_config.in"
1835 fi
1836
1837 CF_DIRS_TO_MAKE
1838
1839 # symbols that differ when compiling Ada95 by itself.
1840 NCURSES_SHLIB2='sh $(top_srcdir)/misc/shlib'
1841 AC_SUBST(NCURSES_SHLIB2)
1842
1843 # values to use as strings
1844 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as library path-separator])
1845
1846 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}",[Define to 1 if machine has ample memory for tic])
1847
1848 ### Now that we're done running tests, add the compiler-warnings, if any
1849 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1850
1851 ### Define substitutions for header files to avoid name-pollution
1852 CF_SUBST_IF(["x$cf_cv_have_tcgetattr" = xyes], HAVE_TCGETATTR, 1, 0)
1853 CF_SUBST_IF(["x$ac_cv_header_termio_h" = xyes], HAVE_TERMIO_H, 1, 0)
1854 CF_SUBST_IF(["x$ac_cv_header_termios_h" = xyes], HAVE_TERMIOS_H, 1, 0)
1855
1856 ################################################################################
1857 test "x$use_database" = xyes && \
1858 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1859
1860 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1861 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${DFT_ARG_SUFFIX}${cf_cv_abi_version}-config.1:man/MKncu_config.in"
1862
1863 if test "x$enable_pc_files" = xyes ; then \
1864 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
1865 MAKE_PC_FILES=
1866 else
1867 MAKE_PC_FILES="#"
1868 fi
1869 AC_SUBST(MAKE_PC_FILES)
1870 AC_SUBST(cross_compiling)
1871
1872 AC_PATH_PROG(TIC_PATH,tic,unknown,$PATH:/usr/local/ncurses/bin)
1873 if test -n "$FALLBACK_LIST"
1874 then
1875         if test "$TIC_PATH" = unknown
1876         then
1877                 AC_MSG_WARN(no tic program found for fallbacks)
1878         fi
1879 fi
1880 AC_SUBST(TIC_PATH)
1881
1882 if test "x$cf_with_tests" != xno ; then
1883         MAKE_TESTS=
1884 else
1885         MAKE_TESTS="#"
1886 fi
1887 AC_SUBST(MAKE_TESTS)
1888
1889 ADAHTML_DIR=../../doc/html/ada
1890 AC_SUBST(ADAHTML_DIR)
1891
1892 SUB_SCRIPTS=
1893
1894 AC_OUTPUT( \
1895         include/MKterm.h.awk \
1896         include/curses.head:include/curses.h.in \
1897         include/ncurses_dll.h \
1898         include/termcap.h \
1899         include/unctrl.h \
1900         $SUB_SCRIPTS \
1901         $SUB_MAKEFILES \
1902         Makefile,[
1903 if test "x$cf_with_tests" != xno ; then
1904         CF_PRG_RULES([$srcdir/test/mk-test.awk INSTALL=no ECHO_LINK="$ECHO_LD"], test)
1905 fi
1906 CF_LIB_RULES($SRC_SUBDIRS)
1907
1908 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
1909 if test -z "$USE_OLD_MAKERULES" ; then
1910         $AWK -f $srcdir/Ada95/mk-1st.awk <$srcdir/Ada95/src/modules >>Ada95/src/Makefile
1911 fi
1912 fi
1913 ],[
1914 ### Special initialization commands, used to pass information from the
1915 ### configuration-run into config.status
1916
1917 AWK="$AWK"
1918 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
1919 DFT_LWR_MODEL="$DFT_LWR_MODEL"
1920 ECHO_LD="$ECHO_LD"
1921 LDCONFIG="$LDCONFIG"
1922 LIBTOOL_VERSION="$LIBTOOL_VERSION"
1923 LIB_NAME="$LIB_NAME"
1924 LIB_PREFIX="$LIB_PREFIX"
1925 LIB_SUBSETS="$LIB_SUBSETS"
1926 LIB_SUFFIX="$LIB_SUFFIX"
1927 LIB_TRACING="$LIB_TRACING"
1928 LN_S="$LN_S"
1929 MAKE_TERMINFO="$MAKE_TERMINFO"
1930 NCURSES_MAJOR="$NCURSES_MAJOR"
1931 NCURSES_MINOR="$NCURSES_MINOR"
1932 NCURSES_OSPEED="$NCURSES_OSPEED"
1933 NCURSES_PATCH="$NCURSES_PATCH"
1934 SRC_SUBDIRS="$SRC_SUBDIRS"
1935 TERMINFO="$TERMINFO"
1936 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
1937 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
1938 TICS_NAME="$TICS_NAME"
1939 TIC_PATH="$TIC_PATH"
1940 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
1941 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
1942 TINFO_NAME="$TINFO_NAME"
1943 TINFO_SUFFIX="$TINFO_SUFFIX"
1944 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
1945 WITH_CURSES_H="$with_curses_h"
1946 WITH_ECHO="${enable_echo:=yes}"
1947 WITH_OVERWRITE="$with_overwrite"
1948 cf_LIST_MODELS="$cf_list_models"
1949 cf_cv_abi_version="$cf_cv_abi_version"
1950 cf_cv_do_relink="$cf_cv_do_relink"
1951 cf_cv_do_symlinks="$cf_cv_do_symlinks"
1952 cf_cv_enable_lp64="$cf_cv_enable_lp64"
1953 cf_cv_enable_opaque="$cf_cv_enable_opaque"
1954 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
1955 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
1956 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
1957 cf_cv_rel_version="$cf_cv_rel_version"
1958 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
1959 cf_cv_shared_soname='$cf_cv_shared_soname'
1960 cf_cv_shlib_version="$cf_cv_shlib_version"
1961 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
1962 cf_cv_system_name="$cf_cv_system_name"
1963 cf_cv_term_driver="$with_term_driver"
1964 cf_with_ada="$cf_with_ada"
1965 cf_with_cxx_binding="$cf_with_cxx_binding"
1966 cf_with_manpages="$cf_with_manpages"
1967 cf_with_tests="$cf_with_tests"
1968 host="$host"
1969 target="$target"
1970
1971 ],cat)dnl
1972 ${MAKE:-make} preinstall