configure.in

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2022,2023 Thomas E. Dickey                                *
   3 dnl Copyright 1998-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl Author: Thomas E. Dickey 1995-on
  31 dnl
  32 dnl $Id: configure.in,v 1.766 2023/10/16 23:04:12 tom Exp $
  33 dnl Process this file with autoconf to produce a configure script.
  34 dnl
  35 dnl For additional information, see
  36 dnl     https://invisible-island.net/autoconf/
  37 dnl     https://invisible-island.net/autoconf/my-autoconf.html
  38 dnl
  39 dnl ---------------------------------------------------------------------------
  40 AC_PREREQ(2.52.20210101)
  41 AC_REVISION($Revision: 1.766 $)
  42 AC_INIT(ncurses/base/lib_initscr.c)
  43 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  44
  45 AC_DEFUN([AC_PATH_XTRA],[])dnl ignore dependencies on this
  46
  47 CF_TOP_BUILDDIR
  48 CF_SUBST_NCURSES_VERSION
  49 CF_VERSION_INFO(NCURSES,ncurses)
  50
  51 CF_WITH_REL_VERSION(NCURSES)
  52 CF_NCURSES_WITH_ABI_VERSION
  53
  54 CF_WITH_SYSTYPE
  55
  56 ###     Save the given $CFLAGS to allow user-override.
  57 cf_user_CFLAGS="$CFLAGS"
  58
  59 ###     Default install-location
  60 CF_CFG_DEFAULTS
  61 ### Defaults for ncurses ABI
  62 CF_ABI_DEFAULTS
  63
  64 ### override ABI version, e.g., packagers
  65 CF_WITH_ABI_ALTERED
  66
  67 ###     Checks for programs.
  68 AC_ARG_WITH(ada,
  69         [  --without-ada           suppress check for Ada compiler, don't build demo],
  70         [cf_with_ada=$withval],
  71         [cf_with_ada=yes])
  72
  73 if test "x$cf_with_ada" = xyes
  74 then
  75         cf_prog_cc="gnatgcc gcc cc"
  76 else
  77         cf_prog_cc="gcc cc"
  78 fi
  79 CF_PROG_CC($cf_prog_cc)
  80
  81 AC_PROG_CPP
  82 AC_PROG_GCC_TRADITIONAL
  83 CF_PROG_CC_C_O(CC,[$CFLAGS $CPPFLAGS])
  84 CF_PROG_LDCONFIG
  85
  86 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  87 dnl                             configure script by not letting us test if C++
  88 dnl                             is present, making this option necessary.
  89 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  90 AC_ARG_WITH(cxx,
  91         [  --without-cxx           do not adjust ncurses bool to match C++],
  92         [cf_with_cxx=$withval],
  93         [cf_with_cxx=yes])
  94 AC_MSG_RESULT($cf_with_cxx)
  95 if test "X$cf_with_cxx" = Xno ; then
  96         CXX=""
  97         GXX=""
  98 else
  99         # with autoconf 2.13, we can change the error to a warning:
 100         pushdef([AC_MSG_ERROR],
 101                 [AC_MSG_RESULT(no)
 102                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
 103                 cf_with_cxx=no; CXX=""; GXX="";])dnl
 104         AC_PROG_CXX
 105         popdef([AC_MSG_ERROR])dnl
 106
 107         AC_LANG_PUSH(C++)
 108         if test "x$cf_with_cxx" != xno
 109         then
 110                 # Several of the C++ configurations do not work, particularly when
 111                 # cross-compiling (20140913 -TD)
 112                 AC_MSG_CHECKING(if $CXX works)
 113
 114                 save_CPPFLAGS="$CPPFLAGS"
 115                 eval cf_includedir=${includedir}
 116                 CPPFLAGS="$CPPFLAGS -I${cf_includedir}"
 117                 AC_TRY_COMPILE([
 118 #include <stdlib.h>
 119 #include <stdio.h>
 120 ],
 121                 [
 122                 printf("Hello world!\n")
 123                 ],
 124                 [cf_cxx_works=yes],
 125                 [cf_cxx_works=no])
 126                 CPPFLAGS="$save_CPPFLAGS"
 127
 128                 AC_MSG_RESULT($cf_cxx_works)
 129                 if test "x$cf_cxx_works" = xno
 130                 then
 131                         AC_MSG_WARN([Ignore $CXX, since it cannot compile hello-world.])
 132                         cf_with_cxx=no; CXX=""; GXX="";
 133                 fi
 134         fi
 135         AC_LANG_POP
 136
 137         # autoconf 2.5x removed the error (hardcoding it to g++, or just blank)
 138         if test "$CXX" = "g++" ; then
 139                 AC_PATH_PROG(CXX,g++)
 140         fi
 141         case "x$CXX" in
 142         (x|xg++)
 143                 AC_MSG_WARN([You don't have any C++ compiler, too bad])
 144                 cf_with_cxx=no; CXX=""; GXX="";
 145                 ;;
 146         esac
 147 fi
 148
 149 CF_GXX_VERSION
 150 case "$GXX_VERSION" in
 151 ([[1-9]][[0-9]].*)
 152         ;;
 153 (1.*|2.[[0-6]]*)
 154         AC_MSG_WARN(templates do not work)
 155         ;;
 156 esac
 157
 158 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 159 AC_ARG_WITH(cxx-binding,
 160         [  --without-cxx-binding   do not build C++ binding and demo],
 161         [cf_with_cxx_binding=$withval],
 162         [cf_with_cxx_binding=$cf_with_cxx])
 163 AC_MSG_RESULT($cf_with_cxx_binding)
 164
 165 AC_MSG_CHECKING(if you want to build with Ada)
 166 AC_MSG_RESULT($cf_with_ada)
 167
 168 AC_MSG_CHECKING(if you want to install terminal database)
 169 AC_ARG_ENABLE(db-install,
 170         [  --disable-db-install    suppress install of terminal database],
 171         [cf_with_db_install=$enableval],
 172         [cf_with_db_install=yes])
 173 AC_MSG_RESULT($cf_with_db_install)
 174
 175 AC_MSG_CHECKING(if you want to install manpages)
 176 AC_ARG_WITH(manpages,
 177         [  --without-manpages      suppress install of manpages],
 178         [cf_with_manpages=$withval],
 179         [cf_with_manpages=yes])
 180 AC_MSG_RESULT($cf_with_manpages)
 181
 182 AC_MSG_CHECKING(if you want to build programs such as tic)
 183 AC_ARG_WITH(progs,
 184         [  --without-progs         suppress build/install with programs (e.g., tic)],
 185         [cf_with_progs=$withval],
 186         [cf_with_progs=yes])
 187 AC_MSG_RESULT($cf_with_progs)
 188
 189 AC_MSG_CHECKING(if you want to build test-programs)
 190 AC_ARG_WITH(tests,
 191         [  --without-tests         suppress build/install with test-programs],
 192         [cf_with_tests=$withval],
 193         [cf_with_tests=yes])
 194 AC_MSG_RESULT($cf_with_tests)
 195
 196 AC_MSG_CHECKING(if you wish to install curses.h)
 197 AC_ARG_WITH(curses-h,
 198         [  --without-curses-h      install curses.h as ncurses.h only],
 199         [with_curses_h=$withval],
 200         [with_curses_h=yes])
 201 AC_MSG_RESULT($with_curses_h)
 202
 203 modules_to_build="ncurses"
 204 test "X$cf_with_progs" != Xno && modules_to_build="$modules_to_build progs"
 205 modules_to_build="$modules_to_build panel menu form"
 206
 207 AC_ARG_PROGRAM
 208
 209 CF_PROG_AWK
 210 CF_PROG_INSTALL
 211 CF_PROG_LINT
 212 CF_PROG_LN_S
 213
 214 AC_SYS_LONG_FILE_NAMES
 215
 216 # Provide for renaming "ncurses5-config" to "ncurses5X-config", etc., in case
 217 # of package conflict.
 218 cf_config_suffix=
 219 AC_ARG_WITH(config-suffix,
 220         [  --with-config-suffix=X  suffixes ncursesXX-config file],
 221         [case "x$withval" in
 222         (xyes|xno)
 223                 AC_MSG_WARN(expected a value for config-suffix option)
 224                 ;;
 225         (*)     cf_config_suffix="$withval"
 226                 ;;
 227         esac])
 228 AC_SUBST(cf_config_suffix)
 229
 230 # If we find pkg-config, check if we should install the ".pc" files.
 231 CF_PKG_CONFIG
 232 CF_WITH_PKG_CONFIG_LIBDIR
 233 CF_ENABLE_PC_FILES
 234 if test -z "$MAKE_PC_FILES"
 235 then
 236         AC_MSG_CHECKING(for suffix to add to pc-files)
 237 AC_ARG_WITH(pc-suffix,
 238         [  --with-pc-suffix        suffixes pc-files],
 239         [case "x$withval" in
 240         (xyes|xno)
 241                 PC_MODULE_SUFFIX=
 242                 ;;
 243         (*)     PC_MODULE_SUFFIX="$withval"
 244                 ;;
 245         esac])
 246         test -z "$PC_MODULE_SUFFIX" && PC_MODULE_SUFFIX=none
 247         AC_MSG_RESULT($PC_MODULE_SUFFIX)
 248         test "$PC_MODULE_SUFFIX" = none && PC_MODULE_SUFFIX=
 249         AC_SUBST(PC_MODULE_SUFFIX)
 250 fi
 251
 252 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 253 AC_ARG_ENABLE(mixed-case,
 254         [  --enable-mixed-case     tic should assume mixed-case filenames],
 255         [enable_mixedcase=$enableval],
 256         [enable_mixedcase=auto])
 257 AC_MSG_RESULT($enable_mixedcase)
 258 if test "$enable_mixedcase" = "auto" ; then
 259         CF_MIXEDCASE_FILENAMES
 260 else
 261         cf_cv_mixedcase=$enable_mixedcase
 262         if test "x$enable_mixedcase" = "xyes" ; then
 263                 AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if tic should assume mixed-case filenames])
 264         fi
 265 fi
 266
 267 # do this after mixed-case option (tags/TAGS is not as important as tic).
 268 AC_PROG_MAKE_SET
 269 CF_MAKE_PHONY
 270 CF_MAKE_TAGS
 271 CF_MAKEFLAGS
 272
 273 dnl These are standard among *NIX systems, but not when cross-compiling
 274 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 275 AC_CHECK_TOOL(LD, ld, ld)
 276 AC_CHECK_TOOL(AR, ar, ar)
 277 AC_CHECK_TOOL(NM, nm, nm)
 278 CF_AR_FLAGS
 279
 280 dnl Special option for use by system-builders: the install-prefix is used to
 281 dnl adjust the location into which the actual install is done, so that an
 282 dnl archive can be built without modifying the host system's configuration.
 283 AC_MSG_CHECKING(if you have specified an install-prefix)
 284 AC_ARG_WITH(install-prefix,
 285         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 286         [case "x$withval" in
 287         (xyes|xno)
 288                 ;;
 289         (*)     DESTDIR="$withval"
 290                 ;;
 291         esac])
 292 AC_MSG_RESULT($DESTDIR)
 293 AC_SUBST(DESTDIR)
 294
 295 ###############################################################################
 296 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 297 # If we're cross-compiling, allow the user to override the tools and their
 298 # options.  The configure script is oriented toward identifying the host
 299 # compiler, etc., but we need a build compiler to generate parts of the source.
 300
 301 case "$cf_cv_system_name" in
 302 (*-msvc*)
 303         LDFLAGS="$LDFLAGS user32.lib"
 304         export LDFLAGS
 305         ;;
 306 esac
 307
 308 CF_BUILD_CC
 309
 310 ###############################################################################
 311 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 312
 313 ### Options to allow the user to specify the set of libraries which are used.
 314 ### Use "--without-normal --with-shared" to allow the default model to be
 315 ### shared, for example.
 316 cf_list_models=""
 317 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 318
 319 CF_WITH_LIBTOOL
 320 if test "$with_libtool" != "no" ; then
 321
 322 cf_list_models="$cf_list_models libtool"
 323
 324 else
 325
 326 AC_MSG_CHECKING(if you want to build shared libraries)
 327 AC_ARG_WITH(shared,
 328         [  --with-shared           generate shared-libraries],
 329         [with_shared=$withval],
 330         [with_shared=no])
 331 AC_MSG_RESULT($with_shared)
 332 test "x$with_shared" = "xyes" && cf_list_models="$cf_list_models shared"
 333
 334 AC_MSG_CHECKING(if you want to build static libraries)
 335 AC_ARG_WITH(normal,
 336         [  --with-normal           generate normal-libraries (default)],
 337         [with_normal=$withval],
 338         [with_normal=yes])
 339 AC_MSG_RESULT($with_normal)
 340 test "x$with_normal" = "xyes" && cf_list_models="$cf_list_models normal"
 341
 342 AC_MSG_CHECKING(if you want to build debug libraries)
 343 AC_ARG_WITH(debug,
 344         [  --with-debug            generate debug-libraries (default)],
 345         [with_debug=$withval],
 346         [with_debug=yes])
 347 AC_MSG_RESULT($with_debug)
 348 test "x$with_debug" = "xyes" && cf_list_models="$cf_list_models debug"
 349
 350 AC_MSG_CHECKING(if you want to build profiling libraries)
 351 AC_ARG_WITH(profile,
 352         [  --with-profile          generate profile-libraries],
 353         [with_profile=$withval],
 354         [with_profile=no])
 355 AC_MSG_RESULT($with_profile)
 356 test "x$with_profile" = "xyes" && cf_list_models="$cf_list_models profile"
 357
 358 fi
 359
 360 if test "X$cf_with_cxx_binding" != Xno; then
 361 if test "x$with_shared" = "xyes"; then
 362 AC_MSG_CHECKING(if you want to build C++ shared libraries)
 363 AC_ARG_WITH(cxx-shared,
 364         [  --with-cxx-shared       generate C++ shared-libraries],
 365         [with_shared_cxx=$withval],
 366         [with_shared_cxx=no])
 367 AC_MSG_RESULT($with_shared_cxx)
 368 fi
 369 fi
 370
 371 ###############################################################################
 372
 373 AC_MSG_CHECKING(for specified models)
 374 test -z "$cf_list_models" && cf_list_models=normal
 375 dnl If we use libtool to generate libraries, then it must be the only
 376 dnl specified model.
 377 test "$with_libtool" != "no" && cf_list_models=libtool
 378 AC_MSG_RESULT($cf_list_models)
 379
 380 ### Use the first model as the default, and save its suffix for use in building
 381 ### up test-applications.
 382 AC_MSG_CHECKING(for default model)
 383 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 384 AC_MSG_RESULT($DFT_LWR_MODEL)
 385
 386 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 387
 388 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 389 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 390
 391 TICS_NAME=tic
 392 AC_SUBST(TICS_NAME)
 393
 394 TINFO_NAME=tinfo
 395 AC_SUBST(TINFO_NAME)
 396
 397 LIB_NAME=ncurses
 398 AC_SUBST(LIB_NAME)
 399
 400 LIB_DIR=../lib
 401 LIB_2ND=../../lib
 402
 403 CF_WITH_LIB_PREFIX(cf_prefix)
 404
 405 LIB_SUFFIX=
 406 AC_SUBST(LIB_SUFFIX)
 407 CF_PATHSEP
 408
 409 # headers needed for checks...
 410 AC_CHECK_DECL(exit)
 411 AC_HEADER_DIRENT
 412
 413 ###############################################################################
 414
 415 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 416 AC_ARG_WITH(termlib,
 417         [  --with-termlib          generate separate terminfo library],
 418         [with_termlib=$withval],
 419         [with_termlib=no])
 420 AC_MSG_RESULT($with_termlib)
 421
 422 AC_MSG_CHECKING(if you want to build a separate tic library)
 423 AC_ARG_WITH(ticlib,
 424         [  --with-ticlib           generate separate tic library],
 425         [with_ticlib=$withval],
 426         [with_ticlib=no])
 427 AC_MSG_RESULT($with_ticlib)
 428
 429 dnl Not all ports of gcc support the -g option
 430
 431 if test X"$CC_G_OPT" = X"" ; then
 432         CC_G_OPT='-g'
 433         test -n "$GCC" && test "x${ac_cv_prog_cc_g}" != xyes && CC_G_OPT=''
 434 fi
 435 AC_SUBST(CC_G_OPT)
 436
 437 if test X"$CXX_G_OPT" = X"" ; then
 438         CXX_G_OPT='-g'
 439         test -n "$GXX" && test "x${ac_cv_prog_cxx_g}" != xyes && CXX_G_OPT=''
 440 fi
 441 AC_SUBST(CXX_G_OPT)
 442
 443 AC_MSG_CHECKING(for default loader flags)
 444 case "$DFT_LWR_MODEL" in
 445 (libtool) LD_MODEL=''   ;;
 446 (normal)  LD_MODEL=''   ;;
 447 (debug)   LD_MODEL=$CC_G_OPT ;;
 448 (profile) LD_MODEL='-pg';;
 449 (shared)  LD_MODEL=''   ;;
 450 esac
 451 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 452 AC_MSG_RESULT($LD_MODEL)
 453
 454 case "$DFT_LWR_MODEL" in
 455 (shared)
 456 CF_ENABLE_RPATH
 457 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 458 AC_ARG_ENABLE(relink,
 459 [  --disable-relink        relink shared libraries during install],
 460 [cf_cv_do_relink=$enableval],
 461 [cf_cv_do_relink=yes])
 462 AC_MSG_RESULT($cf_cv_do_relink)
 463         ;;
 464 esac
 465
 466 # we will build libraries one-level down.
 467 rel_builddir=..
 468 CF_SHARED_OPTS
 469 for model in $cf_list_models ; do
 470         case "$model" in
 471         (libtool)
 472                 CF_WITH_LIBTOOL_OPTS
 473                 CF_WITH_EXPORT_SYMS
 474                 ;;
 475         (shared)
 476                 if test "$CC_SHARED_OPTS" = "unknown"; then
 477                         AC_ERROR(Shared libraries are not supported in this version)
 478                 fi
 479                 # workaround for inept transition to PIE vs PIC...
 480                 AC_MSG_CHECKING(if current CFLAGS link properly)
 481                 AC_TRY_LINK(
 482                         [#include <stdio.h>],
 483                         [printf("Hello work\\n");],
 484                         [cf_cflags_work=yes],
 485                         [cf_cflags_work=no])
 486                 AC_MSG_RESULT($cf_cflags_work)
 487                 if test "$cf_cflags_work" = no
 488                 then
 489                         CF_VERBOSE(try to work around by appending shared-options)
 490                         CFLAGS="$CFLAGS $CC_SHARED_OPTS"
 491                 fi
 492                 CF_WITH_VERSIONED_SYMS
 493                 ;;
 494         esac
 495 done
 496
 497 ### Checks for special libraries, must be done up-front.
 498 SHLIB_LIST=""
 499 CF_WITH_GPM
 500 if test "$with_gpm" != no ; then
 501         AC_MSG_CHECKING(if you want to load GPM dynamically)
 502         AC_ARG_WITH(dlsym,
 503                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 504                 [with_dlsym=$withval],
 505                 [with_dlsym=yes])
 506         AC_MSG_RESULT($with_dlsym)
 507         if test "x$with_dlsym" = xyes ; then
 508                 CF_FUNC_DLSYM
 509                 if test "x$with_gpm" != xyes ; then
 510                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 511                         cf_cv_gpm_soname="$with_gpm"
 512                 else
 513                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 514                 fi
 515                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname",[Define as needed to set the gpm share library soname])
 516                 SHLIB_LIST="-ldl $SHLIB_LIST"
 517                 CF_ADD_LIB(dl,PRIVATE_LIBS)
 518         else
 519                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 520                 CF_ADD_LIB(gpm,TEST_LIBS)
 521                 CF_ADD_LIB(gpm,PRIVATE_LIBS)
 522         fi
 523         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
 524         CF_CHECK_GPM_WGETCH
 525 fi
 526
 527 CF_WITH_PCRE2
 528 CF_WITH_SYSMOUSE
 529
 530 # pretend that ncurses==ncursesw==ncursest
 531 AC_MSG_CHECKING(if you want to disable library suffixes)
 532 CF_ARG_DISABLE(lib-suffixes,
 533         [  --disable-lib-suffixes  disable library suffixes],
 534         [disable_lib_suffixes=yes],
 535         [disable_lib_suffixes=no],
 536         no)
 537 AC_MSG_RESULT($disable_lib_suffixes)
 538
 539 ### If we're building with rpath, try to link non-standard libs that way too.
 540 if test "$DFT_LWR_MODEL" = "shared" && test "x$cf_cv_enable_rpath" != xno; then
 541         CF_DISABLE_RPATH_HACK
 542 fi
 543
 544 ### Depending on the system, someone may use rpath to build ncurses but not
 545 # want users of the package to rely upon that feature.  Give those people an
 546 # option to suppress that detail from EXTRA_LDFLAGS.
 547 EXTRA_PKG_LDFLAGS="$LDFLAGS $EXTRA_LDFLAGS"
 548 if test -n "$EXTRA_PKG_LDFLAGS"
 549 then
 550         AC_MSG_CHECKING(if you want to disable extra LDFLAGS for package-scripts)
 551         CF_ARG_DISABLE(pkg-ldflags,
 552                 [  --disable-pkg-ldflags   disable extra LDFLAGS for package-scripts],
 553                 [disable_pkg_ldflags=yes],
 554                 [disable_pkg_ldflags=no],
 555                 no)
 556         AC_MSG_RESULT($disable_pkg_ldflags)
 557         test "$disable_pkg_ldflags" = yes && EXTRA_PKG_LDFLAGS=
 558 fi
 559 AC_SUBST(EXTRA_PKG_LDFLAGS)
 560
 561 ###############################################################################
 562 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 563
 564 ###     use option --with-extra-suffix to append suffix to headers and libraries
 565 AC_MSG_CHECKING(if you wish to append extra suffix to header/library paths)
 566 EXTRA_SUFFIX=
 567 AC_ARG_WITH(extra-suffix,
 568         [  --with-extra-suffix=X   append extra suffix to header/library paths],
 569         [case x$withval in
 570         (xno)
 571                 ;;
 572         (xyes|x)
 573                 EXTRA_SUFFIX=$cf_cv_abi_version
 574                 ;;
 575         (*)
 576                 EXTRA_SUFFIX=$withval
 577                 ;;
 578         esac
 579         ])
 580 AC_MSG_RESULT($EXTRA_SUFFIX)
 581 AC_SUBST(EXTRA_SUFFIX)
 582
 583 ###     use option --disable-overwrite to leave out the link to -lcurses
 584 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 585 AC_ARG_ENABLE(overwrite,
 586         [  --disable-overwrite     put headers in subdir, omit link to -lcurses],
 587         [with_overwrite=$enableval],
 588         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 589 AC_MSG_RESULT($with_overwrite)
 590
 591 AC_MSG_CHECKING(if external terminfo-database is used)
 592 AC_ARG_ENABLE(database,
 593         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 594         [use_database=$enableval],
 595         [use_database=yes])
 596 AC_MSG_RESULT($use_database)
 597
 598 case "$host_os" in
 599 (os2*)
 600         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 601         ;;
 602 (*)
 603         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 604         ;;
 605 esac
 606 AC_SUBST(TERMINFO_SRC)
 607
 608 NCURSES_USE_DATABASE=0
 609 if test "$use_database" != no ; then
 610         NCURSES_USE_DATABASE=1
 611
 612         AC_MSG_CHECKING(which terminfo source-file will be installed)
 613         AC_ARG_WITH(database,
 614                 [  --with-database=XXX     specify terminfo source to install],
 615                 [TERMINFO_SRC=$withval])
 616         AC_MSG_RESULT($TERMINFO_SRC)
 617
 618         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 619         AC_ARG_WITH(hashed-db,
 620                 [  --with-hashed-db        specify hashed-database library],,
 621                 [with_hashed_db=no])
 622         AC_MSG_RESULT($with_hashed_db)
 623 else
 624         with_hashed_db=no
 625 fi
 626 AC_SUBST(NCURSES_USE_DATABASE)
 627
 628 AC_MSG_CHECKING(for list of fallback descriptions)
 629 AC_ARG_WITH(fallbacks,
 630         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 631         [with_fallback=$withval],
 632         [with_fallback=])
 633 AC_MSG_RESULT($with_fallback)
 634
 635 case ".$with_fallback" in
 636 (.|.no)
 637         FALLBACK_LIST=
 638         ;;
 639 (.yes)
 640         AC_MSG_WARN(expected a list of terminal descriptions)
 641         ;;
 642 (*)
 643         FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
 644         ;;
 645 esac
 646
 647 # The fallback feature in ncurses relies upon tic/infocmp outside the build
 648 # tree for generating the terminal descriptions that will be compiled into the
 649 # library.  If your toolchain is old, it may not handle current terminal
 650 # databases.  Use configure-options to point to the tools which will be used,
 651 # rather than the first ones found on the $PATH.
 652 AC_CHECK_TOOL(TIC, tic)
 653 AC_CHECK_TOOL(INFOCMP, infocmp)
 654 if test -n "$FALLBACK_LIST"
 655 then
 656         CF_WITH_PATH_PROG(TIC,     tic,     [for fallbacks], $PATH:/usr/local/ncurses/bin)
 657         CF_WITH_PATH_PROG(INFOCMP, infocmp, [for fallbacks], $PATH:/usr/local/ncurses/bin)
 658         test -z "$TIC" && FALLBACK_LIST=
 659         test -z "$INFOCMP" && FALLBACK_LIST=
 660         if test -z "$FALLBACK_LIST"
 661         then
 662                 AC_MSG_WARN(ignoring fallback option because tic/infocmp are not available)
 663         fi
 664 fi
 665 AC_SUBST(TIC)
 666 AC_SUBST(INFOCMP)
 667
 668 USE_FALLBACKS=
 669 test -z "$FALLBACK_LIST" && USE_FALLBACKS="#"
 670 AC_SUBST(FALLBACK_LIST)
 671 AC_SUBST(USE_FALLBACKS)
 672
 673 AC_MSG_CHECKING(if you want modern xterm or antique)
 674 AC_ARG_WITH(xterm-new,
 675         [  --without-xterm-new     specify if xterm terminfo should be old version],
 676         [with_xterm_new=$withval],
 677         [with_xterm_new=yes])
 678 case "$with_xterm_new" in
 679 (no) with_xterm_new=xterm-old;;
 680 (*)      with_xterm_new=xterm-new;;
 681 esac
 682 AC_MSG_RESULT($with_xterm_new)
 683 WHICH_XTERM=$with_xterm_new
 684 AC_SUBST(WHICH_XTERM)
 685
 686 case $host_os in
 687 (*linux-gnu|*cygwin|*mingw32|*msys)
 688         want_xterm_kbs=DEL
 689         ;;
 690 (*)
 691         want_xterm_kbs=BS
 692         ;;
 693 esac
 694
 695 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
 696 AC_ARG_WITH(xterm-kbs,
 697         [  --with-xterm-kbs=XXX    specify if xterm backspace sends BS or DEL],
 698         [with_xterm_kbs=$withval],
 699         [with_xterm_kbs=auto])
 700 case x$with_xterm_kbs in
 701 (xyes|xno|xBS|xbs|x8)
 702         with_xterm_kbs=BS
 703         ;;
 704 (xDEL|xdel|x127)
 705         with_xterm_kbs=DEL
 706         ;;
 707 (xauto)
 708         with_xterm_kbs=$want_xterm_kbs
 709         ;;
 710 (*)
 711         with_xterm_kbs=$withval
 712         ;;
 713 esac
 714 AC_MSG_RESULT($with_xterm_kbs)
 715 XTERM_KBS=$with_xterm_kbs
 716 AC_SUBST(XTERM_KBS)
 717
 718 if test "x$with_xterm_kbs" != "x$want_xterm_kbs"
 719 then
 720         AC_MSG_WARN([expected --with-xterm-kbs=$want_xterm_kbs for $host_os, have $with_xterm_kbs])
 721 fi
 722
 723 MAKE_TERMINFO=
 724 if test "$use_database" = no ; then
 725         TERMINFO="${datadir}/terminfo"
 726         MAKE_TERMINFO="#"
 727 else
 728
 729 AC_MSG_CHECKING(for list of terminfo directories)
 730 CF_WITH_PATHLIST(terminfo-dirs,
 731         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 732         TERMINFO_DIRS,
 733         DATADIR/terminfo,
 734         ${datadir}/terminfo)
 735 AC_MSG_RESULT($TERMINFO_DIRS)
 736 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS",[Define as needed to predefine the TERMINFO_DIR searchlist])
 737
 738 case "x$TERMINFO" in
 739 x???:*)
 740         AC_MSG_WARN(ignoring non-directory/file TERMINFO value)
 741         unset TERMINFO
 742         ;;
 743 esac
 744
 745 AC_MSG_CHECKING(for default terminfo directory)
 746 CF_WITH_PATH(default-terminfo-dir,
 747         [  --with-default-terminfo-dir=DIR default terminfo directory],
 748         TERMINFO,
 749         DATADIR/terminfo,
 750         ${datadir}/terminfo)
 751 AC_MSG_RESULT($TERMINFO)
 752 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO",[Define to set the default terminal database path])
 753
 754 fi
 755
 756 AC_SUBST(TERMINFO)
 757 AC_SUBST(MAKE_TERMINFO)
 758
 759 ###     use option --disable-big-core to make tic run on small machines
 760 ###     We need 4Mb, check if we can allocate 50% more than that.
 761 AC_MSG_CHECKING(if big-core option selected)
 762 AC_ARG_ENABLE(big-core,
 763         [  --disable-big-core      assume machine has little memory],
 764         [with_big_core=$enableval],
 765         [AC_TRY_RUN([
 766 #include <stdlib.h>
 767 #include <string.h>
 768 int main() {
 769         unsigned long n = 6000000L;
 770         char *s = malloc(n);
 771         if (s != 0)
 772                 s[0] = s[n-1] = 0;
 773         ${cf_cv_main_return:-return}(s == 0);
 774 }],
 775         [with_big_core=yes],
 776         [with_big_core=no],
 777         [with_big_core=no])])
 778 AC_MSG_RESULT($with_big_core)
 779 test "x$with_big_core" = "xyes" && AC_DEFINE(HAVE_BIG_CORE,1,[Define to 1 if machine has ample memory for tic])
 780
 781 ### ISO C only guarantees 512-char strings, we have tables which load faster
 782 ### when constructed using "big" strings.  More than the C compiler, the awk
 783 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 784 AC_MSG_CHECKING(if big-strings option selected)
 785 AC_ARG_ENABLE(big-strings,
 786         [  --disable-big-strings   assume compiler has only standard-size strings],
 787         [with_big_strings=$enableval],
 788         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 789 AC_MSG_RESULT($with_big_strings)
 790
 791 USE_BIG_STRINGS=0
 792 test "x$with_big_strings" = "xyes" && USE_BIG_STRINGS=1
 793 AC_SUBST(USE_BIG_STRINGS)
 794
 795 ###     use option --enable-termcap to compile in the termcap fallback support
 796 AC_MSG_CHECKING(if you want termcap-fallback support)
 797 AC_ARG_ENABLE(termcap,
 798         [  --enable-termcap        compile in termcap fallback support],
 799         [with_termcap=$enableval],
 800         [with_termcap=no])
 801 AC_MSG_RESULT($with_termcap)
 802
 803 NCURSES_USE_TERMCAP=0
 804 if test "x$with_termcap" != "xyes" ; then
 805         if test "$use_database" = no ; then
 806                 if test -z "$with_fallback" ; then
 807                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 808                 fi
 809         fi
 810         AC_DEFINE(PURE_TERMINFO,1,[Define to 1 if we should support only terminfo])
 811 else
 812
 813         if test "$with_ticlib" != no ; then
 814                 AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 815         fi
 816
 817         NCURSES_USE_TERMCAP=1
 818         AC_MSG_CHECKING(for list of termcap files)
 819         CF_WITH_PATHLIST(termpath,
 820                 [  --with-termpath=XXX     specify list of termcap files],
 821                 TERMPATH,
 822                 /etc/termcap:/usr/share/misc/termcap)
 823         AC_MSG_RESULT($TERMPATH)
 824         test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH",[Define to set the termcap searchlist])
 825
 826         ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 827         AC_MSG_CHECKING(if fast termcap-loader is needed)
 828         AC_ARG_ENABLE(getcap,
 829                 [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 830                 [with_getcap=$enableval],
 831                 [with_getcap=no])
 832         AC_MSG_RESULT($with_getcap)
 833         test "x$with_getcap" = "xyes" && AC_DEFINE(USE_GETCAP,1,[Define to 1 to use fast termcap-loader])
 834
 835         AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 836         AC_ARG_ENABLE(getcap-cache,
 837                 [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 838                 [with_getcap_cache=$enableval],
 839                 [with_getcap_cache=no])
 840         AC_MSG_RESULT($with_getcap_cache)
 841         test "x$with_getcap_cache" = "xyes" && AC_DEFINE(USE_GETCAP_CACHE,1,[Define to 1 if translated termcap should be stored in $HOME/.terminfo])
 842
 843 fi
 844 AC_SUBST(NCURSES_USE_TERMCAP)
 845
 846 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 847 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 848 AC_ARG_ENABLE(home-terminfo,
 849         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 850         [with_home_terminfo=$enableval],
 851         [with_home_terminfo=yes])
 852 AC_MSG_RESULT($with_home_terminfo)
 853 test "x$with_home_terminfo" = "xyes" && AC_DEFINE(USE_HOME_TERMINFO,1,[Define to 1 if $HOME/.terminfo feature is wanted])
 854
 855 AC_MSG_CHECKING(if you want to permit root to use ncurses environment variables)
 856 AC_ARG_ENABLE(root-environ,
 857         [  --disable-root-environ  restrict root use of ncurses environment variables],
 858         [with_root_environ=$enableval],
 859         [with_root_environ=yes])
 860 AC_MSG_RESULT($with_root_environ)
 861 test "x$with_root_environ" = xyes && AC_DEFINE(USE_ROOT_ENVIRON,1,[Define to 1 if root/setuid application is allowed to use ncurses environment])
 862
 863 AC_MSG_CHECKING(if you want to permit setuid programs to access all files)
 864 AC_ARG_ENABLE(root-access,
 865         [  --disable-root-access   restrict file-access when running setuid],
 866         [with_root_access=$enableval],
 867         [with_root_access=yes])
 868 AC_MSG_RESULT($with_root_access)
 869 test "x$with_root_access" = xyes && AC_DEFINE(USE_ROOT_ACCESS,1,[Define to 1 if setuid is allowed all file-access])
 870
 871 AC_MSG_CHECKING(if you want to permit setuid use of ncurses environment variables)
 872 AC_ARG_ENABLE(setuid-environ,
 873         [  --disable-setuid-environ restrict setuid use of ncurses environment variables],
 874         [with_setuid_environ=$enableval],
 875         [with_setuid_environ=$with_root_environ])
 876 AC_MSG_RESULT($with_setuid_environ)
 877 test "x$with_setuid_environ" = xyes && AC_DEFINE(USE_SETUID_ENVIRON,1,[Define to 1 if setuid/setgid application is allowed to use ncurses environment])
 878
 879 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 880 ###   to reduce storage requirements for the terminfo database.
 881 CF_LINK_FUNCS
 882
 883 with_links=no
 884 with_symlinks=no
 885
 886 # soft links (symbolic links) are useful for some systems where hard links do
 887 # not work, or to make it simpler to copy terminfo trees around.
 888 if test "x$ac_cv_func_symlink" = xyes ; then
 889         AC_MSG_CHECKING(if tic should use symbolic links)
 890         AC_ARG_ENABLE(symlinks,
 891         [  --enable-symlinks       make tic use symbolic links not hard links],
 892         [with_symlinks=$enableval],
 893         [with_symlinks=no])
 894         AC_MSG_RESULT($with_symlinks)
 895 fi
 896
 897 # If we have hard links and did not choose to use soft links instead, there is
 898 # no reason to make this choice optional - use the hard links.
 899 if test "$with_symlinks" = no ; then
 900         AC_MSG_CHECKING(if tic should use hard links)
 901         if test "x$ac_cv_func_link" = xyes ; then
 902                 with_links=yes
 903         else
 904                 with_links=no
 905         fi
 906         AC_MSG_RESULT($with_links)
 907 fi
 908
 909 test "x$with_links" = xyes && AC_DEFINE(USE_LINKS,1,[Define to 1 if hardlinks should be used in terminfo database])
 910 test "x$with_symlinks" = xyes && AC_DEFINE(USE_SYMLINKS,1,[Define to 1 if symbolic links should be used in terminfo database])
 911
 912 ###   use option --enable-broken-linker to force on use of broken-linker support
 913 CF_ENABLE_BROKEN_LINKER
 914
 915 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 916 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 917 AC_ARG_ENABLE(bsdpad,
 918         [  --enable-bsdpad         recognize BSD-style prefix padding],
 919         [with_bsdpad=$enableval],
 920         [with_bsdpad=no])
 921 AC_MSG_RESULT($with_bsdpad)
 922 test "x$with_bsdpad" = xyes && AC_DEFINE(BSD_TPUTS,1,[Define to 1 to recognize BSD-style prefix padding])
 923
 924 ###   use option --enable-widec to turn on use of wide-character support
 925 NCURSES_CH_T=chtype
 926 NCURSES_LIBUTF8=0
 927
 928 NEED_WCHAR_H=0
 929 NCURSES_MBSTATE_T=0
 930 NCURSES_WCHAR_T=0
 931 NCURSES_WINT_T=0
 932
 933 # Check to define _XOPEN_SOURCE "automatically"
 934 CPPFLAGS_before_XOPEN="$CPPFLAGS"
 935 CF_XOPEN_SOURCE(600)
 936 CPPFLAGS_after_XOPEN="$CPPFLAGS"
 937
 938 # Work around breakage on OS X
 939 CF_SIGWINCH
 940
 941 # Checks for CODESET support.
 942 AM_LANGINFO_CODESET
 943
 944 # use these variables to work around a defect in gcc's fixincludes.
 945 NCURSES_OK_WCHAR_T=
 946 NCURSES_OK_WINT_T=
 947
 948 AC_MSG_CHECKING(if you want wide-character code)
 949 AC_ARG_ENABLE(widec,
 950         [  --enable-widec          compile with wide-char/UTF-8 code],
 951         [with_widec=$enableval],
 952         [with_widec=no])
 953 AC_MSG_RESULT($with_widec)
 954
 955 NCURSES_WCWIDTH_GRAPHICS=1
 956 AC_SUBST(NCURSES_WCWIDTH_GRAPHICS)
 957
 958 if test "x$with_widec" = xyes ; then
 959         if test "x$disable_lib_suffixes" = xno ; then
 960                 LIB_SUFFIX="w${LIB_SUFFIX}"
 961         fi
 962         AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to compile with wide-char/UTF-8 code])
 963         AC_DEFINE(NCURSES_WIDECHAR,1,[Define to 1 to compile with wide-char/UTF-8 code])
 964         case "$CPPFLAGS" in
 965         (*_XOPEN_SOURCE=*)
 966                 ;;
 967         (*)
 968                 AC_MSG_WARN(_XOPEN_SOURCE feature test macro appears to be predefined)
 969                 # CPPFLAGS="$CPPFLAGS -DNCURSES_WIDECHAR"
 970                 CPPFLAGS_after_XOPEN="$CPPFLAGS_after_XOPEN -DNCURSES_WIDECHAR"
 971                 ;;
 972         esac
 973
 974         CF_CHECK_WCHAR_H
 975         CF_CHECK_WCWIDTH_GRAPHICS
 976         test "$cf_cv_wcwidth_graphics" = no && NCURSES_WCWIDTH_GRAPHICS=0
 977
 978         # with_overwrite=no
 979         NCURSES_CH_T=cchar_t
 980         AC_CHECK_FUNCS(putwc btowc wctob wmemchr mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 981         if test "x$ac_cv_func_putwc" != xyes ; then
 982                 CF_UTF8_LIB
 983                 if test "$cf_cv_utf8_lib" != no ; then
 984                         NCURSES_LIBUTF8=1
 985                 fi
 986         fi
 987         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 988         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 989         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 990
 991         if test "$NCURSES_MBSTATE_T" != 0; then
 992                 AC_DEFINE(NEED_MBSTATE_T_DEF,1,[Define to 1 if we must declare mbstate_t])
 993         fi
 994 fi
 995 AC_SUBST(NCURSES_CH_T)
 996 AC_SUBST(NCURSES_LIBUTF8)
 997
 998 AC_SUBST(NEED_WCHAR_H)
 999 AC_SUBST(NCURSES_MBSTATE_T)
1000 AC_SUBST(NCURSES_WCHAR_T)
1001 AC_SUBST(NCURSES_WINT_T)
1002
1003 AC_SUBST(NCURSES_OK_WCHAR_T)
1004 AC_SUBST(NCURSES_OK_WINT_T)
1005
1006 ###   use option --disable-lp64 to allow long chtype
1007 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
1008 AC_ARG_ENABLE(lp64,
1009         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
1010         [with_lp64=$enableval],
1011         [with_lp64=$cf_dft_with_lp64])
1012 AC_MSG_RESULT($with_lp64)
1013
1014 if test "x$with_lp64" = xyes ; then
1015         cf_cv_enable_lp64=1
1016 else
1017         cf_cv_enable_lp64=0
1018 fi
1019 AC_SUBST(cf_cv_enable_lp64)
1020
1021 CF_LARGEFILE
1022
1023 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
1024 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
1025 AC_ARG_ENABLE(tparm-varargs,
1026         [  --disable-tparm-varargs compile tparm() without varargs interface],
1027         [with_tparm_varargs=$enableval],
1028         [with_tparm_varargs=yes])
1029 AC_MSG_RESULT($with_tparm_varargs)
1030 NCURSES_TPARM_VARARGS=0
1031 test "x$with_tparm_varargs" = xyes && NCURSES_TPARM_VARARGS=1
1032 AC_SUBST(NCURSES_TPARM_VARARGS)
1033
1034 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
1035 if test "$with_ticlib" != no ; then
1036 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
1037 AC_ARG_ENABLE(tic-depends,
1038         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
1039         [with_tic_depends=$enableval],
1040         [with_tic_depends=yes])
1041 AC_MSG_RESULT($with_tic_depends)
1042 else
1043         with_tic_depends=no
1044 fi
1045
1046 ###   use option --enable-wattr-macros to enable wattr* macros in curses.h
1047 AC_MSG_CHECKING(if you want to enable wattr* macros)
1048 AC_ARG_ENABLE(wattr-macros,
1049         [  --enable-wattr-macros   enable wattr* macros],
1050         [with_wattr_macros=$enableval],
1051         [with_wattr_macros=no])
1052 if [[ "x$with_wattr_macros" != xyes ]]; then
1053         NCURSES_WATTR_MACROS=0
1054         AC_MSG_RESULT(no)
1055 else
1056         NCURSES_WATTR_MACROS=1
1057         AC_MSG_RESULT(yes)
1058 fi
1059 AC_SUBST(NCURSES_WATTR_MACROS)
1060
1061 CF_WITH_X11_RGB
1062
1063 ###   use option --with-bool to override bool's type
1064 AC_MSG_CHECKING(for type of bool)
1065 AC_ARG_WITH(bool,
1066         [  --with-bool=TYPE        override fallback type of bool variable],
1067         [NCURSES_BOOL="$withval"],
1068         [NCURSES_BOOL=auto])
1069 AC_MSG_RESULT($NCURSES_BOOL)
1070 AC_SUBST(NCURSES_BOOL)
1071
1072 AC_MSG_CHECKING(for alternate terminal capabilities file)
1073 AC_ARG_WITH(caps,
1074         [  --with-caps=alt         compile with alternate Caps file],
1075         [TERMINFO_CAPS=Caps.$withval],
1076         [TERMINFO_CAPS=Caps])
1077 if test ! -f "${srcdir}/include/${TERMINFO_CAPS}"
1078 then
1079         AC_MSG_WARN(file not found: "${srcdir}/include/${TERMINFO_CAPS}")
1080         TERMINFO_CAPS=Caps
1081 fi
1082 AC_MSG_RESULT($TERMINFO_CAPS)
1083 AC_SUBST(TERMINFO_CAPS)
1084
1085 ###   use option --with-chtype to override chtype's type
1086 AC_MSG_CHECKING(for type of chtype)
1087 AC_ARG_WITH(chtype,
1088         [  --with-chtype=TYPE      override type of chtype],
1089         [NCURSES_CHTYPE="$withval"],
1090         [NCURSES_CHTYPE=$cf_dft_chtype])
1091 AC_MSG_RESULT($NCURSES_CHTYPE)
1092
1093 ###   use option --with-ospeed to override ospeed's type
1094 AC_MSG_CHECKING(for type of ospeed)
1095 AC_ARG_WITH(ospeed,
1096         [  --with-ospeed=TYPE      override type of ospeed variable],
1097         [NCURSES_OSPEED="$withval"],
1098         [NCURSES_OSPEED=short])
1099 AC_MSG_RESULT($NCURSES_OSPEED)
1100 AC_SUBST(NCURSES_OSPEED)
1101
1102 ###   use option --with-mmask-t to override mmask_t's type
1103 AC_MSG_CHECKING(for type of mmask_t)
1104 AC_ARG_WITH(mmask-t,
1105         [  --with-mmask-t=TYPE     override type of mmask_t],
1106         [NCURSES_MMASK_T="$withval"],
1107         [NCURSES_MMASK_T=$cf_dft_mmask_t])
1108 AC_MSG_RESULT($NCURSES_MMASK_T)
1109
1110 ###   use option --with-ccharw-max to override CCHARW_MAX size
1111 AC_MSG_CHECKING(for size CCHARW_MAX)
1112 AC_ARG_WITH(ccharw-max,
1113         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
1114         [NCURSES_CCHARW_MAX="$withval"],
1115         [NCURSES_CCHARW_MAX=$cf_dft_ccharw_max])
1116 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
1117 AC_SUBST(NCURSES_CCHARW_MAX)
1118
1119 AC_CHECK_SIZEOF([signed char])
1120 if test "$ac_cv_sizeof_signed_char" = 1 ; then
1121         NCURSES_SBOOL="signed char"
1122 else
1123         NCURSES_SBOOL="char"
1124 fi
1125 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
1126 AC_ARG_ENABLE(signed-char,
1127         [  --enable-signed-char    compile using signed Boolean's in term.h],
1128         [with_signed_char=$enableval],
1129         [with_signed_char=$cf_dft_signed_char])
1130 AC_MSG_RESULT($with_signed_char)
1131 test "x$with_signed_char" != xyes && NCURSES_SBOOL="char"
1132 AC_SUBST(NCURSES_SBOOL)
1133
1134 ###   use option --with-tparm-arg to override tparm's argument type
1135 AC_MSG_CHECKING(for type of tparm args)
1136 AC_ARG_WITH(tparm-arg,
1137         [  --with-tparm-arg=TYPE   override parameter type of tparm],
1138         [NCURSES_TPARM_ARG="$withval"],
1139         [NCURSES_TPARM_ARG=$cf_dft_tparm_arg])
1140 AC_MSG_RESULT($NCURSES_TPARM_ARG)
1141 AC_SUBST(NCURSES_TPARM_ARG)
1142
1143 ### Enable compiling-in rcs id's
1144 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
1145 AC_ARG_WITH(rcs-ids,
1146         [  --with-rcs-ids          compile-in RCS identifiers],
1147         [with_rcs_ids=$withval],
1148         [with_rcs_ids=no])
1149 AC_MSG_RESULT($with_rcs_ids)
1150 test "x$with_rcs_ids" = xyes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 to compile-in RCS identifiers])
1151
1152 ###############################################################################
1153 CF_MAN_PAGES([ captoinfo clear infocmp infotocap reset tabs tic toe tput tset ])
1154
1155 ###############################################################################
1156 CF_HELP_MESSAGE(Extensions:)
1157
1158 ### Note that some functions (such as const) are normally disabled anyway.
1159 AC_MSG_CHECKING(if you want to build with function extensions)
1160 AC_ARG_ENABLE(ext-funcs,
1161         [  --disable-ext-funcs     disable function-extensions],
1162         [with_ext_funcs=$enableval],
1163         [with_ext_funcs=yes])
1164 AC_MSG_RESULT($with_ext_funcs)
1165 if test "x$with_ext_funcs" = xyes ; then
1166         NCURSES_EXT_FUNCS=1
1167         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 to enable ncurses extended functions])
1168         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS,1,[Define to 1 to enable assume_default_colors() function in test-programs])
1169         AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 to enable curses_version() function in test-programs])
1170         AC_DEFINE(HAVE_HAS_KEY,1,[Define to 1 to enable has_key() function in test-programs])
1171         AC_DEFINE(HAVE_RESIZETERM,1,[Define to 1 to enable resizeterm() function in test-programs])
1172         AC_DEFINE(HAVE_RESIZE_TERM,1,[Define to 1 to enable resize_term() function in test-programs])
1173         AC_DEFINE(HAVE_TERM_ENTRY_H,1,[Define to 1 to enable term_entry() function in test-programs])
1174         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 to enable use_default_colors() function in test-programs])
1175         AC_DEFINE(HAVE_USE_SCREEN,1,[Define to 1 to enable use_screen() function in test-programs])
1176         AC_DEFINE(HAVE_USE_WINDOW,1,[Define to 1 to enable use_window() function in test-programs])
1177         AC_DEFINE(HAVE_WRESIZE,1,[Define to 1 to enable wresize() function in test-programs])
1178         GENERATED_EXT_FUNCS=generated
1179         test "x$with_ext_funcs" = xyes || cf_dft_ext_spfuncs=no
1180 else
1181         NCURSES_EXT_FUNCS=0
1182         GENERATED_EXT_FUNCS=
1183 fi
1184 AC_SUBST(NCURSES_EXT_FUNCS)
1185 AC_SUBST(GENERATED_EXT_FUNCS)
1186
1187 AC_MSG_CHECKING(if you want to build with SCREEN extensions)
1188 AC_ARG_ENABLE(sp-funcs,
1189         [  --enable-sp-funcs       enable SCREEN-extensions],
1190         [with_sp_funcs=$enableval],
1191         [with_sp_funcs=$cf_dft_ext_spfuncs])
1192 AC_MSG_RESULT($with_sp_funcs)
1193 if test "x$with_sp_funcs" = xyes ; then
1194         NCURSES_SP_FUNCS=1
1195         AC_DEFINE(NCURSES_SP_FUNCS,1,[Define to 1 to enable SCREEN-extensions])
1196         AC_DEFINE(HAVE_TPUTS_SP,1,[Define to 1 to enable tputs_sp() function in test-programs])
1197         GENERATED_SP_FUNCS=generated
1198 else
1199         NCURSES_SP_FUNCS=0
1200         GENERATED_SP_FUNCS=
1201 fi
1202 AC_SUBST(NCURSES_SP_FUNCS)
1203 AC_SUBST(GENERATED_SP_FUNCS)
1204
1205 AC_MSG_CHECKING(if you want to build with terminal-driver)
1206 AC_ARG_ENABLE(term-driver,
1207         [  --enable-term-driver    enable terminal-driver],
1208         [with_term_driver=$enableval],
1209         [with_term_driver=no])
1210 AC_MSG_RESULT($with_term_driver)
1211 if test "x$with_term_driver" = xyes ; then
1212         AC_DEFINE(USE_TERM_DRIVER,1,[Define to 1 to enable terminal-driver])
1213         if test "x$with_termlib" != xno ; then
1214                 AC_MSG_ERROR(The term-driver option conflicts with the termlib option)
1215         fi
1216         if test "x$with_sp_funcs" != xyes ; then
1217                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
1218         fi
1219 fi
1220
1221 ###   use option --enable-const to turn on use of const beyond that in XSI.
1222 AC_MSG_CHECKING(for extended use of const keyword)
1223 AC_ARG_ENABLE(const,
1224         [  --enable-const          compile with extra/non-standard const],
1225         [with_ext_const=$enableval],
1226         [with_ext_const=$cf_dft_ext_const])
1227 AC_MSG_RESULT($with_ext_const)
1228 NCURSES_CONST='/*nothing*/'
1229 if test "x$with_ext_const" = xyes ; then
1230         NCURSES_CONST=const
1231 fi
1232 AC_SUBST(NCURSES_CONST)
1233
1234 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
1235 AC_MSG_CHECKING(if you want to use extended colors)
1236 AC_ARG_ENABLE(ext-colors,
1237         [  --enable-ext-colors     compile for 256-color support],
1238         [with_ext_colors=$enableval],
1239         [with_ext_colors=$cf_dft_ext_colors])
1240 AC_MSG_RESULT($with_ext_colors)
1241 NCURSES_EXT_COLORS=0
1242 if test "x$with_ext_colors" = xyes ; then
1243         if test "x$with_widec" != xyes ; then
1244                 AC_MSG_WARN(This option applies only to wide-character library)
1245         else
1246                 # cannot be ABI 5 since it changes sizeof(cchar_t)
1247                 CF_NCURSES_ABI_6
1248                 NCURSES_EXT_COLORS=1
1249                 AC_DEFINE(NCURSES_EXT_COLORS,1,[Define to 1 to compile for 256-color support])
1250                 AC_DEFINE(HAVE_ALLOC_PAIR,1,[Define to 1 to enable alloc_pair() function])
1251                 AC_DEFINE(HAVE_INIT_EXTENDED_COLOR,1,[Define to 1 to enable init_extended_color() function in test-programs])
1252                 AC_DEFINE(HAVE_RESET_COLOR_PAIRS,1,[Define to 1 to enable reset_color_pairs() function in test-programs])
1253         fi
1254 fi
1255 AC_SUBST(NCURSES_EXT_COLORS)
1256
1257 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
1258 AC_MSG_CHECKING(if you want to use extended mouse encoding)
1259 AC_ARG_ENABLE(ext-mouse,
1260         [  --enable-ext-mouse      compile for extended mouse-encoding],
1261         [with_ext_mouse=$enableval],
1262         [with_ext_mouse=$cf_dft_ext_mouse])
1263 AC_MSG_RESULT($with_ext_mouse)
1264 if test "x$with_ext_mouse" = xyes ; then
1265         CF_NCURSES_ABI_6
1266 fi
1267
1268 if test $cf_cv_abi_default -le 5 ; then
1269         NCURSES_MOUSE_VERSION=1
1270 elif test $cf_cv_abi_default -le 6 ; then
1271         NCURSES_MOUSE_VERSION=2
1272 else
1273         NCURSES_MOUSE_VERSION=3
1274 fi
1275
1276 AC_SUBST(NCURSES_MOUSE_VERSION)
1277
1278 ###   use option --enable-ext-putwin to turn on extended screendumps
1279 AC_MSG_CHECKING(if you want to use extended putwin/screendump)
1280 AC_ARG_ENABLE(ext-putwin,
1281         [  --enable-ext-putwin     compile with extended putwin/screendump],
1282         [with_ext_putwin=$enableval],
1283         [with_ext_putwin=$cf_dft_ext_putwin])
1284 AC_MSG_RESULT($with_ext_putwin)
1285 if test "x$with_ext_putwin" = xyes ; then
1286         AC_DEFINE(NCURSES_EXT_PUTWIN,1,[Define to 1 to compile with extended putwin/screendump])
1287 fi
1288
1289 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
1290 AC_ARG_ENABLE(no-padding,
1291         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
1292         [with_no_padding=$enableval],
1293         [with_no_padding=$with_ext_funcs])
1294 AC_MSG_RESULT($with_no_padding)
1295 test "x$with_no_padding" = xyes && AC_DEFINE(NCURSES_NO_PADDING,1,[Define to 1 to compile with $NCURSES_NO_PADDING code])
1296
1297 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1298 AC_MSG_CHECKING(if you want SIGWINCH handler)
1299 AC_ARG_ENABLE(sigwinch,
1300         [  --enable-sigwinch       compile with SIGWINCH handler],
1301         [with_sigwinch=$enableval],
1302         [with_sigwinch=$with_ext_funcs])
1303 AC_MSG_RESULT($with_sigwinch)
1304 test "x$with_sigwinch" = xyes && AC_DEFINE(USE_SIGWINCH,1,[Define to 1 to compile with SIGWINCH handler])
1305
1306 ###   use option --enable-tcap-names to allow user to define new capabilities
1307 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1308 AC_ARG_ENABLE(tcap-names,
1309         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1310         [with_tcap_names=$enableval],
1311         [with_tcap_names=$with_ext_funcs])
1312 AC_MSG_RESULT($with_tcap_names)
1313 NCURSES_XNAMES=0
1314 if test "x$with_tcap_names" = xyes; then
1315         NCURSES_XNAMES=1
1316         AC_DEFINE(NCURSES_XNAMES,1,[Define to 1 to compile with user-definable terminal capabilities])
1317 fi
1318 AC_SUBST(NCURSES_XNAMES)
1319
1320 ##############################################################################
1321 CF_HELP_MESSAGE(Reentrant Code:)
1322 CF_WITH_PTHREAD
1323
1324 if test "x$with_pthread" != xno; then
1325         AC_CHECK_FUNC(pthread_kill,[
1326                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1327                 AC_ARG_ENABLE(pthreads-eintr,
1328                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1329                         [use_pthreads_eintr=$enableval],
1330                         [use_pthreads_eintr=no])
1331                 AC_MSG_RESULT($use_pthreads_eintr)
1332                 if test "x$use_pthreads_eintr" = xyes ; then
1333                         AC_DEFINE(USE_PTHREADS_EINTR,1,[Define to 1 to enable EINTR in wgetch with pthreads])
1334                 fi])
1335
1336         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1337         AC_ARG_ENABLE(weak-symbols,
1338                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1339                 [use_weak_symbols=$enableval],
1340                 [use_weak_symbols=no])
1341         AC_MSG_RESULT($use_weak_symbols)
1342         if test "x$use_weak_symbols" = xyes ; then
1343                 CF_WEAK_SYMBOLS
1344         else
1345                 cf_cv_weak_symbols=no
1346         fi
1347
1348         if test "x$cf_cv_weak_symbols" = xyes ; then
1349                 AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
1350         fi
1351 fi
1352
1353 PTHREAD=
1354 if test "x$with_pthread" = "xyes" ; then
1355         AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use pthreads feature])
1356         enable_reentrant=yes
1357         if test "x$cf_cv_weak_symbols" = xyes ; then
1358                 PTHREAD=-lpthread
1359                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1360         fi
1361 fi
1362 AC_SUBST(PTHREAD)
1363
1364 # Reentrant code has to be opaque; there's little advantage to making ncurses
1365 # opaque outside of that, so there is no --enable-opaque option.  We can use
1366 # this option without --with-pthreads, but this will be always set for
1367 # pthreads.
1368 AC_MSG_CHECKING(if you want reentrant code)
1369 AC_ARG_ENABLE(reentrant,
1370         [  --enable-reentrant      compile with reentrant code],
1371         [with_reentrant=$enableval],
1372         [with_reentrant=no])
1373 AC_MSG_RESULT($with_reentrant)
1374 if test "x$with_reentrant" = xyes ; then
1375         cf_cv_enable_reentrant=1
1376         cf_cv_enable_opaque="NCURSES_INTERNALS"
1377         NCURSES_SIZE_T=int
1378         if test "x$cf_cv_weak_symbols" = xyes ; then
1379                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1380                 CF_ADD_LIB(pthread,TEST_LIBS)
1381                 CF_ADD_LIB(pthread,TEST_LIBS2)
1382                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1383         else
1384                 # when not using weak symbols but with_reentrant,
1385                 # add 't' to the library suffix on all platforms
1386                 # except cygwin, where we only do that if ALSO
1387                 # compiling with full thread support.
1388                 case "$host" in
1389                 (*cygwin* | *msys*)
1390                         if test "$with_pthread" = "yes" ; then
1391                                 if test "x$disable_lib_suffixes" = "xno" ; then
1392                                         LIB_SUFFIX="t${LIB_SUFFIX}"
1393                                 fi
1394                         fi ;;
1395                 (*)
1396                         if test "x$disable_lib_suffixes" = "xno" ; then
1397                                 LIB_SUFFIX="t${LIB_SUFFIX}"
1398                         fi
1399                         ;;
1400                 esac
1401         fi
1402         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to use reentrant feature])
1403         CF_NCURSES_ABI_6
1404 else
1405         cf_cv_enable_reentrant=0
1406         cf_cv_enable_opaque="NCURSES_OPAQUE"
1407         NCURSES_SIZE_T=$cf_dft_ordinate_type
1408 fi
1409 AC_SUBST(cf_cv_enable_reentrant)
1410 AC_SUBST(cf_cv_enable_opaque)
1411
1412 AC_SUBST(NCURSES_SIZE_T)
1413
1414 AC_MSG_CHECKING(if you want opaque curses-library structures)
1415 CF_ARG_ENABLE(opaque-curses,
1416         [  --enable-opaque-curses  make curses WINDOW, etc., "opaque"],
1417         [enable_opaque_curses=yes],[
1418          test "$cf_cv_enable_reentrant" = 1 && enable_opaque_curses=yes
1419          test "$cf_cv_enable_reentrant" = 1 || enable_opaque_curses=$cf_dft_opaque_curses
1420         ])
1421 AC_MSG_RESULT($enable_opaque_curses)
1422
1423 test "$cf_cv_enable_reentrant" = 1 && \
1424 test "$enable_opaque_curses" = no && \
1425 AC_MSG_ERROR(reentrant configuration requires opaque library)
1426
1427 AC_MSG_CHECKING(if you want opaque form-library structures)
1428 AC_ARG_ENABLE(opaque-form,
1429         [  --enable-opaque-form    make form-library structures "opaque"],
1430         [enable_opaque_form=yes],[enable_opaque_form=no])
1431 AC_MSG_RESULT($enable_opaque_form)
1432
1433 AC_MSG_CHECKING(if you want opaque menu-library structures)
1434 AC_ARG_ENABLE(opaque-menu,
1435         [  --enable-opaque-menu    make menu-library structures "opaque"],
1436         [enable_opaque_menu=yes],[enable_opaque_menu=no])
1437 AC_MSG_RESULT($enable_opaque_menu)
1438
1439 AC_MSG_CHECKING(if you want opaque panel-library structures)
1440 AC_ARG_ENABLE(opaque-panel,
1441         [  --enable-opaque-panel   make panel-library structures "opaque"],
1442         [enable_opaque_panel=yes],[enable_opaque_panel=no])
1443 AC_MSG_RESULT($enable_opaque_panel)
1444
1445 NCURSES_OPAQUE=0;               test "$enable_opaque_curses" = yes && NCURSES_OPAQUE=1
1446 NCURSES_OPAQUE_FORM=0;  test "$enable_opaque_form"   = yes && NCURSES_OPAQUE_FORM=1
1447 NCURSES_OPAQUE_MENU=0;  test "$enable_opaque_menu"   = yes && NCURSES_OPAQUE_MENU=1
1448 NCURSES_OPAQUE_PANEL=0; test "$enable_opaque_panel"  = yes && NCURSES_OPAQUE_PANEL=1
1449
1450 AC_SUBST(NCURSES_OPAQUE)
1451 AC_SUBST(NCURSES_OPAQUE_FORM)
1452 AC_SUBST(NCURSES_OPAQUE_MENU)
1453 AC_SUBST(NCURSES_OPAQUE_PANEL)
1454
1455 ### Allow using a different wrap-prefix
1456 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1457         AC_MSG_CHECKING(for prefix used to wrap public variables)
1458         AC_ARG_WITH(wrap-prefix,
1459                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1460                 [NCURSES_WRAP_PREFIX=$withval],
1461                 [NCURSES_WRAP_PREFIX=_nc_])
1462         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1463 else
1464         NCURSES_WRAP_PREFIX=_nc_
1465 fi
1466 AC_SUBST(NCURSES_WRAP_PREFIX)
1467 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ prefix])
1468
1469 ###############################################################################
1470 # These options are relatively safe to experiment with.
1471 CF_HELP_MESSAGE(Development Code:)
1472 AC_MSG_CHECKING(if you want all development code)
1473 AC_ARG_WITH(develop,
1474         [  --without-develop       disable development options],
1475         [with_develop=$withval],
1476         [with_develop=no])
1477 AC_MSG_RESULT($with_develop)
1478
1479 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1480 AC_MSG_CHECKING(if you want hard-tabs code)
1481 AC_ARG_ENABLE(hard-tabs,
1482         [  --enable-hard-tabs      compile with hard-tabs code],,
1483         [enable_hard_tabs=$with_develop])
1484 AC_MSG_RESULT($enable_hard_tabs)
1485 test "x$enable_hard_tabs" = xyes && AC_DEFINE(USE_HARD_TABS,1,[Define to 1 to compile with hard-tabs code])
1486
1487 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1488 AC_MSG_CHECKING(if you want limited support for xmc)
1489 AC_ARG_ENABLE(xmc-glitch,
1490         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1491         [enable_xmc_glitch=$with_develop])
1492 AC_MSG_RESULT($enable_xmc_glitch)
1493 test "x$enable_xmc_glitch" = xyes && AC_DEFINE(USE_XMC_SUPPORT,1,[Define to 1 to compile with support for xmc (magic-cookie)])
1494
1495 ###############################################################################
1496 # These are just experimental, probably should not be in a package:
1497 CF_HELP_MESSAGE(Experimental Code:)
1498
1499 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1500 AC_ARG_ENABLE(assumed-color,
1501         [  --disable-assumed-color do not assume anything about default-colors],
1502         [with_assumed_color=$enableval],
1503         [with_assumed_color=yes])
1504 AC_MSG_RESULT($with_assumed_color)
1505 test "x$with_assumed_color" = xyes && AC_DEFINE(USE_ASSUMED_COLOR,1,[Define to 1 to assume things about default-colors])
1506
1507 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1508 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1509 AC_ARG_ENABLE(hashmap,
1510         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1511         [with_hashmap=$enableval],
1512         [with_hashmap=yes])
1513 AC_MSG_RESULT($with_hashmap)
1514 test "x$with_hashmap" = xyes && AC_DEFINE(USE_HASHMAP,1,[Define to 1 to compile with hashmap scrolling-optimization])
1515
1516 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1517 AC_MSG_CHECKING(if you want code to check screensize)
1518 AC_ARG_ENABLE(check-size,
1519         [  --enable-check-size     compile-in code to detect screensize],
1520         [with_check_size=$enableval],
1521         [with_check_size=no])
1522 AC_MSG_RESULT($with_check_size)
1523 test "x$with_check_size" = xyes && AC_DEFINE(USE_CHECK_SIZE,1,[Define to 1 to compile-in code to detect screensize])
1524
1525 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1526 AC_MSG_CHECKING(if you want colorfgbg code)
1527 AC_ARG_ENABLE(colorfgbg,
1528         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1529         [with_colorfgbg=$enableval],
1530         [with_colorfgbg=no])
1531 AC_MSG_RESULT($with_colorfgbg)
1532 test "x$with_colorfgbg" = xyes && AC_DEFINE(USE_COLORFGBG,1,[Define to 1 to compile-in experimental $COLORFGBG code])
1533
1534 ###   use option --enable-fvisibility to turn on use of gcc-specific feature
1535 AC_MSG_CHECKING(if you want to use gcc -fvisibility option)
1536 AC_ARG_ENABLE(fvisibility,
1537         [  --enable-fvisibility    compile with -fvisibility=hidden],
1538         [cf_with_fvisibility=$enableval],
1539         [cf_with_fvisibility=no])
1540 AC_MSG_RESULT($cf_with_fvisibility)
1541
1542 NCURSES_IMPEXP=
1543 NCURSES_CXX_IMPEXP=
1544 if test "x$cf_with_fvisibility" = xyes; then
1545         CF_CHECK_FVISIBILITY($CC,CFLAGS,cf_cv_fvisibility_hidden)
1546         if test "x$cf_cv_fvisibility_hidden" = xyes
1547         then
1548                 CF_ADD_CFLAGS([-fvisibility=hidden])
1549                 NCURSES_IMPEXP="__attribute__ ((visibility(\"default\")))"
1550         fi
1551         if test -n "$CXX"
1552         then
1553                 AC_LANG_PUSH(C++)
1554                 CF_CHECK_FVISIBILITY($CXX,CXXFLAGS,cf_cv_fvisibility_hidden2)
1555                 if test "x$cf_cv_fvisibility_hidden2" = xyes
1556                 then
1557                         CF_ADD_CXXFLAGS([-fvisibility=hidden])
1558                         NCURSES_CXX_IMPEXP="__attribute__ ((visibility(\"default\")))"
1559                 fi
1560                 AC_LANG_POP
1561         fi
1562 fi
1563 AC_SUBST(NCURSES_IMPEXP)
1564 AC_SUBST(NCURSES_CXX_IMPEXP)
1565
1566 ###   use option --enable-interop to turn on use of bindings used for interop
1567 AC_MSG_CHECKING(if you want interop bindings)
1568 AC_ARG_ENABLE(interop,
1569         [  --enable-interop        compile-in interop bindings],
1570         [with_exp_interop=$enableval],
1571         [with_exp_interop=$cf_dft_interop])
1572 AC_MSG_RESULT($with_exp_interop)
1573
1574 NCURSES_INTEROP_FUNCS=0
1575 test "x$with_exp_interop" = xyes && NCURSES_INTEROP_FUNCS=1
1576 AC_SUBST(NCURSES_INTEROP_FUNCS)
1577
1578
1579 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1580 AC_ARG_ENABLE(safe-sprintf,
1581         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1582         [with_safe_sprintf=$enableval],
1583         [with_safe_sprintf=no])
1584 AC_MSG_RESULT($with_safe_sprintf)
1585
1586 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1587 # when hashmap is used scroll hints are useless
1588 if test "$with_hashmap" = no ; then
1589 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1590 AC_ARG_ENABLE(scroll-hints,
1591         [  --disable-scroll-hints  compile without scroll-hints code],
1592         [with_scroll_hints=$enableval],
1593         [with_scroll_hints=yes])
1594 AC_MSG_RESULT($with_scroll_hints)
1595 test "x$with_scroll_hints" = xyes && AC_DEFINE(USE_SCROLL_HINTS,1,[Define to 1 to compile without scroll-hints code])
1596 fi
1597
1598 AC_MSG_CHECKING(if you want wgetch-events code)
1599 AC_ARG_ENABLE(wgetch-events,
1600         [  --enable-wgetch-events  compile with wgetch-events code],
1601         [with_wgetch_events=$enableval],
1602         [with_wgetch_events=no])
1603 AC_MSG_RESULT($with_wgetch_events)
1604 if test "x$with_wgetch_events" = xyes ; then
1605         AC_DEFINE(NCURSES_WGETCH_EVENTS,1,[Define to 1 to compile with wgetch-events code])
1606         NCURSES_WGETCH_EVENTS=1
1607 else
1608         NCURSES_WGETCH_EVENTS=0
1609 fi
1610 AC_SUBST(NCURSES_WGETCH_EVENTS)
1611
1612 case "$cf_cv_system_name" in
1613 (*mingw32*|*mingw64*|*-msvc*)
1614         AC_MSG_CHECKING(if you want experimental-Windows driver)
1615         AC_ARG_ENABLE(exp-win32,
1616                 [  --enable-exp-win32      compile with experimental-Windows driver],
1617                 [with_exp_win32=$enableval],
1618                 [with_exp_win32=no])
1619         AC_MSG_RESULT($with_exp_win32)
1620         if test "x$with_exp_win32" = xyes
1621         then
1622                 AC_DEFINE(EXP_WIN32_DRIVER,1,[Define to 1 to compile with experimental win32 driver])
1623                 EXP_WIN32_DRIVER=1
1624                 INTERNALS_HDR='[$](INCDIR)/nc_win32.h'
1625         else
1626                 INTERNALS_HDR='[$](INCDIR)/nc_mingw.h'
1627                 EXP_WIN32_DRIVER=0
1628         fi
1629         ;;
1630 (*)
1631         EXP_WIN32_DRIVER=0
1632         INTERNALS_HDR=
1633         ;;
1634 esac
1635 AC_SUBST(EXP_WIN32_DRIVER)
1636 AC_SUBST(INTERNALS_HDR)
1637
1638 ###############################################################################
1639 CF_HELP_MESSAGE(Testing/development Options:)
1640
1641 ###     use option --disable-echo to suppress full display compiling commands
1642 CF_DISABLE_ECHO
1643 if test "x$enable_echo" = xyes; then
1644         ECHO_LINK=
1645 else
1646         ECHO_LINK='@ echo linking $@ ... ;'
1647         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1648         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1649 fi
1650 AC_SUBST(ECHO_LINK)
1651
1652 # --disable-stripping is used for debugging
1653 CF_INSTALL_OPTS
1654
1655 # If we're avoiding relinking of shared libraries during install, that is to
1656 # avoid modifying the build-tree.  For the same reason, avoid doing ranlib if
1657 # the install program has "-p" (for preserving timestamps).
1658 cf_cv_do_reranlib=yes
1659 if test "x$cf_cv_install_p" = xyes
1660 then
1661         if test "x$cf_cv_do_relink" != xyes
1662         then
1663                 cf_cv_do_reranlib=no
1664                 INSTALL_OPT_P="-p"
1665                 INSTALL_LIB="$INSTALL_LIB $INSTALL_OPT_P"
1666         fi
1667 fi
1668 AC_SUBST(INSTALL_OPT_P)
1669
1670 ###     use option --enable-warnings to turn on all gcc warnings
1671 CF_ENABLE_WARNINGS(Wno-unknown-pragmas Wswitch-enum,yes)
1672
1673 if test "x$enable_warnings" = "xyes"; then
1674         CF_ADD_ADAFLAGS(-gnatwa -gnatyg)
1675         if test "x$cf_with_cxx" = xyes ; then
1676                 CF_GXX_WARNINGS(Wno-unused)
1677         fi
1678 fi
1679 CF_ENABLE_STRING_HACKS
1680
1681 ###     use option --enable-assertions to turn on generation of assertion code
1682 AC_MSG_CHECKING(if you want to enable runtime assertions)
1683 AC_ARG_ENABLE(assertions,
1684         [  --enable-assertions     test: turn on generation of assertion code],
1685         [with_assertions=$enableval],
1686         [with_assertions=no])
1687 AC_MSG_RESULT($with_assertions)
1688 if test -n "$GCC"
1689 then
1690         if test "$with_assertions" = no
1691         then
1692                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1693         else
1694                 CF_ADD_ADAFLAGS(-gnata)
1695         fi
1696 fi
1697
1698 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1699 CF_DISABLE_LEAKS
1700 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
1701
1702 ###     use option --enable-expanded to generate certain macros as functions
1703 AC_ARG_ENABLE(expanded,
1704         [  --enable-expanded       test: generate functions for certain macros],
1705         [test "x$enableval" = xyes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 to generate functions for certain macros])])
1706
1707 ###     use option --disable-macros to suppress macros in favor of functions
1708 AC_ARG_ENABLE(macros,
1709         [  --disable-macros        test: use functions rather than macros],
1710         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 to use functions rather than macros])])
1711
1712 # Normally we only add trace() to the debug-library.  Allow this to be
1713 # extended to all models of the ncurses library:
1714 cf_all_traces=no
1715 case "$CFLAGS $CPPFLAGS" in
1716 (*-DTRACE*)
1717         cf_all_traces=yes
1718         ;;
1719 esac
1720
1721 AC_MSG_CHECKING(whether to add trace feature to all models)
1722 AC_ARG_WITH(trace,
1723 [  --with-trace            test: add trace() function to all models of ncurses],
1724 [cf_with_trace=$withval],
1725 [cf_with_trace=$cf_all_traces])
1726 AC_MSG_RESULT($cf_with_trace)
1727
1728 if test "x$cf_with_trace" = xyes ; then
1729         LIB_TRACING=all
1730         ADA_TRACE=TRUE
1731         CF_ADD_CFLAGS(-DTRACE)
1732         AC_DEFINE(HAVE__TRACEF,1,[Define to 1 if we have _tracef function])
1733 else
1734         LIB_TRACING=DEBUG
1735         ADA_TRACE=FALSE
1736 fi
1737
1738 AC_SUBST(ADA_TRACE)
1739
1740 CF_DISABLE_GNAT_PROJECTS
1741
1742 ###     Checks for libraries.
1743 case "$cf_cv_system_name" in
1744 (*mingw32*|*mingw64*)
1745         # Note: WINVER may be a problem with Windows 10
1746         if test "x$with_exp_win32" = xyes ; then
1747                 CPPFLAGS="$CPPFLAGS -DWINVER=0x0600 -DWIN32_LEAN_AND_MEAN"
1748         else
1749                 CPPFLAGS="$CPPFLAGS -DWINVER=0x0501 -DWIN32_LEAN_AND_MEAN"
1750         fi
1751         CF_CHECK_LIBSSP
1752         ;;
1753 (*)
1754         ;;
1755 esac
1756
1757 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
1758 AC_SUBST(MATH_LIB)
1759
1760 ###     Checks for header files.
1761 AC_HEADER_TIME
1762 CF_REGEX
1763
1764 dnl These are some other potentially nonportable headers.
1765 AC_CHECK_HEADERS( \
1766 fcntl.h \
1767 getopt.h \
1768 limits.h \
1769 locale.h \
1770 math.h \
1771 poll.h \
1772 sys/auxv.h \
1773 sys/ioctl.h \
1774 sys/param.h \
1775 sys/poll.h \
1776 sys/select.h \
1777 sys/time.h \
1778 sys/times.h \
1779 unistd.h \
1780 wctype.h \
1781 )
1782
1783 CF_GETOPT_HEADER
1784
1785 CF_CHECK_ENVIRON(environ)
1786 CF_CHECK_GETENV
1787 if test "x$cf_cv_consistent_getenv" = xno && \
1788         test "x$cf_with_trace" = xyes
1789 then
1790         AC_MSG_WARN(The NCURSES_TRACE environment variable is not supported with this configuration)
1791 fi
1792
1793 CF_SYS_TIME_SELECT
1794
1795 ###     checks for compiler characteristics
1796 AC_LANG_C
1797 AC_C_CONST
1798 CF_C_INLINE(NCURSES_INLINE,1200)
1799 CF_SIG_ATOMIC_T
1800
1801 if test "$NCURSES_CHTYPE" = auto ; then
1802         CF_TYPEOF_CHTYPE
1803 else
1804         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1805 fi
1806 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1807 AC_SUBST(cf_cv_typeof_chtype)
1808
1809 CF_UNSIGNED_LITERALS
1810 cf_cv_1UL="1"
1811 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1812 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1813 AC_SUBST(cf_cv_1UL)
1814
1815 if test "$NCURSES_MMASK_T" = auto ; then
1816         cf_cv_typeof_mmask_t=long
1817 else
1818         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1819 fi
1820 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1821 AC_SUBST(cf_cv_typeof_mmask_t)
1822
1823 ###     Checks for external-data
1824 CF_ERRNO
1825 CF_LINK_DATAONLY
1826
1827 ###     Checks for library functions.
1828 CF_FUNC_GETTIME
1829 AC_CHECK_FUNCS( \
1830 fpathconf \
1831 getcwd \
1832 getauxval \
1833 getegid \
1834 geteuid \
1835 getopt \
1836 getuid \
1837 issetugid \
1838 localeconv \
1839 poll \
1840 putenv \
1841 remove \
1842 select \
1843 setbuf \
1844 setbuffer \
1845 setenv \
1846 setfsuid \
1847 setvbuf \
1848 sigaction \
1849 sigvec \
1850 snprintf \
1851 strdup \
1852 strstr \
1853 sysconf \
1854 tcgetpgrp \
1855 times \
1856 tsearch \
1857 vsnprintf \
1858 )
1859
1860 CF_FUNC_GETTTYNAM
1861
1862 if test "x$ac_cv_func_getopt" = xno && \
1863    test "x$cf_with_progs$cf_with_tests" != xnono; then
1864         AC_MSG_ERROR(getopt is required for building programs)
1865 fi
1866
1867 if test "x$with_safe_sprintf" = xyes
1868 then
1869         if test "x$ac_cv_func_vsnprintf" = xyes
1870         then
1871                 AC_MSG_WARN(will use vsnprintf instead of safe-sprintf option)
1872         else
1873                 AC_DEFINE(USE_SAFE_SPRINTF,1,[Define to 1 to compile with experimental safe-sprintf code])
1874         fi
1875 fi
1876
1877 if test "x$with_getcap" = "xyes" ; then
1878         CF_CGETENT
1879 fi
1880
1881 CF_ISASCII
1882 CF_STRUCT_SIGACTION
1883 CF_FUNC_NANOSLEEP
1884 CF_FUNC_TERMIOS
1885 CF_FUNC_VSSCANF
1886 CF_MKSTEMP
1887
1888 # setup for prototype of fallback for vsscanf()
1889 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1890
1891 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1892 if test "x$cross_compiling" = xyes ; then
1893         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1894 else
1895         AC_FUNC_SETVBUF_REVERSED
1896 fi
1897 AC_CHECK_TYPE(intptr_t, long)
1898 AC_CHECK_TYPE(ssize_t, int)
1899 CF_TYPE_SIGACTION
1900 CF_SIZECHANGE
1901 CF_FUNC_MEMMOVE
1902 CF_FUNC_POLL
1903 CF_VA_COPY
1904 AC_FUNC_VFORK
1905 CF_FOPEN_BIN_R
1906
1907 # special check for test/ditto.c
1908 CF_FUNC_OPENPTY
1909 if test "$cf_cv_func_openpty" != no ; then
1910         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
1911         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
1912         if test "x$cf_cv_lib_util" = xyes ; then
1913                 CF_ADD_LIB(util,TEST_LIBS)
1914         fi
1915 fi
1916 AC_SUBST(TEST_LIBS)
1917 AC_SUBST(TEST_LIBS2)
1918
1919 if test "$with_hashed_db" != no ; then
1920         AC_DEFINE(USE_HASHED_DB,1,[Define to 1 if we should build terminfo in hashed database])
1921         CF_HASHED_DB($with_hashed_db)
1922 fi
1923
1924 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1925 if test -z "$cf_user_CFLAGS" && test "$enable_leaks" = yes ; then
1926         CF_STRIP_G_OPT(CFLAGS)
1927         CF_STRIP_G_OPT(CXXFLAGS)
1928 fi
1929
1930 # Just in case, check if the C compiler has a bool type.
1931 CF_BOOL_DECL(cf_cv_cc_bool_type)
1932
1933 # Check for C++ compiler characteristics (and ensure that it's there!)
1934 if test -n "$CXX" ; then
1935         AC_LANG_CPLUSPLUS
1936         CF_STDCPP_LIBRARY
1937         CF_PROG_CC_C_O(CXX,[$CXXFLAGS $CPPFLAGS])
1938
1939         case "$GXX_VERSION" in
1940         (1.*|2.[[0-6]]*|[[1-9]][[0-9]].*)
1941                 cf_cxx_library=yes
1942                 ;;
1943         (*-2.7*|2.7*)
1944                 CF_GPP_LIBRARY
1945                 ;;
1946         (*)
1947                 cf_cxx_library=no
1948                 ;;
1949         esac
1950
1951         AC_CHECK_HEADERS(typeinfo)
1952         CF_CXX_IOSTREAM_NAMESPACE
1953         CF_BOOL_DECL
1954         CF_BOOL_SIZE
1955         CF_ETIP_DEFINES
1956         CF_CPP_OVERRIDE
1957         CF_CPP_PARAM_INIT
1958         CF_CPP_STATIC_CAST
1959         CF_CXX_AR_FLAGS
1960 else
1961         cf_cxx_library=no
1962         cf_cv_builtin_bool=1
1963
1964         # Just because we are not configuring against C++ right now does not
1965         # mean that a user will not want to use C++.  Some distributors disable
1966         # the C++ portion of this configuration as a shortcut (or just to avoid
1967         # compiling the demo in the c++ directory).  So we need a reasonable
1968         # default for the 'bool' type.
1969         #
1970         # Caveat: since the storage of the bool type is not standardized, it
1971         # may change.
1972
1973         if test "$NCURSES_BOOL" != auto ; then
1974                 cf_cv_type_of_bool=$NCURSES_BOOL
1975                 cf_cv_header_stdbool_h=0
1976         else
1977                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1978                         CF_BOOL_SIZE
1979                 else
1980                         AC_MSG_CHECKING(for fallback type of bool)
1981                         case "$host_cpu" in
1982                         (i?86)  cf_cv_type_of_bool=char ;;
1983                         (*)     cf_cv_type_of_bool=int  ;;
1984                         esac
1985                         AC_MSG_RESULT($cf_cv_type_of_bool)
1986                 fi
1987         fi
1988 fi
1989 AC_SUBST(CXXLIBS)
1990
1991 # If the C compiler did not declare bool, and we did not determine that the C++
1992 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1993 # ncurses library use the same type as C++ bool.  Note that this allows one to
1994 # specify the type of bool in a configure-script option and postpone
1995 # integration with the C++ compiler provided that the types are compatible.
1996 USE_CXX_BOOL=1
1997 if test "$cf_cv_cc_bool_type" = 1
1998 then
1999         # oops: C has a bool.  Unlikely, but C++ could differ.
2000         USE_CXX_BOOL=0
2001 elif test "$cf_cv_builtin_bool" = 0
2002 then
2003         # C++ has no bool
2004         USE_CXX_BOOL=0
2005 else
2006         # this is the normal case
2007         USE_CXX_BOOL='defined(__cplusplus)'
2008 fi
2009 AC_SUBST(USE_CXX_BOOL)
2010
2011 CF_HELP_MESSAGE(Ada Binding Options:)
2012
2013 dnl If the Ada95 source-tree is present, add that to the build unless it will
2014 dnl not work, or was not requested.
2015 if test -f "${srcdir}/Ada95/Makefile.in" ; then
2016
2017 dnl libtool does not know anything about GNAT, though a change made in 1998
2018 dnl provided for it "someday".  Disable the ada subtree if we are using
2019 dnl libtool -TD 20070714
2020         if test "$cf_with_ada" != "no" ; then
2021                 if test "$with_libtool" != "no"; then
2022                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
2023                         cf_with_ada=no
2024                 fi
2025         fi
2026
2027 dnl Check for availability of GNU Ada Translator (GNAT).
2028 dnl At the moment we support no other Ada compiler.
2029         if test "$cf_with_ada" != "no" ; then
2030                 CF_PROG_GNAT
2031                 if test "x$cf_cv_prog_gnat_correct" = xyes; then
2032                         CF_ADD_ADAFLAGS(-gnatpn)
2033                         CF_FIXUP_ADAFLAGS
2034
2035                         CF_GNATPREP_OPT_T
2036
2037                         CF_GNAT_GENERICS
2038                         CF_GNAT_SIGINT
2039                         CF_GNAT_PROJECTS
2040
2041                         CF_WITH_ADA_COMPILER
2042
2043                         cf_ada_package=terminal_interface
2044                         AC_SUBST(cf_ada_package)
2045
2046                         CF_WITH_ADA_INCLUDE
2047                         CF_WITH_ADA_OBJECTS
2048                         CF_WITH_ADA_SHAREDLIB
2049
2050                         # allow the Ada binding to be renamed
2051                         CF_WITH_ADA_LIBNAME(AdaCurses)
2052                 fi
2053         fi
2054 else
2055         cf_with_ada=no
2056 fi
2057
2058 # do this "late" to avoid conflict with header-checks
2059 if test "x$with_widec" = xyes ; then
2060         AC_CHECK_SIZEOF(wchar_t)
2061         # cross-compiling to mingw can run into the problem that attempting to
2062         # link with the regex library fails, causing the test to not set this to
2063         # a number.  "recent" autoconf does not address this problem either -TD
2064         if test -z "$ac_cv_sizeof_wchar_t"
2065         then
2066                 CF_VERBOSE(test failed (assume 2))
2067                 sed /SIZEOF_WCHAR_T/d confdefs.h >confdefs.tmp
2068                 mv confdefs.tmp confdefs.h
2069                 echo "#define SIZEOF_WCHAR_T 2" >>confdefs.h
2070         fi
2071 fi
2072
2073 ### Construct the ncurses library-subsets, if any, from this set of keywords:
2074 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
2075 ###
2076 ### ticlib modules may be a separate library, otherwise contained in termlib.
2077 ### termlib modules may be a separate library, otherwise contained in ncurses.
2078 ###
2079 ### The of "+" or " " between the tokens controls the way the script
2080 ### chooses to split module lists into libraries.
2081 ###
2082 ### (see CF_LIB_RULES).
2083 AC_MSG_CHECKING(for library subsets)
2084 LIB_SUBSETS=
2085
2086 if test "x$cf_with_progs" = xyes || test "$with_ticlib" != no || test "$with_termcap" != no; then
2087         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
2088         if test "$with_ticlib" != no ; then
2089                 LIB_SUBSETS="${LIB_SUBSETS} "
2090         else
2091                 LIB_SUBSETS="${LIB_SUBSETS}+"
2092         fi
2093 fi
2094
2095 LIB_SUBSETS="${LIB_SUBSETS}termlib"
2096 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
2097
2098 if test "$with_termlib" != no ; then
2099         LIB_SUBSETS="${LIB_SUBSETS} "
2100 else
2101         LIB_SUBSETS="${LIB_SUBSETS}+"
2102 fi
2103
2104 LIB_SUBSETS="${LIB_SUBSETS}base"
2105
2106 # Most term-driver calls are to tinfo, but some like init_pair are to the
2107 # base library (so it resides in base).
2108 if test "$with_term_driver" != no ; then
2109         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
2110         case "$cf_cv_system_name" in
2111         (*mingw32*|*mingw64*)
2112                 if test "x$with_exp_win32" = xyes ; then
2113                         LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32"
2114                 else
2115                         LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
2116                 fi
2117                 CPPFLAGS="$CPPFLAGS -DUSE_WIN32CON_DRIVER"
2118                 ;;
2119         (*)
2120                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
2121                 ;;
2122         esac
2123 elif test "x$with_exp_win32" = xyes ; then
2124         case "$cf_cv_system_name" in
2125         (*mingw32*|*mingw64*)
2126                 LIB_SUBSETS="${LIB_SUBSETS}+port_win32"
2127                 ;;
2128         (*)
2129                 ;;
2130         esac
2131 fi
2132
2133 test "x$with_widec"     = xyes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
2134 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
2135
2136 AC_MSG_RESULT($LIB_SUBSETS)
2137
2138 ### Construct the list of include-directories to be generated
2139 CF_INCLUDE_DIRS
2140 CF_ADA_INCLUDE_DIRS
2141
2142 ### Build up pieces for makefile rules
2143 AC_MSG_CHECKING(default library suffix)
2144 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
2145 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
2146 AC_MSG_RESULT($DFT_ARG_SUFFIX)
2147
2148 AC_MSG_CHECKING(default library-dependency suffix)
2149 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
2150 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
2151 AC_MSG_RESULT($DFT_DEP_SUFFIX)
2152
2153 AC_MSG_CHECKING(default object directory)
2154 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
2155 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
2156 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
2157
2158 if test "x$cf_with_cxx" = xyes ; then
2159 AC_MSG_CHECKING(c++ library-dependency suffix)
2160 if test "$with_libtool" != "no"; then
2161         # libtool thinks it can make c++ shared libraries (perhaps only g++)
2162         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2163 elif test "$with_shared_cxx" != "no"; then
2164         # also for g++ users...
2165         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2166 else
2167         # we normally make a static library because C/C++ library rules differ
2168         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)
2169 fi
2170 AC_MSG_RESULT($CXX_LIB_SUFFIX)
2171 AC_SUBST(CXX_LIB_SUFFIX)
2172 fi
2173
2174 # do not want -ldl in build except as needed for -lncurses dependency
2175 if test "x$with_dlsym" = xyes ; then
2176 if test "$DFT_LWR_MODEL" = shared || \
2177    test "$DFT_LWR_MODEL" = libtool ; then
2178         CF_REMOVE_LIB(LIBS,$LIBS,dl)
2179 fi
2180 fi
2181 ### Set up low-level terminfo dependencies for makefiles.
2182
2183 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
2184 # do not need libdl
2185 TICS_LIST=
2186 if test "x$with_dlsym" = xyes ; then
2187         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
2188 fi
2189
2190 USE_ARG_SUFFIX="${DFT_ARG_SUFFIX}${EXTRA_SUFFIX}"
2191 USE_LIB_SUFFIX="${LIB_SUFFIX}${EXTRA_SUFFIX}"
2192 USE_CFG_SUFFIX=${DFT_ARG_SUFFIX}${cf_cv_abi_version}
2193 if test -n "$EXTRA_SUFFIX" && test "x$EXTRA_SUFFIX" != "x${cf_cv_abi_version}"
2194 then
2195         USE_CFG_SUFFIX="${USE_CFG_SUFFIX}${EXTRA_SUFFIX}"
2196 fi
2197 AC_SUBST(USE_ARG_SUFFIX)
2198 AC_SUBST(USE_CFG_SUFFIX)
2199 AC_SUBST(USE_LIB_SUFFIX)
2200
2201 if test "$with_ticlib" != no ; then
2202
2203         if test "x$with_ticlib" != xyes ; then
2204                 TICS_NAME=$with_ticlib
2205                 TICS_SUFFIX="`echo "${DFT_LIB_SUFFIX}" |sed -e "s/^${USE_LIB_SUFFIX}//"`"
2206                 TICS_ARG_SUFFIX="${with_ticlib}`echo "${USE_ARG_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2207                 TICS_DEP_SUFFIX="${with_ticlib}`echo "${DFT_DEP_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2208                 TICS_LIB_SUFFIX="${with_ticlib}"
2209         else
2210                 TICS_SUFFIX=${DFT_LIB_SUFFIX}
2211                 TICS_ARG_SUFFIX="${TICS_NAME}${USE_ARG_SUFFIX}"
2212                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
2213                 TICS_LIB_SUFFIX="${TICS_NAME}${USE_LIB_SUFFIX}"
2214         fi
2215         TICS_LDFLAGS="-L${LIB_DIR}"
2216         TICS_LIBS="-l${TICS_ARG_SUFFIX}"
2217 else
2218         TICS_SUFFIX=${DFT_LIB_SUFFIX}
2219         TICS_LDFLAGS="-L${LIB_DIR}"
2220         TICS_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2221 fi
2222 AC_SUBST(TICS_ARG_SUFFIX)
2223 AC_SUBST(TICS_DEP_SUFFIX)
2224 AC_SUBST(TICS_LIB_SUFFIX)
2225 AC_SUBST(TICS_LDFLAGS)
2226 AC_SUBST(TICS_LIBS)
2227
2228 if test "$with_termlib" != no ; then
2229
2230         if test "x$with_termlib" != xyes ; then
2231                 TINFO_NAME=$with_termlib
2232                 TINFO_SUFFIX="`echo "${DFT_LIB_SUFFIX}" |sed -e "s/^${USE_LIB_SUFFIX}//"`"
2233                 TINFO_ARG_SUFFIX="${with_termlib}`echo "${USE_ARG_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2234                 TINFO_DEP_SUFFIX="${with_termlib}`echo "${DFT_DEP_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2235                 TINFO_LIB_SUFFIX="${with_termlib}"
2236         else
2237                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2238                 TINFO_ARG_SUFFIX="${TINFO_NAME}${USE_ARG_SUFFIX}"
2239                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
2240                 TINFO_LIB_SUFFIX="${TINFO_NAME}${USE_LIB_SUFFIX}"
2241         fi
2242
2243         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2244         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2245         if test "$DFT_LWR_MODEL" = "libtool"; then
2246                 TEST_ARGS="${TEST_DEPS}"
2247                 TEST_ARG2="${TEST_DEP2}"
2248                 TINFO_LDFLAGS="-L${LIB_DIR}"
2249                 TINFO_LIBS="$TEST_ARGS"
2250                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
2251                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
2252         else
2253                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
2254                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
2255                 if test "x$with_term_driver" != xno ; then
2256                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2257                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${USE_ARG_SUFFIX}"
2258                         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
2259                 else
2260                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2261                         TINFO_LIBS="$TEST_ARGS"
2262                 fi
2263                 TINFO_LDFLAGS="-L${LIB_DIR}"
2264                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2265         fi
2266 else
2267         # the next lines are needed for linking libtic over libncurses
2268         TINFO_NAME=${LIB_NAME}
2269         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2270         TINFO_ARG_SUFFIX=${LIB_NAME}${USE_ARG_SUFFIX}
2271         if test "x$with_tic_depends" = xyes ; then
2272                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2273         else
2274                 TICS_LIST="$SHLIB_LIST"
2275         fi
2276
2277         TINFO_LDFLAGS="-L${LIB_DIR}"
2278         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2279 fi
2280
2281 if test "$DFT_LWR_MODEL" = shared ; then
2282         case "$cf_cv_system_name" in
2283         (cygwin*|msys*)
2284                 # "lib" files have ".dll.a" suffix, "cyg"or "msys-" files have ".dll"
2285                 TINFO_SUFFIX=.dll
2286                 ;;
2287         esac
2288 fi
2289
2290 AC_SUBST(TINFO_ARG_SUFFIX)
2291 AC_SUBST(TINFO_DEP_SUFFIX)
2292 AC_SUBST(TINFO_LIB_SUFFIX)
2293 AC_SUBST(TINFO_LDFLAGS)
2294 AC_SUBST(TINFO_LIBS)
2295
2296 if test "x$with_dlsym" = xyes ; then
2297         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
2298 fi
2299
2300 if test "$DFT_LWR_MODEL" = "libtool"; then
2301         OBJEXT=lo
2302 fi
2303
2304 # needed for Ada95
2305 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
2306 AC_SUBST(TINFO_LDFLAGS2)
2307
2308 case "$DFT_LWR_MODEL" in
2309 (normal|debug|profile)
2310         CF_LDFLAGS_STATIC
2311         ;;
2312 esac
2313
2314 AC_MSG_CHECKING(where we will install curses.h)
2315 AC_SUBST(includesubdir)
2316 includesubdir=
2317 if test "$with_overwrite" = no && \
2318  { test "x$includedir" = 'x${prefix}/include' || \
2319    test "x$includedir" = "x${prefix}/include"; }
2320 then
2321         includesubdir="/ncurses${USE_LIB_SUFFIX}"
2322 fi
2323 AC_MSG_RESULT(${includedir}${includesubdir})
2324
2325 ### Resolve a conflict between normal and wide-curses by forcing applications
2326 ### that will need libutf8 to add it to their configure script.
2327 if test "$with_overwrite" != no ; then
2328 if test "$NCURSES_LIBUTF8" = 1 ; then
2329         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
2330         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
2331 fi
2332 fi
2333 WITH_OVERWRITE=$with_overwrite
2334
2335 ### At least on MinGW a shared library build without libtool
2336 ### requires adding the additional libs to the link list.
2337 case "$cf_cv_system_name" in
2338 (*mingw32*|*mingw64*)
2339         if test "$DFT_LWR_MODEL" != "libtool"; then
2340            SHLIB_LIST="$SHLIB_LIST ${LIBS}"
2341         fi
2342         ;;
2343 *)      ;;
2344 esac
2345
2346 AC_SUBST(WITH_OVERWRITE)
2347 AC_SUBST(TICS_LIST)
2348 AC_SUBST(TINFO_LIST)
2349 AC_SUBST(SHLIB_LIST)
2350
2351 ### predefined stuff for the test programs
2352 AC_DEFINE(HAVE_SLK_COLOR,1,[Define to 1 if we have slk_color for test-programs])
2353
2354 # pkgsrc uses these
2355 CF_WITH_LIB_BASENAME(FORM_NAME,form)
2356 CF_WITH_LIB_BASENAME(MENU_NAME,menu)
2357 CF_WITH_LIB_BASENAME(PANEL_NAME,panel)
2358 CF_WITH_LIB_BASENAME(CXX_NAME,cxx,ncurses++)
2359
2360 ### Construct the list of subdirectories for which we'll customize makefiles
2361 ### with the appropriate compile-rules.
2362
2363 CF_SRC_MODULES($modules_to_build)
2364
2365 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2366    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/src/library.gpr:Ada95/src/library.gpr.in"
2367    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${USE_CFG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
2368    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${USE_CFG_SUFFIX}-config.1:man/MKada_config.in"
2369 fi
2370
2371 CF_DIRS_TO_MAKE
2372
2373 # symbols that differ when compiling Ada95 by itself.
2374 NCURSES_SHLIB2=$SHELL' $(top_srcdir)/misc/shlib'
2375 AC_SUBST(NCURSES_SHLIB2)
2376
2377 # values to use as strings
2378 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as library path-separator])
2379
2380 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}",[Define to 1 if machine has ample memory for tic])
2381
2382 ### Define substitutions for header files to avoid name-pollution
2383 CF_SUBST_IF(["x$cf_cv_have_tcgetattr" = xyes], HAVE_TCGETATTR, 1, 0)
2384 CF_SUBST_IF(["x$ac_cv_header_stdint_h" = xyes], HAVE_STDINT_H, 1, 0)
2385 CF_SUBST_IF(["x$ac_cv_header_termio_h" = xyes], HAVE_TERMIO_H, 1, 0)
2386 CF_SUBST_IF(["x$ac_cv_header_termios_h" = xyes], HAVE_TERMIOS_H, 1, 0)
2387
2388 ################################################################################
2389 test "x$use_database" = xyes && \
2390 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
2391
2392 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
2393 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${USE_CFG_SUFFIX}-config.1:man/MKncu_config.in"
2394
2395 if test "x$enable_pc_files" = xyes && test -z "$MAKE_PC_FILES" ; then
2396 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
2397 fi
2398 AC_SUBST(cross_compiling)
2399
2400 if test "x$cf_with_tests" != xno ; then
2401         MAKE_TESTS=
2402 else
2403         MAKE_TESTS="#"
2404 fi
2405 AC_SUBST(MAKE_TESTS)
2406
2407 ADAHTML_DIR=../../doc/html/ada
2408 AC_SUBST(ADAHTML_DIR)
2409
2410 # workaround for OS/2 (20151017)
2411 case "$cf_cv_system_name" in
2412 (os2*)
2413         LIBTOOL_OPTS_CXX="-os2dllname ncurs++"
2414         ;;
2415 (*)
2416         LIBTOOL_OPTS_CXX=
2417         ;;
2418 esac
2419 AC_SUBST(LIBTOOL_OPTS_CXX)
2420
2421 # workaround for g++ versus Solaris (20131116)
2422 case "$cf_cv_system_name" in
2423 (solaris2*)
2424         case "x$CPPFLAGS" in
2425         (*-D_XOPEN_SOURCE_EXTENDED*)
2426                 CF_VERBOSE(moving _XOPEN_SOURCE_EXTENDED to work around g++ problem)
2427                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
2428                 CPPFLAGS=`echo "x$CPPFLAGS" | sed -e  's/^.//' -e 's/-D_XOPEN_SOURCE_EXTENDED//'`
2429                 ;;
2430         esac
2431         ;;
2432 esac
2433
2434 # Help to automatically enable the extended curses features when using either
2435 # the *-config or the ".pc" files by adding defines.
2436 AC_MSG_CHECKING(for defines to add to ncurses${USE_CFG_SUFFIX}-config script)
2437 PKG_CFLAGS=
2438 for cf_loop1 in $CPPFLAGS_after_XOPEN
2439 do
2440         cf_found=no
2441         for cf_loop2 in $CPPFLAGS_before_XOPEN
2442         do
2443                 if test "x$cf_loop1" = "x$cf_loop2"
2444                 then
2445                         cf_found=yes
2446                         break
2447                 fi
2448         done
2449         test "$cf_found" = no && PKG_CFLAGS="$PKG_CFLAGS $cf_loop1"
2450 done
2451 AC_MSG_RESULT($PKG_CFLAGS)
2452 AC_SUBST(PKG_CFLAGS)
2453
2454 # AC_CHECK_SIZEOF demands a literal parameter, no variables.  So we do this.
2455 case "x$NCURSES_OSPEED" in
2456 (*short*)
2457         cf_compatible=1
2458         ;;
2459 (*)
2460         cf_compatible=0
2461         ;;
2462 esac
2463 AC_DEFINE_UNQUOTED(NCURSES_OSPEED_COMPAT,$cf_compatible,[Define to 1 if termcap variable ospeed is short])
2464
2465 case "x$cf_cv_typeof_chtype" in
2466 (xshort|xint|xlong)
2467         cf_cv_typeof_chtype="unsigned $cf_cv_typeof_chtype"
2468         ;;
2469 esac
2470
2471 case "x$cf_cv_typeof_mmask_t" in
2472 (xshort|xint|xlong)
2473         cf_cv_typeof_mmask_t="unsigned $cf_cv_typeof_mmask_t"
2474         ;;
2475 esac
2476
2477 # substitute into misc/Makefile to suppress
2478 # (un)install.data from the
2479 # (un)install rules.
2480 if test "x$cf_with_db_install" = "xno"; then
2481         MISC_INSTALL_DATA=
2482         MISC_UNINSTALL_DATA=
2483 else
2484         MISC_INSTALL_DATA=install.data
2485         MISC_UNINSTALL_DATA=uninstall.data
2486 fi
2487 AC_SUBST(MISC_INSTALL_DATA)
2488 AC_SUBST(MISC_UNINSTALL_DATA)
2489
2490 if test "x$cf_with_db_install" = "xno" || test "x$TERMINFO_SRC" = "xno"; then
2491         MAKE_DATABASE="#"
2492 else
2493         MAKE_DATABASE="$MAKE_TERMINFO"
2494 fi
2495 AC_SUBST(MAKE_DATABASE)
2496
2497 dnl Override the package used for exported symbols
2498 if test -n "$PACKAGE"
2499 then
2500         PACKAGE="${PACKAGE}${DFT_ARG_SUFFIX}"
2501         export PACKAGE
2502         echo "package: $PACKAGE"
2503 fi
2504
2505 UNALTERED_SYMS=
2506 cf_filter_syms=no
2507
2508 if test -n "$RESULTING_SYMS"
2509 then
2510         cf_filter_syms=$cf_dft_filter_syms
2511         CF_VERBOSE(will map symbols to ABI=$cf_cv_abi_default)
2512 fi
2513
2514 if test "x$WILDCARD_SYMS" = xno
2515 then
2516         cf_filter_syms=yes
2517 fi
2518
2519 test "x$cf_with_trace" = xyes && NCURSES_INLINE=
2520
2521 UNALTERED_SYMS=`echo "$RESULTING_SYMS" | sed -e 's/\\$/\\\\$/g'`
2522 if test "$cf_filter_syms" = yes
2523 then
2524         RESULTING_SYMS=resulting.map
2525 fi
2526 AC_SUBST(UNALTERED_SYMS)
2527
2528 if test "x$cross_compiling" = xyes ; then
2529         ADAGEN_LDFLAGS='$(CROSS_LDFLAGS)'
2530         CHECK_BUILD="#"
2531 else
2532         ADAGEN_LDFLAGS='$(NATIVE_LDFLAGS)'
2533         CHECK_BUILD=
2534 fi
2535 AC_SUBST(ADAGEN_LDFLAGS)
2536 AC_SUBST(CHECK_BUILD)
2537 AC_SUBST(PRIVATE_LIBS)
2538
2539 # This is used for the *-config script and *.pc data files.
2540 CF_LD_SEARCHPATH
2541
2542 AC_OUTPUT( \
2543         include/MKterm.h.awk \
2544         include/curses.head:include/curses.h.in \
2545         include/ncurses_dll.h \
2546         include/termcap.h \
2547         include/unctrl.h \
2548         man/man_db.renames \
2549         $SUB_MAKEFILES \
2550         Makefile,[
2551 if test "x$cf_with_tests" != xno ; then
2552         CF_PRG_RULES(["$srcdir/test/mk-test.awk" INSTALL=no ECHO_LINK="$ECHO_LD"], test)
2553 fi
2554 CF_LIB_RULES($SRC_SUBDIRS)
2555 CF_OUTPUT_MANPAGE_RENAMES
2556
2557 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2558 if test -z "$USE_OLD_MAKERULES" ; then
2559         $AWK -f "$srcdir/Ada95/mk-1st.awk" <"$srcdir/Ada95/src/modules" >>Ada95/src/Makefile
2560 fi
2561 fi
2562 ],[
2563 ### Special initialization commands, used to pass information from the
2564 ### configuration-run into config.status
2565
2566 ALTERNATE_SYMS="$ALTERNATE_SYMS"
2567 AWK="$AWK"
2568 CXX_NAME="$CXX_NAME"
2569 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
2570 DFT_LWR_MODEL="$DFT_LWR_MODEL"
2571 ECHO_LD="$ECHO_LD"
2572 EXTRA_SUFFIX="$EXTRA_SUFFIX"
2573 FORM_NAME="$FORM_NAME"
2574 LDCONFIG="$LDCONFIG"
2575 LIBTOOL_VERSION="$LIBTOOL_VERSION"
2576 LIB_NAME="$LIB_NAME"
2577 LIB_PREFIX="$LIB_PREFIX"
2578 LIB_SUBSETS="$LIB_SUBSETS"
2579 LIB_SUFFIX="$LIB_SUFFIX"
2580 LIB_TRACING="$LIB_TRACING"
2581 LN_S="$LN_S"
2582 MAKE_TERMINFO="$MAKE_TERMINFO"
2583 MANPAGE_RENAMES="$MANPAGE_RENAMES"
2584 MENU_NAME="$MENU_NAME"
2585 NCURSES_MAJOR="$NCURSES_MAJOR"
2586 NCURSES_MINOR="$NCURSES_MINOR"
2587 NCURSES_OSPEED="$NCURSES_OSPEED"
2588 NCURSES_PATCH="$NCURSES_PATCH"
2589 PANEL_NAME="$PANEL_NAME"
2590 SRC_SUBDIRS="$SRC_SUBDIRS"
2591 TERMINFO="$TERMINFO"
2592 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
2593 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
2594 TICS_NAME="$TICS_NAME"
2595 TICS_SUFFIX="$TICS_SUFFIX"
2596 TIC_PATH="$TIC_PATH"
2597 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
2598 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
2599 TINFO_NAME="$TINFO_NAME"
2600 TINFO_SUFFIX="$TINFO_SUFFIX"
2601 UNALTERED_SYMS="$UNALTERED_SYMS"
2602 USE_ARG_SUFFIX="$USE_ARG_SUFFIX"
2603 USE_CFG_SUFFIX="$USE_CFG_SUFFIX"
2604 USE_LIB_SUFFIX="$USE_LIB_SUFFIX"
2605 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
2606 WILDCARD_SYMS="$WILDCARD_SYMS"
2607 WITH_CURSES_H="$with_curses_h"
2608 WITH_ECHO="${enable_echo:=yes}"
2609 WITH_OVERWRITE="$with_overwrite"
2610 cf_LIST_MODELS="$cf_list_models"
2611 cf_cv_VERSION_GNATMAKE=$cf_cv_VERSION_GNATMAKE
2612 cf_cv_VERSION_GPRBUILD=$cf_cv_VERSION_GPRBUILD
2613 cf_cv_abi_default="$cf_cv_abi_default"
2614 cf_cv_abi_version="$cf_cv_abi_version"
2615 cf_cv_do_relink="$cf_cv_do_relink"
2616 cf_cv_do_reranlib="$cf_cv_do_reranlib"
2617 cf_cv_do_symlinks="$cf_cv_do_symlinks"
2618 cf_cv_enable_lp64="$cf_cv_enable_lp64"
2619 cf_cv_enable_opaque="$cf_cv_enable_opaque"
2620 cf_cv_make_PHONY="$cf_cv_make_PHONY"
2621 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
2622 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
2623 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
2624 cf_cv_rel_version="$cf_cv_rel_version"
2625 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
2626 cf_cv_shared_soname='$cf_cv_shared_soname'
2627 cf_cv_shlib_version="$cf_cv_shlib_version"
2628 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
2629 cf_cv_system_name="$cf_cv_system_name"
2630 cf_cv_term_driver="$with_term_driver"
2631 cf_with_ada="$cf_with_ada"
2632 cf_with_cxx_binding="$cf_with_cxx_binding"
2633 cf_with_db_install="$cf_with_db_install"
2634 cf_with_manpages="$cf_with_manpages"
2635 cf_with_tests="$cf_with_tests"
2636 host="$host"
2637 target="$target"
2638 verbose="$verbose"
2639 with_shared_cxx="$with_shared_cxx"
2640
2641 ],cat)dnl
2642 ${MAKE:-make} preinstall