configure.in

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2022,2023 Thomas E. Dickey                                *
   3 dnl Copyright 1998-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl Author: Thomas E. Dickey 1995-on
  31 dnl
  32 dnl $Id: configure.in,v 1.764 2023/05/06 19:40:40 tom Exp $
  33 dnl Process this file with autoconf to produce a configure script.
  34 dnl
  35 dnl For additional information, see
  36 dnl     https://invisible-island.net/autoconf/
  37 dnl     https://invisible-island.net/autoconf/my-autoconf.html
  38 dnl
  39 dnl ---------------------------------------------------------------------------
  40 AC_PREREQ(2.52.20210101)
  41 AC_REVISION($Revision: 1.764 $)
  42 AC_INIT(ncurses/base/lib_initscr.c)
  43 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  44
  45 AC_DEFUN([AC_PATH_XTRA],[])dnl ignore dependencies on this
  46
  47 CF_TOP_BUILDDIR
  48 CF_SUBST_NCURSES_VERSION
  49 CF_VERSION_INFO(NCURSES,ncurses)
  50
  51 CF_WITH_REL_VERSION(NCURSES)
  52 CF_NCURSES_WITH_ABI_VERSION
  53
  54 CF_WITH_SYSTYPE
  55
  56 ###     Save the given $CFLAGS to allow user-override.
  57 cf_user_CFLAGS="$CFLAGS"
  58
  59 ###     Default install-location
  60 CF_CFG_DEFAULTS
  61 ### Defaults for ncurses ABI
  62 CF_ABI_DEFAULTS
  63
  64 ### override ABI version, e.g., packagers
  65 CF_WITH_ABI_ALTERED
  66
  67 ###     Checks for programs.
  68 AC_ARG_WITH(ada,
  69         [  --without-ada           suppress check for Ada compiler, don't build demo],
  70         [cf_with_ada=$withval],
  71         [cf_with_ada=yes])
  72
  73 if test "x$cf_with_ada" = xyes
  74 then
  75         cf_prog_cc="gnatgcc gcc cc"
  76 else
  77         cf_prog_cc="gcc cc"
  78 fi
  79 CF_PROG_CC($cf_prog_cc)
  80
  81 AC_PROG_CPP
  82 AC_PROG_GCC_TRADITIONAL
  83 CF_PROG_CC_C_O(CC,[$CFLAGS $CPPFLAGS])
  84 CF_PROG_LDCONFIG
  85
  86 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  87 dnl                             configure script by not letting us test if C++
  88 dnl                             is present, making this option necessary.
  89 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  90 AC_ARG_WITH(cxx,
  91         [  --without-cxx           do not adjust ncurses bool to match C++],
  92         [cf_with_cxx=$withval],
  93         [cf_with_cxx=yes])
  94 AC_MSG_RESULT($cf_with_cxx)
  95 if test "X$cf_with_cxx" = Xno ; then
  96         CXX=""
  97         GXX=""
  98 else
  99         # with autoconf 2.13, we can change the error to a warning:
 100         pushdef([AC_MSG_ERROR],
 101                 [AC_MSG_RESULT(no)
 102                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
 103                 cf_with_cxx=no; CXX=""; GXX="";])dnl
 104         AC_PROG_CXX
 105         popdef([AC_MSG_ERROR])dnl
 106
 107         AC_LANG_PUSH(C++)
 108         if test "x$cf_with_cxx" != xno
 109         then
 110                 # Several of the C++ configurations do not work, particularly when
 111                 # cross-compiling (20140913 -TD)
 112                 AC_MSG_CHECKING(if $CXX works)
 113
 114                 save_CPPFLAGS="$CPPFLAGS"
 115                 eval cf_includedir=${includedir}
 116                 CPPFLAGS="$CPPFLAGS -I${cf_includedir}"
 117                 AC_TRY_COMPILE([
 118 #include <stdlib.h>
 119 #include <stdio.h>
 120 ],
 121                 [
 122                 printf("Hello world!\n")
 123                 ],
 124                 [cf_cxx_works=yes],
 125                 [cf_cxx_works=no])
 126                 CPPFLAGS="$save_CPPFLAGS"
 127
 128                 AC_MSG_RESULT($cf_cxx_works)
 129                 if test "x$cf_cxx_works" = xno
 130                 then
 131                         AC_MSG_WARN([Ignore $CXX, since it cannot compile hello-world.])
 132                         cf_with_cxx=no; CXX=""; GXX="";
 133                 fi
 134         fi
 135         AC_LANG_POP
 136
 137         # autoconf 2.5x removed the error (hardcoding it to g++, or just blank)
 138         if test "$CXX" = "g++" ; then
 139                 AC_PATH_PROG(CXX,g++)
 140         fi
 141         case "x$CXX" in
 142         (x|xg++)
 143                 AC_MSG_WARN([You don't have any C++ compiler, too bad])
 144                 cf_with_cxx=no; CXX=""; GXX="";
 145                 ;;
 146         esac
 147 fi
 148
 149 CF_GXX_VERSION
 150 case "$GXX_VERSION" in
 151 ([[1-9]][[0-9]].*)
 152         ;;
 153 (1.*|2.[[0-6]]*)
 154         AC_MSG_WARN(templates do not work)
 155         ;;
 156 esac
 157
 158 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 159 AC_ARG_WITH(cxx-binding,
 160         [  --without-cxx-binding   do not build C++ binding and demo],
 161         [cf_with_cxx_binding=$withval],
 162         [cf_with_cxx_binding=$cf_with_cxx])
 163 AC_MSG_RESULT($cf_with_cxx_binding)
 164
 165 AC_MSG_CHECKING(if you want to build with Ada)
 166 AC_MSG_RESULT($cf_with_ada)
 167
 168 AC_MSG_CHECKING(if you want to install terminal database)
 169 AC_ARG_ENABLE(db-install,
 170         [  --disable-db-install    suppress install of terminal database],
 171         [cf_with_db_install=$enableval],
 172         [cf_with_db_install=yes])
 173 AC_MSG_RESULT($cf_with_db_install)
 174
 175 AC_MSG_CHECKING(if you want to install manpages)
 176 AC_ARG_WITH(manpages,
 177         [  --without-manpages      suppress install of manpages],
 178         [cf_with_manpages=$withval],
 179         [cf_with_manpages=yes])
 180 AC_MSG_RESULT($cf_with_manpages)
 181
 182 AC_MSG_CHECKING(if you want to build programs such as tic)
 183 AC_ARG_WITH(progs,
 184         [  --without-progs         suppress build/install with programs (e.g., tic)],
 185         [cf_with_progs=$withval],
 186         [cf_with_progs=yes])
 187 AC_MSG_RESULT($cf_with_progs)
 188
 189 AC_MSG_CHECKING(if you want to build test-programs)
 190 AC_ARG_WITH(tests,
 191         [  --without-tests         suppress build/install with test-programs],
 192         [cf_with_tests=$withval],
 193         [cf_with_tests=yes])
 194 AC_MSG_RESULT($cf_with_tests)
 195
 196 AC_MSG_CHECKING(if you wish to install curses.h)
 197 AC_ARG_WITH(curses-h,
 198         [  --without-curses-h      install curses.h as ncurses.h only],
 199         [with_curses_h=$withval],
 200         [with_curses_h=yes])
 201 AC_MSG_RESULT($with_curses_h)
 202
 203 modules_to_build="ncurses"
 204 test "X$cf_with_progs" != Xno && modules_to_build="$modules_to_build progs"
 205 modules_to_build="$modules_to_build panel menu form"
 206
 207 AC_ARG_PROGRAM
 208
 209 CF_PROG_AWK
 210 CF_PROG_INSTALL
 211 CF_PROG_LINT
 212 CF_PROG_LN_S
 213
 214 AC_SYS_LONG_FILE_NAMES
 215
 216 # Provide for renaming "ncurses5-config" to "ncurses5X-config", etc., in case
 217 # of package conflict.
 218 cf_config_suffix=
 219 AC_ARG_WITH(config-suffix,
 220         [  --with-config-suffix=X  suffixes ncursesXX-config file],
 221         [case "x$withval" in
 222         (xyes|xno)
 223                 AC_MSG_WARN(expected a value for config-suffix option)
 224                 ;;
 225         (*)     cf_config_suffix="$withval"
 226                 ;;
 227         esac])
 228 AC_SUBST(cf_config_suffix)
 229
 230 # If we find pkg-config, check if we should install the ".pc" files.
 231 CF_PKG_CONFIG
 232 CF_WITH_PKG_CONFIG_LIBDIR
 233 CF_ENABLE_PC_FILES
 234 if test -z "$MAKE_PC_FILES"
 235 then
 236         AC_MSG_CHECKING(for suffix to add to pc-files)
 237 AC_ARG_WITH(pc-suffix,
 238         [  --with-pc-suffix        suffixes pc-files],
 239         [case "x$withval" in
 240         (xyes|xno)
 241                 PC_MODULE_SUFFIX=
 242                 ;;
 243         (*)     PC_MODULE_SUFFIX="$withval"
 244                 ;;
 245         esac])
 246         test -z "$PC_MODULE_SUFFIX" && PC_MODULE_SUFFIX=none
 247         AC_MSG_RESULT($PC_MODULE_SUFFIX)
 248         test "$PC_MODULE_SUFFIX" = none && PC_MODULE_SUFFIX=
 249         AC_SUBST(PC_MODULE_SUFFIX)
 250 fi
 251
 252 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 253 AC_ARG_ENABLE(mixed-case,
 254         [  --enable-mixed-case     tic should assume mixed-case filenames],
 255         [enable_mixedcase=$enableval],
 256         [enable_mixedcase=auto])
 257 AC_MSG_RESULT($enable_mixedcase)
 258 if test "$enable_mixedcase" = "auto" ; then
 259         CF_MIXEDCASE_FILENAMES
 260 else
 261         cf_cv_mixedcase=$enable_mixedcase
 262         if test "x$enable_mixedcase" = "xyes" ; then
 263                 AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if tic should assume mixed-case filenames])
 264         fi
 265 fi
 266
 267 # do this after mixed-case option (tags/TAGS is not as important as tic).
 268 AC_PROG_MAKE_SET
 269 CF_MAKE_PHONY
 270 CF_MAKE_TAGS
 271 CF_MAKEFLAGS
 272
 273 dnl These are standard among *NIX systems, but not when cross-compiling
 274 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 275 AC_CHECK_TOOL(LD, ld, ld)
 276 AC_CHECK_TOOL(AR, ar, ar)
 277 AC_CHECK_TOOL(NM, nm, nm)
 278 CF_AR_FLAGS
 279
 280 dnl Special option for use by system-builders: the install-prefix is used to
 281 dnl adjust the location into which the actual install is done, so that an
 282 dnl archive can be built without modifying the host system's configuration.
 283 AC_MSG_CHECKING(if you have specified an install-prefix)
 284 AC_ARG_WITH(install-prefix,
 285         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 286         [case "x$withval" in
 287         (xyes|xno)
 288                 ;;
 289         (*)     DESTDIR="$withval"
 290                 ;;
 291         esac])
 292 AC_MSG_RESULT($DESTDIR)
 293 AC_SUBST(DESTDIR)
 294
 295 ###############################################################################
 296 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 297 # If we're cross-compiling, allow the user to override the tools and their
 298 # options.  The configure script is oriented toward identifying the host
 299 # compiler, etc., but we need a build compiler to generate parts of the source.
 300
 301 case "$cf_cv_system_name" in
 302 (*-msvc*)
 303         LDFLAGS="$LDFLAGS user32.lib"
 304         export LDFLAGS
 305         ;;
 306 esac
 307
 308 CF_BUILD_CC
 309
 310 ###############################################################################
 311 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 312
 313 ### Options to allow the user to specify the set of libraries which are used.
 314 ### Use "--without-normal --with-shared" to allow the default model to be
 315 ### shared, for example.
 316 cf_list_models=""
 317 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 318
 319 CF_WITH_LIBTOOL
 320 if test "$with_libtool" != "no" ; then
 321
 322 cf_list_models="$cf_list_models libtool"
 323
 324 else
 325
 326 AC_MSG_CHECKING(if you want to build shared libraries)
 327 AC_ARG_WITH(shared,
 328         [  --with-shared           generate shared-libraries],
 329         [with_shared=$withval],
 330         [with_shared=no])
 331 AC_MSG_RESULT($with_shared)
 332 test "x$with_shared" = "xyes" && cf_list_models="$cf_list_models shared"
 333
 334 AC_MSG_CHECKING(if you want to build static libraries)
 335 AC_ARG_WITH(normal,
 336         [  --with-normal           generate normal-libraries (default)],
 337         [with_normal=$withval],
 338         [with_normal=yes])
 339 AC_MSG_RESULT($with_normal)
 340 test "x$with_normal" = "xyes" && cf_list_models="$cf_list_models normal"
 341
 342 AC_MSG_CHECKING(if you want to build debug libraries)
 343 AC_ARG_WITH(debug,
 344         [  --with-debug            generate debug-libraries (default)],
 345         [with_debug=$withval],
 346         [with_debug=yes])
 347 AC_MSG_RESULT($with_debug)
 348 test "x$with_debug" = "xyes" && cf_list_models="$cf_list_models debug"
 349
 350 AC_MSG_CHECKING(if you want to build profiling libraries)
 351 AC_ARG_WITH(profile,
 352         [  --with-profile          generate profile-libraries],
 353         [with_profile=$withval],
 354         [with_profile=no])
 355 AC_MSG_RESULT($with_profile)
 356 test "x$with_profile" = "xyes" && cf_list_models="$cf_list_models profile"
 357
 358 fi
 359
 360 if test "X$cf_with_cxx_binding" != Xno; then
 361 if test "x$with_shared" = "xyes"; then
 362 AC_MSG_CHECKING(if you want to build C++ shared libraries)
 363 AC_ARG_WITH(cxx-shared,
 364         [  --with-cxx-shared       generate C++ shared-libraries],
 365         [with_shared_cxx=$withval],
 366         [with_shared_cxx=no])
 367 AC_MSG_RESULT($with_shared_cxx)
 368 fi
 369 fi
 370
 371 ###############################################################################
 372
 373 AC_MSG_CHECKING(for specified models)
 374 test -z "$cf_list_models" && cf_list_models=normal
 375 dnl If we use libtool to generate libraries, then it must be the only
 376 dnl specified model.
 377 test "$with_libtool" != "no" && cf_list_models=libtool
 378 AC_MSG_RESULT($cf_list_models)
 379
 380 ### Use the first model as the default, and save its suffix for use in building
 381 ### up test-applications.
 382 AC_MSG_CHECKING(for default model)
 383 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 384 AC_MSG_RESULT($DFT_LWR_MODEL)
 385
 386 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 387
 388 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 389 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 390
 391 TICS_NAME=tic
 392 AC_SUBST(TICS_NAME)
 393
 394 TINFO_NAME=tinfo
 395 AC_SUBST(TINFO_NAME)
 396
 397 LIB_NAME=ncurses
 398 AC_SUBST(LIB_NAME)
 399
 400 LIB_DIR=../lib
 401 LIB_2ND=../../lib
 402
 403 CF_WITH_LIB_PREFIX(cf_prefix)
 404
 405 LIB_SUFFIX=
 406 AC_SUBST(LIB_SUFFIX)
 407 CF_PATHSEP
 408
 409 # headers needed for checks...
 410 AC_CHECK_DECL(exit)
 411 AC_HEADER_DIRENT
 412
 413 ###############################################################################
 414
 415 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 416 AC_ARG_WITH(termlib,
 417         [  --with-termlib          generate separate terminfo library],
 418         [with_termlib=$withval],
 419         [with_termlib=no])
 420 AC_MSG_RESULT($with_termlib)
 421
 422 AC_MSG_CHECKING(if you want to build a separate tic library)
 423 AC_ARG_WITH(ticlib,
 424         [  --with-ticlib           generate separate tic library],
 425         [with_ticlib=$withval],
 426         [with_ticlib=no])
 427 AC_MSG_RESULT($with_ticlib)
 428
 429 dnl Not all ports of gcc support the -g option
 430
 431 if test X"$CC_G_OPT" = X"" ; then
 432         CC_G_OPT='-g'
 433         test -n "$GCC" && test "x${ac_cv_prog_cc_g}" != xyes && CC_G_OPT=''
 434 fi
 435 AC_SUBST(CC_G_OPT)
 436
 437 if test X"$CXX_G_OPT" = X"" ; then
 438         CXX_G_OPT='-g'
 439         test -n "$GXX" && test "x${ac_cv_prog_cxx_g}" != xyes && CXX_G_OPT=''
 440 fi
 441 AC_SUBST(CXX_G_OPT)
 442
 443 AC_MSG_CHECKING(for default loader flags)
 444 case "$DFT_LWR_MODEL" in
 445 (libtool) LD_MODEL=''   ;;
 446 (normal)  LD_MODEL=''   ;;
 447 (debug)   LD_MODEL=$CC_G_OPT ;;
 448 (profile) LD_MODEL='-pg';;
 449 (shared)  LD_MODEL=''   ;;
 450 esac
 451 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 452 AC_MSG_RESULT($LD_MODEL)
 453
 454 case "$DFT_LWR_MODEL" in
 455 (shared)
 456 CF_ENABLE_RPATH
 457 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 458 AC_ARG_ENABLE(relink,
 459 [  --disable-relink        relink shared libraries during install],
 460 [cf_cv_do_relink=$enableval],
 461 [cf_cv_do_relink=yes])
 462 AC_MSG_RESULT($cf_cv_do_relink)
 463         ;;
 464 esac
 465
 466 # we will build libraries one-level down.
 467 rel_builddir=..
 468 CF_SHARED_OPTS
 469 for model in $cf_list_models ; do
 470         case "$model" in
 471         (libtool)
 472                 CF_WITH_LIBTOOL_OPTS
 473                 CF_WITH_EXPORT_SYMS
 474                 ;;
 475         (shared)
 476                 if test "$CC_SHARED_OPTS" = "unknown"; then
 477                         AC_ERROR(Shared libraries are not supported in this version)
 478                 fi
 479                 # workaround for inept transition to PIE vs PIC...
 480                 AC_MSG_CHECKING(if current CFLAGS link properly)
 481                 AC_TRY_LINK(
 482                         [#include <stdio.h>],
 483                         [printf("Hello work\\n");],
 484                         [cf_cflags_work=yes],
 485                         [cf_cflags_work=no])
 486                 AC_MSG_RESULT($cf_cflags_work)
 487                 if test "$cf_cflags_work" = no
 488                 then
 489                         CF_VERBOSE(try to work around by appending shared-options)
 490                         CFLAGS="$CFLAGS $CC_SHARED_OPTS"
 491                 fi
 492                 CF_WITH_VERSIONED_SYMS
 493                 ;;
 494         esac
 495 done
 496
 497 ### Checks for special libraries, must be done up-front.
 498 SHLIB_LIST=""
 499 CF_WITH_GPM
 500 if test "$with_gpm" != no ; then
 501         AC_MSG_CHECKING(if you want to load GPM dynamically)
 502         AC_ARG_WITH(dlsym,
 503                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 504                 [with_dlsym=$withval],
 505                 [with_dlsym=yes])
 506         AC_MSG_RESULT($with_dlsym)
 507         if test "x$with_dlsym" = xyes ; then
 508                 CF_FUNC_DLSYM
 509                 if test "x$with_gpm" != xyes ; then
 510                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 511                         cf_cv_gpm_soname="$with_gpm"
 512                 else
 513                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 514                 fi
 515                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname",[Define as needed to set the gpm share library soname])
 516                 SHLIB_LIST="-ldl $SHLIB_LIST"
 517                 CF_ADD_LIB(dl,PRIVATE_LIBS)
 518         else
 519                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 520                 CF_ADD_LIB(gpm,TEST_LIBS)
 521                 CF_ADD_LIB(gpm,PRIVATE_LIBS)
 522         fi
 523         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
 524         CF_CHECK_GPM_WGETCH
 525 fi
 526
 527 CF_WITH_PCRE2
 528 CF_WITH_SYSMOUSE
 529
 530 # pretend that ncurses==ncursesw==ncursest
 531 AC_MSG_CHECKING(if you want to disable library suffixes)
 532 CF_ARG_DISABLE(lib-suffixes,
 533         [  --disable-lib-suffixes  disable library suffixes],
 534         [disable_lib_suffixes=yes],
 535         [disable_lib_suffixes=no],
 536         no)
 537 AC_MSG_RESULT($disable_lib_suffixes)
 538
 539 ### If we're building with rpath, try to link non-standard libs that way too.
 540 if test "$DFT_LWR_MODEL" = "shared" && test "x$cf_cv_enable_rpath" != xno; then
 541         CF_DISABLE_RPATH_HACK
 542 fi
 543
 544 ### Depending on the system, someone may use rpath to build ncurses but not
 545 # want users of the package to rely upon that feature.  Give those people an
 546 # option to suppress that detail from EXTRA_LDFLAGS.
 547 EXTRA_PKG_LDFLAGS="$LDFLAGS $EXTRA_LDFLAGS"
 548 if test -n "$EXTRA_PKG_LDFLAGS"
 549 then
 550         AC_MSG_CHECKING(if you want to disable extra LDFLAGS for package-scripts)
 551         CF_ARG_DISABLE(pkg-ldflags,
 552                 [  --disable-pkg-ldflags   disable extra LDFLAGS for package-scripts],
 553                 [disable_pkg_ldflags=yes],
 554                 [disable_pkg_ldflags=no],
 555                 no)
 556         AC_MSG_RESULT($disable_pkg_ldflags)
 557         test "$disable_pkg_ldflags" = yes && EXTRA_PKG_LDFLAGS=
 558 fi
 559 AC_SUBST(EXTRA_PKG_LDFLAGS)
 560
 561 ###############################################################################
 562 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 563
 564 ###     use option --with-extra-suffix to append suffix to headers and libraries
 565 AC_MSG_CHECKING(if you wish to append extra suffix to header/library paths)
 566 EXTRA_SUFFIX=
 567 AC_ARG_WITH(extra-suffix,
 568         [  --with-extra-suffix=X   append extra suffix to header/library paths],
 569         [case x$withval in
 570         (xno)
 571                 ;;
 572         (xyes|x)
 573                 EXTRA_SUFFIX=$cf_cv_abi_version
 574                 ;;
 575         (*)
 576                 EXTRA_SUFFIX=$withval
 577                 ;;
 578         esac
 579         ])
 580 AC_MSG_RESULT($EXTRA_SUFFIX)
 581 AC_SUBST(EXTRA_SUFFIX)
 582
 583 ###     use option --disable-overwrite to leave out the link to -lcurses
 584 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 585 AC_ARG_ENABLE(overwrite,
 586         [  --disable-overwrite     put headers in subdir, omit link to -lcurses],
 587         [with_overwrite=$enableval],
 588         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 589 AC_MSG_RESULT($with_overwrite)
 590
 591 AC_MSG_CHECKING(if external terminfo-database is used)
 592 AC_ARG_ENABLE(database,
 593         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 594         [use_database=$enableval],
 595         [use_database=yes])
 596 AC_MSG_RESULT($use_database)
 597
 598 case "$host_os" in
 599 (os2*)
 600         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 601         ;;
 602 (*)
 603         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 604         ;;
 605 esac
 606 AC_SUBST(TERMINFO_SRC)
 607
 608 NCURSES_USE_DATABASE=0
 609 if test "$use_database" != no ; then
 610         NCURSES_USE_DATABASE=1
 611
 612         AC_MSG_CHECKING(which terminfo source-file will be installed)
 613         AC_ARG_WITH(database,
 614                 [  --with-database=XXX     specify terminfo source to install],
 615                 [TERMINFO_SRC=$withval])
 616         AC_MSG_RESULT($TERMINFO_SRC)
 617
 618         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 619         AC_ARG_WITH(hashed-db,
 620                 [  --with-hashed-db        specify hashed-database library],,
 621                 [with_hashed_db=no])
 622         AC_MSG_RESULT($with_hashed_db)
 623 else
 624         with_hashed_db=no
 625 fi
 626 AC_SUBST(NCURSES_USE_DATABASE)
 627
 628 AC_MSG_CHECKING(for list of fallback descriptions)
 629 AC_ARG_WITH(fallbacks,
 630         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 631         [with_fallback=$withval],
 632         [with_fallback=])
 633 AC_MSG_RESULT($with_fallback)
 634
 635 case ".$with_fallback" in
 636 (.|.no)
 637         FALLBACK_LIST=
 638         ;;
 639 (.yes)
 640         AC_MSG_WARN(expected a list of terminal descriptions)
 641         ;;
 642 (*)
 643         FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
 644         ;;
 645 esac
 646
 647 # The fallback feature in ncurses relies upon tic/infocmp outside the build
 648 # tree for generating the terminal descriptions that will be compiled into the
 649 # library.  If your toolchain is old, it may not handle current terminal
 650 # databases.  Use configure-options to point to the tools which will be used,
 651 # rather than the first ones found on the $PATH.
 652 AC_CHECK_TOOL(TIC, tic)
 653 AC_CHECK_TOOL(INFOCMP, infocmp)
 654 if test -n "$FALLBACK_LIST"
 655 then
 656         CF_WITH_PATH_PROG(TIC,     tic,     [for fallbacks], $PATH:/usr/local/ncurses/bin)
 657         CF_WITH_PATH_PROG(INFOCMP, infocmp, [for fallbacks], $PATH:/usr/local/ncurses/bin)
 658         test -z "$TIC" && FALLBACK_LIST=
 659         test -z "$INFOCMP" && FALLBACK_LIST=
 660         if test -z "$FALLBACK_LIST"
 661         then
 662                 AC_MSG_WARN(ignoring fallback option because tic/infocmp are not available)
 663         fi
 664 fi
 665 AC_SUBST(TIC)
 666 AC_SUBST(INFOCMP)
 667
 668 USE_FALLBACKS=
 669 test -z "$FALLBACK_LIST" && USE_FALLBACKS="#"
 670 AC_SUBST(FALLBACK_LIST)
 671 AC_SUBST(USE_FALLBACKS)
 672
 673 AC_MSG_CHECKING(if you want modern xterm or antique)
 674 AC_ARG_WITH(xterm-new,
 675         [  --without-xterm-new     specify if xterm terminfo should be old version],
 676         [with_xterm_new=$withval],
 677         [with_xterm_new=yes])
 678 case "$with_xterm_new" in
 679 (no) with_xterm_new=xterm-old;;
 680 (*)      with_xterm_new=xterm-new;;
 681 esac
 682 AC_MSG_RESULT($with_xterm_new)
 683 WHICH_XTERM=$with_xterm_new
 684 AC_SUBST(WHICH_XTERM)
 685
 686 case $host_os in
 687 (*linux-gnu|*cygwin|*mingw32|*msys)
 688         want_xterm_kbs=DEL
 689         ;;
 690 (*)
 691         want_xterm_kbs=BS
 692         ;;
 693 esac
 694
 695 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
 696 AC_ARG_WITH(xterm-kbs,
 697         [  --with-xterm-kbs=XXX    specify if xterm backspace sends BS or DEL],
 698         [with_xterm_kbs=$withval],
 699         [with_xterm_kbs=BS])
 700 case x$with_xterm_kbs in
 701 (xyes|xno|xBS|xbs|x8)
 702         with_xterm_kbs=BS
 703         ;;
 704 (xDEL|xdel|x127)
 705         with_xterm_kbs=DEL
 706         ;;
 707 (*)
 708         with_xterm_kbs=$withval
 709         ;;
 710 esac
 711 AC_MSG_RESULT($with_xterm_kbs)
 712 XTERM_KBS=$with_xterm_kbs
 713 AC_SUBST(XTERM_KBS)
 714
 715 if test "x$with_xterm_kbs" != "x$want_xterm_kbs"
 716 then
 717         AC_MSG_WARN(expected --with-xterm-kbs=$want_xterm_kbs for $host_os)
 718 fi
 719
 720 MAKE_TERMINFO=
 721 if test "$use_database" = no ; then
 722         TERMINFO="${datadir}/terminfo"
 723         MAKE_TERMINFO="#"
 724 else
 725
 726 AC_MSG_CHECKING(for list of terminfo directories)
 727 CF_WITH_PATHLIST(terminfo-dirs,
 728         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 729         TERMINFO_DIRS,
 730         DATADIR/terminfo,
 731         ${datadir}/terminfo)
 732 AC_MSG_RESULT($TERMINFO_DIRS)
 733 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS",[Define as needed to predefine the TERMINFO_DIR searchlist])
 734
 735 case "x$TERMINFO" in
 736 x???:*)
 737         AC_MSG_WARN(ignoring non-directory/file TERMINFO value)
 738         unset TERMINFO
 739         ;;
 740 esac
 741
 742 AC_MSG_CHECKING(for default terminfo directory)
 743 CF_WITH_PATH(default-terminfo-dir,
 744         [  --with-default-terminfo-dir=DIR default terminfo directory],
 745         TERMINFO,
 746         DATADIR/terminfo,
 747         ${datadir}/terminfo)
 748 AC_MSG_RESULT($TERMINFO)
 749 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO",[Define to set the default terminal database path])
 750
 751 fi
 752
 753 AC_SUBST(TERMINFO)
 754 AC_SUBST(MAKE_TERMINFO)
 755
 756 ###     use option --disable-big-core to make tic run on small machines
 757 ###     We need 4Mb, check if we can allocate 50% more than that.
 758 AC_MSG_CHECKING(if big-core option selected)
 759 AC_ARG_ENABLE(big-core,
 760         [  --disable-big-core      assume machine has little memory],
 761         [with_big_core=$enableval],
 762         [AC_TRY_RUN([
 763 #include <stdlib.h>
 764 #include <string.h>
 765 int main() {
 766         unsigned long n = 6000000L;
 767         char *s = malloc(n);
 768         if (s != 0)
 769                 s[0] = s[n-1] = 0;
 770         ${cf_cv_main_return:-return}(s == 0);
 771 }],
 772         [with_big_core=yes],
 773         [with_big_core=no],
 774         [with_big_core=no])])
 775 AC_MSG_RESULT($with_big_core)
 776 test "x$with_big_core" = "xyes" && AC_DEFINE(HAVE_BIG_CORE,1,[Define to 1 if machine has ample memory for tic])
 777
 778 ### ISO C only guarantees 512-char strings, we have tables which load faster
 779 ### when constructed using "big" strings.  More than the C compiler, the awk
 780 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 781 AC_MSG_CHECKING(if big-strings option selected)
 782 AC_ARG_ENABLE(big-strings,
 783         [  --disable-big-strings   assume compiler has only standard-size strings],
 784         [with_big_strings=$enableval],
 785         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 786 AC_MSG_RESULT($with_big_strings)
 787
 788 USE_BIG_STRINGS=0
 789 test "x$with_big_strings" = "xyes" && USE_BIG_STRINGS=1
 790 AC_SUBST(USE_BIG_STRINGS)
 791
 792 ###     use option --enable-termcap to compile in the termcap fallback support
 793 AC_MSG_CHECKING(if you want termcap-fallback support)
 794 AC_ARG_ENABLE(termcap,
 795         [  --enable-termcap        compile in termcap fallback support],
 796         [with_termcap=$enableval],
 797         [with_termcap=no])
 798 AC_MSG_RESULT($with_termcap)
 799
 800 NCURSES_USE_TERMCAP=0
 801 if test "x$with_termcap" != "xyes" ; then
 802         if test "$use_database" = no ; then
 803                 if test -z "$with_fallback" ; then
 804                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 805                 fi
 806         fi
 807         AC_DEFINE(PURE_TERMINFO,1,[Define to 1 if we should support only terminfo])
 808 else
 809
 810         if test "$with_ticlib" != no ; then
 811                 AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 812         fi
 813
 814         NCURSES_USE_TERMCAP=1
 815         AC_MSG_CHECKING(for list of termcap files)
 816         CF_WITH_PATHLIST(termpath,
 817                 [  --with-termpath=XXX     specify list of termcap files],
 818                 TERMPATH,
 819                 /etc/termcap:/usr/share/misc/termcap)
 820         AC_MSG_RESULT($TERMPATH)
 821         test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH",[Define to set the termcap searchlist])
 822
 823         ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 824         AC_MSG_CHECKING(if fast termcap-loader is needed)
 825         AC_ARG_ENABLE(getcap,
 826                 [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 827                 [with_getcap=$enableval],
 828                 [with_getcap=no])
 829         AC_MSG_RESULT($with_getcap)
 830         test "x$with_getcap" = "xyes" && AC_DEFINE(USE_GETCAP,1,[Define to 1 to use fast termcap-loader])
 831
 832         AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 833         AC_ARG_ENABLE(getcap-cache,
 834                 [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 835                 [with_getcap_cache=$enableval],
 836                 [with_getcap_cache=no])
 837         AC_MSG_RESULT($with_getcap_cache)
 838         test "x$with_getcap_cache" = "xyes" && AC_DEFINE(USE_GETCAP_CACHE,1,[Define to 1 if translated termcap should be stored in $HOME/.terminfo])
 839
 840 fi
 841 AC_SUBST(NCURSES_USE_TERMCAP)
 842
 843 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 844 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 845 AC_ARG_ENABLE(home-terminfo,
 846         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 847         [with_home_terminfo=$enableval],
 848         [with_home_terminfo=yes])
 849 AC_MSG_RESULT($with_home_terminfo)
 850 test "x$with_home_terminfo" = "xyes" && AC_DEFINE(USE_HOME_TERMINFO,1,[Define to 1 if $HOME/.terminfo feature is wanted])
 851
 852 AC_MSG_CHECKING(if you want to permit root to use ncurses environment variables)
 853 AC_ARG_ENABLE(root-environ,
 854         [  --disable-root-environ  restrict root use of ncurses environment variables],
 855         [with_root_environ=$enableval],
 856         [with_root_environ=yes])
 857 AC_MSG_RESULT($with_root_environ)
 858 test "x$with_root_environ" = xyes && AC_DEFINE(USE_ROOT_ENVIRON,1,[Define to 1 if root/setuid application is allowed to use ncurses environment])
 859
 860 AC_MSG_CHECKING(if you want to permit setuid programs to access all files)
 861 AC_ARG_ENABLE(root-access,
 862         [  --disable-root-access   restrict file-access when running setuid],
 863         [with_root_access=$enableval],
 864         [with_root_access=yes])
 865 AC_MSG_RESULT($with_root_access)
 866 test "x$with_root_access" = xyes && AC_DEFINE(USE_ROOT_ACCESS,1,[Define to 1 if setuid is allowed all file-access])
 867
 868 AC_MSG_CHECKING(if you want to permit setuid use of ncurses environment variables)
 869 AC_ARG_ENABLE(setuid-environ,
 870         [  --disable-setuid-environ restrict setuid use of ncurses environment variables],
 871         [with_setuid_environ=$enableval],
 872         [with_setuid_environ=$with_root_environ])
 873 AC_MSG_RESULT($with_setuid_environ)
 874 test "x$with_setuid_environ" = xyes && AC_DEFINE(USE_SETUID_ENVIRON,1,[Define to 1 if setuid/setgid application is allowed to use ncurses environment])
 875
 876 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 877 ###   to reduce storage requirements for the terminfo database.
 878 CF_LINK_FUNCS
 879
 880 with_links=no
 881 with_symlinks=no
 882
 883 # soft links (symbolic links) are useful for some systems where hard links do
 884 # not work, or to make it simpler to copy terminfo trees around.
 885 if test "x$ac_cv_func_symlink" = xyes ; then
 886         AC_MSG_CHECKING(if tic should use symbolic links)
 887         AC_ARG_ENABLE(symlinks,
 888         [  --enable-symlinks       make tic use symbolic links not hard links],
 889         [with_symlinks=$enableval],
 890         [with_symlinks=no])
 891         AC_MSG_RESULT($with_symlinks)
 892 fi
 893
 894 # If we have hard links and did not choose to use soft links instead, there is
 895 # no reason to make this choice optional - use the hard links.
 896 if test "$with_symlinks" = no ; then
 897         AC_MSG_CHECKING(if tic should use hard links)
 898         if test "x$ac_cv_func_link" = xyes ; then
 899                 with_links=yes
 900         else
 901                 with_links=no
 902         fi
 903         AC_MSG_RESULT($with_links)
 904 fi
 905
 906 test "x$with_links" = xyes && AC_DEFINE(USE_LINKS,1,[Define to 1 if hardlinks should be used in terminfo database])
 907 test "x$with_symlinks" = xyes && AC_DEFINE(USE_SYMLINKS,1,[Define to 1 if symbolic links should be used in terminfo database])
 908
 909 ###   use option --enable-broken-linker to force on use of broken-linker support
 910 CF_ENABLE_BROKEN_LINKER
 911
 912 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 913 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 914 AC_ARG_ENABLE(bsdpad,
 915         [  --enable-bsdpad         recognize BSD-style prefix padding],
 916         [with_bsdpad=$enableval],
 917         [with_bsdpad=no])
 918 AC_MSG_RESULT($with_bsdpad)
 919 test "x$with_bsdpad" = xyes && AC_DEFINE(BSD_TPUTS,1,[Define to 1 to recognize BSD-style prefix padding])
 920
 921 ###   use option --enable-widec to turn on use of wide-character support
 922 NCURSES_CH_T=chtype
 923 NCURSES_LIBUTF8=0
 924
 925 NEED_WCHAR_H=0
 926 NCURSES_MBSTATE_T=0
 927 NCURSES_WCHAR_T=0
 928 NCURSES_WINT_T=0
 929
 930 # Check to define _XOPEN_SOURCE "automatically"
 931 CPPFLAGS_before_XOPEN="$CPPFLAGS"
 932 CF_XOPEN_SOURCE(600)
 933 CPPFLAGS_after_XOPEN="$CPPFLAGS"
 934
 935 # Work around breakage on OS X
 936 CF_SIGWINCH
 937
 938 # Checks for CODESET support.
 939 AM_LANGINFO_CODESET
 940
 941 # use these variables to work around a defect in gcc's fixincludes.
 942 NCURSES_OK_WCHAR_T=
 943 NCURSES_OK_WINT_T=
 944
 945 AC_MSG_CHECKING(if you want wide-character code)
 946 AC_ARG_ENABLE(widec,
 947         [  --enable-widec          compile with wide-char/UTF-8 code],
 948         [with_widec=$enableval],
 949         [with_widec=no])
 950 AC_MSG_RESULT($with_widec)
 951
 952 NCURSES_WCWIDTH_GRAPHICS=1
 953 AC_SUBST(NCURSES_WCWIDTH_GRAPHICS)
 954
 955 if test "x$with_widec" = xyes ; then
 956         if test "x$disable_lib_suffixes" = xno ; then
 957                 LIB_SUFFIX="w${LIB_SUFFIX}"
 958         fi
 959         AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to compile with wide-char/UTF-8 code])
 960         AC_DEFINE(NCURSES_WIDECHAR,1,[Define to 1 to compile with wide-char/UTF-8 code])
 961         case "$CPPFLAGS" in
 962         (*_XOPEN_SOURCE=*)
 963                 ;;
 964         (*)
 965                 AC_MSG_WARN(_XOPEN_SOURCE feature test macro appears to be predefined)
 966                 # CPPFLAGS="$CPPFLAGS -DNCURSES_WIDECHAR"
 967                 CPPFLAGS_after_XOPEN="$CPPFLAGS_after_XOPEN -DNCURSES_WIDECHAR"
 968                 ;;
 969         esac
 970
 971         CF_CHECK_WCHAR_H
 972         CF_CHECK_WCWIDTH_GRAPHICS
 973         test "$cf_cv_wcwidth_graphics" = no && NCURSES_WCWIDTH_GRAPHICS=0
 974
 975         # with_overwrite=no
 976         NCURSES_CH_T=cchar_t
 977         AC_CHECK_FUNCS(putwc btowc wctob wmemchr mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 978         if test "x$ac_cv_func_putwc" != xyes ; then
 979                 CF_UTF8_LIB
 980                 if test "$cf_cv_utf8_lib" != no ; then
 981                         NCURSES_LIBUTF8=1
 982                 fi
 983         fi
 984         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 985         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 986         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 987
 988         if test "$NCURSES_MBSTATE_T" != 0; then
 989                 AC_DEFINE(NEED_MBSTATE_T_DEF,1,[Define to 1 if we must declare mbstate_t])
 990         fi
 991 fi
 992 AC_SUBST(NCURSES_CH_T)
 993 AC_SUBST(NCURSES_LIBUTF8)
 994
 995 AC_SUBST(NEED_WCHAR_H)
 996 AC_SUBST(NCURSES_MBSTATE_T)
 997 AC_SUBST(NCURSES_WCHAR_T)
 998 AC_SUBST(NCURSES_WINT_T)
 999
1000 AC_SUBST(NCURSES_OK_WCHAR_T)
1001 AC_SUBST(NCURSES_OK_WINT_T)
1002
1003 ###   use option --disable-lp64 to allow long chtype
1004 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
1005 AC_ARG_ENABLE(lp64,
1006         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
1007         [with_lp64=$enableval],
1008         [with_lp64=$cf_dft_with_lp64])
1009 AC_MSG_RESULT($with_lp64)
1010
1011 if test "x$with_lp64" = xyes ; then
1012         cf_cv_enable_lp64=1
1013 else
1014         cf_cv_enable_lp64=0
1015 fi
1016 AC_SUBST(cf_cv_enable_lp64)
1017
1018 CF_LARGEFILE
1019
1020 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
1021 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
1022 AC_ARG_ENABLE(tparm-varargs,
1023         [  --disable-tparm-varargs compile tparm() without varargs interface],
1024         [with_tparm_varargs=$enableval],
1025         [with_tparm_varargs=yes])
1026 AC_MSG_RESULT($with_tparm_varargs)
1027 NCURSES_TPARM_VARARGS=0
1028 test "x$with_tparm_varargs" = xyes && NCURSES_TPARM_VARARGS=1
1029 AC_SUBST(NCURSES_TPARM_VARARGS)
1030
1031 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
1032 if test "$with_ticlib" != no ; then
1033 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
1034 AC_ARG_ENABLE(tic-depends,
1035         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
1036         [with_tic_depends=$enableval],
1037         [with_tic_depends=yes])
1038 AC_MSG_RESULT($with_tic_depends)
1039 else
1040         with_tic_depends=no
1041 fi
1042
1043 ###   use option --enable-wattr-macros to enable wattr* macros in curses.h
1044 AC_MSG_CHECKING(if you want to enable wattr* macros)
1045 AC_ARG_ENABLE(wattr-macros,
1046         [  --enable-wattr-macros   enable wattr* macros],
1047         [with_wattr_macros=$enableval],
1048         [with_wattr_macros=no])
1049 if [[ "x$with_wattr_macros" != xyes ]]; then
1050         NCURSES_WATTR_MACROS=0
1051         AC_MSG_RESULT(no)
1052 else
1053         NCURSES_WATTR_MACROS=1
1054         AC_MSG_RESULT(yes)
1055 fi
1056 AC_SUBST(NCURSES_WATTR_MACROS)
1057
1058 CF_WITH_X11_RGB
1059
1060 ###   use option --with-bool to override bool's type
1061 AC_MSG_CHECKING(for type of bool)
1062 AC_ARG_WITH(bool,
1063         [  --with-bool=TYPE        override fallback type of bool variable],
1064         [NCURSES_BOOL="$withval"],
1065         [NCURSES_BOOL=auto])
1066 AC_MSG_RESULT($NCURSES_BOOL)
1067 AC_SUBST(NCURSES_BOOL)
1068
1069 AC_MSG_CHECKING(for alternate terminal capabilities file)
1070 AC_ARG_WITH(caps,
1071         [  --with-caps=alt         compile with alternate Caps file],
1072         [TERMINFO_CAPS=Caps.$withval],
1073         [TERMINFO_CAPS=Caps])
1074 if test ! -f "${srcdir}/include/${TERMINFO_CAPS}"
1075 then
1076         AC_MSG_WARN(file not found: "${srcdir}/include/${TERMINFO_CAPS}")
1077         TERMINFO_CAPS=Caps
1078 fi
1079 AC_MSG_RESULT($TERMINFO_CAPS)
1080 AC_SUBST(TERMINFO_CAPS)
1081
1082 ###   use option --with-chtype to override chtype's type
1083 AC_MSG_CHECKING(for type of chtype)
1084 AC_ARG_WITH(chtype,
1085         [  --with-chtype=TYPE      override type of chtype],
1086         [NCURSES_CHTYPE="$withval"],
1087         [NCURSES_CHTYPE=$cf_dft_chtype])
1088 AC_MSG_RESULT($NCURSES_CHTYPE)
1089
1090 ###   use option --with-ospeed to override ospeed's type
1091 AC_MSG_CHECKING(for type of ospeed)
1092 AC_ARG_WITH(ospeed,
1093         [  --with-ospeed=TYPE      override type of ospeed variable],
1094         [NCURSES_OSPEED="$withval"],
1095         [NCURSES_OSPEED=short])
1096 AC_MSG_RESULT($NCURSES_OSPEED)
1097 AC_SUBST(NCURSES_OSPEED)
1098
1099 ###   use option --with-mmask-t to override mmask_t's type
1100 AC_MSG_CHECKING(for type of mmask_t)
1101 AC_ARG_WITH(mmask-t,
1102         [  --with-mmask-t=TYPE     override type of mmask_t],
1103         [NCURSES_MMASK_T="$withval"],
1104         [NCURSES_MMASK_T=$cf_dft_mmask_t])
1105 AC_MSG_RESULT($NCURSES_MMASK_T)
1106
1107 ###   use option --with-ccharw-max to override CCHARW_MAX size
1108 AC_MSG_CHECKING(for size CCHARW_MAX)
1109 AC_ARG_WITH(ccharw-max,
1110         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
1111         [NCURSES_CCHARW_MAX="$withval"],
1112         [NCURSES_CCHARW_MAX=$cf_dft_ccharw_max])
1113 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
1114 AC_SUBST(NCURSES_CCHARW_MAX)
1115
1116 AC_CHECK_SIZEOF([signed char])
1117 if test "$ac_cv_sizeof_signed_char" = 1 ; then
1118         NCURSES_SBOOL="signed char"
1119 else
1120         NCURSES_SBOOL="char"
1121 fi
1122 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
1123 AC_ARG_ENABLE(signed-char,
1124         [  --enable-signed-char    compile using signed Boolean's in term.h],
1125         [with_signed_char=$enableval],
1126         [with_signed_char=$cf_dft_signed_char])
1127 AC_MSG_RESULT($with_signed_char)
1128 test "x$with_signed_char" != xyes && NCURSES_SBOOL="char"
1129 AC_SUBST(NCURSES_SBOOL)
1130
1131 ###   use option --with-tparm-arg to override tparm's argument type
1132 AC_MSG_CHECKING(for type of tparm args)
1133 AC_ARG_WITH(tparm-arg,
1134         [  --with-tparm-arg=TYPE   override parameter type of tparm],
1135         [NCURSES_TPARM_ARG="$withval"],
1136         [NCURSES_TPARM_ARG=$cf_dft_tparm_arg])
1137 AC_MSG_RESULT($NCURSES_TPARM_ARG)
1138 AC_SUBST(NCURSES_TPARM_ARG)
1139
1140 ### Enable compiling-in rcs id's
1141 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
1142 AC_ARG_WITH(rcs-ids,
1143         [  --with-rcs-ids          compile-in RCS identifiers],
1144         [with_rcs_ids=$withval],
1145         [with_rcs_ids=no])
1146 AC_MSG_RESULT($with_rcs_ids)
1147 test "x$with_rcs_ids" = xyes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 to compile-in RCS identifiers])
1148
1149 ###############################################################################
1150 CF_MAN_PAGES([ captoinfo clear infocmp infotocap reset tabs tic toe tput tset ])
1151
1152 ###############################################################################
1153 CF_HELP_MESSAGE(Extensions:)
1154
1155 ### Note that some functions (such as const) are normally disabled anyway.
1156 AC_MSG_CHECKING(if you want to build with function extensions)
1157 AC_ARG_ENABLE(ext-funcs,
1158         [  --disable-ext-funcs     disable function-extensions],
1159         [with_ext_funcs=$enableval],
1160         [with_ext_funcs=yes])
1161 AC_MSG_RESULT($with_ext_funcs)
1162 if test "x$with_ext_funcs" = xyes ; then
1163         NCURSES_EXT_FUNCS=1
1164         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 to enable ncurses extended functions])
1165         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS,1,[Define to 1 to enable assume_default_colors() function in test-programs])
1166         AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 to enable curses_version() function in test-programs])
1167         AC_DEFINE(HAVE_HAS_KEY,1,[Define to 1 to enable has_key() function in test-programs])
1168         AC_DEFINE(HAVE_RESIZETERM,1,[Define to 1 to enable resizeterm() function in test-programs])
1169         AC_DEFINE(HAVE_RESIZE_TERM,1,[Define to 1 to enable resize_term() function in test-programs])
1170         AC_DEFINE(HAVE_TERM_ENTRY_H,1,[Define to 1 to enable term_entry() function in test-programs])
1171         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 to enable use_default_colors() function in test-programs])
1172         AC_DEFINE(HAVE_USE_SCREEN,1,[Define to 1 to enable use_screen() function in test-programs])
1173         AC_DEFINE(HAVE_USE_WINDOW,1,[Define to 1 to enable use_window() function in test-programs])
1174         AC_DEFINE(HAVE_WRESIZE,1,[Define to 1 to enable wresize() function in test-programs])
1175         GENERATED_EXT_FUNCS=generated
1176         test "x$with_ext_funcs" = xyes || cf_dft_ext_spfuncs=no
1177 else
1178         NCURSES_EXT_FUNCS=0
1179         GENERATED_EXT_FUNCS=
1180 fi
1181 AC_SUBST(NCURSES_EXT_FUNCS)
1182 AC_SUBST(GENERATED_EXT_FUNCS)
1183
1184 AC_MSG_CHECKING(if you want to build with SCREEN extensions)
1185 AC_ARG_ENABLE(sp-funcs,
1186         [  --enable-sp-funcs       enable SCREEN-extensions],
1187         [with_sp_funcs=$enableval],
1188         [with_sp_funcs=$cf_dft_ext_spfuncs])
1189 AC_MSG_RESULT($with_sp_funcs)
1190 if test "x$with_sp_funcs" = xyes ; then
1191         NCURSES_SP_FUNCS=1
1192         AC_DEFINE(NCURSES_SP_FUNCS,1,[Define to 1 to enable SCREEN-extensions])
1193         AC_DEFINE(HAVE_TPUTS_SP,1,[Define to 1 to enable tputs_sp() function in test-programs])
1194         GENERATED_SP_FUNCS=generated
1195 else
1196         NCURSES_SP_FUNCS=0
1197         GENERATED_SP_FUNCS=
1198 fi
1199 AC_SUBST(NCURSES_SP_FUNCS)
1200 AC_SUBST(GENERATED_SP_FUNCS)
1201
1202 AC_MSG_CHECKING(if you want to build with terminal-driver)
1203 AC_ARG_ENABLE(term-driver,
1204         [  --enable-term-driver    enable terminal-driver],
1205         [with_term_driver=$enableval],
1206         [with_term_driver=no])
1207 AC_MSG_RESULT($with_term_driver)
1208 if test "x$with_term_driver" = xyes ; then
1209         AC_DEFINE(USE_TERM_DRIVER,1,[Define to 1 to enable terminal-driver])
1210         if test "x$with_termlib" != xno ; then
1211                 AC_MSG_ERROR(The term-driver option conflicts with the termlib option)
1212         fi
1213         if test "x$with_sp_funcs" != xyes ; then
1214                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
1215         fi
1216 fi
1217
1218 ###   use option --enable-const to turn on use of const beyond that in XSI.
1219 AC_MSG_CHECKING(for extended use of const keyword)
1220 AC_ARG_ENABLE(const,
1221         [  --enable-const          compile with extra/non-standard const],
1222         [with_ext_const=$enableval],
1223         [with_ext_const=$cf_dft_ext_const])
1224 AC_MSG_RESULT($with_ext_const)
1225 NCURSES_CONST='/*nothing*/'
1226 if test "x$with_ext_const" = xyes ; then
1227         NCURSES_CONST=const
1228 fi
1229 AC_SUBST(NCURSES_CONST)
1230
1231 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
1232 AC_MSG_CHECKING(if you want to use extended colors)
1233 AC_ARG_ENABLE(ext-colors,
1234         [  --enable-ext-colors     compile for 256-color support],
1235         [with_ext_colors=$enableval],
1236         [with_ext_colors=$cf_dft_ext_colors])
1237 AC_MSG_RESULT($with_ext_colors)
1238 NCURSES_EXT_COLORS=0
1239 if test "x$with_ext_colors" = xyes ; then
1240         if test "x$with_widec" != xyes ; then
1241                 AC_MSG_WARN(This option applies only to wide-character library)
1242         else
1243                 # cannot be ABI 5 since it changes sizeof(cchar_t)
1244                 CF_NCURSES_ABI_6
1245                 NCURSES_EXT_COLORS=1
1246                 AC_DEFINE(NCURSES_EXT_COLORS,1,[Define to 1 to compile for 256-color support])
1247                 AC_DEFINE(HAVE_ALLOC_PAIR,1,[Define to 1 to enable alloc_pair() function])
1248                 AC_DEFINE(HAVE_INIT_EXTENDED_COLOR,1,[Define to 1 to enable init_extended_color() function in test-programs])
1249                 AC_DEFINE(HAVE_RESET_COLOR_PAIRS,1,[Define to 1 to enable reset_color_pairs() function in test-programs])
1250         fi
1251 fi
1252 AC_SUBST(NCURSES_EXT_COLORS)
1253
1254 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
1255 AC_MSG_CHECKING(if you want to use extended mouse encoding)
1256 AC_ARG_ENABLE(ext-mouse,
1257         [  --enable-ext-mouse      compile for extended mouse-encoding],
1258         [with_ext_mouse=$enableval],
1259         [with_ext_mouse=$cf_dft_ext_mouse])
1260 AC_MSG_RESULT($with_ext_mouse)
1261 if test "x$with_ext_mouse" = xyes ; then
1262         CF_NCURSES_ABI_6
1263 fi
1264
1265 if test $cf_cv_abi_default -le 5 ; then
1266         NCURSES_MOUSE_VERSION=1
1267 elif test $cf_cv_abi_default -le 6 ; then
1268         NCURSES_MOUSE_VERSION=2
1269 else
1270         NCURSES_MOUSE_VERSION=3
1271 fi
1272
1273 AC_SUBST(NCURSES_MOUSE_VERSION)
1274
1275 ###   use option --enable-ext-putwin to turn on extended screendumps
1276 AC_MSG_CHECKING(if you want to use extended putwin/screendump)
1277 AC_ARG_ENABLE(ext-putwin,
1278         [  --enable-ext-putwin     compile with extended putwin/screendump],
1279         [with_ext_putwin=$enableval],
1280         [with_ext_putwin=$cf_dft_ext_putwin])
1281 AC_MSG_RESULT($with_ext_putwin)
1282 if test "x$with_ext_putwin" = xyes ; then
1283         AC_DEFINE(NCURSES_EXT_PUTWIN,1,[Define to 1 to compile with extended putwin/screendump])
1284 fi
1285
1286 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
1287 AC_ARG_ENABLE(no-padding,
1288         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
1289         [with_no_padding=$enableval],
1290         [with_no_padding=$with_ext_funcs])
1291 AC_MSG_RESULT($with_no_padding)
1292 test "x$with_no_padding" = xyes && AC_DEFINE(NCURSES_NO_PADDING,1,[Define to 1 to compile with $NCURSES_NO_PADDING code])
1293
1294 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1295 AC_MSG_CHECKING(if you want SIGWINCH handler)
1296 AC_ARG_ENABLE(sigwinch,
1297         [  --enable-sigwinch       compile with SIGWINCH handler],
1298         [with_sigwinch=$enableval],
1299         [with_sigwinch=$with_ext_funcs])
1300 AC_MSG_RESULT($with_sigwinch)
1301 test "x$with_sigwinch" = xyes && AC_DEFINE(USE_SIGWINCH,1,[Define to 1 to compile with SIGWINCH handler])
1302
1303 ###   use option --enable-tcap-names to allow user to define new capabilities
1304 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1305 AC_ARG_ENABLE(tcap-names,
1306         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1307         [with_tcap_names=$enableval],
1308         [with_tcap_names=$with_ext_funcs])
1309 AC_MSG_RESULT($with_tcap_names)
1310 NCURSES_XNAMES=0
1311 if test "x$with_tcap_names" = xyes; then
1312         NCURSES_XNAMES=1
1313         AC_DEFINE(NCURSES_XNAMES,1,[Define to 1 to compile with user-definable terminal capabilities])
1314 fi
1315 AC_SUBST(NCURSES_XNAMES)
1316
1317 ##############################################################################
1318 CF_HELP_MESSAGE(Reentrant Code:)
1319 CF_WITH_PTHREAD
1320
1321 if test "x$with_pthread" != xno; then
1322         AC_CHECK_FUNC(pthread_kill,[
1323                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1324                 AC_ARG_ENABLE(pthreads-eintr,
1325                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1326                         [use_pthreads_eintr=$enableval],
1327                         [use_pthreads_eintr=no])
1328                 AC_MSG_RESULT($use_pthreads_eintr)
1329                 if test "x$use_pthreads_eintr" = xyes ; then
1330                         AC_DEFINE(USE_PTHREADS_EINTR,1,[Define to 1 to enable EINTR in wgetch with pthreads])
1331                 fi])
1332
1333         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1334         AC_ARG_ENABLE(weak-symbols,
1335                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1336                 [use_weak_symbols=$enableval],
1337                 [use_weak_symbols=no])
1338         AC_MSG_RESULT($use_weak_symbols)
1339         if test "x$use_weak_symbols" = xyes ; then
1340                 CF_WEAK_SYMBOLS
1341         else
1342                 cf_cv_weak_symbols=no
1343         fi
1344
1345         if test "x$cf_cv_weak_symbols" = xyes ; then
1346                 AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
1347         fi
1348 fi
1349
1350 PTHREAD=
1351 if test "x$with_pthread" = "xyes" ; then
1352         AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use pthreads feature])
1353         enable_reentrant=yes
1354         if test "x$cf_cv_weak_symbols" = xyes ; then
1355                 PTHREAD=-lpthread
1356                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1357         fi
1358 fi
1359 AC_SUBST(PTHREAD)
1360
1361 # Reentrant code has to be opaque; there's little advantage to making ncurses
1362 # opaque outside of that, so there is no --enable-opaque option.  We can use
1363 # this option without --with-pthreads, but this will be always set for
1364 # pthreads.
1365 AC_MSG_CHECKING(if you want reentrant code)
1366 AC_ARG_ENABLE(reentrant,
1367         [  --enable-reentrant      compile with reentrant code],
1368         [with_reentrant=$enableval],
1369         [with_reentrant=no])
1370 AC_MSG_RESULT($with_reentrant)
1371 if test "x$with_reentrant" = xyes ; then
1372         cf_cv_enable_reentrant=1
1373         cf_cv_enable_opaque="NCURSES_INTERNALS"
1374         NCURSES_SIZE_T=int
1375         if test "x$cf_cv_weak_symbols" = xyes ; then
1376                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1377                 CF_ADD_LIB(pthread,TEST_LIBS)
1378                 CF_ADD_LIB(pthread,TEST_LIBS2)
1379                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1380         else
1381                 # when not using weak symbols but with_reentrant,
1382                 # add 't' to the library suffix on all platforms
1383                 # except cygwin, where we only do that if ALSO
1384                 # compiling with full thread support.
1385                 case "$host" in
1386                 (*cygwin* | *msys*)
1387                         if test "$with_pthread" = "yes" ; then
1388                                 if test "x$disable_lib_suffixes" = "xno" ; then
1389                                         LIB_SUFFIX="t${LIB_SUFFIX}"
1390                                 fi
1391                         fi ;;
1392                 (*)
1393                         if test "x$disable_lib_suffixes" = "xno" ; then
1394                                 LIB_SUFFIX="t${LIB_SUFFIX}"
1395                         fi
1396                         ;;
1397                 esac
1398         fi
1399         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to use reentrant feature])
1400         CF_NCURSES_ABI_6
1401 else
1402         cf_cv_enable_reentrant=0
1403         cf_cv_enable_opaque="NCURSES_OPAQUE"
1404         NCURSES_SIZE_T=$cf_dft_ordinate_type
1405 fi
1406 AC_SUBST(cf_cv_enable_reentrant)
1407 AC_SUBST(cf_cv_enable_opaque)
1408
1409 AC_SUBST(NCURSES_SIZE_T)
1410
1411 AC_MSG_CHECKING(if you want opaque curses-library structures)
1412 CF_ARG_ENABLE(opaque-curses,
1413         [  --enable-opaque-curses  make curses WINDOW, etc., "opaque"],
1414         [enable_opaque_curses=yes],[
1415          test "$cf_cv_enable_reentrant" = 1 && enable_opaque_curses=yes
1416          test "$cf_cv_enable_reentrant" = 1 || enable_opaque_curses=$cf_dft_opaque_curses
1417         ])
1418 AC_MSG_RESULT($enable_opaque_curses)
1419
1420 test "$cf_cv_enable_reentrant" = 1 && \
1421 test "$enable_opaque_curses" = no && \
1422 AC_MSG_ERROR(reentrant configuration requires opaque library)
1423
1424 AC_MSG_CHECKING(if you want opaque form-library structures)
1425 AC_ARG_ENABLE(opaque-form,
1426         [  --enable-opaque-form    make form-library structures "opaque"],
1427         [enable_opaque_form=yes],[enable_opaque_form=no])
1428 AC_MSG_RESULT($enable_opaque_form)
1429
1430 AC_MSG_CHECKING(if you want opaque menu-library structures)
1431 AC_ARG_ENABLE(opaque-menu,
1432         [  --enable-opaque-menu    make menu-library structures "opaque"],
1433         [enable_opaque_menu=yes],[enable_opaque_menu=no])
1434 AC_MSG_RESULT($enable_opaque_menu)
1435
1436 AC_MSG_CHECKING(if you want opaque panel-library structures)
1437 AC_ARG_ENABLE(opaque-panel,
1438         [  --enable-opaque-panel   make panel-library structures "opaque"],
1439         [enable_opaque_panel=yes],[enable_opaque_panel=no])
1440 AC_MSG_RESULT($enable_opaque_panel)
1441
1442 NCURSES_OPAQUE=0;               test "$enable_opaque_curses" = yes && NCURSES_OPAQUE=1
1443 NCURSES_OPAQUE_FORM=0;  test "$enable_opaque_form"   = yes && NCURSES_OPAQUE_FORM=1
1444 NCURSES_OPAQUE_MENU=0;  test "$enable_opaque_menu"   = yes && NCURSES_OPAQUE_MENU=1
1445 NCURSES_OPAQUE_PANEL=0; test "$enable_opaque_panel"  = yes && NCURSES_OPAQUE_PANEL=1
1446
1447 AC_SUBST(NCURSES_OPAQUE)
1448 AC_SUBST(NCURSES_OPAQUE_FORM)
1449 AC_SUBST(NCURSES_OPAQUE_MENU)
1450 AC_SUBST(NCURSES_OPAQUE_PANEL)
1451
1452 ### Allow using a different wrap-prefix
1453 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1454         AC_MSG_CHECKING(for prefix used to wrap public variables)
1455         AC_ARG_WITH(wrap-prefix,
1456                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1457                 [NCURSES_WRAP_PREFIX=$withval],
1458                 [NCURSES_WRAP_PREFIX=_nc_])
1459         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1460 else
1461         NCURSES_WRAP_PREFIX=_nc_
1462 fi
1463 AC_SUBST(NCURSES_WRAP_PREFIX)
1464 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ prefix])
1465
1466 ###############################################################################
1467 # These options are relatively safe to experiment with.
1468 CF_HELP_MESSAGE(Development Code:)
1469 AC_MSG_CHECKING(if you want all development code)
1470 AC_ARG_WITH(develop,
1471         [  --without-develop       disable development options],
1472         [with_develop=$withval],
1473         [with_develop=no])
1474 AC_MSG_RESULT($with_develop)
1475
1476 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1477 AC_MSG_CHECKING(if you want hard-tabs code)
1478 AC_ARG_ENABLE(hard-tabs,
1479         [  --enable-hard-tabs      compile with hard-tabs code],,
1480         [enable_hard_tabs=$with_develop])
1481 AC_MSG_RESULT($enable_hard_tabs)
1482 test "x$enable_hard_tabs" = xyes && AC_DEFINE(USE_HARD_TABS,1,[Define to 1 to compile with hard-tabs code])
1483
1484 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1485 AC_MSG_CHECKING(if you want limited support for xmc)
1486 AC_ARG_ENABLE(xmc-glitch,
1487         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1488         [enable_xmc_glitch=$with_develop])
1489 AC_MSG_RESULT($enable_xmc_glitch)
1490 test "x$enable_xmc_glitch" = xyes && AC_DEFINE(USE_XMC_SUPPORT,1,[Define to 1 to compile with support for xmc (magic-cookie)])
1491
1492 ###############################################################################
1493 # These are just experimental, probably should not be in a package:
1494 CF_HELP_MESSAGE(Experimental Code:)
1495
1496 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1497 AC_ARG_ENABLE(assumed-color,
1498         [  --disable-assumed-color do not assume anything about default-colors],
1499         [with_assumed_color=$enableval],
1500         [with_assumed_color=yes])
1501 AC_MSG_RESULT($with_assumed_color)
1502 test "x$with_assumed_color" = xyes && AC_DEFINE(USE_ASSUMED_COLOR,1,[Define to 1 to assume things about default-colors])
1503
1504 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1505 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1506 AC_ARG_ENABLE(hashmap,
1507         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1508         [with_hashmap=$enableval],
1509         [with_hashmap=yes])
1510 AC_MSG_RESULT($with_hashmap)
1511 test "x$with_hashmap" = xyes && AC_DEFINE(USE_HASHMAP,1,[Define to 1 to compile with hashmap scrolling-optimization])
1512
1513 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1514 AC_MSG_CHECKING(if you want colorfgbg code)
1515 AC_ARG_ENABLE(colorfgbg,
1516         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1517         [with_colorfgbg=$enableval],
1518         [with_colorfgbg=no])
1519 AC_MSG_RESULT($with_colorfgbg)
1520 test "x$with_colorfgbg" = xyes && AC_DEFINE(USE_COLORFGBG,1,[Define to 1 to compile-in experimental $COLORFGBG code])
1521
1522 ###   use option --enable-fvisibility to turn on use of gcc-specific feature
1523 AC_MSG_CHECKING(if you want to use gcc -fvisibility option)
1524 AC_ARG_ENABLE(fvisibility,
1525         [  --enable-fvisibility    compile with -fvisibility=hidden],
1526         [cf_with_fvisibility=$enableval],
1527         [cf_with_fvisibility=no])
1528 AC_MSG_RESULT($cf_with_fvisibility)
1529
1530 NCURSES_IMPEXP=
1531 NCURSES_CXX_IMPEXP=
1532 if test "x$cf_with_fvisibility" = xyes; then
1533         CF_CHECK_FVISIBILITY($CC,CFLAGS,cf_cv_fvisibility_hidden)
1534         if test "x$cf_cv_fvisibility_hidden" = xyes
1535         then
1536                 CF_ADD_CFLAGS([-fvisibility=hidden])
1537                 NCURSES_IMPEXP="__attribute__ ((visibility(\"default\")))"
1538         fi
1539         if test -n "$CXX"
1540         then
1541                 AC_LANG_PUSH(C++)
1542                 CF_CHECK_FVISIBILITY($CXX,CXXFLAGS,cf_cv_fvisibility_hidden2)
1543                 if test "x$cf_cv_fvisibility_hidden2" = xyes
1544                 then
1545                         CF_ADD_CXXFLAGS([-fvisibility=hidden])
1546                         NCURSES_CXX_IMPEXP="__attribute__ ((visibility(\"default\")))"
1547                 fi
1548                 AC_LANG_POP
1549         fi
1550 fi
1551 AC_SUBST(NCURSES_IMPEXP)
1552 AC_SUBST(NCURSES_CXX_IMPEXP)
1553
1554 ###   use option --enable-interop to turn on use of bindings used for interop
1555 AC_MSG_CHECKING(if you want interop bindings)
1556 AC_ARG_ENABLE(interop,
1557         [  --enable-interop        compile-in interop bindings],
1558         [with_exp_interop=$enableval],
1559         [with_exp_interop=$cf_dft_interop])
1560 AC_MSG_RESULT($with_exp_interop)
1561
1562 NCURSES_INTEROP_FUNCS=0
1563 test "x$with_exp_interop" = xyes && NCURSES_INTEROP_FUNCS=1
1564 AC_SUBST(NCURSES_INTEROP_FUNCS)
1565
1566
1567 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1568 AC_ARG_ENABLE(safe-sprintf,
1569         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1570         [with_safe_sprintf=$enableval],
1571         [with_safe_sprintf=no])
1572 AC_MSG_RESULT($with_safe_sprintf)
1573
1574 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1575 # when hashmap is used scroll hints are useless
1576 if test "$with_hashmap" = no ; then
1577 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1578 AC_ARG_ENABLE(scroll-hints,
1579         [  --disable-scroll-hints  compile without scroll-hints code],
1580         [with_scroll_hints=$enableval],
1581         [with_scroll_hints=yes])
1582 AC_MSG_RESULT($with_scroll_hints)
1583 test "x$with_scroll_hints" = xyes && AC_DEFINE(USE_SCROLL_HINTS,1,[Define to 1 to compile without scroll-hints code])
1584 fi
1585
1586 AC_MSG_CHECKING(if you want wgetch-events code)
1587 AC_ARG_ENABLE(wgetch-events,
1588         [  --enable-wgetch-events  compile with wgetch-events code],
1589         [with_wgetch_events=$enableval],
1590         [with_wgetch_events=no])
1591 AC_MSG_RESULT($with_wgetch_events)
1592 if test "x$with_wgetch_events" = xyes ; then
1593         AC_DEFINE(NCURSES_WGETCH_EVENTS,1,[Define to 1 to compile with wgetch-events code])
1594         NCURSES_WGETCH_EVENTS=1
1595 else
1596         NCURSES_WGETCH_EVENTS=0
1597 fi
1598 AC_SUBST(NCURSES_WGETCH_EVENTS)
1599
1600 case "$cf_cv_system_name" in
1601 (*mingw32*|*mingw64*|*-msvc*)
1602         AC_MSG_CHECKING(if you want experimental-Windows driver)
1603         AC_ARG_ENABLE(exp-win32,
1604                 [  --enable-exp-win32      compile with experimental-Windows driver],
1605                 [with_exp_win32=$enableval],
1606                 [with_exp_win32=no])
1607         AC_MSG_RESULT($with_exp_win32)
1608         if test "x$with_exp_win32" = xyes
1609         then
1610                 AC_DEFINE(EXP_WIN32_DRIVER,1,[Define to 1 to compile with experimental win32 driver])
1611                 EXP_WIN32_DRIVER=1
1612                 INTERNALS_HDR='[$](INCDIR)/nc_win32.h'
1613         else
1614                 INTERNALS_HDR='[$](INCDIR)/nc_mingw.h'
1615                 EXP_WIN32_DRIVER=0
1616         fi
1617         ;;
1618 (*)
1619         EXP_WIN32_DRIVER=0
1620         INTERNALS_HDR=
1621         ;;
1622 esac
1623 AC_SUBST(EXP_WIN32_DRIVER)
1624 AC_SUBST(INTERNALS_HDR)
1625
1626 ###############################################################################
1627 CF_HELP_MESSAGE(Testing/development Options:)
1628
1629 ###     use option --disable-echo to suppress full display compiling commands
1630 CF_DISABLE_ECHO
1631 if test "x$enable_echo" = xyes; then
1632         ECHO_LINK=
1633 else
1634         ECHO_LINK='@ echo linking $@ ... ;'
1635         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1636         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1637 fi
1638 AC_SUBST(ECHO_LINK)
1639
1640 # --disable-stripping is used for debugging
1641 CF_INSTALL_OPTS
1642
1643 # If we're avoiding relinking of shared libraries during install, that is to
1644 # avoid modifying the build-tree.  For the same reason, avoid doing ranlib if
1645 # the install program has "-p" (for preserving timestamps).
1646 cf_cv_do_reranlib=yes
1647 if test "x$cf_cv_install_p" = xyes
1648 then
1649         if test "x$cf_cv_do_relink" != xyes
1650         then
1651                 cf_cv_do_reranlib=no
1652                 INSTALL_OPT_P="-p"
1653                 INSTALL_LIB="$INSTALL_LIB $INSTALL_OPT_P"
1654         fi
1655 fi
1656 AC_SUBST(INSTALL_OPT_P)
1657
1658 ###     use option --enable-warnings to turn on all gcc warnings
1659 CF_ENABLE_WARNINGS(Wno-unknown-pragmas Wswitch-enum,yes)
1660
1661 if test "x$enable_warnings" = "xyes"; then
1662         CF_ADD_ADAFLAGS(-gnatwa -gnatyg)
1663         if test "x$cf_with_cxx" = xyes ; then
1664                 CF_GXX_WARNINGS(Wno-unused)
1665         fi
1666 fi
1667 CF_ENABLE_STRING_HACKS
1668
1669 ###     use option --enable-assertions to turn on generation of assertion code
1670 AC_MSG_CHECKING(if you want to enable runtime assertions)
1671 AC_ARG_ENABLE(assertions,
1672         [  --enable-assertions     test: turn on generation of assertion code],
1673         [with_assertions=$enableval],
1674         [with_assertions=no])
1675 AC_MSG_RESULT($with_assertions)
1676 if test -n "$GCC"
1677 then
1678         if test "$with_assertions" = no
1679         then
1680                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1681         else
1682                 CF_ADD_ADAFLAGS(-gnata)
1683         fi
1684 fi
1685
1686 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1687 CF_DISABLE_LEAKS
1688 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
1689
1690 ###     use option --enable-expanded to generate certain macros as functions
1691 AC_ARG_ENABLE(expanded,
1692         [  --enable-expanded       test: generate functions for certain macros],
1693         [test "x$enableval" = xyes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 to generate functions for certain macros])])
1694
1695 ###     use option --disable-macros to suppress macros in favor of functions
1696 AC_ARG_ENABLE(macros,
1697         [  --disable-macros        test: use functions rather than macros],
1698         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 to use functions rather than macros])])
1699
1700 # Normally we only add trace() to the debug-library.  Allow this to be
1701 # extended to all models of the ncurses library:
1702 cf_all_traces=no
1703 case "$CFLAGS $CPPFLAGS" in
1704 (*-DTRACE*)
1705         cf_all_traces=yes
1706         ;;
1707 esac
1708
1709 AC_MSG_CHECKING(whether to add trace feature to all models)
1710 AC_ARG_WITH(trace,
1711 [  --with-trace            test: add trace() function to all models of ncurses],
1712 [cf_with_trace=$withval],
1713 [cf_with_trace=$cf_all_traces])
1714 AC_MSG_RESULT($cf_with_trace)
1715
1716 if test "x$cf_with_trace" = xyes ; then
1717         LIB_TRACING=all
1718         ADA_TRACE=TRUE
1719         CF_ADD_CFLAGS(-DTRACE)
1720         AC_DEFINE(HAVE__TRACEF,1,[Define to 1 if we have _tracef function])
1721 else
1722         LIB_TRACING=DEBUG
1723         ADA_TRACE=FALSE
1724 fi
1725
1726 AC_SUBST(ADA_TRACE)
1727
1728 CF_DISABLE_GNAT_PROJECTS
1729
1730 ###     Checks for libraries.
1731 case "$cf_cv_system_name" in
1732 (*mingw32*|*mingw64*)
1733         # Note: WINVER may be a problem with Windows 10
1734         if test "x$with_exp_win32" = xyes ; then
1735                 CPPFLAGS="$CPPFLAGS -DWINVER=0x0600 -DWIN32_LEAN_AND_MEAN"
1736         else
1737                 CPPFLAGS="$CPPFLAGS -DWINVER=0x0501 -DWIN32_LEAN_AND_MEAN"
1738         fi
1739         CF_CHECK_LIBSSP
1740         ;;
1741 (*)
1742         ;;
1743 esac
1744
1745 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
1746 AC_SUBST(MATH_LIB)
1747
1748 ###     Checks for header files.
1749 AC_HEADER_TIME
1750 CF_REGEX
1751
1752 dnl These are some other potentially nonportable headers.
1753 AC_CHECK_HEADERS( \
1754 fcntl.h \
1755 getopt.h \
1756 limits.h \
1757 locale.h \
1758 math.h \
1759 poll.h \
1760 sys/auxv.h \
1761 sys/ioctl.h \
1762 sys/param.h \
1763 sys/poll.h \
1764 sys/select.h \
1765 sys/time.h \
1766 sys/times.h \
1767 unistd.h \
1768 wctype.h \
1769 )
1770
1771 CF_GETOPT_HEADER
1772
1773 CF_CHECK_ENVIRON(environ)
1774 CF_CHECK_GETENV
1775 if test "x$cf_cv_consistent_getenv" = xno && \
1776         test "x$cf_with_trace" = xyes
1777 then
1778         AC_MSG_WARN(The NCURSES_TRACE environment variable is not supported with this configuration)
1779 fi
1780
1781 CF_SYS_TIME_SELECT
1782
1783 ###     checks for compiler characteristics
1784 AC_LANG_C
1785 AC_C_CONST
1786 CF_C_INLINE(NCURSES_INLINE,1200)
1787 CF_SIG_ATOMIC_T
1788
1789 if test "$NCURSES_CHTYPE" = auto ; then
1790         CF_TYPEOF_CHTYPE
1791 else
1792         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1793 fi
1794 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1795 AC_SUBST(cf_cv_typeof_chtype)
1796
1797 CF_UNSIGNED_LITERALS
1798 cf_cv_1UL="1"
1799 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1800 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1801 AC_SUBST(cf_cv_1UL)
1802
1803 if test "$NCURSES_MMASK_T" = auto ; then
1804         cf_cv_typeof_mmask_t=long
1805 else
1806         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1807 fi
1808 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1809 AC_SUBST(cf_cv_typeof_mmask_t)
1810
1811 ###     Checks for external-data
1812 CF_ERRNO
1813 CF_LINK_DATAONLY
1814
1815 ###     Checks for library functions.
1816 CF_FUNC_GETTIME
1817 AC_CHECK_FUNCS( \
1818 fpathconf \
1819 getcwd \
1820 getauxval \
1821 getegid \
1822 geteuid \
1823 getopt \
1824 getuid \
1825 issetugid \
1826 localeconv \
1827 poll \
1828 putenv \
1829 remove \
1830 select \
1831 setbuf \
1832 setbuffer \
1833 setenv \
1834 setfsuid \
1835 setvbuf \
1836 sigaction \
1837 sigvec \
1838 snprintf \
1839 strdup \
1840 strstr \
1841 sysconf \
1842 tcgetpgrp \
1843 times \
1844 tsearch \
1845 vsnprintf \
1846 )
1847
1848 CF_FUNC_GETTTYNAM
1849
1850 if test "x$ac_cv_func_getopt" = xno && \
1851    test "x$cf_with_progs$cf_with_tests" != xnono; then
1852         AC_MSG_ERROR(getopt is required for building programs)
1853 fi
1854
1855 if test "x$with_safe_sprintf" = xyes
1856 then
1857         if test "x$ac_cv_func_vsnprintf" = xyes
1858         then
1859                 AC_MSG_WARN(will use vsnprintf instead of safe-sprintf option)
1860         else
1861                 AC_DEFINE(USE_SAFE_SPRINTF,1,[Define to 1 to compile with experimental safe-sprintf code])
1862         fi
1863 fi
1864
1865 if test "x$with_getcap" = "xyes" ; then
1866         CF_CGETENT
1867 fi
1868
1869 CF_ISASCII
1870 CF_STRUCT_SIGACTION
1871 CF_FUNC_NANOSLEEP
1872 CF_FUNC_TERMIOS
1873 CF_FUNC_VSSCANF
1874 CF_MKSTEMP
1875
1876 # setup for prototype of fallback for vsscanf()
1877 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1878
1879 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1880 if test "x$cross_compiling" = xyes ; then
1881         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1882 else
1883         AC_FUNC_SETVBUF_REVERSED
1884 fi
1885 AC_CHECK_TYPE(intptr_t, long)
1886 AC_CHECK_TYPE(ssize_t, int)
1887 CF_TYPE_SIGACTION
1888 CF_SIZECHANGE
1889 CF_FUNC_MEMMOVE
1890 CF_FUNC_POLL
1891 CF_VA_COPY
1892 AC_FUNC_VFORK
1893 CF_FOPEN_BIN_R
1894
1895 # special check for test/ditto.c
1896 CF_FUNC_OPENPTY
1897 if test "$cf_cv_func_openpty" != no ; then
1898         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
1899         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
1900         if test "x$cf_cv_lib_util" = xyes ; then
1901                 CF_ADD_LIB(util,TEST_LIBS)
1902         fi
1903 fi
1904 AC_SUBST(TEST_LIBS)
1905 AC_SUBST(TEST_LIBS2)
1906
1907 if test "$with_hashed_db" != no ; then
1908         AC_DEFINE(USE_HASHED_DB,1,[Define to 1 if we should build terminfo in hashed database])
1909         CF_HASHED_DB($with_hashed_db)
1910 fi
1911
1912 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1913 if test -z "$cf_user_CFLAGS" && test "$enable_leaks" = yes ; then
1914         CF_STRIP_G_OPT(CFLAGS)
1915         CF_STRIP_G_OPT(CXXFLAGS)
1916 fi
1917
1918 # Just in case, check if the C compiler has a bool type.
1919 CF_BOOL_DECL(cf_cv_cc_bool_type)
1920
1921 # Check for C++ compiler characteristics (and ensure that it's there!)
1922 if test -n "$CXX" ; then
1923         AC_LANG_CPLUSPLUS
1924         CF_STDCPP_LIBRARY
1925         CF_PROG_CC_C_O(CXX,[$CXXFLAGS $CPPFLAGS])
1926
1927         case "$GXX_VERSION" in
1928         (1.*|2.[[0-6]]*|[[1-9]][[0-9]].*)
1929                 cf_cxx_library=yes
1930                 ;;
1931         (*-2.7*|2.7*)
1932                 CF_GPP_LIBRARY
1933                 ;;
1934         (*)
1935                 cf_cxx_library=no
1936                 ;;
1937         esac
1938
1939         AC_CHECK_HEADERS(typeinfo)
1940         CF_CXX_IOSTREAM_NAMESPACE
1941         CF_BOOL_DECL
1942         CF_BOOL_SIZE
1943         CF_ETIP_DEFINES
1944         CF_CPP_OVERRIDE
1945         CF_CPP_PARAM_INIT
1946         CF_CPP_STATIC_CAST
1947         CF_CXX_AR_FLAGS
1948 else
1949         cf_cxx_library=no
1950         cf_cv_builtin_bool=1
1951
1952         # Just because we are not configuring against C++ right now does not
1953         # mean that a user will not want to use C++.  Some distributors disable
1954         # the C++ portion of this configuration as a shortcut (or just to avoid
1955         # compiling the demo in the c++ directory).  So we need a reasonable
1956         # default for the 'bool' type.
1957         #
1958         # Caveat: since the storage of the bool type is not standardized, it
1959         # may change.
1960
1961         if test "$NCURSES_BOOL" != auto ; then
1962                 cf_cv_type_of_bool=$NCURSES_BOOL
1963                 cf_cv_header_stdbool_h=0
1964         else
1965                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1966                         CF_BOOL_SIZE
1967                 else
1968                         AC_MSG_CHECKING(for fallback type of bool)
1969                         case "$host_cpu" in
1970                         (i?86)  cf_cv_type_of_bool=char ;;
1971                         (*)     cf_cv_type_of_bool=int  ;;
1972                         esac
1973                         AC_MSG_RESULT($cf_cv_type_of_bool)
1974                 fi
1975         fi
1976 fi
1977 AC_SUBST(CXXLIBS)
1978
1979 # If the C compiler did not declare bool, and we did not determine that the C++
1980 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1981 # ncurses library use the same type as C++ bool.  Note that this allows one to
1982 # specify the type of bool in a configure-script option and postpone
1983 # integration with the C++ compiler provided that the types are compatible.
1984 USE_CXX_BOOL=1
1985 if test "$cf_cv_cc_bool_type" = 1
1986 then
1987         # oops: C has a bool.  Unlikely, but C++ could differ.
1988         USE_CXX_BOOL=0
1989 elif test "$cf_cv_builtin_bool" = 0
1990 then
1991         # C++ has no bool
1992         USE_CXX_BOOL=0
1993 else
1994         # this is the normal case
1995         USE_CXX_BOOL='defined(__cplusplus)'
1996 fi
1997 AC_SUBST(USE_CXX_BOOL)
1998
1999 CF_HELP_MESSAGE(Ada Binding Options:)
2000
2001 dnl If the Ada95 source-tree is present, add that to the build unless it will
2002 dnl not work, or was not requested.
2003 if test -f "${srcdir}/Ada95/Makefile.in" ; then
2004
2005 dnl libtool does not know anything about GNAT, though a change made in 1998
2006 dnl provided for it "someday".  Disable the ada subtree if we are using
2007 dnl libtool -TD 20070714
2008         if test "$cf_with_ada" != "no" ; then
2009                 if test "$with_libtool" != "no"; then
2010                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
2011                         cf_with_ada=no
2012                 fi
2013         fi
2014
2015 dnl Check for availability of GNU Ada Translator (GNAT).
2016 dnl At the moment we support no other Ada compiler.
2017         if test "$cf_with_ada" != "no" ; then
2018                 CF_PROG_GNAT
2019                 if test "x$cf_cv_prog_gnat_correct" = xyes; then
2020                         CF_ADD_ADAFLAGS(-gnatpn)
2021                         CF_FIXUP_ADAFLAGS
2022
2023                         CF_GNATPREP_OPT_T
2024
2025                         CF_GNAT_GENERICS
2026                         CF_GNAT_SIGINT
2027                         CF_GNAT_PROJECTS
2028
2029                         CF_WITH_ADA_COMPILER
2030
2031                         cf_ada_package=terminal_interface
2032                         AC_SUBST(cf_ada_package)
2033
2034                         CF_WITH_ADA_INCLUDE
2035                         CF_WITH_ADA_OBJECTS
2036                         CF_WITH_ADA_SHAREDLIB
2037
2038                         # allow the Ada binding to be renamed
2039                         CF_WITH_ADA_LIBNAME(AdaCurses)
2040                 fi
2041         fi
2042 else
2043         cf_with_ada=no
2044 fi
2045
2046 # do this "late" to avoid conflict with header-checks
2047 if test "x$with_widec" = xyes ; then
2048         AC_CHECK_SIZEOF(wchar_t)
2049         # cross-compiling to mingw can run into the problem that attempting to
2050         # link with the regex library fails, causing the test to not set this to
2051         # a number.  "recent" autoconf does not address this problem either -TD
2052         if test -z "$ac_cv_sizeof_wchar_t"
2053         then
2054                 CF_VERBOSE(test failed (assume 2))
2055                 sed /SIZEOF_WCHAR_T/d confdefs.h >confdefs.tmp
2056                 mv confdefs.tmp confdefs.h
2057                 echo "#define SIZEOF_WCHAR_T 2" >>confdefs.h
2058         fi
2059 fi
2060
2061 ### Construct the ncurses library-subsets, if any, from this set of keywords:
2062 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
2063 ###
2064 ### ticlib modules may be a separate library, otherwise contained in termlib.
2065 ### termlib modules may be a separate library, otherwise contained in ncurses.
2066 ###
2067 ### The of "+" or " " between the tokens controls the way the script
2068 ### chooses to split module lists into libraries.
2069 ###
2070 ### (see CF_LIB_RULES).
2071 AC_MSG_CHECKING(for library subsets)
2072 LIB_SUBSETS=
2073
2074 if test "x$cf_with_progs" = xyes || test "$with_ticlib" != no || test "$with_termcap" != no; then
2075         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
2076         if test "$with_ticlib" != no ; then
2077                 LIB_SUBSETS="${LIB_SUBSETS} "
2078         else
2079                 LIB_SUBSETS="${LIB_SUBSETS}+"
2080         fi
2081 fi
2082
2083 LIB_SUBSETS="${LIB_SUBSETS}termlib"
2084 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
2085
2086 if test "$with_termlib" != no ; then
2087         LIB_SUBSETS="${LIB_SUBSETS} "
2088 else
2089         LIB_SUBSETS="${LIB_SUBSETS}+"
2090 fi
2091
2092 LIB_SUBSETS="${LIB_SUBSETS}base"
2093
2094 # Most term-driver calls are to tinfo, but some like init_pair are to the
2095 # base library (so it resides in base).
2096 if test "$with_term_driver" != no ; then
2097         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
2098         case "$cf_cv_system_name" in
2099         (*mingw32*|*mingw64*)
2100                 if test "x$with_exp_win32" = xyes ; then
2101                         LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32"
2102                 else
2103                         LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
2104                 fi
2105                 CPPFLAGS="$CPPFLAGS -DUSE_WIN32CON_DRIVER"
2106                 ;;
2107         (*)
2108                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
2109                 ;;
2110         esac
2111 elif test "x$with_exp_win32" = xyes ; then
2112         case "$cf_cv_system_name" in
2113         (*mingw32*|*mingw64*)
2114                 LIB_SUBSETS="${LIB_SUBSETS}+port_win32"
2115                 ;;
2116         (*)
2117                 ;;
2118         esac
2119 fi
2120
2121 test "x$with_widec"     = xyes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
2122 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
2123
2124 AC_MSG_RESULT($LIB_SUBSETS)
2125
2126 ### Construct the list of include-directories to be generated
2127 CF_INCLUDE_DIRS
2128 CF_ADA_INCLUDE_DIRS
2129
2130 ### Build up pieces for makefile rules
2131 AC_MSG_CHECKING(default library suffix)
2132 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
2133 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
2134 AC_MSG_RESULT($DFT_ARG_SUFFIX)
2135
2136 AC_MSG_CHECKING(default library-dependency suffix)
2137 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
2138 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
2139 AC_MSG_RESULT($DFT_DEP_SUFFIX)
2140
2141 AC_MSG_CHECKING(default object directory)
2142 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
2143 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
2144 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
2145
2146 if test "x$cf_with_cxx" = xyes ; then
2147 AC_MSG_CHECKING(c++ library-dependency suffix)
2148 if test "$with_libtool" != "no"; then
2149         # libtool thinks it can make c++ shared libraries (perhaps only g++)
2150         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2151 elif test "$with_shared_cxx" != "no"; then
2152         # also for g++ users...
2153         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2154 else
2155         # we normally make a static library because C/C++ library rules differ
2156         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)
2157 fi
2158 AC_MSG_RESULT($CXX_LIB_SUFFIX)
2159 AC_SUBST(CXX_LIB_SUFFIX)
2160 fi
2161
2162 # do not want -ldl in build except as needed for -lncurses dependency
2163 if test "x$with_dlsym" = xyes ; then
2164 if test "$DFT_LWR_MODEL" = shared || \
2165    test "$DFT_LWR_MODEL" = libtool ; then
2166         CF_REMOVE_LIB(LIBS,$LIBS,dl)
2167 fi
2168 fi
2169 ### Set up low-level terminfo dependencies for makefiles.
2170
2171 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
2172 # do not need libdl
2173 TICS_LIST=
2174 if test "x$with_dlsym" = xyes ; then
2175         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
2176 fi
2177
2178 USE_ARG_SUFFIX="${DFT_ARG_SUFFIX}${EXTRA_SUFFIX}"
2179 USE_LIB_SUFFIX="${LIB_SUFFIX}${EXTRA_SUFFIX}"
2180 USE_CFG_SUFFIX=${DFT_ARG_SUFFIX}${cf_cv_abi_version}
2181 if test -n "$EXTRA_SUFFIX" && test "x$EXTRA_SUFFIX" != "x${cf_cv_abi_version}"
2182 then
2183         USE_CFG_SUFFIX="${USE_CFG_SUFFIX}${EXTRA_SUFFIX}"
2184 fi
2185 AC_SUBST(USE_ARG_SUFFIX)
2186 AC_SUBST(USE_CFG_SUFFIX)
2187 AC_SUBST(USE_LIB_SUFFIX)
2188
2189 if test "$with_ticlib" != no ; then
2190
2191         if test "x$with_ticlib" != xyes ; then
2192                 TICS_NAME=$with_ticlib
2193                 TICS_SUFFIX="`echo "${DFT_LIB_SUFFIX}" |sed -e "s/^${USE_LIB_SUFFIX}//"`"
2194                 TICS_ARG_SUFFIX="${with_ticlib}`echo "${USE_ARG_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2195                 TICS_DEP_SUFFIX="${with_ticlib}`echo "${DFT_DEP_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2196                 TICS_LIB_SUFFIX="${with_ticlib}"
2197         else
2198                 TICS_SUFFIX=${DFT_LIB_SUFFIX}
2199                 TICS_ARG_SUFFIX="${TICS_NAME}${USE_ARG_SUFFIX}"
2200                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
2201                 TICS_LIB_SUFFIX="${TICS_NAME}${USE_LIB_SUFFIX}"
2202         fi
2203         TICS_LDFLAGS="-L${LIB_DIR}"
2204         TICS_LIBS="-l${TICS_ARG_SUFFIX}"
2205 else
2206         TICS_SUFFIX=${DFT_LIB_SUFFIX}
2207         TICS_LDFLAGS="-L${LIB_DIR}"
2208         TICS_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2209 fi
2210 AC_SUBST(TICS_ARG_SUFFIX)
2211 AC_SUBST(TICS_DEP_SUFFIX)
2212 AC_SUBST(TICS_LIB_SUFFIX)
2213 AC_SUBST(TICS_LDFLAGS)
2214 AC_SUBST(TICS_LIBS)
2215
2216 if test "$with_termlib" != no ; then
2217
2218         if test "x$with_termlib" != xyes ; then
2219                 TINFO_NAME=$with_termlib
2220                 TINFO_SUFFIX="`echo "${DFT_LIB_SUFFIX}" |sed -e "s/^${USE_LIB_SUFFIX}//"`"
2221                 TINFO_ARG_SUFFIX="${with_termlib}`echo "${USE_ARG_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2222                 TINFO_DEP_SUFFIX="${with_termlib}`echo "${DFT_DEP_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2223                 TINFO_LIB_SUFFIX="${with_termlib}"
2224         else
2225                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2226                 TINFO_ARG_SUFFIX="${TINFO_NAME}${USE_ARG_SUFFIX}"
2227                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
2228                 TINFO_LIB_SUFFIX="${TINFO_NAME}${USE_LIB_SUFFIX}"
2229         fi
2230
2231         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2232         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2233         if test "$DFT_LWR_MODEL" = "libtool"; then
2234                 TEST_ARGS="${TEST_DEPS}"
2235                 TEST_ARG2="${TEST_DEP2}"
2236                 TINFO_LDFLAGS="-L${LIB_DIR}"
2237                 TINFO_LIBS="$TEST_ARGS"
2238                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
2239                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
2240         else
2241                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
2242                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
2243                 if test "x$with_term_driver" != xno ; then
2244                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2245                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${USE_ARG_SUFFIX}"
2246                         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
2247                 else
2248                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2249                         TINFO_LIBS="$TEST_ARGS"
2250                 fi
2251                 TINFO_LDFLAGS="-L${LIB_DIR}"
2252                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2253         fi
2254 else
2255         # the next lines are needed for linking libtic over libncurses
2256         TINFO_NAME=${LIB_NAME}
2257         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2258         TINFO_ARG_SUFFIX=${LIB_NAME}${USE_ARG_SUFFIX}
2259         if test "x$with_tic_depends" = xyes ; then
2260                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2261         else
2262                 TICS_LIST="$SHLIB_LIST"
2263         fi
2264
2265         TINFO_LDFLAGS="-L${LIB_DIR}"
2266         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2267 fi
2268
2269 if test "$DFT_LWR_MODEL" = shared ; then
2270         case "$cf_cv_system_name" in
2271         (cygwin*|msys*)
2272                 # "lib" files have ".dll.a" suffix, "cyg"or "msys-" files have ".dll"
2273                 TINFO_SUFFIX=.dll
2274                 ;;
2275         esac
2276 fi
2277
2278 AC_SUBST(TINFO_ARG_SUFFIX)
2279 AC_SUBST(TINFO_DEP_SUFFIX)
2280 AC_SUBST(TINFO_LIB_SUFFIX)
2281 AC_SUBST(TINFO_LDFLAGS)
2282 AC_SUBST(TINFO_LIBS)
2283
2284 if test "x$with_dlsym" = xyes ; then
2285         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
2286 fi
2287
2288 if test "$DFT_LWR_MODEL" = "libtool"; then
2289         OBJEXT=lo
2290 fi
2291
2292 # needed for Ada95
2293 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
2294 AC_SUBST(TINFO_LDFLAGS2)
2295
2296 case "$DFT_LWR_MODEL" in
2297 (normal|debug|profile)
2298         CF_LDFLAGS_STATIC
2299         ;;
2300 esac
2301
2302 AC_MSG_CHECKING(where we will install curses.h)
2303 AC_SUBST(includesubdir)
2304 includesubdir=
2305 if test "$with_overwrite" = no && \
2306  { test "x$includedir" = 'x${prefix}/include' || \
2307    test "x$includedir" = "x${prefix}/include"; }
2308 then
2309         includesubdir="/ncurses${USE_LIB_SUFFIX}"
2310 fi
2311 AC_MSG_RESULT(${includedir}${includesubdir})
2312
2313 ### Resolve a conflict between normal and wide-curses by forcing applications
2314 ### that will need libutf8 to add it to their configure script.
2315 if test "$with_overwrite" != no ; then
2316 if test "$NCURSES_LIBUTF8" = 1 ; then
2317         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
2318         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
2319 fi
2320 fi
2321 WITH_OVERWRITE=$with_overwrite
2322
2323 ### At least on MinGW a shared library build without libtool
2324 ### requires adding the additional libs to the link list.
2325 case "$cf_cv_system_name" in
2326 (*mingw32*|*mingw64*)
2327         if test "$DFT_LWR_MODEL" != "libtool"; then
2328            SHLIB_LIST="$SHLIB_LIST ${LIBS}"
2329         fi
2330         ;;
2331 *)      ;;
2332 esac
2333
2334 AC_SUBST(WITH_OVERWRITE)
2335 AC_SUBST(TICS_LIST)
2336 AC_SUBST(TINFO_LIST)
2337 AC_SUBST(SHLIB_LIST)
2338
2339 ### predefined stuff for the test programs
2340 AC_DEFINE(HAVE_SLK_COLOR,1,[Define to 1 if we have slk_color for test-programs])
2341
2342 # pkgsrc uses these
2343 CF_WITH_LIB_BASENAME(FORM_NAME,form)
2344 CF_WITH_LIB_BASENAME(MENU_NAME,menu)
2345 CF_WITH_LIB_BASENAME(PANEL_NAME,panel)
2346 CF_WITH_LIB_BASENAME(CXX_NAME,cxx,ncurses++)
2347
2348 ### Construct the list of subdirectories for which we'll customize makefiles
2349 ### with the appropriate compile-rules.
2350
2351 CF_SRC_MODULES($modules_to_build)
2352
2353 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2354    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/src/library.gpr:Ada95/src/library.gpr.in"
2355    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${USE_CFG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
2356    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${USE_CFG_SUFFIX}-config.1:man/MKada_config.in"
2357 fi
2358
2359 CF_DIRS_TO_MAKE
2360
2361 # symbols that differ when compiling Ada95 by itself.
2362 NCURSES_SHLIB2=$SHELL' $(top_srcdir)/misc/shlib'
2363 AC_SUBST(NCURSES_SHLIB2)
2364
2365 # values to use as strings
2366 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as library path-separator])
2367
2368 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}",[Define to 1 if machine has ample memory for tic])
2369
2370 ### Define substitutions for header files to avoid name-pollution
2371 CF_SUBST_IF(["x$cf_cv_have_tcgetattr" = xyes], HAVE_TCGETATTR, 1, 0)
2372 CF_SUBST_IF(["x$ac_cv_header_stdint_h" = xyes], HAVE_STDINT_H, 1, 0)
2373 CF_SUBST_IF(["x$ac_cv_header_termio_h" = xyes], HAVE_TERMIO_H, 1, 0)
2374 CF_SUBST_IF(["x$ac_cv_header_termios_h" = xyes], HAVE_TERMIOS_H, 1, 0)
2375
2376 ################################################################################
2377 test "x$use_database" = xyes && \
2378 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
2379
2380 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
2381 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${USE_CFG_SUFFIX}-config.1:man/MKncu_config.in"
2382
2383 if test "x$enable_pc_files" = xyes && test -z "$MAKE_PC_FILES" ; then
2384 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
2385 fi
2386 AC_SUBST(cross_compiling)
2387
2388 if test "x$cf_with_tests" != xno ; then
2389         MAKE_TESTS=
2390 else
2391         MAKE_TESTS="#"
2392 fi
2393 AC_SUBST(MAKE_TESTS)
2394
2395 ADAHTML_DIR=../../doc/html/ada
2396 AC_SUBST(ADAHTML_DIR)
2397
2398 # workaround for OS/2 (20151017)
2399 case "$cf_cv_system_name" in
2400 (os2*)
2401         LIBTOOL_OPTS_CXX="-os2dllname ncurs++"
2402         ;;
2403 (*)
2404         LIBTOOL_OPTS_CXX=
2405         ;;
2406 esac
2407 AC_SUBST(LIBTOOL_OPTS_CXX)
2408
2409 # workaround for g++ versus Solaris (20131116)
2410 case "$cf_cv_system_name" in
2411 (solaris2*)
2412         case "x$CPPFLAGS" in
2413         (*-D_XOPEN_SOURCE_EXTENDED*)
2414                 CF_VERBOSE(moving _XOPEN_SOURCE_EXTENDED to work around g++ problem)
2415                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
2416                 CPPFLAGS=`echo "x$CPPFLAGS" | sed -e  's/^.//' -e 's/-D_XOPEN_SOURCE_EXTENDED//'`
2417                 ;;
2418         esac
2419         ;;
2420 esac
2421
2422 # Help to automatically enable the extended curses features when using either
2423 # the *-config or the ".pc" files by adding defines.
2424 AC_MSG_CHECKING(for defines to add to ncurses${USE_CFG_SUFFIX}-config script)
2425 PKG_CFLAGS=
2426 for cf_loop1 in $CPPFLAGS_after_XOPEN
2427 do
2428         cf_found=no
2429         for cf_loop2 in $CPPFLAGS_before_XOPEN
2430         do
2431                 if test "x$cf_loop1" = "x$cf_loop2"
2432                 then
2433                         cf_found=yes
2434                         break
2435                 fi
2436         done
2437         test "$cf_found" = no && PKG_CFLAGS="$PKG_CFLAGS $cf_loop1"
2438 done
2439 AC_MSG_RESULT($PKG_CFLAGS)
2440 AC_SUBST(PKG_CFLAGS)
2441
2442 # AC_CHECK_SIZEOF demands a literal parameter, no variables.  So we do this.
2443 case "x$NCURSES_OSPEED" in
2444 (*short*)
2445         cf_compatible=1
2446         ;;
2447 (*)
2448         cf_compatible=0
2449         ;;
2450 esac
2451 AC_DEFINE_UNQUOTED(NCURSES_OSPEED_COMPAT,$cf_compatible,[Define to 1 if termcap variable ospeed is short])
2452
2453 case "x$cf_cv_typeof_chtype" in
2454 (xshort|xint|xlong)
2455         cf_cv_typeof_chtype="unsigned $cf_cv_typeof_chtype"
2456         ;;
2457 esac
2458
2459 case "x$cf_cv_typeof_mmask_t" in
2460 (xshort|xint|xlong)
2461         cf_cv_typeof_mmask_t="unsigned $cf_cv_typeof_mmask_t"
2462         ;;
2463 esac
2464
2465 # substitute into misc/Makefile to suppress
2466 # (un)install.data from the
2467 # (un)install rules.
2468 if test "x$cf_with_db_install" = "xno"; then
2469         MISC_INSTALL_DATA=
2470         MISC_UNINSTALL_DATA=
2471 else
2472         MISC_INSTALL_DATA=install.data
2473         MISC_UNINSTALL_DATA=uninstall.data
2474 fi
2475 AC_SUBST(MISC_INSTALL_DATA)
2476 AC_SUBST(MISC_UNINSTALL_DATA)
2477
2478 if test "x$cf_with_db_install" = "xno" || test "x$TERMINFO_SRC" = "xno"; then
2479         MAKE_DATABASE="#"
2480 else
2481         MAKE_DATABASE="$MAKE_TERMINFO"
2482 fi
2483 AC_SUBST(MAKE_DATABASE)
2484
2485 dnl Override the package used for exported symbols
2486 if test -n "$PACKAGE"
2487 then
2488         PACKAGE="${PACKAGE}${DFT_ARG_SUFFIX}"
2489         export PACKAGE
2490         echo "package: $PACKAGE"
2491 fi
2492
2493 UNALTERED_SYMS=
2494 cf_filter_syms=no
2495
2496 if test -n "$RESULTING_SYMS"
2497 then
2498         cf_filter_syms=$cf_dft_filter_syms
2499         CF_VERBOSE(will map symbols to ABI=$cf_cv_abi_default)
2500 fi
2501
2502 if test "x$WILDCARD_SYMS" = xno
2503 then
2504         cf_filter_syms=yes
2505 fi
2506
2507 test "x$cf_with_trace" = xyes && NCURSES_INLINE=
2508
2509 UNALTERED_SYMS=`echo "$RESULTING_SYMS" | sed -e 's/\\$/\\\\$/g'`
2510 if test "$cf_filter_syms" = yes
2511 then
2512         RESULTING_SYMS=resulting.map
2513 fi
2514 AC_SUBST(UNALTERED_SYMS)
2515
2516 if test "x$cross_compiling" = xyes ; then
2517         ADAGEN_LDFLAGS='$(CROSS_LDFLAGS)'
2518         CHECK_BUILD="#"
2519 else
2520         ADAGEN_LDFLAGS='$(NATIVE_LDFLAGS)'
2521         CHECK_BUILD=
2522 fi
2523 AC_SUBST(ADAGEN_LDFLAGS)
2524 AC_SUBST(CHECK_BUILD)
2525 AC_SUBST(PRIVATE_LIBS)
2526
2527 # This is used for the *-config script and *.pc data files.
2528 CF_LD_SEARCHPATH
2529
2530 AC_OUTPUT( \
2531         include/MKterm.h.awk \
2532         include/curses.head:include/curses.h.in \
2533         include/ncurses_dll.h \
2534         include/termcap.h \
2535         include/unctrl.h \
2536         man/man_db.renames \
2537         $SUB_MAKEFILES \
2538         Makefile,[
2539 if test "x$cf_with_tests" != xno ; then
2540         CF_PRG_RULES(["$srcdir/test/mk-test.awk" INSTALL=no ECHO_LINK="$ECHO_LD"], test)
2541 fi
2542 CF_LIB_RULES($SRC_SUBDIRS)
2543 CF_OUTPUT_MANPAGE_RENAMES
2544
2545 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2546 if test -z "$USE_OLD_MAKERULES" ; then
2547         $AWK -f "$srcdir/Ada95/mk-1st.awk" <"$srcdir/Ada95/src/modules" >>Ada95/src/Makefile
2548 fi
2549 fi
2550 ],[
2551 ### Special initialization commands, used to pass information from the
2552 ### configuration-run into config.status
2553
2554 ALTERNATE_SYMS="$ALTERNATE_SYMS"
2555 AWK="$AWK"
2556 CXX_NAME="$CXX_NAME"
2557 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
2558 DFT_LWR_MODEL="$DFT_LWR_MODEL"
2559 ECHO_LD="$ECHO_LD"
2560 EXTRA_SUFFIX="$EXTRA_SUFFIX"
2561 FORM_NAME="$FORM_NAME"
2562 LDCONFIG="$LDCONFIG"
2563 LIBTOOL_VERSION="$LIBTOOL_VERSION"
2564 LIB_NAME="$LIB_NAME"
2565 LIB_PREFIX="$LIB_PREFIX"
2566 LIB_SUBSETS="$LIB_SUBSETS"
2567 LIB_SUFFIX="$LIB_SUFFIX"
2568 LIB_TRACING="$LIB_TRACING"
2569 LN_S="$LN_S"
2570 MAKE_TERMINFO="$MAKE_TERMINFO"
2571 MANPAGE_RENAMES="$MANPAGE_RENAMES"
2572 MENU_NAME="$MENU_NAME"
2573 NCURSES_MAJOR="$NCURSES_MAJOR"
2574 NCURSES_MINOR="$NCURSES_MINOR"
2575 NCURSES_OSPEED="$NCURSES_OSPEED"
2576 NCURSES_PATCH="$NCURSES_PATCH"
2577 PANEL_NAME="$PANEL_NAME"
2578 SRC_SUBDIRS="$SRC_SUBDIRS"
2579 TERMINFO="$TERMINFO"
2580 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
2581 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
2582 TICS_NAME="$TICS_NAME"
2583 TICS_SUFFIX="$TICS_SUFFIX"
2584 TIC_PATH="$TIC_PATH"
2585 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
2586 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
2587 TINFO_NAME="$TINFO_NAME"
2588 TINFO_SUFFIX="$TINFO_SUFFIX"
2589 UNALTERED_SYMS="$UNALTERED_SYMS"
2590 USE_ARG_SUFFIX="$USE_ARG_SUFFIX"
2591 USE_CFG_SUFFIX="$USE_CFG_SUFFIX"
2592 USE_LIB_SUFFIX="$USE_LIB_SUFFIX"
2593 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
2594 WILDCARD_SYMS="$WILDCARD_SYMS"
2595 WITH_CURSES_H="$with_curses_h"
2596 WITH_ECHO="${enable_echo:=yes}"
2597 WITH_OVERWRITE="$with_overwrite"
2598 cf_LIST_MODELS="$cf_list_models"
2599 cf_cv_VERSION_GNATMAKE=$cf_cv_VERSION_GNATMAKE
2600 cf_cv_VERSION_GPRBUILD=$cf_cv_VERSION_GPRBUILD
2601 cf_cv_abi_default="$cf_cv_abi_default"
2602 cf_cv_abi_version="$cf_cv_abi_version"
2603 cf_cv_do_relink="$cf_cv_do_relink"
2604 cf_cv_do_reranlib="$cf_cv_do_reranlib"
2605 cf_cv_do_symlinks="$cf_cv_do_symlinks"
2606 cf_cv_enable_lp64="$cf_cv_enable_lp64"
2607 cf_cv_enable_opaque="$cf_cv_enable_opaque"
2608 cf_cv_make_PHONY="$cf_cv_make_PHONY"
2609 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
2610 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
2611 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
2612 cf_cv_rel_version="$cf_cv_rel_version"
2613 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
2614 cf_cv_shared_soname='$cf_cv_shared_soname'
2615 cf_cv_shlib_version="$cf_cv_shlib_version"
2616 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
2617 cf_cv_system_name="$cf_cv_system_name"
2618 cf_cv_term_driver="$with_term_driver"
2619 cf_with_ada="$cf_with_ada"
2620 cf_with_cxx_binding="$cf_with_cxx_binding"
2621 cf_with_db_install="$cf_with_db_install"
2622 cf_with_manpages="$cf_with_manpages"
2623 cf_with_tests="$cf_with_tests"
2624 host="$host"
2625 target="$target"
2626 verbose="$verbose"
2627 with_shared_cxx="$with_shared_cxx"
2628
2629 ],cat)dnl
2630 ${MAKE:-make} preinstall