configure.in

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2022,2023 Thomas E. Dickey                                *
   3 dnl Copyright 1998-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl Author: Thomas E. Dickey 1995-on
  31 dnl
  32 dnl $Id: configure.in,v 1.772 2023/11/25 21:05:05 tom Exp $
  33 dnl Process this file with autoconf to produce a configure script.
  34 dnl
  35 dnl For additional information, see
  36 dnl     https://invisible-island.net/autoconf/
  37 dnl     https://invisible-island.net/autoconf/my-autoconf.html
  38 dnl
  39 dnl ---------------------------------------------------------------------------
  40 AC_PREREQ(2.52.20210101)
  41 AC_REVISION($Revision: 1.772 $)
  42 AC_INIT(ncurses/base/lib_initscr.c)
  43 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  44
  45 AC_DEFUN([AC_PATH_XTRA],[])dnl ignore dependencies on this
  46
  47 CF_TOP_BUILDDIR
  48 CF_SUBST_NCURSES_VERSION
  49 CF_VERSION_INFO(NCURSES,ncurses)
  50
  51 CF_WITH_REL_VERSION(NCURSES)
  52 CF_NCURSES_WITH_ABI_VERSION
  53
  54 CF_WITH_SYSTYPE
  55
  56 ###     Save the given $CFLAGS to allow user-override.
  57 cf_user_CFLAGS="$CFLAGS"
  58
  59 ###     Default install-location
  60 CF_CFG_DEFAULTS
  61 ### Defaults for ncurses ABI
  62 CF_ABI_DEFAULTS
  63
  64 ### override ABI version, e.g., packagers
  65 CF_WITH_ABI_ALTERED
  66
  67 ###     Checks for programs.
  68 AC_ARG_WITH(ada,
  69         [  --without-ada           suppress check for Ada compiler, don't build demo],
  70         [cf_with_ada=$withval],
  71         [cf_with_ada=yes])
  72
  73 if test "x$cf_with_ada" = xyes
  74 then
  75         cf_prog_cc="gnatgcc gcc cc"
  76 else
  77         cf_prog_cc="gcc cc"
  78 fi
  79 CF_PROG_CC($cf_prog_cc)
  80
  81 AC_PROG_CPP
  82 AC_PROG_GCC_TRADITIONAL
  83 CF_PROG_CC_C_O(CC,[$CFLAGS $CPPFLAGS])
  84 CF_PROG_LDCONFIG
  85
  86 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  87 dnl                             configure script by not letting us test if C++
  88 dnl                             is present, making this option necessary.
  89 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  90 AC_ARG_WITH(cxx,
  91         [  --without-cxx           do not adjust ncurses bool to match C++],
  92         [cf_with_cxx=$withval],
  93         [cf_with_cxx=yes])
  94 AC_MSG_RESULT($cf_with_cxx)
  95 if test "X$cf_with_cxx" = Xno ; then
  96         CXX=""
  97         GXX=""
  98 else
  99         # with autoconf 2.13, we can change the error to a warning:
 100         pushdef([AC_MSG_ERROR],
 101                 [AC_MSG_RESULT(no)
 102                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
 103                 cf_with_cxx=no; CXX=""; GXX="";])dnl
 104         AC_PROG_CXX
 105         popdef([AC_MSG_ERROR])dnl
 106
 107         AC_LANG_PUSH(C++)
 108         if test "x$cf_with_cxx" != xno
 109         then
 110                 # Several of the C++ configurations do not work, particularly when
 111                 # cross-compiling (20140913 -TD)
 112                 AC_MSG_CHECKING(if $CXX works)
 113
 114                 save_CPPFLAGS="$CPPFLAGS"
 115                 eval cf_includedir=${includedir}
 116                 CPPFLAGS="$CPPFLAGS -I${cf_includedir}"
 117                 AC_TRY_COMPILE([
 118 #include <stdlib.h>
 119 #include <stdio.h>
 120 ],
 121                 [
 122                 printf("Hello world!\n")
 123                 ],
 124                 [cf_cxx_works=yes],
 125                 [cf_cxx_works=no])
 126                 CPPFLAGS="$save_CPPFLAGS"
 127
 128                 AC_MSG_RESULT($cf_cxx_works)
 129                 if test "x$cf_cxx_works" = xno
 130                 then
 131                         AC_MSG_WARN([Ignore $CXX, since it cannot compile hello-world.])
 132                         cf_with_cxx=no; CXX=""; GXX="";
 133                 fi
 134         fi
 135         AC_LANG_POP
 136
 137         # autoconf 2.5x removed the error (hardcoding it to g++, or just blank)
 138         if test "$CXX" = "g++" ; then
 139                 AC_PATH_PROG(CXX,g++)
 140         fi
 141         case "x$CXX" in
 142         (x|xg++)
 143                 AC_MSG_WARN([You don't have any C++ compiler, too bad])
 144                 cf_with_cxx=no; CXX=""; GXX="";
 145                 ;;
 146         esac
 147 fi
 148
 149 CF_GXX_VERSION
 150 case "$GXX_VERSION" in
 151 ([[1-9]][[0-9]].*)
 152         ;;
 153 (1.*|2.[[0-6]]*)
 154         AC_MSG_WARN(templates do not work)
 155         ;;
 156 esac
 157
 158 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 159 AC_ARG_WITH(cxx-binding,
 160         [  --without-cxx-binding   do not build C++ binding and demo],
 161         [cf_with_cxx_binding=$withval],
 162         [cf_with_cxx_binding=$cf_with_cxx])
 163 AC_MSG_RESULT($cf_with_cxx_binding)
 164
 165 AC_MSG_CHECKING(if you want to build with Ada)
 166 AC_MSG_RESULT($cf_with_ada)
 167
 168 AC_MSG_CHECKING(if you want to install terminal database)
 169 AC_ARG_ENABLE(db-install,
 170         [  --disable-db-install    suppress install of terminal database],
 171         [cf_with_db_install=$enableval],
 172         [cf_with_db_install=yes])
 173 AC_MSG_RESULT($cf_with_db_install)
 174
 175 AC_MSG_CHECKING(if you want to install manpages)
 176 AC_ARG_WITH(manpages,
 177         [  --without-manpages      suppress install of manpages],
 178         [cf_with_manpages=$withval],
 179         [cf_with_manpages=yes])
 180 AC_MSG_RESULT($cf_with_manpages)
 181
 182 AC_MSG_CHECKING(if you want to build programs such as tic)
 183 AC_ARG_WITH(progs,
 184         [  --without-progs         suppress build/install with programs (e.g., tic)],
 185         [cf_with_progs=$withval],
 186         [cf_with_progs=yes])
 187 AC_MSG_RESULT($cf_with_progs)
 188
 189 AC_MSG_CHECKING(if you want to build test-programs)
 190 AC_ARG_WITH(tests,
 191         [  --without-tests         suppress build/install with test-programs],
 192         [cf_with_tests=$withval],
 193         [cf_with_tests=yes])
 194 AC_MSG_RESULT($cf_with_tests)
 195
 196 AC_MSG_CHECKING(if you wish to install curses.h)
 197 AC_ARG_WITH(curses-h,
 198         [  --without-curses-h      install curses.h as ncurses.h only],
 199         [with_curses_h=$withval],
 200         [with_curses_h=yes])
 201 AC_MSG_RESULT($with_curses_h)
 202
 203 modules_to_build="ncurses"
 204 test "X$cf_with_progs" != Xno && modules_to_build="$modules_to_build progs"
 205 modules_to_build="$modules_to_build panel menu form"
 206
 207 AC_ARG_PROGRAM
 208
 209 CF_PROG_AWK
 210 CF_PROG_INSTALL
 211 CF_PROG_LINT
 212 CF_PROG_LN_S
 213
 214 AC_SYS_LONG_FILE_NAMES
 215
 216 # Provide for renaming "ncurses5-config" to "ncurses5X-config", etc., in case
 217 # of package conflict.
 218 cf_config_suffix=
 219 AC_ARG_WITH(config-suffix,
 220         [  --with-config-suffix=X  name ncurses*X-config file with X],
 221         [case "x$withval" in
 222         (xyes|xno)
 223                 AC_MSG_WARN(expected a value for config-suffix option)
 224                 ;;
 225         (*)     cf_config_suffix="$withval"
 226                 ;;
 227         esac])
 228 AC_SUBST(cf_config_suffix)
 229
 230 # If we find pkg-config, check if we should install the ".pc" files.
 231 CF_PKG_CONFIG
 232 CF_WITH_PKG_CONFIG_LIBDIR
 233 CF_ENABLE_PC_FILES
 234 if test -z "$MAKE_PC_FILES"
 235 then
 236         AC_MSG_CHECKING(for suffix to add to pkg-config files)
 237 AC_ARG_WITH(pc-suffix,
 238         [[  --with-pc-suffix[=XXX]  suffix pkg-config files with XXX]],
 239         [case "x$withval" in
 240         (xyes|xno)
 241                 PC_MODULE_SUFFIX=
 242                 ;;
 243         (*)     PC_MODULE_SUFFIX="$withval"
 244                 ;;
 245         esac])
 246         test -z "$PC_MODULE_SUFFIX" && PC_MODULE_SUFFIX=none
 247         AC_MSG_RESULT($PC_MODULE_SUFFIX)
 248         test "$PC_MODULE_SUFFIX" = none && PC_MODULE_SUFFIX=
 249         AC_SUBST(PC_MODULE_SUFFIX)
 250 fi
 251
 252 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 253 AC_ARG_ENABLE(mixed-case,
 254         [  --enable-mixed-case     tic should assume mixed-case filenames],
 255         [enable_mixedcase=$enableval],
 256         [enable_mixedcase=auto])
 257 AC_MSG_RESULT($enable_mixedcase)
 258 if test "$enable_mixedcase" = "auto" ; then
 259         CF_MIXEDCASE_FILENAMES
 260 else
 261         cf_cv_mixedcase=$enable_mixedcase
 262         if test "x$enable_mixedcase" = "xyes" ; then
 263                 AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if tic should assume mixed-case filenames])
 264         fi
 265 fi
 266
 267 # do this after mixed-case option (tags/TAGS is not as important as tic).
 268 AC_PROG_MAKE_SET
 269 CF_MAKE_PHONY
 270 CF_MAKE_TAGS
 271 CF_MAKEFLAGS
 272
 273 dnl These are standard among *NIX systems, but not when cross-compiling
 274 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 275 AC_CHECK_TOOL(LD, ld, ld)
 276 AC_CHECK_TOOL(AR, ar, ar)
 277 AC_CHECK_TOOL(NM, nm, nm)
 278 CF_AR_FLAGS
 279
 280 dnl Special option for use by system-builders: the install-prefix is used to
 281 dnl adjust the location into which the actual install is done, so that an
 282 dnl archive can be built without modifying the host system's configuration.
 283 AC_MSG_CHECKING(for an installation directory prefix)
 284 AC_ARG_WITH(install-prefix,
 285         [  --with-install-prefix=DESTDIR use DESTDIR as installation directory prefix],
 286         [case "x$withval" in
 287         (xyes|xno)
 288                 ;;
 289         (*)     DESTDIR="$withval"
 290                 ;;
 291         esac])
 292 AC_MSG_RESULT([${DESTDIR:-(none)}])
 293 AC_SUBST(DESTDIR)
 294
 295 ###############################################################################
 296 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 297 # If we're cross-compiling, allow the user to override the tools and their
 298 # options.  The configure script is oriented toward identifying the host
 299 # compiler, etc., but we need a build compiler to generate parts of the source.
 300
 301 case "$cf_cv_system_name" in
 302 (*-msvc*)
 303         LDFLAGS="$LDFLAGS user32.lib"
 304         export LDFLAGS
 305         ;;
 306 esac
 307
 308 CF_BUILD_CC
 309
 310 ###############################################################################
 311 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 312
 313 ### Options to allow the user to specify the set of libraries which are used.
 314 ### Use "--without-normal --with-shared" to allow the default model to be
 315 ### shared, for example.
 316 cf_list_models=""
 317 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 318
 319 CF_WITH_LIBTOOL
 320 if test "$with_libtool" != "no" ; then
 321
 322 cf_list_models="$cf_list_models libtool"
 323
 324 else
 325
 326 AC_MSG_CHECKING(if you want to build shared libraries)
 327 AC_ARG_WITH(shared,
 328         [  --with-shared           generate shared-libraries],
 329         [with_shared=$withval],
 330         [with_shared=no])
 331 AC_MSG_RESULT($with_shared)
 332 test "x$with_shared" = "xyes" && cf_list_models="$cf_list_models shared"
 333
 334 AC_MSG_CHECKING(if you want to build static libraries)
 335 AC_ARG_WITH(normal,
 336         [  --with-normal           generate normal-libraries (default)],
 337         [with_normal=$withval],
 338         [with_normal=yes])
 339 AC_MSG_RESULT($with_normal)
 340 test "x$with_normal" = "xyes" && cf_list_models="$cf_list_models normal"
 341
 342 AC_MSG_CHECKING(if you want to build debug libraries)
 343 AC_ARG_WITH(debug,
 344         [  --with-debug            generate debug-libraries (default)],
 345         [with_debug=$withval],
 346         [with_debug=yes])
 347 AC_MSG_RESULT($with_debug)
 348 test "x$with_debug" = "xyes" && cf_list_models="$cf_list_models debug"
 349
 350 AC_MSG_CHECKING(if you want to build profiling libraries)
 351 AC_ARG_WITH(profile,
 352         [  --with-profile          generate profile-libraries],
 353         [with_profile=$withval],
 354         [with_profile=no])
 355 AC_MSG_RESULT($with_profile)
 356 test "x$with_profile" = "xyes" && cf_list_models="$cf_list_models profile"
 357
 358 fi
 359
 360 if test "X$cf_with_cxx_binding" != Xno; then
 361 if test "x$with_shared" = "xyes"; then
 362 AC_MSG_CHECKING(if you want to build C++ shared libraries)
 363 AC_ARG_WITH(cxx-shared,
 364         [  --with-cxx-shared       generate C++ shared-libraries],
 365         [with_shared_cxx=$withval],
 366         [with_shared_cxx=no])
 367 AC_MSG_RESULT($with_shared_cxx)
 368 fi
 369 fi
 370
 371 ###############################################################################
 372
 373 AC_MSG_CHECKING(for specified models)
 374 test -z "$cf_list_models" && cf_list_models=normal
 375 dnl If we use libtool to generate libraries, then it must be the only
 376 dnl specified model.
 377 test "$with_libtool" != "no" && cf_list_models=libtool
 378 AC_MSG_RESULT($cf_list_models)
 379
 380 ### Use the first model as the default, and save its suffix for use in building
 381 ### up test-applications.
 382 AC_MSG_CHECKING(for default model)
 383 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 384 AC_MSG_RESULT($DFT_LWR_MODEL)
 385
 386 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 387
 388 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 389 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 390
 391 TICS_NAME=tic
 392 AC_SUBST(TICS_NAME)
 393
 394 TINFO_NAME=tinfo
 395 AC_SUBST(TINFO_NAME)
 396
 397 LIB_NAME=ncurses
 398 AC_SUBST(LIB_NAME)
 399
 400 LIB_DIR=../lib
 401 LIB_2ND=../../lib
 402
 403 CF_WITH_LIB_PREFIX(cf_prefix)
 404
 405 LIB_SUFFIX=
 406 AC_SUBST(LIB_SUFFIX)
 407 CF_PATHSEP
 408
 409 # headers needed for checks...
 410 AC_CHECK_DECL(exit)
 411 AC_HEADER_DIRENT
 412
 413 ###############################################################################
 414
 415 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 416 AC_ARG_WITH(termlib,
 417         [  --with-termlib          generate separate terminfo library],
 418         [with_termlib=$withval],
 419         [with_termlib=no])
 420 AC_MSG_RESULT($with_termlib)
 421
 422 AC_MSG_CHECKING(if you want to build a separate tic library)
 423 AC_ARG_WITH(ticlib,
 424         [  --with-ticlib           generate separate tic library],
 425         [with_ticlib=$withval],
 426         [with_ticlib=no])
 427 AC_MSG_RESULT($with_ticlib)
 428
 429 dnl Not all ports of gcc support the -g option
 430
 431 if test X"$CC_G_OPT" = X"" ; then
 432         CC_G_OPT='-g'
 433         test -n "$GCC" && test "x${ac_cv_prog_cc_g}" != xyes && CC_G_OPT=''
 434 fi
 435 AC_SUBST(CC_G_OPT)
 436
 437 if test X"$CXX_G_OPT" = X"" ; then
 438         CXX_G_OPT='-g'
 439         test -n "$GXX" && test "x${ac_cv_prog_cxx_g}" != xyes && CXX_G_OPT=''
 440 fi
 441 AC_SUBST(CXX_G_OPT)
 442
 443 AC_MSG_CHECKING(for default loader flags)
 444 case "$DFT_LWR_MODEL" in
 445 (libtool) LD_MODEL=''   ;;
 446 (normal)  LD_MODEL=''   ;;
 447 (debug)   LD_MODEL=$CC_G_OPT ;;
 448 (profile) LD_MODEL='-pg';;
 449 (shared)  LD_MODEL=''   ;;
 450 esac
 451 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 452 AC_MSG_RESULT([${LD_MODEL:-(none)}])
 453
 454 case "$DFT_LWR_MODEL" in
 455 (shared)
 456 CF_ENABLE_RPATH
 457 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 458 AC_ARG_ENABLE(relink,
 459 [  --disable-relink        relink shared libraries during install],
 460 [cf_cv_do_relink=$enableval],
 461 [cf_cv_do_relink=yes])
 462 AC_MSG_RESULT($cf_cv_do_relink)
 463         ;;
 464 esac
 465
 466 # we will build libraries one-level down.
 467 rel_builddir=..
 468 CF_SHARED_OPTS
 469 for model in $cf_list_models ; do
 470         case "$model" in
 471         (libtool)
 472                 CF_WITH_LIBTOOL_OPTS
 473                 CF_WITH_EXPORT_SYMS
 474                 ;;
 475         (shared)
 476                 if test "$CC_SHARED_OPTS" = "unknown"; then
 477                         AC_ERROR(Shared libraries are not supported in this version)
 478                 fi
 479                 # workaround for inept transition to PIE vs PIC...
 480                 AC_MSG_CHECKING(if current CFLAGS link properly)
 481                 AC_TRY_LINK(
 482                         [#include <stdio.h>],
 483                         [printf("Hello work\\n");],
 484                         [cf_cflags_work=yes],
 485                         [cf_cflags_work=no])
 486                 AC_MSG_RESULT($cf_cflags_work)
 487                 if test "$cf_cflags_work" = no
 488                 then
 489                         CF_VERBOSE(try to work around by appending shared-options)
 490                         CFLAGS="$CFLAGS $CC_SHARED_OPTS"
 491                 fi
 492                 CF_WITH_VERSIONED_SYMS
 493                 ;;
 494         esac
 495 done
 496
 497 ### Checks for special libraries, must be done up-front.
 498 SHLIB_LIST=""
 499 CF_WITH_GPM
 500 if test "$with_gpm" != no ; then
 501         AC_MSG_CHECKING(if you want to load GPM dynamically)
 502         AC_ARG_WITH(dlsym,
 503                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 504                 [with_dlsym=$withval],
 505                 [with_dlsym=yes])
 506         AC_MSG_RESULT($with_dlsym)
 507         if test "x$with_dlsym" = xyes ; then
 508                 CF_FUNC_DLSYM
 509                 if test "x$with_gpm" != xyes ; then
 510                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 511                         cf_cv_gpm_soname="$with_gpm"
 512                 else
 513                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 514                 fi
 515                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname",[Define as needed to set the gpm share library soname])
 516                 SHLIB_LIST="-ldl $SHLIB_LIST"
 517                 CF_ADD_LIB(dl,PRIVATE_LIBS)
 518         else
 519                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 520                 CF_ADD_LIB(gpm,TEST_LIBS)
 521                 CF_ADD_LIB(gpm,PRIVATE_LIBS)
 522         fi
 523         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
 524         CF_CHECK_GPM_WGETCH
 525 fi
 526
 527 CF_WITH_PCRE2
 528 CF_WITH_SYSMOUSE
 529
 530 # pretend that ncurses==ncursesw==ncursest
 531 AC_MSG_CHECKING(if you want to disable library suffixes)
 532 CF_ARG_DISABLE(lib-suffixes,
 533         [  --disable-lib-suffixes  disable library suffixes],
 534         [disable_lib_suffixes=yes],
 535         [disable_lib_suffixes=no],
 536         no)
 537 AC_MSG_RESULT($disable_lib_suffixes)
 538
 539 ### If we're building with rpath, try to link non-standard libs that way too.
 540 if test "$DFT_LWR_MODEL" = "shared" && test "x$cf_cv_enable_rpath" != xno; then
 541         CF_DISABLE_RPATH_HACK
 542 fi
 543
 544 ### Depending on the system, someone may use rpath to build ncurses but not
 545 # want users of the package to rely upon that feature.  Give those people an
 546 # option to suppress that detail from EXTRA_LDFLAGS.
 547 EXTRA_PKG_LDFLAGS="$LDFLAGS $EXTRA_LDFLAGS"
 548 if test -n "$EXTRA_PKG_LDFLAGS"
 549 then
 550         AC_MSG_CHECKING(if you want to disable extra LDFLAGS for package-scripts)
 551         CF_ARG_DISABLE(pkg-ldflags,
 552                 [  --disable-pkg-ldflags   disable extra LDFLAGS for package-scripts],
 553                 [disable_pkg_ldflags=yes],
 554                 [disable_pkg_ldflags=no],
 555                 no)
 556         AC_MSG_RESULT($disable_pkg_ldflags)
 557         test "$disable_pkg_ldflags" = yes && EXTRA_PKG_LDFLAGS=
 558 fi
 559 AC_SUBST(EXTRA_PKG_LDFLAGS)
 560
 561 ###############################################################################
 562 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 563
 564 ###     use option --with-extra-suffix to append suffix to headers and libraries
 565 AC_MSG_CHECKING(for extra suffix to append to header/library paths)
 566 EXTRA_SUFFIX=
 567 AC_ARG_WITH(extra-suffix,
 568         [[  --with-extra-suffix[=X] append extra suffix X to header/library paths]],
 569         [case x$withval in
 570         (xno)
 571                 ;;
 572         (xyes|x)
 573                 EXTRA_SUFFIX=$cf_cv_abi_version
 574                 ;;
 575         (*)
 576                 EXTRA_SUFFIX=$withval
 577                 ;;
 578         esac
 579         ])
 580 AC_MSG_RESULT([${EXTRA_SUFFIX:-(none)}])
 581 AC_SUBST(EXTRA_SUFFIX)
 582
 583 ###     use option --disable-overwrite to leave out the link to -lcurses
 584 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 585 AC_ARG_ENABLE(overwrite,
 586         [  --disable-overwrite     put headers in subdir, omit link to -lcurses],
 587         [with_overwrite=$enableval],
 588         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 589 AC_MSG_RESULT($with_overwrite)
 590
 591 AC_MSG_CHECKING(if external terminfo-database is used)
 592 AC_ARG_ENABLE(database,
 593         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 594         [use_database=$enableval],
 595         [use_database=yes])
 596 AC_MSG_RESULT($use_database)
 597
 598 case "$host_os" in
 599 (os2*)
 600         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 601         ;;
 602 (*)
 603         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 604         ;;
 605 esac
 606 AC_SUBST(TERMINFO_SRC)
 607
 608 NCURSES_USE_DATABASE=0
 609 if test "$use_database" != no ; then
 610         NCURSES_USE_DATABASE=1
 611
 612         AC_MSG_CHECKING(which terminfo source-file will be installed)
 613         AC_ARG_WITH(database,
 614                 [  --with-database=XXX     specify terminfo source to install],
 615                 [TERMINFO_SRC=$withval])
 616         AC_MSG_RESULT($TERMINFO_SRC)
 617
 618         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 619         AC_ARG_WITH(hashed-db,
 620                 [  --with-hashed-db        specify hashed-database library],,
 621                 [with_hashed_db=no])
 622         AC_MSG_RESULT($with_hashed_db)
 623 else
 624         with_hashed_db=no
 625 fi
 626 AC_SUBST(NCURSES_USE_DATABASE)
 627
 628 AC_MSG_CHECKING(for list of fallback terminal descriptions)
 629 AC_ARG_WITH(fallbacks,
 630         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 631         [with_fallback=$withval],
 632         [with_fallback=])
 633 AC_MSG_RESULT([${with_fallback:-(none)}])
 634
 635 case ".$with_fallback" in
 636 (.|.no)
 637         FALLBACK_LIST=
 638         ;;
 639 (.yes)
 640         AC_MSG_WARN(expected a list of terminal descriptions)
 641         ;;
 642 (*)
 643         FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
 644         ;;
 645 esac
 646
 647 # The fallback feature in ncurses relies upon tic/infocmp outside the build
 648 # tree for generating the terminal descriptions that will be compiled into the
 649 # library.  If your toolchain is old, it may not handle current terminal
 650 # databases.  Use configure-options to point to the tools which will be used,
 651 # rather than the first ones found on the $PATH.
 652 AC_CHECK_TOOL(TIC, tic)
 653 AC_CHECK_TOOL(INFOCMP, infocmp)
 654 if test -n "$FALLBACK_LIST"
 655 then
 656         CF_WITH_PATH_PROG(TIC,     tic,     [for fallbacks], $PATH:/usr/local/ncurses/bin)
 657         CF_WITH_PATH_PROG(INFOCMP, infocmp, [for fallbacks], $PATH:/usr/local/ncurses/bin)
 658         test -z "$TIC" && FALLBACK_LIST=
 659         test -z "$INFOCMP" && FALLBACK_LIST=
 660         if test -z "$FALLBACK_LIST"
 661         then
 662                 AC_MSG_WARN(ignoring fallback option because tic/infocmp are not available)
 663         fi
 664 fi
 665 AC_SUBST(TIC)
 666 AC_SUBST(INFOCMP)
 667
 668 USE_FALLBACKS=
 669 test -z "$FALLBACK_LIST" && USE_FALLBACKS="#"
 670 AC_SUBST(FALLBACK_LIST)
 671 AC_SUBST(USE_FALLBACKS)
 672
 673 AC_MSG_CHECKING(if you want modern xterm or antique)
 674 AC_ARG_WITH(xterm-new,
 675         [  --without-xterm-new     specify if xterm terminfo should be old version],
 676         [with_xterm_new=$withval],
 677         [with_xterm_new=yes])
 678 case "$with_xterm_new" in
 679 (no) with_xterm_new=xterm-old;;
 680 (*)      with_xterm_new=xterm-new;;
 681 esac
 682 AC_MSG_RESULT($with_xterm_new)
 683 WHICH_XTERM=$with_xterm_new
 684 AC_SUBST(WHICH_XTERM)
 685
 686 case $host_os in
 687 (*linux-gnu|*cygwin|*mingw32|*msys)
 688         want_xterm_kbs=DEL
 689         ;;
 690 (*)
 691         want_xterm_kbs=BS
 692         ;;
 693 esac
 694
 695 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
 696 AC_ARG_WITH(xterm-kbs,
 697         [[  --with-xterm-kbs[=XXX]  specify if xterm backspace sends BS or DEL]],
 698         [with_xterm_kbs=$withval],
 699         [with_xterm_kbs=auto])
 700 case x$with_xterm_kbs in
 701 (xyes|xno|xBS|xbs|x8)
 702         with_xterm_kbs=BS
 703         ;;
 704 (xDEL|xdel|x127)
 705         with_xterm_kbs=DEL
 706         ;;
 707 (xauto)
 708         with_xterm_kbs=$want_xterm_kbs
 709         ;;
 710 (*)
 711         with_xterm_kbs=$withval
 712         ;;
 713 esac
 714 AC_MSG_RESULT($with_xterm_kbs)
 715 XTERM_KBS=$with_xterm_kbs
 716 AC_SUBST(XTERM_KBS)
 717
 718 if test "x$with_xterm_kbs" != "x$want_xterm_kbs"
 719 then
 720         AC_MSG_WARN([expected --with-xterm-kbs=$want_xterm_kbs for $host_os, have $with_xterm_kbs])
 721 fi
 722
 723 MAKE_TERMINFO=
 724 if test "$use_database" = no ; then
 725         TERMINFO="${datadir}/terminfo"
 726         MAKE_TERMINFO="#"
 727 else
 728
 729 AC_MSG_CHECKING(for list of terminfo directories)
 730 CF_WITH_PATHLIST(terminfo-dirs,
 731         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 732         TERMINFO_DIRS,
 733         DATADIR/terminfo,
 734         ${datadir}/terminfo)
 735 AC_MSG_RESULT($TERMINFO_DIRS)
 736 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS",[Define as needed to predefine the TERMINFO_DIR searchlist])
 737
 738 case "x$TERMINFO" in
 739 x???:*)
 740         AC_MSG_WARN(ignoring non-directory/file TERMINFO value)
 741         unset TERMINFO
 742         ;;
 743 esac
 744
 745 AC_MSG_CHECKING(for default terminfo directory)
 746 CF_WITH_PATH(default-terminfo-dir,
 747         [  --with-default-terminfo-dir=DIR default terminfo directory],
 748         TERMINFO,
 749         DATADIR/terminfo,
 750         ${datadir}/terminfo)
 751 AC_MSG_RESULT($TERMINFO)
 752 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO",[Define to set the default terminal database path])
 753
 754 fi
 755
 756 AC_SUBST(TERMINFO)
 757 AC_SUBST(MAKE_TERMINFO)
 758
 759 ###     use option --disable-big-core to make tic run on small machines
 760 ###     We need 4Mb, check if we can allocate 50% more than that.
 761 AC_MSG_CHECKING(if big-core option selected)
 762 AC_ARG_ENABLE(big-core,
 763         [  --disable-big-core      assume machine has little memory],
 764         [with_big_core=$enableval],
 765         [AC_TRY_RUN([
 766 #include <stdlib.h>
 767 #include <string.h>
 768 int main() {
 769         unsigned long n = 6000000L;
 770         char *s = malloc(n);
 771         if (s != 0)
 772                 s[0] = s[n-1] = 0;
 773         ${cf_cv_main_return:-return}(s == 0);
 774 }],
 775         [with_big_core=yes],
 776         [with_big_core=no],
 777         [with_big_core=no])])
 778 AC_MSG_RESULT($with_big_core)
 779 test "x$with_big_core" = "xyes" && AC_DEFINE(HAVE_BIG_CORE,1,[Define to 1 if machine has ample memory for tic])
 780
 781 ### ISO C only guarantees 512-char strings, we have tables which load faster
 782 ### when constructed using "big" strings.  More than the C compiler, the awk
 783 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 784 AC_MSG_CHECKING(if big-strings option selected)
 785 AC_ARG_ENABLE(big-strings,
 786         [  --disable-big-strings   assume compiler has only standard-size strings],
 787         [with_big_strings=$enableval],
 788         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 789 AC_MSG_RESULT($with_big_strings)
 790
 791 USE_BIG_STRINGS=0
 792 test "x$with_big_strings" = "xyes" && USE_BIG_STRINGS=1
 793 AC_SUBST(USE_BIG_STRINGS)
 794
 795 ###     use option --enable-termcap to compile in the termcap fallback support
 796 AC_MSG_CHECKING(if you want termcap-fallback support)
 797 AC_ARG_ENABLE(termcap,
 798         [  --enable-termcap        compile in termcap fallback support],
 799         [with_termcap=$enableval],
 800         [with_termcap=no])
 801 AC_MSG_RESULT($with_termcap)
 802
 803 NCURSES_USE_TERMCAP=0
 804 if test "x$with_termcap" != "xyes" ; then
 805         if test "$use_database" = no ; then
 806                 if test -z "$with_fallback" ; then
 807                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 808                 fi
 809         fi
 810         AC_DEFINE(PURE_TERMINFO,1,[Define to 1 if we should support only terminfo])
 811 else
 812
 813         if test "$with_ticlib" != no ; then
 814                 AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 815         fi
 816
 817         NCURSES_USE_TERMCAP=1
 818         AC_MSG_CHECKING(for list of termcap files)
 819         CF_WITH_PATHLIST(termpath,
 820                 [  --with-termpath=XXX     specify list of termcap files],
 821                 TERMPATH,
 822                 /etc/termcap:/usr/share/misc/termcap)
 823         AC_MSG_RESULT($TERMPATH)
 824         test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH",[Define to set the termcap searchlist])
 825
 826         ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 827         AC_MSG_CHECKING(if fast termcap-loader is needed)
 828         AC_ARG_ENABLE(getcap,
 829                 [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 830                 [with_getcap=$enableval],
 831                 [with_getcap=no])
 832         AC_MSG_RESULT($with_getcap)
 833         test "x$with_getcap" = "xyes" && AC_DEFINE(USE_GETCAP,1,[Define to 1 to use fast termcap-loader])
 834
 835         AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 836         AC_ARG_ENABLE(getcap-cache,
 837                 [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 838                 [with_getcap_cache=$enableval],
 839                 [with_getcap_cache=no])
 840         AC_MSG_RESULT($with_getcap_cache)
 841         test "x$with_getcap_cache" = "xyes" && AC_DEFINE(USE_GETCAP_CACHE,1,[Define to 1 if translated termcap should be stored in $HOME/.terminfo])
 842
 843 fi
 844 AC_SUBST(NCURSES_USE_TERMCAP)
 845
 846 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 847 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 848 AC_ARG_ENABLE(home-terminfo,
 849         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 850         [with_home_terminfo=$enableval],
 851         [with_home_terminfo=yes])
 852 AC_MSG_RESULT($with_home_terminfo)
 853 test "x$with_home_terminfo" = "xyes" && AC_DEFINE(USE_HOME_TERMINFO,1,[Define to 1 if $HOME/.terminfo feature is wanted])
 854
 855 AC_MSG_CHECKING(if you want to permit root to use ncurses environment variables)
 856 AC_ARG_ENABLE(root-environ,
 857         [  --disable-root-environ  restrict root use of ncurses environment variables],
 858         [with_root_environ=$enableval],
 859         [with_root_environ=yes])
 860 AC_MSG_RESULT($with_root_environ)
 861 test "x$with_root_environ" = xyes && AC_DEFINE(USE_ROOT_ENVIRON,1,[Define to 1 if root/setuid application is allowed to use ncurses environment])
 862
 863 AC_MSG_CHECKING(if you want to permit setuid programs to access all files)
 864 AC_ARG_ENABLE(root-access,
 865         [  --disable-root-access   restrict file-access when running setuid],
 866         [with_root_access=$enableval],
 867         [with_root_access=yes])
 868 AC_MSG_RESULT($with_root_access)
 869 test "x$with_root_access" = xyes && AC_DEFINE(USE_ROOT_ACCESS,1,[Define to 1 if setuid is allowed all file-access])
 870
 871 AC_MSG_CHECKING(if you want to permit setuid use of ncurses environment variables)
 872 AC_ARG_ENABLE(setuid-environ,
 873         [  --disable-setuid-environ restrict setuid use of ncurses environment variables],
 874         [with_setuid_environ=$enableval],
 875         [with_setuid_environ=$with_root_environ])
 876 AC_MSG_RESULT($with_setuid_environ)
 877 test "x$with_setuid_environ" = xyes && AC_DEFINE(USE_SETUID_ENVIRON,1,[Define to 1 if setuid/setgid application is allowed to use ncurses environment])
 878
 879 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 880 ###   to reduce storage requirements for the terminfo database.
 881 CF_LINK_FUNCS
 882
 883 with_links=no
 884 with_symlinks=no
 885
 886 # soft links (symbolic links) are useful for some systems where hard links do
 887 # not work, or to make it simpler to copy terminfo trees around.
 888 if test "x$ac_cv_func_symlink" = xyes ; then
 889         AC_MSG_CHECKING(if tic should use symbolic links)
 890         AC_ARG_ENABLE(symlinks,
 891         [  --enable-symlinks       make tic use symbolic links not hard links],
 892         [with_symlinks=$enableval],
 893         [with_symlinks=no])
 894         AC_MSG_RESULT($with_symlinks)
 895 fi
 896
 897 # If we have hard links and did not choose to use soft links instead, there is
 898 # no reason to make this choice optional - use the hard links.
 899 if test "$with_symlinks" = no ; then
 900         AC_MSG_CHECKING(if tic should use hard links)
 901         if test "x$ac_cv_func_link" = xyes ; then
 902                 with_links=yes
 903         else
 904                 with_links=no
 905         fi
 906         AC_MSG_RESULT($with_links)
 907 fi
 908
 909 test "x$with_links" = xyes && AC_DEFINE(USE_LINKS,1,[Define to 1 if hardlinks should be used in terminfo database])
 910 test "x$with_symlinks" = xyes && AC_DEFINE(USE_SYMLINKS,1,[Define to 1 if symbolic links should be used in terminfo database])
 911
 912 ###   use option --enable-broken-linker to force on use of broken-linker support
 913 CF_ENABLE_BROKEN_LINKER
 914
 915 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 916 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 917 AC_ARG_ENABLE(bsdpad,
 918         [  --enable-bsdpad         recognize BSD-style prefix padding],
 919         [with_bsdpad=$enableval],
 920         [with_bsdpad=no])
 921 AC_MSG_RESULT($with_bsdpad)
 922 test "x$with_bsdpad" = xyes && AC_DEFINE(BSD_TPUTS,1,[Define to 1 to recognize BSD-style prefix padding])
 923
 924 ###   use option --enable-widec to turn on use of wide-character support
 925 NCURSES_CH_T=chtype
 926 NCURSES_LIBUTF8=0
 927
 928 NEED_WCHAR_H=0
 929 NCURSES_MBSTATE_T=0
 930 NCURSES_WCHAR_T=0
 931 NCURSES_WINT_T=0
 932
 933 # Check to define _XOPEN_SOURCE "automatically"
 934 CPPFLAGS_before_XOPEN="$CPPFLAGS"
 935 CF_XOPEN_SOURCE(600)
 936 CPPFLAGS_after_XOPEN="$CPPFLAGS"
 937
 938 # Work around breakage on OS X
 939 CF_SIGWINCH
 940
 941 # Checks for CODESET support.
 942 AM_LANGINFO_CODESET
 943
 944 # use these variables to work around a defect in gcc's fixincludes.
 945 NCURSES_OK_WCHAR_T=
 946 NCURSES_OK_WINT_T=
 947
 948 AC_MSG_CHECKING(if you want wide-character code)
 949 AC_ARG_ENABLE(widec,
 950         [  --disable-widec         compile without wide character and UTF-8 support],
 951         [with_widec=$enableval],
 952         [with_widec=$cf_dft_widec])
 953 AC_MSG_RESULT($with_widec)
 954
 955 NCURSES_WCWIDTH_GRAPHICS=1
 956 AC_SUBST(NCURSES_WCWIDTH_GRAPHICS)
 957
 958 if test "x$with_widec" = xyes ; then
 959         if test "x$disable_lib_suffixes" = xno ; then
 960                 LIB_SUFFIX="w${LIB_SUFFIX}"
 961         fi
 962         AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to compile with wide character and UTF-8 support])
 963         AC_DEFINE(NCURSES_WIDECHAR,1,[Define to 1 to compile with wide character and UTF-8 support])
 964         case "$CPPFLAGS" in
 965         (*_XOPEN_SOURCE=*)
 966                 ;;
 967         (*)
 968                 AC_MSG_WARN(_XOPEN_SOURCE feature test macro appears to be predefined)
 969                 # CPPFLAGS="$CPPFLAGS -DNCURSES_WIDECHAR"
 970                 CPPFLAGS_after_XOPEN="$CPPFLAGS_after_XOPEN -DNCURSES_WIDECHAR"
 971                 ;;
 972         esac
 973
 974         CF_CHECK_WCHAR_H
 975         CF_CHECK_WCWIDTH_GRAPHICS
 976         test "$cf_cv_wcwidth_graphics" = no && NCURSES_WCWIDTH_GRAPHICS=0
 977
 978         # with_overwrite=no
 979         NCURSES_CH_T=cchar_t
 980         AC_CHECK_FUNCS(putwc btowc wctob wmemchr mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 981         if test "x$ac_cv_func_putwc" != xyes ; then
 982                 CF_UTF8_LIB
 983                 if test "$cf_cv_utf8_lib" != no ; then
 984                         NCURSES_LIBUTF8=1
 985                 fi
 986         fi
 987         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 988         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 989         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 990
 991         if test "$NCURSES_MBSTATE_T" != 0; then
 992                 AC_DEFINE(NEED_MBSTATE_T_DEF,1,[Define to 1 if we must declare mbstate_t])
 993         fi
 994 fi
 995 AC_SUBST(NCURSES_CH_T)
 996 AC_SUBST(NCURSES_LIBUTF8)
 997
 998 AC_SUBST(NEED_WCHAR_H)
 999 AC_SUBST(NCURSES_MBSTATE_T)
1000 AC_SUBST(NCURSES_WCHAR_T)
1001 AC_SUBST(NCURSES_WINT_T)
1002
1003 AC_SUBST(NCURSES_OK_WCHAR_T)
1004 AC_SUBST(NCURSES_OK_WINT_T)
1005
1006 ###   use option --disable-lp64 to allow long chtype
1007 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
1008 AC_ARG_ENABLE(lp64,
1009         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
1010         [with_lp64=$enableval],
1011         [with_lp64=$cf_dft_with_lp64])
1012 AC_MSG_RESULT($with_lp64)
1013
1014 if test "x$with_lp64" = xyes ; then
1015         cf_cv_enable_lp64=1
1016 else
1017         cf_cv_enable_lp64=0
1018 fi
1019 AC_SUBST(cf_cv_enable_lp64)
1020
1021 CF_LARGEFILE
1022
1023 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
1024 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
1025 AC_ARG_ENABLE(tparm-varargs,
1026         [  --disable-tparm-varargs compile tparm() without varargs interface],
1027         [with_tparm_varargs=$enableval],
1028         [with_tparm_varargs=yes])
1029 AC_MSG_RESULT($with_tparm_varargs)
1030 NCURSES_TPARM_VARARGS=0
1031 test "x$with_tparm_varargs" = xyes && NCURSES_TPARM_VARARGS=1
1032 AC_SUBST(NCURSES_TPARM_VARARGS)
1033
1034 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
1035 if test "$with_ticlib" != no ; then
1036 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
1037 AC_ARG_ENABLE(tic-depends,
1038         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
1039         [with_tic_depends=$enableval],
1040         [with_tic_depends=yes])
1041 AC_MSG_RESULT($with_tic_depends)
1042 else
1043         with_tic_depends=no
1044 fi
1045
1046 ###   use option --enable-wattr-macros to enable wattr* macros in curses.h
1047 AC_MSG_CHECKING(if you want to enable wattr* macros)
1048 AC_ARG_ENABLE(wattr-macros,
1049         [  --enable-wattr-macros   enable wattr* macros],
1050         [with_wattr_macros=$enableval],
1051         [with_wattr_macros=no])
1052 if [[ "x$with_wattr_macros" != xyes ]]; then
1053         NCURSES_WATTR_MACROS=0
1054         AC_MSG_RESULT(no)
1055 else
1056         NCURSES_WATTR_MACROS=1
1057         AC_MSG_RESULT(yes)
1058 fi
1059 AC_SUBST(NCURSES_WATTR_MACROS)
1060
1061 CF_WITH_X11_RGB
1062
1063 ###   use option --with-bool to override bool's type
1064 CF_WITH_TYPE(bool,
1065         [  --with-bool=TYPE        fall back to TYPE for curses 'bool' typedef],
1066         NCURSES_BOOL,
1067         auto)
1068
1069 AC_MSG_CHECKING(for alternate terminal capabilities file)
1070 AC_ARG_WITH(caps,
1071         [  --with-caps=alt         compile with alternate Caps file],
1072         [TERMINFO_CAPS=Caps.$withval],
1073         [TERMINFO_CAPS=Caps])
1074 if test ! -f "${srcdir}/include/${TERMINFO_CAPS}"
1075 then
1076         AC_MSG_WARN(file not found: "${srcdir}/include/${TERMINFO_CAPS}")
1077         TERMINFO_CAPS=Caps
1078 fi
1079 AC_MSG_RESULT($TERMINFO_CAPS)
1080 AC_SUBST(TERMINFO_CAPS)
1081
1082 ###   use option --with-chtype to override chtype's type
1083 CF_WITH_TYPE(chtype,
1084         [  --with-chtype=TYPE      override type of chtype],
1085         NCURSES_CHTYPE,
1086         $cf_dft_chtype)
1087
1088 ###   use option --with-ospeed to override ospeed's type
1089 CF_WITH_TYPE(ospeed,
1090         [  --with-ospeed=TYPE      override type of ospeed variable],
1091         NCURSES_OSPEED,
1092         short)
1093
1094 ###   use option --with-mmask-t to override mmask_t's type
1095 CF_WITH_TYPE(mmask-t,
1096         [  --with-mmask-t=TYPE     override type of mmask_t],
1097         NCURSES_MMASK_T,
1098         $cf_dft_mmask_t)
1099
1100 ###   use option --with-ccharw-max to override CCHARW_MAX size
1101 AC_MSG_CHECKING(for size CCHARW_MAX)
1102 AC_ARG_WITH(ccharw-max,
1103         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
1104         [NCURSES_CCHARW_MAX="$withval"],
1105         [NCURSES_CCHARW_MAX=$cf_dft_ccharw_max])
1106 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
1107 AC_SUBST(NCURSES_CCHARW_MAX)
1108
1109 AC_CHECK_SIZEOF([signed char])
1110 if test "$ac_cv_sizeof_signed_char" = 1 ; then
1111         NCURSES_SBOOL="signed char"
1112 else
1113         NCURSES_SBOOL="char"
1114 fi
1115 AC_MSG_CHECKING(whether to use signed chars for Boolean array in term.h)
1116 AC_ARG_ENABLE(signed-char,
1117         [  --enable-signed-char    use signed chars for Boolean array in term.h],
1118         [with_signed_char=$enableval],
1119         [with_signed_char=$cf_dft_signed_char])
1120 AC_MSG_RESULT($with_signed_char)
1121 test "x$with_signed_char" != xyes && NCURSES_SBOOL="char"
1122 AC_SUBST(NCURSES_SBOOL)
1123
1124 ###   use option --with-tparm-arg to override tparm's argument type
1125 CF_WITH_TYPE(tparm-arg,
1126         [  --with-tparm-arg=TYPE   override parameter type of tparm],
1127         NCURSES_TPARM_ARG,
1128         $cf_dft_tparm_arg)
1129
1130 ### Enable compiling-in rcs id's
1131 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
1132 AC_ARG_WITH(rcs-ids,
1133         [  --with-rcs-ids          compile-in RCS identifiers],
1134         [with_rcs_ids=$withval],
1135         [with_rcs_ids=no])
1136 AC_MSG_RESULT($with_rcs_ids)
1137 test "x$with_rcs_ids" = xyes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 to compile-in RCS identifiers])
1138
1139 ###############################################################################
1140 CF_MAN_PAGES([ captoinfo clear infocmp infotocap reset tabs tic toe tput tset ])
1141
1142 ###############################################################################
1143 CF_HELP_MESSAGE(Extensions:)
1144
1145 ### Note that some functions (such as const) are normally disabled anyway.
1146 AC_MSG_CHECKING(if you want to build with function extensions)
1147 AC_ARG_ENABLE(ext-funcs,
1148         [  --disable-ext-funcs     disable function-extensions],
1149         [with_ext_funcs=$enableval],
1150         [with_ext_funcs=yes])
1151 AC_MSG_RESULT($with_ext_funcs)
1152 if test "x$with_ext_funcs" = xyes ; then
1153         NCURSES_EXT_FUNCS=1
1154         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 to enable ncurses extended functions])
1155         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS,1,[Define to 1 to enable assume_default_colors() function in test-programs])
1156         AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 to enable curses_version() function in test-programs])
1157         AC_DEFINE(HAVE_HAS_KEY,1,[Define to 1 to enable has_key() function in test-programs])
1158         AC_DEFINE(HAVE_RESIZETERM,1,[Define to 1 to enable resizeterm() function in test-programs])
1159         AC_DEFINE(HAVE_RESIZE_TERM,1,[Define to 1 to enable resize_term() function in test-programs])
1160         AC_DEFINE(HAVE_TERM_ENTRY_H,1,[Define to 1 to enable term_entry() function in test-programs])
1161         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 to enable use_default_colors() function in test-programs])
1162         AC_DEFINE(HAVE_USE_SCREEN,1,[Define to 1 to enable use_screen() function in test-programs])
1163         AC_DEFINE(HAVE_USE_WINDOW,1,[Define to 1 to enable use_window() function in test-programs])
1164         AC_DEFINE(HAVE_WRESIZE,1,[Define to 1 to enable wresize() function in test-programs])
1165         GENERATED_EXT_FUNCS=generated
1166         test "x$with_ext_funcs" = xyes || cf_dft_ext_spfuncs=no
1167 else
1168         NCURSES_EXT_FUNCS=0
1169         GENERATED_EXT_FUNCS=
1170 fi
1171 AC_SUBST(NCURSES_EXT_FUNCS)
1172 AC_SUBST(GENERATED_EXT_FUNCS)
1173
1174 AC_MSG_CHECKING(if you want to build with SCREEN extensions)
1175 AC_ARG_ENABLE(sp-funcs,
1176         [  --enable-sp-funcs       enable SCREEN-extensions],
1177         [with_sp_funcs=$enableval],
1178         [with_sp_funcs=$cf_dft_ext_spfuncs])
1179 AC_MSG_RESULT($with_sp_funcs)
1180 if test "x$with_sp_funcs" = xyes ; then
1181         NCURSES_SP_FUNCS=1
1182         AC_DEFINE(NCURSES_SP_FUNCS,1,[Define to 1 to enable SCREEN-extensions])
1183         AC_DEFINE(HAVE_TPUTS_SP,1,[Define to 1 to enable tputs_sp() function in test-programs])
1184         GENERATED_SP_FUNCS=generated
1185 else
1186         NCURSES_SP_FUNCS=0
1187         GENERATED_SP_FUNCS=
1188 fi
1189 AC_SUBST(NCURSES_SP_FUNCS)
1190 AC_SUBST(GENERATED_SP_FUNCS)
1191
1192 AC_MSG_CHECKING(if you want to build with terminal-driver)
1193 AC_ARG_ENABLE(term-driver,
1194         [  --enable-term-driver    enable terminal-driver],
1195         [with_term_driver=$enableval],
1196         [with_term_driver=no])
1197 AC_MSG_RESULT($with_term_driver)
1198 if test "x$with_term_driver" = xyes ; then
1199         AC_DEFINE(USE_TERM_DRIVER,1,[Define to 1 to enable terminal-driver])
1200         if test "x$with_termlib" != xno ; then
1201                 AC_MSG_ERROR(The term-driver option conflicts with the termlib option)
1202         fi
1203         if test "x$with_sp_funcs" != xyes ; then
1204                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
1205         fi
1206 fi
1207
1208 ###   use option --enable-const to turn on use of const beyond that in XSI.
1209 AC_MSG_CHECKING(for extended use of const keyword)
1210 AC_ARG_ENABLE(const,
1211         [  --enable-const          compile with extra/non-standard const],
1212         [with_ext_const=$enableval],
1213         [with_ext_const=$cf_dft_ext_const])
1214 AC_MSG_RESULT($with_ext_const)
1215 NCURSES_CONST='/*nothing*/'
1216 if test "x$with_ext_const" = xyes ; then
1217         NCURSES_CONST=const
1218 fi
1219 AC_SUBST(NCURSES_CONST)
1220
1221 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
1222 AC_MSG_CHECKING(if you want to use extended colors)
1223 AC_ARG_ENABLE(ext-colors,
1224         [  --enable-ext-colors     compile for 256-color support],
1225         [with_ext_colors=$enableval],
1226         [with_ext_colors=$cf_dft_ext_colors])
1227 AC_MSG_RESULT($with_ext_colors)
1228 NCURSES_EXT_COLORS=0
1229 if test "x$with_ext_colors" = xyes ; then
1230         if test "x$with_widec" != xyes ; then
1231                 AC_MSG_WARN(This option applies only to wide-character library)
1232         else
1233                 # cannot be ABI 5 since it changes sizeof(cchar_t)
1234                 CF_NCURSES_ABI_6
1235                 NCURSES_EXT_COLORS=1
1236                 AC_DEFINE(NCURSES_EXT_COLORS,1,[Define to 1 to compile for 256-color support])
1237                 AC_DEFINE(HAVE_ALLOC_PAIR,1,[Define to 1 to enable alloc_pair() function])
1238                 AC_DEFINE(HAVE_INIT_EXTENDED_COLOR,1,[Define to 1 to enable init_extended_color() function in test-programs])
1239                 AC_DEFINE(HAVE_RESET_COLOR_PAIRS,1,[Define to 1 to enable reset_color_pairs() function in test-programs])
1240         fi
1241 fi
1242 AC_SUBST(NCURSES_EXT_COLORS)
1243
1244 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
1245 AC_MSG_CHECKING(if you want to use extended mouse encoding)
1246 AC_ARG_ENABLE(ext-mouse,
1247         [  --enable-ext-mouse      compile for extended mouse-encoding],
1248         [with_ext_mouse=$enableval],
1249         [with_ext_mouse=$cf_dft_ext_mouse])
1250 AC_MSG_RESULT($with_ext_mouse)
1251 if test "x$with_ext_mouse" = xyes ; then
1252         CF_NCURSES_ABI_6
1253 fi
1254
1255 if test $cf_cv_abi_default -le 5 ; then
1256         NCURSES_MOUSE_VERSION=1
1257 elif test $cf_cv_abi_default -le 6 ; then
1258         NCURSES_MOUSE_VERSION=2
1259 else
1260         NCURSES_MOUSE_VERSION=3
1261 fi
1262
1263 AC_SUBST(NCURSES_MOUSE_VERSION)
1264
1265 ###   use option --enable-ext-putwin to turn on extended screendumps
1266 AC_MSG_CHECKING(if you want to use extended putwin/screendump)
1267 AC_ARG_ENABLE(ext-putwin,
1268         [  --enable-ext-putwin     compile with extended putwin/screendump],
1269         [with_ext_putwin=$enableval],
1270         [with_ext_putwin=$cf_dft_ext_putwin])
1271 AC_MSG_RESULT($with_ext_putwin)
1272 if test "x$with_ext_putwin" = xyes ; then
1273         AC_DEFINE(NCURSES_EXT_PUTWIN,1,[Define to 1 to compile with extended putwin/screendump])
1274 fi
1275
1276 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
1277 AC_ARG_ENABLE(no-padding,
1278         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
1279         [with_no_padding=$enableval],
1280         [with_no_padding=$with_ext_funcs])
1281 AC_MSG_RESULT($with_no_padding)
1282 test "x$with_no_padding" = xyes && AC_DEFINE(NCURSES_NO_PADDING,1,[Define to 1 to compile with $NCURSES_NO_PADDING code])
1283
1284 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1285 AC_MSG_CHECKING(if you want SIGWINCH handler)
1286 AC_ARG_ENABLE(sigwinch,
1287         [  --enable-sigwinch       compile with SIGWINCH handler],
1288         [with_sigwinch=$enableval],
1289         [with_sigwinch=$with_ext_funcs])
1290 AC_MSG_RESULT($with_sigwinch)
1291 test "x$with_sigwinch" = xyes && AC_DEFINE(USE_SIGWINCH,1,[Define to 1 to compile with SIGWINCH handler])
1292
1293 ###   use option --enable-tcap-names to allow user to define new capabilities
1294 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1295 AC_ARG_ENABLE(tcap-names,
1296         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1297         [with_tcap_names=$enableval],
1298         [with_tcap_names=$with_ext_funcs])
1299 AC_MSG_RESULT($with_tcap_names)
1300 NCURSES_XNAMES=0
1301 if test "x$with_tcap_names" = xyes; then
1302         NCURSES_XNAMES=1
1303         AC_DEFINE(NCURSES_XNAMES,1,[Define to 1 to compile with user-definable terminal capabilities])
1304 fi
1305 AC_SUBST(NCURSES_XNAMES)
1306
1307 ##############################################################################
1308 CF_HELP_MESSAGE(Reentrant Code:)
1309 CF_WITH_PTHREAD
1310
1311 if test "x$with_pthread" != xno; then
1312         AC_CHECK_FUNC(pthread_kill,[
1313                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1314                 AC_ARG_ENABLE(pthreads-eintr,
1315                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1316                         [use_pthreads_eintr=$enableval],
1317                         [use_pthreads_eintr=no])
1318                 AC_MSG_RESULT($use_pthreads_eintr)
1319                 if test "x$use_pthreads_eintr" = xyes ; then
1320                         AC_DEFINE(USE_PTHREADS_EINTR,1,[Define to 1 to enable EINTR in wgetch with pthreads])
1321                 fi])
1322
1323         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1324         AC_ARG_ENABLE(weak-symbols,
1325                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1326                 [use_weak_symbols=$enableval],
1327                 [use_weak_symbols=no])
1328         AC_MSG_RESULT($use_weak_symbols)
1329         if test "x$use_weak_symbols" = xyes ; then
1330                 CF_WEAK_SYMBOLS
1331         else
1332                 cf_cv_weak_symbols=no
1333         fi
1334
1335         if test "x$cf_cv_weak_symbols" = xyes ; then
1336                 AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
1337         fi
1338 fi
1339
1340 PTHREAD=
1341 if test "x$with_pthread" = "xyes" ; then
1342         AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use pthreads feature])
1343         enable_reentrant=yes
1344         if test "x$cf_cv_weak_symbols" = xyes ; then
1345                 PTHREAD=-lpthread
1346                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1347         fi
1348 fi
1349 AC_SUBST(PTHREAD)
1350
1351 # Reentrant code has to be opaque; there's little advantage to making ncurses
1352 # opaque outside of that, so there is no --enable-opaque option.  We can use
1353 # this option without --with-pthreads, but this will be always set for
1354 # pthreads.
1355 AC_MSG_CHECKING(if you want reentrant code)
1356 AC_ARG_ENABLE(reentrant,
1357         [  --enable-reentrant      compile with reentrant code],
1358         [with_reentrant=$enableval],
1359         [with_reentrant=no])
1360 AC_MSG_RESULT($with_reentrant)
1361 if test "x$with_reentrant" = xyes ; then
1362         cf_cv_enable_reentrant=1
1363         cf_cv_enable_opaque="NCURSES_INTERNALS"
1364         NCURSES_SIZE_T=int
1365         if test "x$cf_cv_weak_symbols" = xyes ; then
1366                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1367                 CF_ADD_LIB(pthread,TEST_LIBS)
1368                 CF_ADD_LIB(pthread,TEST_LIBS2)
1369                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1370         else
1371                 # when not using weak symbols but with_reentrant,
1372                 # add 't' to the library suffix on all platforms
1373                 # except cygwin, where we only do that if ALSO
1374                 # compiling with full thread support.
1375                 case "$host" in
1376                 (*cygwin* | *msys*)
1377                         if test "$with_pthread" = "yes" ; then
1378                                 if test "x$disable_lib_suffixes" = "xno" ; then
1379                                         LIB_SUFFIX="t${LIB_SUFFIX}"
1380                                 fi
1381                         fi ;;
1382                 (*)
1383                         if test "x$disable_lib_suffixes" = "xno" ; then
1384                                 LIB_SUFFIX="t${LIB_SUFFIX}"
1385                         fi
1386                         ;;
1387                 esac
1388         fi
1389         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to use reentrant feature])
1390         CF_NCURSES_ABI_6
1391 else
1392         cf_cv_enable_reentrant=0
1393         cf_cv_enable_opaque="NCURSES_OPAQUE"
1394         NCURSES_SIZE_T=$cf_dft_ordinate_type
1395 fi
1396 AC_SUBST(cf_cv_enable_reentrant)
1397 AC_SUBST(cf_cv_enable_opaque)
1398
1399 AC_SUBST(NCURSES_SIZE_T)
1400
1401 AC_MSG_CHECKING(whether curses library structures should be opaque)
1402 CF_ARG_ENABLE(opaque-curses,
1403         [  --disable-opaque-curses do not make WINDOW, etc., structures opaque],
1404         [enable_opaque_curses=yes],[
1405          test "$cf_cv_enable_reentrant" = 1 && enable_opaque_curses=yes
1406          test "$cf_cv_enable_reentrant" = 1 || enable_opaque_curses=$cf_dft_opaque_curses
1407         ])
1408 AC_MSG_RESULT($enable_opaque_curses)
1409
1410 test "$cf_cv_enable_reentrant" = 1 && \
1411 test "$enable_opaque_curses" = no && \
1412 AC_MSG_ERROR(reentrant configuration requires opaque library)
1413
1414 AC_MSG_CHECKING(whether form library structures should be opaque)
1415 AC_ARG_ENABLE(opaque-form,
1416         [  --disable-opaque-form   do not make form library structures opaque],
1417         [enable_opaque_form=yes],[enable_opaque_form=$cf_dft_opaque_curses])
1418 AC_MSG_RESULT($enable_opaque_form)
1419
1420 AC_MSG_CHECKING(whether menu library structures should be opaque)
1421 AC_ARG_ENABLE(opaque-menu,
1422         [  --disable-opaque-menu   do not make menu library structures opaque],
1423         [enable_opaque_menu=yes],[enable_opaque_menu=$cf_dft_opaque_curses])
1424 AC_MSG_RESULT($enable_opaque_menu)
1425
1426 AC_MSG_CHECKING(whether panel library structures should be opaque)
1427 AC_ARG_ENABLE(opaque-panel,
1428         [  --disable-opaque-panel  do not make panel library structures opaque],
1429         [enable_opaque_panel=yes],[enable_opaque_panel=$cf_dft_opaque_curses])
1430 AC_MSG_RESULT($enable_opaque_panel)
1431
1432 NCURSES_OPAQUE=0;               test "$enable_opaque_curses" = yes && NCURSES_OPAQUE=1
1433 NCURSES_OPAQUE_FORM=0;  test "$enable_opaque_form"   = yes && NCURSES_OPAQUE_FORM=1
1434 NCURSES_OPAQUE_MENU=0;  test "$enable_opaque_menu"   = yes && NCURSES_OPAQUE_MENU=1
1435 NCURSES_OPAQUE_PANEL=0; test "$enable_opaque_panel"  = yes && NCURSES_OPAQUE_PANEL=1
1436
1437 AC_SUBST(NCURSES_OPAQUE)
1438 AC_SUBST(NCURSES_OPAQUE_FORM)
1439 AC_SUBST(NCURSES_OPAQUE_MENU)
1440 AC_SUBST(NCURSES_OPAQUE_PANEL)
1441
1442 ### Allow using a different wrap-prefix
1443 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1444         AC_MSG_CHECKING(for prefix used to wrap public variables)
1445         AC_ARG_WITH(wrap-prefix,
1446                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1447                 [NCURSES_WRAP_PREFIX=$withval],
1448                 [NCURSES_WRAP_PREFIX=_nc_])
1449         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1450 else
1451         NCURSES_WRAP_PREFIX=_nc_
1452 fi
1453 AC_SUBST(NCURSES_WRAP_PREFIX)
1454 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ prefix])
1455
1456 ###############################################################################
1457 # These options are relatively safe to experiment with.
1458 CF_HELP_MESSAGE(Development Code:)
1459 AC_MSG_CHECKING(if you want all development code)
1460 AC_ARG_WITH(develop,
1461         [  --without-develop       disable development options],
1462         [with_develop=$withval],
1463         [with_develop=no])
1464 AC_MSG_RESULT($with_develop)
1465
1466 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1467 AC_MSG_CHECKING(if you want hard-tabs code)
1468 AC_ARG_ENABLE(hard-tabs,
1469         [  --enable-hard-tabs      compile with hard-tabs code],,
1470         [enable_hard_tabs=$with_develop])
1471 AC_MSG_RESULT($enable_hard_tabs)
1472 test "x$enable_hard_tabs" = xyes && AC_DEFINE(USE_HARD_TABS,1,[Define to 1 to compile with hard-tabs code])
1473
1474 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1475 AC_MSG_CHECKING(if you want limited support for xmc)
1476 AC_ARG_ENABLE(xmc-glitch,
1477         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1478         [enable_xmc_glitch=$with_develop])
1479 AC_MSG_RESULT($enable_xmc_glitch)
1480 test "x$enable_xmc_glitch" = xyes && AC_DEFINE(USE_XMC_SUPPORT,1,[Define to 1 to compile with support for xmc (magic-cookie)])
1481
1482 ###############################################################################
1483 # These are just experimental, probably should not be in a package:
1484 CF_HELP_MESSAGE(Experimental Code:)
1485
1486 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1487 AC_ARG_ENABLE(assumed-color,
1488         [  --disable-assumed-color do not assume anything about default-colors],
1489         [with_assumed_color=$enableval],
1490         [with_assumed_color=yes])
1491 AC_MSG_RESULT($with_assumed_color)
1492 test "x$with_assumed_color" = xyes && AC_DEFINE(USE_ASSUMED_COLOR,1,[Define to 1 to assume things about default-colors])
1493
1494 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1495 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1496 AC_ARG_ENABLE(hashmap,
1497         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1498         [with_hashmap=$enableval],
1499         [with_hashmap=yes])
1500 AC_MSG_RESULT($with_hashmap)
1501 test "x$with_hashmap" = xyes && AC_DEFINE(USE_HASHMAP,1,[Define to 1 to compile with hashmap scrolling-optimization])
1502
1503 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1504 AC_MSG_CHECKING(if you want code to check screensize)
1505 AC_ARG_ENABLE(check-size,
1506         [  --enable-check-size     compile-in code to detect screensize],
1507         [with_check_size=$enableval],
1508         [with_check_size=no])
1509 AC_MSG_RESULT($with_check_size)
1510 test "x$with_check_size" = xyes && AC_DEFINE(USE_CHECK_SIZE,1,[Define to 1 to compile-in code to detect screensize])
1511
1512 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1513 AC_MSG_CHECKING(if you want colorfgbg code)
1514 AC_ARG_ENABLE(colorfgbg,
1515         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1516         [with_colorfgbg=$enableval],
1517         [with_colorfgbg=no])
1518 AC_MSG_RESULT($with_colorfgbg)
1519 test "x$with_colorfgbg" = xyes && AC_DEFINE(USE_COLORFGBG,1,[Define to 1 to compile-in experimental $COLORFGBG code])
1520
1521 ###   use option --enable-fvisibility to turn on use of gcc-specific feature
1522 AC_MSG_CHECKING(if you want to use gcc -fvisibility option)
1523 AC_ARG_ENABLE(fvisibility,
1524         [  --enable-fvisibility    compile with -fvisibility=hidden],
1525         [cf_with_fvisibility=$enableval],
1526         [cf_with_fvisibility=no])
1527 AC_MSG_RESULT($cf_with_fvisibility)
1528
1529 NCURSES_IMPEXP=
1530 NCURSES_CXX_IMPEXP=
1531 if test "x$cf_with_fvisibility" = xyes; then
1532         CF_CHECK_FVISIBILITY($CC,CFLAGS,cf_cv_fvisibility_hidden)
1533         if test "x$cf_cv_fvisibility_hidden" = xyes
1534         then
1535                 CF_ADD_CFLAGS([-fvisibility=hidden])
1536                 NCURSES_IMPEXP="__attribute__ ((visibility(\"default\")))"
1537         fi
1538         if test -n "$CXX"
1539         then
1540                 AC_LANG_PUSH(C++)
1541                 CF_CHECK_FVISIBILITY($CXX,CXXFLAGS,cf_cv_fvisibility_hidden2)
1542                 if test "x$cf_cv_fvisibility_hidden2" = xyes
1543                 then
1544                         CF_ADD_CXXFLAGS([-fvisibility=hidden])
1545                         NCURSES_CXX_IMPEXP="__attribute__ ((visibility(\"default\")))"
1546                 fi
1547                 AC_LANG_POP
1548         fi
1549 fi
1550 AC_SUBST(NCURSES_IMPEXP)
1551 AC_SUBST(NCURSES_CXX_IMPEXP)
1552
1553 ###   use option --enable-interop to turn on use of bindings used for interop
1554 AC_MSG_CHECKING(if you want interop bindings)
1555 AC_ARG_ENABLE(interop,
1556         [  --enable-interop        compile-in interop bindings],
1557         [with_exp_interop=$enableval],
1558         [with_exp_interop=$cf_dft_interop])
1559 AC_MSG_RESULT($with_exp_interop)
1560
1561 NCURSES_INTEROP_FUNCS=0
1562 test "x$with_exp_interop" = xyes && NCURSES_INTEROP_FUNCS=1
1563 AC_SUBST(NCURSES_INTEROP_FUNCS)
1564
1565
1566 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1567 AC_ARG_ENABLE(safe-sprintf,
1568         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1569         [with_safe_sprintf=$enableval],
1570         [with_safe_sprintf=no])
1571 AC_MSG_RESULT($with_safe_sprintf)
1572
1573 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1574 # when hashmap is used scroll hints are useless
1575 if test "$with_hashmap" = no ; then
1576 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1577 AC_ARG_ENABLE(scroll-hints,
1578         [  --disable-scroll-hints  compile without scroll-hints code],
1579         [with_scroll_hints=$enableval],
1580         [with_scroll_hints=yes])
1581 AC_MSG_RESULT($with_scroll_hints)
1582 test "x$with_scroll_hints" = xyes && AC_DEFINE(USE_SCROLL_HINTS,1,[Define to 1 to compile without scroll-hints code])
1583 fi
1584
1585 AC_MSG_CHECKING(if you want wgetch-events code)
1586 AC_ARG_ENABLE(wgetch-events,
1587         [  --enable-wgetch-events  compile with wgetch-events code],
1588         [with_wgetch_events=$enableval],
1589         [with_wgetch_events=no])
1590 AC_MSG_RESULT($with_wgetch_events)
1591 if test "x$with_wgetch_events" = xyes ; then
1592         AC_DEFINE(NCURSES_WGETCH_EVENTS,1,[Define to 1 to compile with wgetch-events code])
1593         NCURSES_WGETCH_EVENTS=1
1594 else
1595         NCURSES_WGETCH_EVENTS=0
1596 fi
1597 AC_SUBST(NCURSES_WGETCH_EVENTS)
1598
1599 case "$cf_cv_system_name" in
1600 (*mingw32*|*mingw64*|*-msvc*)
1601         AC_MSG_CHECKING(if you want experimental-Windows driver)
1602         AC_ARG_ENABLE(exp-win32,
1603                 [  --enable-exp-win32      compile with experimental-Windows driver],
1604                 [with_exp_win32=$enableval],
1605                 [with_exp_win32=no])
1606         AC_MSG_RESULT($with_exp_win32)
1607         if test "x$with_exp_win32" = xyes
1608         then
1609                 AC_DEFINE(EXP_WIN32_DRIVER,1,[Define to 1 to compile with experimental win32 driver])
1610                 EXP_WIN32_DRIVER=1
1611                 INTERNALS_HDR='[$](INCDIR)/nc_win32.h'
1612         else
1613                 INTERNALS_HDR='[$](INCDIR)/nc_mingw.h'
1614                 EXP_WIN32_DRIVER=0
1615         fi
1616         ;;
1617 (*)
1618         EXP_WIN32_DRIVER=0
1619         INTERNALS_HDR=
1620         ;;
1621 esac
1622 AC_SUBST(EXP_WIN32_DRIVER)
1623 AC_SUBST(INTERNALS_HDR)
1624
1625 ###############################################################################
1626 CF_HELP_MESSAGE(Testing/development Options:)
1627
1628 ###     use option --disable-echo to suppress full display compiling commands
1629 CF_DISABLE_ECHO
1630 if test "x$enable_echo" = xyes; then
1631         ECHO_LINK=
1632 else
1633         ECHO_LINK='@ echo linking $@ ... ;'
1634         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1635         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1636 fi
1637 AC_SUBST(ECHO_LINK)
1638
1639 # --disable-stripping is used for debugging
1640 CF_INSTALL_OPTS
1641
1642 # If we're avoiding relinking of shared libraries during install, that is to
1643 # avoid modifying the build-tree.  For the same reason, avoid doing ranlib if
1644 # the install program has "-p" (for preserving timestamps).
1645 cf_cv_do_reranlib=yes
1646 if test "x$cf_cv_install_p" = xyes
1647 then
1648         if test "x$cf_cv_do_relink" != xyes
1649         then
1650                 cf_cv_do_reranlib=no
1651                 INSTALL_OPT_P="-p"
1652                 INSTALL_LIB="$INSTALL_LIB $INSTALL_OPT_P"
1653         fi
1654 fi
1655 AC_SUBST(INSTALL_OPT_P)
1656
1657 ###     use option --enable-warnings to turn on all gcc warnings
1658 CF_ENABLE_WARNINGS(Wno-unknown-pragmas Wswitch-enum,yes)
1659
1660 if test "x$enable_warnings" = "xyes"; then
1661         CF_ADD_ADAFLAGS(-gnatwa -gnatyg)
1662         if test "x$cf_with_cxx" = xyes ; then
1663                 CF_GXX_WARNINGS(Wno-unused)
1664         fi
1665 fi
1666 CF_ENABLE_STRING_HACKS
1667
1668 ###     use option --enable-assertions to turn on generation of assertion code
1669 AC_MSG_CHECKING(if you want to enable runtime assertions)
1670 AC_ARG_ENABLE(assertions,
1671         [  --enable-assertions     test: turn on generation of assertion code],
1672         [with_assertions=$enableval],
1673         [with_assertions=no])
1674 AC_MSG_RESULT($with_assertions)
1675 if test -n "$GCC"
1676 then
1677         if test "$with_assertions" = no
1678         then
1679                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1680         else
1681                 CF_ADD_ADAFLAGS(-gnata)
1682         fi
1683 fi
1684
1685 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1686 CF_DISABLE_LEAKS
1687 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
1688
1689 ###     use option --enable-expanded to generate certain macros as functions
1690 AC_ARG_ENABLE(expanded,
1691         [  --enable-expanded       test: generate functions for certain macros],
1692         [test "x$enableval" = xyes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 to generate functions for certain macros])])
1693
1694 ###     use option --disable-macros to suppress macros in favor of functions
1695 AC_ARG_ENABLE(macros,
1696         [  --disable-macros        test: use functions rather than macros],
1697         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 to use functions rather than macros])])
1698
1699 # Normally we only add trace() to the debug-library.  Allow this to be
1700 # extended to all models of the ncurses library:
1701 cf_all_traces=no
1702 case "$CFLAGS $CPPFLAGS" in
1703 (*-DTRACE*)
1704         cf_all_traces=yes
1705         ;;
1706 esac
1707
1708 AC_MSG_CHECKING(whether to add trace feature to all models)
1709 AC_ARG_WITH(trace,
1710 [  --with-trace            test: add trace() function to all models of ncurses],
1711 [cf_with_trace=$withval],
1712 [cf_with_trace=$cf_all_traces])
1713 AC_MSG_RESULT($cf_with_trace)
1714
1715 if test "x$cf_with_trace" = xyes ; then
1716         LIB_TRACING=all
1717         ADA_TRACE=TRUE
1718         CF_ADD_CFLAGS(-DTRACE)
1719         AC_DEFINE(HAVE__TRACEF,1,[Define to 1 if we have _tracef function])
1720 else
1721         LIB_TRACING=DEBUG
1722         ADA_TRACE=FALSE
1723 fi
1724
1725 AC_SUBST(ADA_TRACE)
1726
1727 CF_DISABLE_GNAT_PROJECTS
1728
1729 ###     Checks for libraries.
1730 case "$cf_cv_system_name" in
1731 (*mingw32*|*mingw64*)
1732         # Note: WINVER may be a problem with Windows 10
1733         if test "x$with_exp_win32" = xyes ; then
1734                 CPPFLAGS="$CPPFLAGS -DWINVER=0x0600 -DWIN32_LEAN_AND_MEAN"
1735         else
1736                 CPPFLAGS="$CPPFLAGS -DWINVER=0x0501 -DWIN32_LEAN_AND_MEAN"
1737         fi
1738         CF_CHECK_LIBSSP
1739         ;;
1740 (*)
1741         ;;
1742 esac
1743
1744 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
1745 AC_SUBST(MATH_LIB)
1746
1747 ###     Checks for header files.
1748 AC_HEADER_TIME
1749 CF_REGEX
1750
1751 dnl These are some other potentially nonportable headers.
1752 AC_CHECK_HEADERS( \
1753 fcntl.h \
1754 getopt.h \
1755 limits.h \
1756 locale.h \
1757 math.h \
1758 poll.h \
1759 sys/auxv.h \
1760 sys/ioctl.h \
1761 sys/param.h \
1762 sys/poll.h \
1763 sys/select.h \
1764 sys/time.h \
1765 sys/times.h \
1766 unistd.h \
1767 wctype.h \
1768 )
1769
1770 CF_GETOPT_HEADER
1771
1772 CF_CHECK_ENVIRON(environ)
1773 CF_CHECK_GETENV
1774 if test "x$cf_cv_consistent_getenv" = xno && \
1775         test "x$cf_with_trace" = xyes
1776 then
1777         AC_MSG_WARN(The NCURSES_TRACE environment variable is not supported with this configuration)
1778 fi
1779
1780 CF_SYS_TIME_SELECT
1781
1782 ###     checks for compiler characteristics
1783 AC_LANG_C
1784 AC_C_CONST
1785 CF_C_INLINE(NCURSES_INLINE,1200)
1786 CF_SIG_ATOMIC_T
1787
1788 if test "$NCURSES_CHTYPE" = auto ; then
1789         CF_TYPEOF_CHTYPE
1790 else
1791         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1792 fi
1793 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1794 AC_SUBST(cf_cv_typeof_chtype)
1795
1796 CF_UNSIGNED_LITERALS
1797 cf_cv_1UL="1"
1798 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1799 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1800 AC_SUBST(cf_cv_1UL)
1801
1802 if test "$NCURSES_MMASK_T" = auto ; then
1803         cf_cv_typeof_mmask_t=long
1804 else
1805         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1806 fi
1807 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1808 AC_SUBST(cf_cv_typeof_mmask_t)
1809
1810 ###     Checks for external-data
1811 CF_ERRNO
1812 CF_LINK_DATAONLY
1813
1814 ###     Checks for library functions.
1815 CF_FUNC_GETTIME
1816 AC_CHECK_FUNCS( \
1817 fpathconf \
1818 getcwd \
1819 getauxval \
1820 getegid \
1821 geteuid \
1822 getopt \
1823 getuid \
1824 issetugid \
1825 localeconv \
1826 poll \
1827 putenv \
1828 remove \
1829 select \
1830 setbuf \
1831 setbuffer \
1832 setenv \
1833 setfsuid \
1834 setvbuf \
1835 sigaction \
1836 sigvec \
1837 snprintf \
1838 strdup \
1839 strstr \
1840 sysconf \
1841 tcgetpgrp \
1842 times \
1843 tsearch \
1844 vsnprintf \
1845 )
1846
1847 CF_FUNC_GETTTYNAM
1848
1849 if test "x$ac_cv_func_getopt" = xno && \
1850    test "x$cf_with_progs$cf_with_tests" != xnono; then
1851         AC_MSG_ERROR(getopt is required for building programs)
1852 fi
1853
1854 if test "x$with_safe_sprintf" = xyes
1855 then
1856         if test "x$ac_cv_func_vsnprintf" = xyes
1857         then
1858                 AC_MSG_WARN(will use vsnprintf instead of safe-sprintf option)
1859         else
1860                 AC_DEFINE(USE_SAFE_SPRINTF,1,[Define to 1 to compile with experimental safe-sprintf code])
1861         fi
1862 fi
1863
1864 if test "x$with_getcap" = "xyes" ; then
1865         CF_CGETENT
1866 fi
1867
1868 CF_ISASCII
1869 CF_STRUCT_SIGACTION
1870 CF_FUNC_NANOSLEEP
1871 CF_FUNC_TERMIOS
1872 CF_FUNC_VSSCANF
1873 CF_MKSTEMP
1874
1875 # setup for prototype of fallback for vsscanf()
1876 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1877
1878 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1879 if test "x$cross_compiling" = xyes ; then
1880         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1881 else
1882         AC_FUNC_SETVBUF_REVERSED
1883 fi
1884 AC_CHECK_TYPE(intptr_t, long)
1885 AC_CHECK_TYPE(ssize_t, int)
1886 CF_TYPE_SIGACTION
1887 CF_SIZECHANGE
1888 CF_FUNC_MEMMOVE
1889 CF_FUNC_POLL
1890 CF_VA_COPY
1891 AC_FUNC_VFORK
1892 CF_FOPEN_BIN_R
1893
1894 # special check for test/ditto.c
1895 CF_FUNC_OPENPTY
1896 if test "$cf_cv_func_openpty" != no ; then
1897         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
1898         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
1899         if test "x$cf_cv_lib_util" = xyes ; then
1900                 CF_ADD_LIB(util,TEST_LIBS)
1901         fi
1902 fi
1903 AC_SUBST(TEST_LIBS)
1904 AC_SUBST(TEST_LIBS2)
1905
1906 if test "$with_hashed_db" != no ; then
1907         AC_DEFINE(USE_HASHED_DB,1,[Define to 1 if we should build terminfo in hashed database])
1908         CF_HASHED_DB($with_hashed_db)
1909 fi
1910
1911 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1912 if test -z "$cf_user_CFLAGS" && test "$enable_leaks" = yes ; then
1913         CF_STRIP_G_OPT(CFLAGS)
1914         CF_STRIP_G_OPT(CXXFLAGS)
1915 fi
1916
1917 # Just in case, check if the C compiler has a bool type.
1918 CF_BOOL_DECL(cf_cv_cc_bool_type)
1919
1920 # Check for C++ compiler characteristics (and ensure that it's there!)
1921 if test -n "$CXX" ; then
1922         AC_LANG_CPLUSPLUS
1923         CF_STDCPP_LIBRARY
1924         CF_PROG_CC_C_O(CXX,[$CXXFLAGS $CPPFLAGS])
1925
1926         case "$GXX_VERSION" in
1927         (1.*|2.[[0-6]]*|[[1-9]][[0-9]].*)
1928                 cf_cxx_library=yes
1929                 ;;
1930         (*-2.7*|2.7*)
1931                 CF_GPP_LIBRARY
1932                 ;;
1933         (*)
1934                 cf_cxx_library=no
1935                 ;;
1936         esac
1937
1938         AC_CHECK_HEADERS(typeinfo)
1939         CF_CXX_IOSTREAM_NAMESPACE
1940         CF_BOOL_DECL
1941         CF_BOOL_SIZE
1942         CF_ETIP_DEFINES
1943         CF_CPP_OVERRIDE
1944         CF_CPP_PARAM_INIT
1945         CF_CPP_STATIC_CAST
1946         CF_CXX_AR_FLAGS
1947 else
1948         cf_cxx_library=no
1949         cf_cv_builtin_bool=1
1950
1951         # Just because we are not configuring against C++ right now does not
1952         # mean that a user will not want to use C++.  Some distributors disable
1953         # the C++ portion of this configuration as a shortcut (or just to avoid
1954         # compiling the demo in the c++ directory).  So we need a reasonable
1955         # default for the 'bool' type.
1956         #
1957         # Caveat: since the storage of the bool type is not standardized, it
1958         # may change.
1959
1960         if test "$NCURSES_BOOL" != auto ; then
1961                 cf_cv_type_of_bool=$NCURSES_BOOL
1962                 cf_cv_header_stdbool_h=0
1963         else
1964                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1965                         CF_BOOL_SIZE
1966                 else
1967                         AC_MSG_CHECKING(for fallback type of bool)
1968                         case "$host_cpu" in
1969                         (i?86)  cf_cv_type_of_bool=char ;;
1970                         (*)     cf_cv_type_of_bool=int  ;;
1971                         esac
1972                         AC_MSG_RESULT($cf_cv_type_of_bool)
1973                 fi
1974         fi
1975 fi
1976 AC_SUBST(CXXLIBS)
1977
1978 # If the C compiler did not declare bool, and we did not determine that the C++
1979 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1980 # ncurses library use the same type as C++ bool.  Note that this allows one to
1981 # specify the type of bool in a configure-script option and postpone
1982 # integration with the C++ compiler provided that the types are compatible.
1983 USE_CXX_BOOL=1
1984 if test "$cf_cv_cc_bool_type" = 1
1985 then
1986         # oops: C has a bool.  Unlikely, but C++ could differ.
1987         USE_CXX_BOOL=0
1988 elif test "$cf_cv_builtin_bool" = 0
1989 then
1990         # C++ has no bool
1991         USE_CXX_BOOL=0
1992 else
1993         # this is the normal case
1994         USE_CXX_BOOL='defined(__cplusplus)'
1995 fi
1996 AC_SUBST(USE_CXX_BOOL)
1997
1998 CF_HELP_MESSAGE(Ada Binding Options:)
1999
2000 dnl If the Ada95 source-tree is present, add that to the build unless it will
2001 dnl not work, or was not requested.
2002 if test -f "${srcdir}/Ada95/Makefile.in" ; then
2003
2004 dnl libtool does not know anything about GNAT, though a change made in 1998
2005 dnl provided for it "someday".  Disable the ada subtree if we are using
2006 dnl libtool -TD 20070714
2007         if test "$cf_with_ada" != "no" ; then
2008                 if test "$with_libtool" != "no"; then
2009                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
2010                         cf_with_ada=no
2011                 fi
2012         fi
2013
2014 dnl Check for availability of GNU Ada Translator (GNAT).
2015 dnl At the moment we support no other Ada compiler.
2016         if test "$cf_with_ada" != "no" ; then
2017                 CF_PROG_GNAT
2018                 if test "x$cf_cv_prog_gnat_correct" = xyes; then
2019                         CF_ADD_ADAFLAGS(-gnatpn)
2020                         CF_FIXUP_ADAFLAGS
2021
2022                         CF_GNATPREP_OPT_T
2023
2024                         CF_GNAT_GENERICS
2025                         CF_GNAT_SIGINT
2026                         CF_GNAT_PROJECTS
2027
2028                         CF_WITH_ADA_COMPILER
2029
2030                         cf_ada_package=terminal_interface
2031                         AC_SUBST(cf_ada_package)
2032
2033                         CF_WITH_ADA_INCLUDE
2034                         CF_WITH_ADA_OBJECTS
2035                         CF_WITH_ADA_SHAREDLIB
2036
2037                         # allow the Ada binding to be renamed
2038                         CF_WITH_ADA_LIBNAME(AdaCurses)
2039                 fi
2040         fi
2041 else
2042         cf_with_ada=no
2043 fi
2044
2045 # do this "late" to avoid conflict with header-checks
2046 if test "x$with_widec" = xyes ; then
2047         AC_CHECK_SIZEOF(wchar_t)
2048         # cross-compiling to mingw can run into the problem that attempting to
2049         # link with the regex library fails, causing the test to not set this to
2050         # a number.  "recent" autoconf does not address this problem either -TD
2051         if test -z "$ac_cv_sizeof_wchar_t"
2052         then
2053                 CF_VERBOSE(test failed (assume 2))
2054                 sed /SIZEOF_WCHAR_T/d confdefs.h >confdefs.tmp
2055                 mv confdefs.tmp confdefs.h
2056                 echo "#define SIZEOF_WCHAR_T 2" >>confdefs.h
2057         fi
2058 fi
2059
2060 ### Construct the ncurses library-subsets, if any, from this set of keywords:
2061 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
2062 ###
2063 ### ticlib modules may be a separate library, otherwise contained in termlib.
2064 ### termlib modules may be a separate library, otherwise contained in ncurses.
2065 ###
2066 ### The of "+" or " " between the tokens controls the way the script
2067 ### chooses to split module lists into libraries.
2068 ###
2069 ### (see CF_LIB_RULES).
2070 AC_MSG_CHECKING(for library subsets)
2071 LIB_SUBSETS=
2072
2073 if test "x$cf_with_progs" = xyes || test "$with_ticlib" != no || test "$with_termcap" != no; then
2074         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
2075         if test "$with_ticlib" != no ; then
2076                 LIB_SUBSETS="${LIB_SUBSETS} "
2077         else
2078                 LIB_SUBSETS="${LIB_SUBSETS}+"
2079         fi
2080 fi
2081
2082 LIB_SUBSETS="${LIB_SUBSETS}termlib"
2083 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
2084
2085 if test "$with_termlib" != no ; then
2086         LIB_SUBSETS="${LIB_SUBSETS} "
2087 else
2088         LIB_SUBSETS="${LIB_SUBSETS}+"
2089 fi
2090
2091 LIB_SUBSETS="${LIB_SUBSETS}base"
2092
2093 # Most term-driver calls are to tinfo, but some like init_pair are to the
2094 # base library (so it resides in base).
2095 if test "$with_term_driver" != no ; then
2096         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
2097         case "$cf_cv_system_name" in
2098         (*mingw32*|*mingw64*)
2099                 if test "x$with_exp_win32" = xyes ; then
2100                         LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32"
2101                 else
2102                         LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
2103                 fi
2104                 CPPFLAGS="$CPPFLAGS -DUSE_WIN32CON_DRIVER"
2105                 ;;
2106         (*)
2107                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
2108                 ;;
2109         esac
2110 elif test "x$with_exp_win32" = xyes ; then
2111         case "$cf_cv_system_name" in
2112         (*mingw32*|*mingw64*)
2113                 LIB_SUBSETS="${LIB_SUBSETS}+port_win32"
2114                 ;;
2115         (*)
2116                 ;;
2117         esac
2118 fi
2119
2120 test "x$with_widec"     = xyes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
2121 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
2122
2123 AC_MSG_RESULT($LIB_SUBSETS)
2124
2125 ### Construct the list of include-directories to be generated
2126 CF_INCLUDE_DIRS
2127 CF_ADA_INCLUDE_DIRS
2128
2129 ### Build up pieces for makefile rules
2130 AC_MSG_CHECKING(default library suffix)
2131 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
2132 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
2133 AC_MSG_RESULT($DFT_ARG_SUFFIX)
2134
2135 AC_MSG_CHECKING(default library-dependency suffix)
2136 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
2137 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
2138 AC_MSG_RESULT($DFT_DEP_SUFFIX)
2139
2140 AC_MSG_CHECKING(default object directory)
2141 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
2142 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
2143 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
2144
2145 if test "x$cf_with_cxx" = xyes ; then
2146 AC_MSG_CHECKING(c++ library-dependency suffix)
2147 if test "$with_libtool" != "no"; then
2148         # libtool thinks it can make c++ shared libraries (perhaps only g++)
2149         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2150 elif test "$with_shared_cxx" != "no"; then
2151         # also for g++ users...
2152         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2153 else
2154         # we normally make a static library because C/C++ library rules differ
2155         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)
2156 fi
2157 AC_MSG_RESULT($CXX_LIB_SUFFIX)
2158 AC_SUBST(CXX_LIB_SUFFIX)
2159 fi
2160
2161 # do not want -ldl in build except as needed for -lncurses dependency
2162 if test "x$with_dlsym" = xyes ; then
2163 if test "$DFT_LWR_MODEL" = shared || \
2164    test "$DFT_LWR_MODEL" = libtool ; then
2165         CF_REMOVE_LIB(LIBS,$LIBS,dl)
2166 fi
2167 fi
2168 ### Set up low-level terminfo dependencies for makefiles.
2169
2170 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
2171 # do not need libdl
2172 TICS_LIST=
2173 if test "x$with_dlsym" = xyes ; then
2174         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
2175 fi
2176
2177 USE_ARG_SUFFIX="${DFT_ARG_SUFFIX}${EXTRA_SUFFIX}"
2178 USE_LIB_SUFFIX="${LIB_SUFFIX}${EXTRA_SUFFIX}"
2179 USE_CFG_SUFFIX=${DFT_ARG_SUFFIX}${cf_cv_abi_version}
2180 if test -n "$EXTRA_SUFFIX" && test "x$EXTRA_SUFFIX" != "x${cf_cv_abi_version}"
2181 then
2182         USE_CFG_SUFFIX="${USE_CFG_SUFFIX}${EXTRA_SUFFIX}"
2183 fi
2184 AC_SUBST(USE_ARG_SUFFIX)
2185 AC_SUBST(USE_CFG_SUFFIX)
2186 AC_SUBST(USE_LIB_SUFFIX)
2187
2188 if test "$with_ticlib" != no ; then
2189
2190         if test "x$with_ticlib" != xyes ; then
2191                 TICS_NAME=$with_ticlib
2192                 TICS_SUFFIX="`echo "${DFT_LIB_SUFFIX}" |sed -e "s/^${USE_LIB_SUFFIX}//"`"
2193                 TICS_ARG_SUFFIX="${with_ticlib}`echo "${USE_ARG_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2194                 TICS_DEP_SUFFIX="${with_ticlib}`echo "${DFT_DEP_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2195                 TICS_LIB_SUFFIX="${with_ticlib}"
2196         else
2197                 TICS_SUFFIX=${DFT_LIB_SUFFIX}
2198                 TICS_ARG_SUFFIX="${TICS_NAME}${USE_ARG_SUFFIX}"
2199                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
2200                 TICS_LIB_SUFFIX="${TICS_NAME}${USE_LIB_SUFFIX}"
2201         fi
2202         TICS_LDFLAGS="-L${LIB_DIR}"
2203         TICS_LIBS="-l${TICS_ARG_SUFFIX}"
2204 else
2205         TICS_SUFFIX=${DFT_LIB_SUFFIX}
2206         TICS_LDFLAGS="-L${LIB_DIR}"
2207         TICS_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2208 fi
2209 AC_SUBST(TICS_ARG_SUFFIX)
2210 AC_SUBST(TICS_DEP_SUFFIX)
2211 AC_SUBST(TICS_LIB_SUFFIX)
2212 AC_SUBST(TICS_LDFLAGS)
2213 AC_SUBST(TICS_LIBS)
2214
2215 if test "$with_termlib" != no ; then
2216
2217         if test "x$with_termlib" != xyes ; then
2218                 TINFO_NAME=$with_termlib
2219                 TINFO_SUFFIX="`echo "${DFT_LIB_SUFFIX}" |sed -e "s/^${USE_LIB_SUFFIX}//"`"
2220                 TINFO_ARG_SUFFIX="${with_termlib}`echo "${USE_ARG_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2221                 TINFO_DEP_SUFFIX="${with_termlib}`echo "${DFT_DEP_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2222                 TINFO_LIB_SUFFIX="${with_termlib}"
2223         else
2224                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2225                 TINFO_ARG_SUFFIX="${TINFO_NAME}${USE_ARG_SUFFIX}"
2226                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
2227                 TINFO_LIB_SUFFIX="${TINFO_NAME}${USE_LIB_SUFFIX}"
2228         fi
2229
2230         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2231         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2232         if test "$DFT_LWR_MODEL" = "libtool"; then
2233                 TEST_ARGS="${TEST_DEPS}"
2234                 TEST_ARG2="${TEST_DEP2}"
2235                 TINFO_LDFLAGS="-L${LIB_DIR}"
2236                 TINFO_LIBS="$TEST_ARGS"
2237                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
2238                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
2239         else
2240                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
2241                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
2242                 if test "x$with_term_driver" != xno ; then
2243                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2244                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${USE_ARG_SUFFIX}"
2245                         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
2246                 else
2247                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2248                         TINFO_LIBS="$TEST_ARGS"
2249                 fi
2250                 TINFO_LDFLAGS="-L${LIB_DIR}"
2251                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2252         fi
2253 else
2254         # the next lines are needed for linking libtic over libncurses
2255         TINFO_NAME=${LIB_NAME}
2256         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2257         TINFO_ARG_SUFFIX=${LIB_NAME}${USE_ARG_SUFFIX}
2258         if test "x$with_tic_depends" = xyes ; then
2259                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2260         else
2261                 TICS_LIST="$SHLIB_LIST"
2262         fi
2263
2264         TINFO_LDFLAGS="-L${LIB_DIR}"
2265         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2266 fi
2267
2268 if test "$DFT_LWR_MODEL" = shared ; then
2269         case "$cf_cv_system_name" in
2270         (cygwin*|msys*)
2271                 # "lib" files have ".dll.a" suffix, "cyg"or "msys-" files have ".dll"
2272                 TINFO_SUFFIX=.dll
2273                 ;;
2274         esac
2275 fi
2276
2277 AC_SUBST(TINFO_ARG_SUFFIX)
2278 AC_SUBST(TINFO_DEP_SUFFIX)
2279 AC_SUBST(TINFO_LIB_SUFFIX)
2280 AC_SUBST(TINFO_LDFLAGS)
2281 AC_SUBST(TINFO_LIBS)
2282
2283 if test "x$with_dlsym" = xyes ; then
2284         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
2285 fi
2286
2287 if test "$DFT_LWR_MODEL" = "libtool"; then
2288         OBJEXT=lo
2289 fi
2290
2291 # needed for Ada95
2292 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
2293 AC_SUBST(TINFO_LDFLAGS2)
2294
2295 case "$DFT_LWR_MODEL" in
2296 (normal|debug|profile)
2297         CF_LDFLAGS_STATIC
2298         ;;
2299 esac
2300
2301 AC_MSG_CHECKING(where we will install curses.h)
2302 AC_SUBST(includesubdir)
2303 includesubdir=
2304 if test "$with_overwrite" = no && \
2305  { test "x$includedir" = 'x${prefix}/include' || \
2306    test "x$includedir" = "x${prefix}/include"; }
2307 then
2308         includesubdir="/ncurses${USE_LIB_SUFFIX}"
2309 fi
2310 AC_MSG_RESULT(${includedir}${includesubdir})
2311
2312 ### Resolve a conflict between normal and wide-curses by forcing applications
2313 ### that will need libutf8 to add it to their configure script.
2314 if test "$with_overwrite" != no ; then
2315 if test "$NCURSES_LIBUTF8" = 1 ; then
2316         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
2317         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
2318 fi
2319 fi
2320 WITH_OVERWRITE=$with_overwrite
2321
2322 ### At least on MinGW a shared library build without libtool
2323 ### requires adding the additional libs to the link list.
2324 case "$cf_cv_system_name" in
2325 (*mingw32*|*mingw64*)
2326         if test "$DFT_LWR_MODEL" != "libtool"; then
2327            SHLIB_LIST="$SHLIB_LIST ${LIBS}"
2328         fi
2329         ;;
2330 *)      ;;
2331 esac
2332
2333 AC_SUBST(WITH_OVERWRITE)
2334 AC_SUBST(TICS_LIST)
2335 AC_SUBST(TINFO_LIST)
2336 AC_SUBST(SHLIB_LIST)
2337
2338 ### predefined stuff for the test programs
2339 AC_DEFINE(HAVE_SLK_COLOR,1,[Define to 1 if we have slk_color for test-programs])
2340
2341 # pkgsrc uses these
2342 CF_HELP_MESSAGE(Library basenames for pkgsrc:)
2343 CF_WITH_LIB_BASENAME(FORM_NAME,form)
2344 CF_WITH_LIB_BASENAME(MENU_NAME,menu)
2345 CF_WITH_LIB_BASENAME(PANEL_NAME,panel)
2346 CF_WITH_LIB_BASENAME(CXX_NAME,cxx,ncurses++)
2347
2348 ### Construct the list of subdirectories for which we'll customize makefiles
2349 ### with the appropriate compile-rules.
2350
2351 CF_SRC_MODULES($modules_to_build)
2352
2353 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2354    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/src/library.gpr:Ada95/src/library.gpr.in"
2355    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${USE_CFG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
2356    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${USE_CFG_SUFFIX}-config.1:man/MKada_config.in"
2357 fi
2358
2359 CF_DIRS_TO_MAKE
2360
2361 # symbols that differ when compiling Ada95 by itself.
2362 NCURSES_SHLIB2=$SHELL' $(top_srcdir)/misc/shlib'
2363 AC_SUBST(NCURSES_SHLIB2)
2364
2365 # values to use as strings
2366 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as library path-separator])
2367
2368 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}",[Define to 1 if machine has ample memory for tic])
2369
2370 ### Define substitutions for header files to avoid name-pollution
2371 CF_SUBST_IF(["x$cf_cv_have_tcgetattr" = xyes], HAVE_TCGETATTR, 1, 0)
2372 CF_SUBST_IF(["x$ac_cv_header_stdint_h" = xyes], HAVE_STDINT_H, 1, 0)
2373 CF_SUBST_IF(["x$ac_cv_header_termio_h" = xyes], HAVE_TERMIO_H, 1, 0)
2374 CF_SUBST_IF(["x$ac_cv_header_termios_h" = xyes], HAVE_TERMIOS_H, 1, 0)
2375
2376 ################################################################################
2377 test "x$use_database" = xyes && \
2378 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
2379
2380 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
2381 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${USE_CFG_SUFFIX}-config.1:man/MKncu_config.in"
2382
2383 if test "x$enable_pc_files" = xyes && test -z "$MAKE_PC_FILES" ; then
2384 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
2385 fi
2386 AC_SUBST(cross_compiling)
2387
2388 if test "x$cf_with_tests" != xno ; then
2389         MAKE_TESTS=
2390 else
2391         MAKE_TESTS="#"
2392 fi
2393 AC_SUBST(MAKE_TESTS)
2394
2395 ADAHTML_DIR=../../doc/html/ada
2396 AC_SUBST(ADAHTML_DIR)
2397
2398 # workaround for OS/2 (20151017)
2399 case "$cf_cv_system_name" in
2400 (os2*)
2401         LIBTOOL_OPTS_CXX="-os2dllname ncurs++"
2402         ;;
2403 (*)
2404         LIBTOOL_OPTS_CXX=
2405         ;;
2406 esac
2407 AC_SUBST(LIBTOOL_OPTS_CXX)
2408
2409 # workaround for g++ versus Solaris (20131116)
2410 case "$cf_cv_system_name" in
2411 (solaris2*)
2412         case "x$CPPFLAGS" in
2413         (*-D_XOPEN_SOURCE_EXTENDED*)
2414                 CF_VERBOSE(moving _XOPEN_SOURCE_EXTENDED to work around g++ problem)
2415                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
2416                 CPPFLAGS=`echo "x$CPPFLAGS" | sed -e  's/^.//' -e 's/-D_XOPEN_SOURCE_EXTENDED//'`
2417                 ;;
2418         esac
2419         ;;
2420 esac
2421
2422 # Help to automatically enable the extended curses features when using either
2423 # the *-config or the ".pc" files by adding defines.
2424 AC_MSG_CHECKING(for defines to add to ncurses${USE_CFG_SUFFIX}${cf_config_suffix}-config script)
2425 PKG_CFLAGS=
2426 for cf_loop1 in $CPPFLAGS_after_XOPEN
2427 do
2428         cf_found=no
2429         for cf_loop2 in $CPPFLAGS_before_XOPEN
2430         do
2431                 if test "x$cf_loop1" = "x$cf_loop2"
2432                 then
2433                         cf_found=yes
2434                         break
2435                 fi
2436         done
2437         test "$cf_found" = no && PKG_CFLAGS="$PKG_CFLAGS $cf_loop1"
2438 done
2439 AC_MSG_RESULT($PKG_CFLAGS)
2440 AC_SUBST(PKG_CFLAGS)
2441
2442 # AC_CHECK_SIZEOF demands a literal parameter, no variables.  So we do this.
2443 case "x$NCURSES_OSPEED" in
2444 (*short*)
2445         cf_compatible=1
2446         ;;
2447 (*)
2448         cf_compatible=0
2449         ;;
2450 esac
2451 AC_DEFINE_UNQUOTED(NCURSES_OSPEED_COMPAT,$cf_compatible,[Define to 1 if termcap variable ospeed is short])
2452
2453 case "x$cf_cv_typeof_chtype" in
2454 (xshort|xint|xlong)
2455         cf_cv_typeof_chtype="unsigned $cf_cv_typeof_chtype"
2456         ;;
2457 esac
2458
2459 case "x$cf_cv_typeof_mmask_t" in
2460 (xshort|xint|xlong)
2461         cf_cv_typeof_mmask_t="unsigned $cf_cv_typeof_mmask_t"
2462         ;;
2463 esac
2464
2465 # substitute into misc/Makefile to suppress
2466 # (un)install.data from the
2467 # (un)install rules.
2468 if test "x$cf_with_db_install" = "xno"; then
2469         MISC_INSTALL_DATA=
2470         MISC_UNINSTALL_DATA=
2471 else
2472         MISC_INSTALL_DATA=install.data
2473         MISC_UNINSTALL_DATA=uninstall.data
2474 fi
2475 AC_SUBST(MISC_INSTALL_DATA)
2476 AC_SUBST(MISC_UNINSTALL_DATA)
2477
2478 if test "x$cf_with_db_install" = "xno" || test "x$TERMINFO_SRC" = "xno"; then
2479         MAKE_DATABASE="#"
2480 else
2481         MAKE_DATABASE="$MAKE_TERMINFO"
2482 fi
2483 AC_SUBST(MAKE_DATABASE)
2484
2485 dnl Override the package used for exported symbols
2486 if test -n "$PACKAGE"
2487 then
2488         PACKAGE="${PACKAGE}${DFT_ARG_SUFFIX}"
2489         export PACKAGE
2490         echo "package: $PACKAGE"
2491 fi
2492
2493 UNALTERED_SYMS=
2494 cf_filter_syms=no
2495
2496 if test -n "$RESULTING_SYMS"
2497 then
2498         cf_filter_syms=$cf_dft_filter_syms
2499         CF_VERBOSE(will map symbols to ABI=$cf_cv_abi_default)
2500 fi
2501
2502 if test "x$WILDCARD_SYMS" = xno
2503 then
2504         cf_filter_syms=yes
2505 fi
2506
2507 test "x$cf_with_trace" = xyes && NCURSES_INLINE=
2508
2509 UNALTERED_SYMS=`echo "$RESULTING_SYMS" | sed -e 's/\\$/\\\\$/g'`
2510 if test "$cf_filter_syms" = yes
2511 then
2512         RESULTING_SYMS=resulting.map
2513 fi
2514 AC_SUBST(UNALTERED_SYMS)
2515
2516 if test "x$cross_compiling" = xyes ; then
2517         ADAGEN_LDFLAGS='$(CROSS_LDFLAGS)'
2518         CHECK_BUILD="#"
2519 else
2520         ADAGEN_LDFLAGS='$(NATIVE_LDFLAGS)'
2521         CHECK_BUILD=
2522 fi
2523 AC_SUBST(ADAGEN_LDFLAGS)
2524 AC_SUBST(CHECK_BUILD)
2525 AC_SUBST(PRIVATE_LIBS)
2526
2527 # This is used for the *-config script and *.pc data files.
2528 CF_LD_SEARCHPATH
2529
2530 AC_OUTPUT( \
2531         include/MKterm.h.awk \
2532         include/curses.head:include/curses.h.in \
2533         include/ncurses_dll.h \
2534         include/termcap.h \
2535         include/unctrl.h \
2536         man/man_db.renames \
2537         $SUB_MAKEFILES \
2538         Makefile,[
2539 if test "x$cf_with_tests" != xno ; then
2540         CF_PRG_RULES(["$srcdir/test/mk-test.awk" INSTALL=no ECHO_LINK="$ECHO_LD"], test)
2541 fi
2542 CF_LIB_RULES($SRC_SUBDIRS)
2543 CF_OUTPUT_MANPAGE_RENAMES
2544
2545 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2546 if test -z "$USE_OLD_MAKERULES" ; then
2547         $AWK -f "$srcdir/Ada95/mk-1st.awk" <"$srcdir/Ada95/src/modules" >>Ada95/src/Makefile
2548 fi
2549 fi
2550 ],[
2551 ### Special initialization commands, used to pass information from the
2552 ### configuration-run into config.status
2553
2554 ALTERNATE_SYMS="$ALTERNATE_SYMS"
2555 AWK="$AWK"
2556 CXX_NAME="$CXX_NAME"
2557 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
2558 DFT_LWR_MODEL="$DFT_LWR_MODEL"
2559 ECHO_LD="$ECHO_LD"
2560 EXTRA_SUFFIX="$EXTRA_SUFFIX"
2561 FORM_NAME="$FORM_NAME"
2562 LDCONFIG="$LDCONFIG"
2563 LIBTOOL_VERSION="$LIBTOOL_VERSION"
2564 LIB_NAME="$LIB_NAME"
2565 LIB_PREFIX="$LIB_PREFIX"
2566 LIB_SUBSETS="$LIB_SUBSETS"
2567 LIB_SUFFIX="$LIB_SUFFIX"
2568 LIB_TRACING="$LIB_TRACING"
2569 LN_S="$LN_S"
2570 MAKE_TERMINFO="$MAKE_TERMINFO"
2571 MANPAGE_RENAMES="$MANPAGE_RENAMES"
2572 MENU_NAME="$MENU_NAME"
2573 NCURSES_MAJOR="$NCURSES_MAJOR"
2574 NCURSES_MINOR="$NCURSES_MINOR"
2575 NCURSES_OSPEED="$NCURSES_OSPEED"
2576 NCURSES_PATCH="$NCURSES_PATCH"
2577 PANEL_NAME="$PANEL_NAME"
2578 SRC_SUBDIRS="$SRC_SUBDIRS"
2579 TERMINFO="$TERMINFO"
2580 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
2581 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
2582 TICS_NAME="$TICS_NAME"
2583 TICS_SUFFIX="$TICS_SUFFIX"
2584 TIC_PATH="$TIC_PATH"
2585 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
2586 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
2587 TINFO_NAME="$TINFO_NAME"
2588 TINFO_SUFFIX="$TINFO_SUFFIX"
2589 UNALTERED_SYMS="$UNALTERED_SYMS"
2590 USE_ARG_SUFFIX="$USE_ARG_SUFFIX"
2591 USE_CFG_SUFFIX="$USE_CFG_SUFFIX"
2592 USE_LIB_SUFFIX="$USE_LIB_SUFFIX"
2593 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
2594 WILDCARD_SYMS="$WILDCARD_SYMS"
2595 WITH_CURSES_H="$with_curses_h"
2596 WITH_ECHO="${enable_echo:=yes}"
2597 WITH_OVERWRITE="$with_overwrite"
2598 cf_LIST_MODELS="$cf_list_models"
2599 cf_cv_VERSION_GNATMAKE=$cf_cv_VERSION_GNATMAKE
2600 cf_cv_VERSION_GPRBUILD=$cf_cv_VERSION_GPRBUILD
2601 cf_cv_abi_default="$cf_cv_abi_default"
2602 cf_cv_abi_version="$cf_cv_abi_version"
2603 cf_cv_do_relink="$cf_cv_do_relink"
2604 cf_cv_do_reranlib="$cf_cv_do_reranlib"
2605 cf_cv_do_symlinks="$cf_cv_do_symlinks"
2606 cf_cv_enable_lp64="$cf_cv_enable_lp64"
2607 cf_cv_enable_opaque="$cf_cv_enable_opaque"
2608 cf_cv_make_PHONY="$cf_cv_make_PHONY"
2609 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
2610 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
2611 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
2612 cf_cv_rel_version="$cf_cv_rel_version"
2613 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
2614 cf_cv_shared_soname='$cf_cv_shared_soname'
2615 cf_cv_shlib_version="$cf_cv_shlib_version"
2616 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
2617 cf_cv_system_name="$cf_cv_system_name"
2618 cf_cv_term_driver="$with_term_driver"
2619 cf_with_ada="$cf_with_ada"
2620 cf_with_cxx_binding="$cf_with_cxx_binding"
2621 cf_with_db_install="$cf_with_db_install"
2622 cf_with_manpages="$cf_with_manpages"
2623 cf_with_tests="$cf_with_tests"
2624 host="$host"
2625 target="$target"
2626 verbose="$verbose"
2627 with_shared_cxx="$with_shared_cxx"
2628
2629 ],cat)dnl
2630 ${MAKE:-make} preinstall