configure.in

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2022,2023 Thomas E. Dickey                                *
   3 dnl Copyright 1998-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl Author: Thomas E. Dickey 1995-on
  31 dnl
  32 dnl $Id: configure.in,v 1.758 2023/04/15 20:06:19 Sven.Joachim Exp $
  33 dnl Process this file with autoconf to produce a configure script.
  34 dnl
  35 dnl For additional information, see
  36 dnl     https://invisible-island.net/autoconf/
  37 dnl     https://invisible-island.net/autoconf/my-autoconf.html
  38 dnl
  39 dnl ---------------------------------------------------------------------------
  40 AC_PREREQ(2.52.20210101)
  41 AC_REVISION($Revision: 1.758 $)
  42 AC_INIT(ncurses/base/lib_initscr.c)
  43 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  44
  45 AC_DEFUN([AC_PATH_XTRA],[])dnl ignore dependencies on this
  46
  47 CF_TOP_BUILDDIR
  48 CF_SUBST_NCURSES_VERSION
  49 CF_VERSION_INFO(NCURSES,ncurses)
  50
  51 CF_WITH_REL_VERSION(NCURSES)
  52 CF_NCURSES_WITH_ABI_VERSION
  53
  54 CF_WITH_SYSTYPE
  55
  56 ###     Save the given $CFLAGS to allow user-override.
  57 cf_user_CFLAGS="$CFLAGS"
  58
  59 ###     Default install-location
  60 CF_CFG_DEFAULTS
  61 ### Defaults for ncurses ABI
  62 CF_ABI_DEFAULTS
  63
  64 ### override ABI version, e.g., packagers
  65 CF_WITH_ABI_ALTERED
  66
  67 ###     Checks for programs.
  68 AC_ARG_WITH(ada,
  69         [  --without-ada           suppress check for Ada compiler, don't build demo],
  70         [cf_with_ada=$withval],
  71         [cf_with_ada=yes])
  72
  73 if test "x$cf_with_ada" = xyes
  74 then
  75         cf_prog_cc="gnatgcc gcc cc"
  76 else
  77         cf_prog_cc="gcc cc"
  78 fi
  79 CF_PROG_CC($cf_prog_cc)
  80
  81 AC_PROG_CPP
  82 AC_PROG_GCC_TRADITIONAL
  83 CF_PROG_CC_C_O(CC,[$CFLAGS $CPPFLAGS])
  84 CF_PROG_LDCONFIG
  85
  86 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  87 dnl                             configure script by not letting us test if C++
  88 dnl                             is present, making this option necessary.
  89 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  90 AC_ARG_WITH(cxx,
  91         [  --without-cxx           do not adjust ncurses bool to match C++],
  92         [cf_with_cxx=$withval],
  93         [cf_with_cxx=yes])
  94 AC_MSG_RESULT($cf_with_cxx)
  95 if test "X$cf_with_cxx" = Xno ; then
  96         CXX=""
  97         GXX=""
  98 else
  99         # with autoconf 2.13, we can change the error to a warning:
 100         pushdef([AC_MSG_ERROR],
 101                 [AC_MSG_RESULT(no)
 102                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
 103                 cf_with_cxx=no; CXX=""; GXX="";])dnl
 104         AC_PROG_CXX
 105         popdef([AC_MSG_ERROR])dnl
 106
 107         AC_LANG_PUSH(C++)
 108         if test "x$cf_with_cxx" != xno
 109         then
 110                 # Several of the C++ configurations do not work, particularly when
 111                 # cross-compiling (20140913 -TD)
 112                 AC_MSG_CHECKING(if $CXX works)
 113
 114                 save_CPPFLAGS="$CPPFLAGS"
 115                 eval cf_includedir=${includedir}
 116                 CPPFLAGS="$CPPFLAGS -I${cf_includedir}"
 117                 AC_TRY_COMPILE([
 118 #include <stdlib.h>
 119 #include <stdio.h>
 120 ],
 121                 [
 122                 printf("Hello world!\n")
 123                 ],
 124                 [cf_cxx_works=yes],
 125                 [cf_cxx_works=no])
 126                 CPPFLAGS="$save_CPPFLAGS"
 127
 128                 AC_MSG_RESULT($cf_cxx_works)
 129                 if test "x$cf_cxx_works" = xno
 130                 then
 131                         AC_MSG_WARN([Ignore $CXX, since it cannot compile hello-world.])
 132                         cf_with_cxx=no; CXX=""; GXX="";
 133                 fi
 134         fi
 135         AC_LANG_POP
 136
 137         # autoconf 2.5x removed the error (hardcoding it to g++, or just blank)
 138         if test "$CXX" = "g++" ; then
 139                 AC_PATH_PROG(CXX,g++)
 140         fi
 141         case "x$CXX" in
 142         (x|xg++)
 143                 AC_MSG_WARN([You don't have any C++ compiler, too bad])
 144                 cf_with_cxx=no; CXX=""; GXX="";
 145                 ;;
 146         esac
 147 fi
 148
 149 CF_GXX_VERSION
 150 case "$GXX_VERSION" in
 151 ([[1-9]][[0-9]].*)
 152         ;;
 153 (1.*|2.[[0-6]]*)
 154         AC_MSG_WARN(templates do not work)
 155         ;;
 156 esac
 157
 158 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 159 AC_ARG_WITH(cxx-binding,
 160         [  --without-cxx-binding   do not build C++ binding and demo],
 161         [cf_with_cxx_binding=$withval],
 162         [cf_with_cxx_binding=$cf_with_cxx])
 163 AC_MSG_RESULT($cf_with_cxx_binding)
 164
 165 AC_MSG_CHECKING(if you want to build with Ada)
 166 AC_MSG_RESULT($cf_with_ada)
 167
 168 AC_MSG_CHECKING(if you want to install terminal database)
 169 AC_ARG_ENABLE(db-install,
 170         [  --disable-db-install    suppress install of terminal database],
 171         [cf_with_db_install=$enableval],
 172         [cf_with_db_install=yes])
 173 AC_MSG_RESULT($cf_with_db_install)
 174
 175 AC_MSG_CHECKING(if you want to install manpages)
 176 AC_ARG_WITH(manpages,
 177         [  --without-manpages      suppress install of manpages],
 178         [cf_with_manpages=$withval],
 179         [cf_with_manpages=yes])
 180 AC_MSG_RESULT($cf_with_manpages)
 181
 182 AC_MSG_CHECKING(if you want to build programs such as tic)
 183 AC_ARG_WITH(progs,
 184         [  --without-progs         suppress build/install with programs (e.g., tic)],
 185         [cf_with_progs=$withval],
 186         [cf_with_progs=yes])
 187 AC_MSG_RESULT($cf_with_progs)
 188
 189 if test -f "$srcdir/tack/tack.h" ; then
 190         if test "x$cross_compiling" = xyes ; then
 191                 CF_VERBOSE(ignoring tack because we are cross-compiling)
 192                 cf_with_tack=no
 193         else
 194                 AC_MSG_CHECKING(if you want to build the tack program)
 195                 AC_ARG_WITH(tack,
 196                         [  --without-tack          suppress build/install with tack program],
 197                         [cf_with_tack=$withval],
 198                         [cf_with_tack=$cf_with_progs])
 199                 AC_MSG_RESULT($cf_with_tack)
 200         fi
 201 else
 202         cf_with_tack=no
 203 fi
 204
 205 AC_MSG_CHECKING(if you want to build test-programs)
 206 AC_ARG_WITH(tests,
 207         [  --without-tests         suppress build/install with test-programs],
 208         [cf_with_tests=$withval],
 209         [cf_with_tests=yes])
 210 AC_MSG_RESULT($cf_with_tests)
 211
 212 AC_MSG_CHECKING(if you wish to install curses.h)
 213 AC_ARG_WITH(curses-h,
 214         [  --without-curses-h      install curses.h as ncurses.h only],
 215         [with_curses_h=$withval],
 216         [with_curses_h=yes])
 217 AC_MSG_RESULT($with_curses_h)
 218
 219 modules_to_build="ncurses"
 220 test "X$cf_with_progs" != Xno && modules_to_build="$modules_to_build progs"
 221 test "X$cf_with_tack"  != Xno && modules_to_build="$modules_to_build tack"
 222 modules_to_build="$modules_to_build panel menu form"
 223
 224 AC_ARG_PROGRAM
 225
 226 CF_PROG_AWK
 227 CF_PROG_INSTALL
 228 CF_PROG_LINT
 229 CF_PROG_LN_S
 230
 231 AC_SYS_LONG_FILE_NAMES
 232
 233 # Provide for renaming "ncurses5-config" to "ncurses5X-config", etc., in case
 234 # of package conflict.
 235 cf_config_suffix=
 236 AC_ARG_WITH(config-suffix,
 237         [  --with-config-suffix=X  suffixes ncursesXX-config file],
 238         [case "x$withval" in
 239         (xyes|xno)
 240                 AC_MSG_WARN(expected a value for config-suffix option)
 241                 ;;
 242         (*)     cf_config_suffix="$withval"
 243                 ;;
 244         esac])
 245 AC_SUBST(cf_config_suffix)
 246
 247 # If we find pkg-config, check if we should install the ".pc" files.
 248 CF_PKG_CONFIG
 249 CF_WITH_PKG_CONFIG_LIBDIR
 250 CF_ENABLE_PC_FILES
 251 if test -z "$MAKE_PC_FILES"
 252 then
 253         AC_MSG_CHECKING(for suffix to add to pc-files)
 254 AC_ARG_WITH(pc-suffix,
 255         [  --with-pc-suffix        suffixes pc-files],
 256         [case "x$withval" in
 257         (xyes|xno)
 258                 PC_MODULE_SUFFIX=
 259                 ;;
 260         (*)     PC_MODULE_SUFFIX="$withval"
 261                 ;;
 262         esac])
 263         test -z "$PC_MODULE_SUFFIX" && PC_MODULE_SUFFIX=none
 264         AC_MSG_RESULT($PC_MODULE_SUFFIX)
 265         test "$PC_MODULE_SUFFIX" = none && PC_MODULE_SUFFIX=
 266         AC_SUBST(PC_MODULE_SUFFIX)
 267 fi
 268
 269 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 270 AC_ARG_ENABLE(mixed-case,
 271         [  --enable-mixed-case     tic should assume mixed-case filenames],
 272         [enable_mixedcase=$enableval],
 273         [enable_mixedcase=auto])
 274 AC_MSG_RESULT($enable_mixedcase)
 275 if test "$enable_mixedcase" = "auto" ; then
 276         CF_MIXEDCASE_FILENAMES
 277 else
 278         cf_cv_mixedcase=$enable_mixedcase
 279         if test "x$enable_mixedcase" = "xyes" ; then
 280                 AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if tic should assume mixed-case filenames])
 281         fi
 282 fi
 283
 284 # do this after mixed-case option (tags/TAGS is not as important as tic).
 285 AC_PROG_MAKE_SET
 286 CF_MAKE_PHONY
 287 CF_MAKE_TAGS
 288 CF_MAKEFLAGS
 289
 290 dnl These are standard among *NIX systems, but not when cross-compiling
 291 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 292 AC_CHECK_TOOL(LD, ld, ld)
 293 AC_CHECK_TOOL(AR, ar, ar)
 294 AC_CHECK_TOOL(NM, nm, nm)
 295 CF_AR_FLAGS
 296
 297 dnl Special option for use by system-builders: the install-prefix is used to
 298 dnl adjust the location into which the actual install is done, so that an
 299 dnl archive can be built without modifying the host system's configuration.
 300 AC_MSG_CHECKING(if you have specified an install-prefix)
 301 AC_ARG_WITH(install-prefix,
 302         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 303         [case "x$withval" in
 304         (xyes|xno)
 305                 ;;
 306         (*)     DESTDIR="$withval"
 307                 ;;
 308         esac])
 309 AC_MSG_RESULT($DESTDIR)
 310 AC_SUBST(DESTDIR)
 311
 312 ###############################################################################
 313 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 314 # If we're cross-compiling, allow the user to override the tools and their
 315 # options.  The configure script is oriented toward identifying the host
 316 # compiler, etc., but we need a build compiler to generate parts of the source.
 317
 318 case "$cf_cv_system_name" in
 319 (*-msvc*)
 320         LDFLAGS="$LDFLAGS user32.lib"
 321         export LDFLAGS
 322         ;;
 323 esac
 324
 325 CF_BUILD_CC
 326
 327 ###############################################################################
 328 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 329
 330 ### Options to allow the user to specify the set of libraries which are used.
 331 ### Use "--without-normal --with-shared" to allow the default model to be
 332 ### shared, for example.
 333 cf_list_models=""
 334 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 335
 336 CF_WITH_LIBTOOL
 337 if test "$with_libtool" != "no" ; then
 338
 339 cf_list_models="$cf_list_models libtool"
 340
 341 else
 342
 343 AC_MSG_CHECKING(if you want to build shared libraries)
 344 AC_ARG_WITH(shared,
 345         [  --with-shared           generate shared-libraries],
 346         [with_shared=$withval],
 347         [with_shared=no])
 348 AC_MSG_RESULT($with_shared)
 349 test "x$with_shared" = "xyes" && cf_list_models="$cf_list_models shared"
 350
 351 AC_MSG_CHECKING(if you want to build static libraries)
 352 AC_ARG_WITH(normal,
 353         [  --with-normal           generate normal-libraries (default)],
 354         [with_normal=$withval],
 355         [with_normal=yes])
 356 AC_MSG_RESULT($with_normal)
 357 test "x$with_normal" = "xyes" && cf_list_models="$cf_list_models normal"
 358
 359 AC_MSG_CHECKING(if you want to build debug libraries)
 360 AC_ARG_WITH(debug,
 361         [  --with-debug            generate debug-libraries (default)],
 362         [with_debug=$withval],
 363         [with_debug=yes])
 364 AC_MSG_RESULT($with_debug)
 365 test "x$with_debug" = "xyes" && cf_list_models="$cf_list_models debug"
 366
 367 AC_MSG_CHECKING(if you want to build profiling libraries)
 368 AC_ARG_WITH(profile,
 369         [  --with-profile          generate profile-libraries],
 370         [with_profile=$withval],
 371         [with_profile=no])
 372 AC_MSG_RESULT($with_profile)
 373 test "x$with_profile" = "xyes" && cf_list_models="$cf_list_models profile"
 374
 375 fi
 376
 377 if test "X$cf_with_cxx_binding" != Xno; then
 378 if test "x$with_shared" = "xyes"; then
 379 AC_MSG_CHECKING(if you want to build C++ shared libraries)
 380 AC_ARG_WITH(cxx-shared,
 381         [  --with-cxx-shared       generate C++ shared-libraries],
 382         [with_shared_cxx=$withval],
 383         [with_shared_cxx=no])
 384 AC_MSG_RESULT($with_shared_cxx)
 385 fi
 386 fi
 387
 388 ###############################################################################
 389
 390 AC_MSG_CHECKING(for specified models)
 391 test -z "$cf_list_models" && cf_list_models=normal
 392 dnl If we use libtool to generate libraries, then it must be the only
 393 dnl specified model.
 394 test "$with_libtool" != "no" && cf_list_models=libtool
 395 AC_MSG_RESULT($cf_list_models)
 396
 397 ### Use the first model as the default, and save its suffix for use in building
 398 ### up test-applications.
 399 AC_MSG_CHECKING(for default model)
 400 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 401 AC_MSG_RESULT($DFT_LWR_MODEL)
 402
 403 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 404
 405 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 406 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 407
 408 TICS_NAME=tic
 409 AC_SUBST(TICS_NAME)
 410
 411 TINFO_NAME=tinfo
 412 AC_SUBST(TINFO_NAME)
 413
 414 LIB_NAME=ncurses
 415 AC_SUBST(LIB_NAME)
 416
 417 LIB_DIR=../lib
 418 LIB_2ND=../../lib
 419
 420 CF_WITH_LIB_PREFIX(cf_prefix)
 421
 422 LIB_SUFFIX=
 423 AC_SUBST(LIB_SUFFIX)
 424 CF_PATHSEP
 425
 426 # headers needed for checks...
 427 AC_CHECK_DECL(exit)
 428 AC_HEADER_DIRENT
 429
 430 ###############################################################################
 431
 432 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 433 AC_ARG_WITH(termlib,
 434         [  --with-termlib          generate separate terminfo library],
 435         [with_termlib=$withval],
 436         [with_termlib=no])
 437 AC_MSG_RESULT($with_termlib)
 438
 439 AC_MSG_CHECKING(if you want to build a separate tic library)
 440 AC_ARG_WITH(ticlib,
 441         [  --with-ticlib           generate separate tic library],
 442         [with_ticlib=$withval],
 443         [with_ticlib=no])
 444 AC_MSG_RESULT($with_ticlib)
 445
 446 dnl Not all ports of gcc support the -g option
 447
 448 if test X"$CC_G_OPT" = X"" ; then
 449         CC_G_OPT='-g'
 450         test -n "$GCC" && test "x${ac_cv_prog_cc_g}" != xyes && CC_G_OPT=''
 451 fi
 452 AC_SUBST(CC_G_OPT)
 453
 454 if test X"$CXX_G_OPT" = X"" ; then
 455         CXX_G_OPT='-g'
 456         test -n "$GXX" && test "x${ac_cv_prog_cxx_g}" != xyes && CXX_G_OPT=''
 457 fi
 458 AC_SUBST(CXX_G_OPT)
 459
 460 AC_MSG_CHECKING(for default loader flags)
 461 case "$DFT_LWR_MODEL" in
 462 (libtool) LD_MODEL=''   ;;
 463 (normal)  LD_MODEL=''   ;;
 464 (debug)   LD_MODEL=$CC_G_OPT ;;
 465 (profile) LD_MODEL='-pg';;
 466 (shared)  LD_MODEL=''   ;;
 467 esac
 468 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 469 AC_MSG_RESULT($LD_MODEL)
 470
 471 case "$DFT_LWR_MODEL" in
 472 (shared)
 473 CF_ENABLE_RPATH
 474 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 475 AC_ARG_ENABLE(relink,
 476 [  --disable-relink        relink shared libraries during install],
 477 [cf_cv_do_relink=$enableval],
 478 [cf_cv_do_relink=yes])
 479 AC_MSG_RESULT($cf_cv_do_relink)
 480         ;;
 481 esac
 482
 483 # we will build libraries one-level down.
 484 rel_builddir=..
 485 CF_SHARED_OPTS
 486 for model in $cf_list_models ; do
 487         case "$model" in
 488         (libtool)
 489                 CF_WITH_LIBTOOL_OPTS
 490                 CF_WITH_EXPORT_SYMS
 491                 ;;
 492         (shared)
 493                 if test "$CC_SHARED_OPTS" = "unknown"; then
 494                         AC_ERROR(Shared libraries are not supported in this version)
 495                 fi
 496                 # workaround for inept transition to PIE vs PIC...
 497                 AC_MSG_CHECKING(if current CFLAGS link properly)
 498                 AC_TRY_LINK(
 499                         [#include <stdio.h>],
 500                         [printf("Hello work\\n");],
 501                         [cf_cflags_work=yes],
 502                         [cf_cflags_work=no])
 503                 AC_MSG_RESULT($cf_cflags_work)
 504                 if test "$cf_cflags_work" = no
 505                 then
 506                         CF_VERBOSE(try to work around by appending shared-options)
 507                         CFLAGS="$CFLAGS $CC_SHARED_OPTS"
 508                 fi
 509                 CF_WITH_VERSIONED_SYMS
 510                 ;;
 511         esac
 512 done
 513
 514 ### Checks for special libraries, must be done up-front.
 515 SHLIB_LIST=""
 516 CF_WITH_GPM
 517 if test "$with_gpm" != no ; then
 518         AC_MSG_CHECKING(if you want to load GPM dynamically)
 519         AC_ARG_WITH(dlsym,
 520                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 521                 [with_dlsym=$withval],
 522                 [with_dlsym=yes])
 523         AC_MSG_RESULT($with_dlsym)
 524         if test "x$with_dlsym" = xyes ; then
 525                 CF_FUNC_DLSYM
 526                 if test "x$with_gpm" != xyes ; then
 527                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 528                         cf_cv_gpm_soname="$with_gpm"
 529                 else
 530                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 531                 fi
 532                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname",[Define as needed to set the gpm share library soname])
 533                 SHLIB_LIST="-ldl $SHLIB_LIST"
 534                 CF_ADD_LIB(dl,PRIVATE_LIBS)
 535         else
 536                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 537                 CF_ADD_LIB(gpm,TEST_LIBS)
 538                 CF_ADD_LIB(gpm,PRIVATE_LIBS)
 539         fi
 540         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
 541         CF_CHECK_GPM_WGETCH
 542 fi
 543
 544 CF_WITH_PCRE2
 545 CF_WITH_SYSMOUSE
 546
 547 # pretend that ncurses==ncursesw==ncursest
 548 AC_MSG_CHECKING(if you want to disable library suffixes)
 549 CF_ARG_DISABLE(lib-suffixes,
 550         [  --disable-lib-suffixes  disable library suffixes],
 551         [disable_lib_suffixes=yes],
 552         [disable_lib_suffixes=no],
 553         no)
 554 AC_MSG_RESULT($disable_lib_suffixes)
 555
 556 ### If we're building with rpath, try to link non-standard libs that way too.
 557 if test "$DFT_LWR_MODEL" = "shared" && test "x$cf_cv_enable_rpath" != xno; then
 558         CF_DISABLE_RPATH_HACK
 559 fi
 560
 561 ### Depending on the system, someone may use rpath to build ncurses but not
 562 # want users of the package to rely upon that feature.  Give those people an
 563 # option to suppress that detail from EXTRA_LDFLAGS.
 564 EXTRA_PKG_LDFLAGS="$LDFLAGS $EXTRA_LDFLAGS"
 565 if test -n "$EXTRA_PKG_LDFLAGS"
 566 then
 567         AC_MSG_CHECKING(if you want to disable extra LDFLAGS for package-scripts)
 568         CF_ARG_DISABLE(pkg-ldflags,
 569                 [  --disable-pkg-ldflags   disable extra LDFLAGS for package-scripts],
 570                 [disable_pkg_ldflags=yes],
 571                 [disable_pkg_ldflags=no],
 572                 no)
 573         AC_MSG_RESULT($disable_pkg_ldflags)
 574         test "$disable_pkg_ldflags" = yes && EXTRA_PKG_LDFLAGS=
 575 fi
 576 AC_SUBST(EXTRA_PKG_LDFLAGS)
 577
 578 ###############################################################################
 579 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 580
 581 ###     use option --with-extra-suffix to append suffix to headers and libraries
 582 AC_MSG_CHECKING(if you wish to append extra suffix to header/library paths)
 583 EXTRA_SUFFIX=
 584 AC_ARG_WITH(extra-suffix,
 585         [  --with-extra-suffix=X   append extra suffix to header/library paths],
 586         [case x$withval in
 587         (xno)
 588                 ;;
 589         (xyes|x)
 590                 EXTRA_SUFFIX=$cf_cv_abi_version
 591                 ;;
 592         (*)
 593                 EXTRA_SUFFIX=$withval
 594                 ;;
 595         esac
 596         ])
 597 AC_MSG_RESULT($EXTRA_SUFFIX)
 598 AC_SUBST(EXTRA_SUFFIX)
 599
 600 ###     use option --disable-overwrite to leave out the link to -lcurses
 601 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 602 AC_ARG_ENABLE(overwrite,
 603         [  --disable-overwrite     put headers in subdir, omit link to -lcurses],
 604         [with_overwrite=$enableval],
 605         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 606 AC_MSG_RESULT($with_overwrite)
 607
 608 AC_MSG_CHECKING(if external terminfo-database is used)
 609 AC_ARG_ENABLE(database,
 610         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 611         [use_database=$enableval],
 612         [use_database=yes])
 613 AC_MSG_RESULT($use_database)
 614
 615 case "$host_os" in
 616 (os2*)
 617         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 618         ;;
 619 (*)
 620         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 621         ;;
 622 esac
 623 AC_SUBST(TERMINFO_SRC)
 624
 625 NCURSES_USE_DATABASE=0
 626 if test "$use_database" != no ; then
 627         NCURSES_USE_DATABASE=1
 628
 629         AC_MSG_CHECKING(which terminfo source-file will be installed)
 630         AC_ARG_WITH(database,
 631                 [  --with-database=XXX     specify terminfo source to install],
 632                 [TERMINFO_SRC=$withval])
 633         AC_MSG_RESULT($TERMINFO_SRC)
 634
 635         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 636         AC_ARG_WITH(hashed-db,
 637                 [  --with-hashed-db        specify hashed-database library],,
 638                 [with_hashed_db=no])
 639         AC_MSG_RESULT($with_hashed_db)
 640 else
 641         with_hashed_db=no
 642 fi
 643 AC_SUBST(NCURSES_USE_DATABASE)
 644
 645 AC_MSG_CHECKING(for list of fallback descriptions)
 646 AC_ARG_WITH(fallbacks,
 647         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 648         [with_fallback=$withval],
 649         [with_fallback=])
 650 AC_MSG_RESULT($with_fallback)
 651
 652 case ".$with_fallback" in
 653 (.|.no)
 654         FALLBACK_LIST=
 655         ;;
 656 (.yes)
 657         AC_MSG_WARN(expected a list of terminal descriptions)
 658         ;;
 659 (*)
 660         FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
 661         ;;
 662 esac
 663
 664 # The fallback feature in ncurses relies upon tic/infocmp outside the build
 665 # tree for generating the terminal descriptions that will be compiled into the
 666 # library.  If your toolchain is old, it may not handle current terminal
 667 # databases.  Use configure-options to point to the tools which will be used,
 668 # rather than the first ones found on the $PATH.
 669 AC_CHECK_TOOL(TIC, tic)
 670 AC_CHECK_TOOL(INFOCMP, infocmp)
 671 if test -n "$FALLBACK_LIST"
 672 then
 673         CF_WITH_PATH_PROG(TIC,     tic,     [for fallbacks], $PATH:/usr/local/ncurses/bin)
 674         CF_WITH_PATH_PROG(INFOCMP, infocmp, [for fallbacks], $PATH:/usr/local/ncurses/bin)
 675         test -z "$TIC" && FALLBACK_LIST=
 676         test -z "$INFOCMP" && FALLBACK_LIST=
 677         if test -z "$FALLBACK_LIST"
 678         then
 679                 AC_MSG_WARN(ignoring fallback option because tic/infocmp are not available)
 680         fi
 681 fi
 682 AC_SUBST(TIC)
 683 AC_SUBST(INFOCMP)
 684
 685 USE_FALLBACKS=
 686 test -z "$FALLBACK_LIST" && USE_FALLBACKS="#"
 687 AC_SUBST(FALLBACK_LIST)
 688 AC_SUBST(USE_FALLBACKS)
 689
 690 AC_MSG_CHECKING(if you want modern xterm or antique)
 691 AC_ARG_WITH(xterm-new,
 692         [  --without-xterm-new     specify if xterm terminfo should be old version],
 693         [with_xterm_new=$withval],
 694         [with_xterm_new=yes])
 695 case "$with_xterm_new" in
 696 (no) with_xterm_new=xterm-old;;
 697 (*)      with_xterm_new=xterm-new;;
 698 esac
 699 AC_MSG_RESULT($with_xterm_new)
 700 WHICH_XTERM=$with_xterm_new
 701 AC_SUBST(WHICH_XTERM)
 702
 703 case $host_os in
 704 (*linux-gnu|*cygwin|*mingw32|*msys)
 705         want_xterm_kbs=DEL
 706         ;;
 707 (*)
 708         want_xterm_kbs=BS
 709         ;;
 710 esac
 711
 712 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
 713 AC_ARG_WITH(xterm-kbs,
 714         [  --with-xterm-kbs=XXX    specify if xterm backspace sends BS or DEL],
 715         [with_xterm_kbs=$withval],
 716         [with_xterm_kbs=BS])
 717 case x$with_xterm_kbs in
 718 (xyes|xno|xBS|xbs|x8)
 719         with_xterm_kbs=BS
 720         ;;
 721 (xDEL|xdel|x127)
 722         with_xterm_kbs=DEL
 723         ;;
 724 (*)
 725         with_xterm_kbs=$withval
 726         ;;
 727 esac
 728 AC_MSG_RESULT($with_xterm_kbs)
 729 XTERM_KBS=$with_xterm_kbs
 730 AC_SUBST(XTERM_KBS)
 731
 732 if test "x$with_xterm_kbs" != "x$want_xterm_kbs"
 733 then
 734         AC_MSG_WARN(expected --with-xterm-kbs=$want_xterm_kbs for $host_os)
 735 fi
 736
 737 MAKE_TERMINFO=
 738 if test "$use_database" = no ; then
 739         TERMINFO="${datadir}/terminfo"
 740         MAKE_TERMINFO="#"
 741 else
 742
 743 AC_MSG_CHECKING(for list of terminfo directories)
 744 CF_WITH_PATHLIST(terminfo-dirs,
 745         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 746         TERMINFO_DIRS,
 747         DATADIR/terminfo,
 748         ${datadir}/terminfo)
 749 AC_MSG_RESULT($TERMINFO_DIRS)
 750 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS",[Define as needed to predefine the TERMINFO_DIR searchlist])
 751
 752 case "x$TERMINFO" in
 753 x???:*)
 754         AC_MSG_WARN(ignoring non-directory/file TERMINFO value)
 755         unset TERMINFO
 756         ;;
 757 esac
 758
 759 AC_MSG_CHECKING(for default terminfo directory)
 760 CF_WITH_PATH(default-terminfo-dir,
 761         [  --with-default-terminfo-dir=DIR default terminfo directory],
 762         TERMINFO,
 763         DATADIR/terminfo,
 764         ${datadir}/terminfo)
 765 AC_MSG_RESULT($TERMINFO)
 766 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO",[Define to set the default terminal database path])
 767
 768 fi
 769
 770 AC_SUBST(TERMINFO)
 771 AC_SUBST(MAKE_TERMINFO)
 772
 773 ###     use option --disable-big-core to make tic run on small machines
 774 ###     We need 4Mb, check if we can allocate 50% more than that.
 775 AC_MSG_CHECKING(if big-core option selected)
 776 AC_ARG_ENABLE(big-core,
 777         [  --disable-big-core      assume machine has little memory],
 778         [with_big_core=$enableval],
 779         [AC_TRY_RUN([
 780 #include <stdlib.h>
 781 #include <string.h>
 782 int main() {
 783         unsigned long n = 6000000L;
 784         char *s = malloc(n);
 785         if (s != 0)
 786                 s[0] = s[n-1] = 0;
 787         ${cf_cv_main_return:-return}(s == 0);
 788 }],
 789         [with_big_core=yes],
 790         [with_big_core=no],
 791         [with_big_core=no])])
 792 AC_MSG_RESULT($with_big_core)
 793 test "x$with_big_core" = "xyes" && AC_DEFINE(HAVE_BIG_CORE,1,[Define to 1 if machine has ample memory for tic])
 794
 795 ### ISO C only guarantees 512-char strings, we have tables which load faster
 796 ### when constructed using "big" strings.  More than the C compiler, the awk
 797 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 798 AC_MSG_CHECKING(if big-strings option selected)
 799 AC_ARG_ENABLE(big-strings,
 800         [  --disable-big-strings   assume compiler has only standard-size strings],
 801         [with_big_strings=$enableval],
 802         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 803 AC_MSG_RESULT($with_big_strings)
 804
 805 USE_BIG_STRINGS=0
 806 test "x$with_big_strings" = "xyes" && USE_BIG_STRINGS=1
 807 AC_SUBST(USE_BIG_STRINGS)
 808
 809 ###     use option --enable-termcap to compile in the termcap fallback support
 810 AC_MSG_CHECKING(if you want termcap-fallback support)
 811 AC_ARG_ENABLE(termcap,
 812         [  --enable-termcap        compile in termcap fallback support],
 813         [with_termcap=$enableval],
 814         [with_termcap=no])
 815 AC_MSG_RESULT($with_termcap)
 816
 817 NCURSES_USE_TERMCAP=0
 818 if test "x$with_termcap" != "xyes" ; then
 819         if test "$use_database" = no ; then
 820                 if test -z "$with_fallback" ; then
 821                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 822                 fi
 823         fi
 824         AC_DEFINE(PURE_TERMINFO,1,[Define to 1 if we should support only terminfo])
 825 else
 826
 827         if test "$with_ticlib" != no ; then
 828                 AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 829         fi
 830
 831         NCURSES_USE_TERMCAP=1
 832         AC_MSG_CHECKING(for list of termcap files)
 833         CF_WITH_PATHLIST(termpath,
 834                 [  --with-termpath=XXX     specify list of termcap files],
 835                 TERMPATH,
 836                 /etc/termcap:/usr/share/misc/termcap)
 837         AC_MSG_RESULT($TERMPATH)
 838         test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH",[Define to set the termcap searchlist])
 839
 840         ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 841         AC_MSG_CHECKING(if fast termcap-loader is needed)
 842         AC_ARG_ENABLE(getcap,
 843                 [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 844                 [with_getcap=$enableval],
 845                 [with_getcap=no])
 846         AC_MSG_RESULT($with_getcap)
 847         test "x$with_getcap" = "xyes" && AC_DEFINE(USE_GETCAP,1,[Define to 1 to use fast termcap-loader])
 848
 849         AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 850         AC_ARG_ENABLE(getcap-cache,
 851                 [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 852                 [with_getcap_cache=$enableval],
 853                 [with_getcap_cache=no])
 854         AC_MSG_RESULT($with_getcap_cache)
 855         test "x$with_getcap_cache" = "xyes" && AC_DEFINE(USE_GETCAP_CACHE,1,[Define to 1 if translated termcap should be stored in $HOME/.terminfo])
 856
 857 fi
 858 AC_SUBST(NCURSES_USE_TERMCAP)
 859
 860 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 861 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 862 AC_ARG_ENABLE(home-terminfo,
 863         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 864         [with_home_terminfo=$enableval],
 865         [with_home_terminfo=yes])
 866 AC_MSG_RESULT($with_home_terminfo)
 867 test "x$with_home_terminfo" = "xyes" && AC_DEFINE(USE_HOME_TERMINFO,1,[Define to 1 if $HOME/.terminfo feature is wanted])
 868
 869 AC_MSG_CHECKING(if you want to permit root to use ncurses environment variables)
 870 AC_ARG_ENABLE(root-environ,
 871         [  --disable-root-environ  restrict root use of ncurses environment variables],
 872         [with_root_environ=$enableval],
 873         [with_root_environ=yes])
 874 AC_MSG_RESULT($with_root_environ)
 875 test "x$with_root_environ" = xyes && AC_DEFINE(USE_ROOT_ENVIRON,1,[Define to 1 if root is allowed to use ncurses environment])
 876
 877 AC_MSG_CHECKING(if you want to permit setuid programs to access all files)
 878 AC_ARG_ENABLE(root-access,
 879         [  --disable-root-access   restrict file-access when running setuid],
 880         [with_root_access=$enableval],
 881         [with_root_access=yes])
 882 AC_MSG_RESULT($with_root_access)
 883 test "x$with_root_access" = xyes && AC_DEFINE(USE_ROOT_ACCESS,1,[Define to 1 if setuid is allowed all file-access])
 884
 885 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 886 ###   to reduce storage requirements for the terminfo database.
 887 CF_LINK_FUNCS
 888
 889 with_links=no
 890 with_symlinks=no
 891
 892 # soft links (symbolic links) are useful for some systems where hard links do
 893 # not work, or to make it simpler to copy terminfo trees around.
 894 if test "x$ac_cv_func_symlink" = xyes ; then
 895         AC_MSG_CHECKING(if tic should use symbolic links)
 896         AC_ARG_ENABLE(symlinks,
 897         [  --enable-symlinks       make tic use symbolic links not hard links],
 898         [with_symlinks=$enableval],
 899         [with_symlinks=no])
 900         AC_MSG_RESULT($with_symlinks)
 901 fi
 902
 903 # If we have hard links and did not choose to use soft links instead, there is
 904 # no reason to make this choice optional - use the hard links.
 905 if test "$with_symlinks" = no ; then
 906         AC_MSG_CHECKING(if tic should use hard links)
 907         if test "x$ac_cv_func_link" = xyes ; then
 908                 with_links=yes
 909         else
 910                 with_links=no
 911         fi
 912         AC_MSG_RESULT($with_links)
 913 fi
 914
 915 test "x$with_links" = xyes && AC_DEFINE(USE_LINKS,1,[Define to 1 if hardlinks should be used in terminfo database])
 916 test "x$with_symlinks" = xyes && AC_DEFINE(USE_SYMLINKS,1,[Define to 1 if symbolic links should be used in terminfo database])
 917
 918 ###   use option --enable-broken-linker to force on use of broken-linker support
 919 CF_ENABLE_BROKEN_LINKER
 920
 921 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 922 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 923 AC_ARG_ENABLE(bsdpad,
 924         [  --enable-bsdpad         recognize BSD-style prefix padding],
 925         [with_bsdpad=$enableval],
 926         [with_bsdpad=no])
 927 AC_MSG_RESULT($with_bsdpad)
 928 test "x$with_bsdpad" = xyes && AC_DEFINE(BSD_TPUTS,1,[Define to 1 to recognize BSD-style prefix padding])
 929
 930 ###   use option --enable-widec to turn on use of wide-character support
 931 NCURSES_CH_T=chtype
 932 NCURSES_LIBUTF8=0
 933
 934 NEED_WCHAR_H=0
 935 NCURSES_MBSTATE_T=0
 936 NCURSES_WCHAR_T=0
 937 NCURSES_WINT_T=0
 938
 939 # Check to define _XOPEN_SOURCE "automatically"
 940 CPPFLAGS_before_XOPEN="$CPPFLAGS"
 941 CF_XOPEN_SOURCE(600)
 942 CPPFLAGS_after_XOPEN="$CPPFLAGS"
 943
 944 # Work around breakage on OS X
 945 CF_SIGWINCH
 946
 947 # Checks for CODESET support.
 948 AM_LANGINFO_CODESET
 949
 950 # use these variables to work around a defect in gcc's fixincludes.
 951 NCURSES_OK_WCHAR_T=
 952 NCURSES_OK_WINT_T=
 953
 954 AC_MSG_CHECKING(if you want wide-character code)
 955 AC_ARG_ENABLE(widec,
 956         [  --enable-widec          compile with wide-char/UTF-8 code],
 957         [with_widec=$enableval],
 958         [with_widec=no])
 959 AC_MSG_RESULT($with_widec)
 960
 961 NCURSES_WCWIDTH_GRAPHICS=1
 962 AC_SUBST(NCURSES_WCWIDTH_GRAPHICS)
 963
 964 if test "x$with_widec" = xyes ; then
 965         if test "x$disable_lib_suffixes" = xno ; then
 966                 LIB_SUFFIX="w${LIB_SUFFIX}"
 967         fi
 968         AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to compile with wide-char/UTF-8 code])
 969         AC_DEFINE(NCURSES_WIDECHAR,1,[Define to 1 to compile with wide-char/UTF-8 code])
 970         case "$CPPFLAGS" in
 971         (*_XOPEN_SOURCE=*)
 972                 ;;
 973         (*)
 974                 AC_MSG_WARN(_XOPEN_SOURCE feature test macro appears to be predefined)
 975                 # CPPFLAGS="$CPPFLAGS -DNCURSES_WIDECHAR"
 976                 CPPFLAGS_after_XOPEN="$CPPFLAGS_after_XOPEN -DNCURSES_WIDECHAR"
 977                 ;;
 978         esac
 979
 980         CF_CHECK_WCHAR_H
 981         CF_CHECK_WCWIDTH_GRAPHICS
 982         test "$cf_cv_wcwidth_graphics" = no && NCURSES_WCWIDTH_GRAPHICS=0
 983
 984         # with_overwrite=no
 985         NCURSES_CH_T=cchar_t
 986         AC_CHECK_FUNCS(putwc btowc wctob wmemchr mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 987         if test "x$ac_cv_func_putwc" != xyes ; then
 988                 CF_UTF8_LIB
 989                 if test "$cf_cv_utf8_lib" != no ; then
 990                         NCURSES_LIBUTF8=1
 991                 fi
 992         fi
 993         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 994         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 995         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 996
 997         if test "$NCURSES_MBSTATE_T" != 0; then
 998                 AC_DEFINE(NEED_MBSTATE_T_DEF,1,[Define to 1 if we must declare mbstate_t])
 999         fi
1000 fi
1001 AC_SUBST(NCURSES_CH_T)
1002 AC_SUBST(NCURSES_LIBUTF8)
1003
1004 AC_SUBST(NEED_WCHAR_H)
1005 AC_SUBST(NCURSES_MBSTATE_T)
1006 AC_SUBST(NCURSES_WCHAR_T)
1007 AC_SUBST(NCURSES_WINT_T)
1008
1009 AC_SUBST(NCURSES_OK_WCHAR_T)
1010 AC_SUBST(NCURSES_OK_WINT_T)
1011
1012 ###   use option --disable-lp64 to allow long chtype
1013 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
1014 AC_ARG_ENABLE(lp64,
1015         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
1016         [with_lp64=$enableval],
1017         [with_lp64=$cf_dft_with_lp64])
1018 AC_MSG_RESULT($with_lp64)
1019
1020 if test "x$with_lp64" = xyes ; then
1021         cf_cv_enable_lp64=1
1022 else
1023         cf_cv_enable_lp64=0
1024 fi
1025 AC_SUBST(cf_cv_enable_lp64)
1026
1027 CF_LARGEFILE
1028
1029 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
1030 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
1031 AC_ARG_ENABLE(tparm-varargs,
1032         [  --disable-tparm-varargs compile tparm() without varargs interface],
1033         [with_tparm_varargs=$enableval],
1034         [with_tparm_varargs=yes])
1035 AC_MSG_RESULT($with_tparm_varargs)
1036 NCURSES_TPARM_VARARGS=0
1037 test "x$with_tparm_varargs" = xyes && NCURSES_TPARM_VARARGS=1
1038 AC_SUBST(NCURSES_TPARM_VARARGS)
1039
1040 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
1041 if test "$with_ticlib" != no ; then
1042 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
1043 AC_ARG_ENABLE(tic-depends,
1044         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
1045         [with_tic_depends=$enableval],
1046         [with_tic_depends=yes])
1047 AC_MSG_RESULT($with_tic_depends)
1048 else
1049         with_tic_depends=no
1050 fi
1051
1052 ###   use option --enable-wattr-macros to enable wattr* macros in curses.h
1053 AC_MSG_CHECKING(if you want to enable wattr* macros)
1054 AC_ARG_ENABLE(wattr-macros,
1055         [  --enable-wattr-macros   enable wattr* macros],
1056         [with_wattr_macros=$enableval],
1057         [with_wattr_macros=no])
1058 if [[ "x$with_wattr_macros" != xyes ]]; then
1059         NCURSES_WATTR_MACROS=0
1060         AC_MSG_RESULT(no)
1061 else
1062         NCURSES_WATTR_MACROS=1
1063         AC_MSG_RESULT(yes)
1064 fi
1065 AC_SUBST(NCURSES_WATTR_MACROS)
1066
1067 CF_WITH_X11_RGB
1068
1069 ###   use option --with-bool to override bool's type
1070 AC_MSG_CHECKING(for type of bool)
1071 AC_ARG_WITH(bool,
1072         [  --with-bool=TYPE        override fallback type of bool variable],
1073         [NCURSES_BOOL="$withval"],
1074         [NCURSES_BOOL=auto])
1075 AC_MSG_RESULT($NCURSES_BOOL)
1076 AC_SUBST(NCURSES_BOOL)
1077
1078 AC_MSG_CHECKING(for alternate terminal capabilities file)
1079 AC_ARG_WITH(caps,
1080         [  --with-caps=alt         compile with alternate Caps file],
1081         [TERMINFO_CAPS=Caps.$withval],
1082         [TERMINFO_CAPS=Caps])
1083 if test ! -f "${srcdir}/include/${TERMINFO_CAPS}"
1084 then
1085         AC_MSG_WARN(file not found: "${srcdir}/include/${TERMINFO_CAPS}")
1086         TERMINFO_CAPS=Caps
1087 fi
1088 AC_MSG_RESULT($TERMINFO_CAPS)
1089 AC_SUBST(TERMINFO_CAPS)
1090
1091 ###   use option --with-chtype to override chtype's type
1092 AC_MSG_CHECKING(for type of chtype)
1093 AC_ARG_WITH(chtype,
1094         [  --with-chtype=TYPE      override type of chtype],
1095         [NCURSES_CHTYPE="$withval"],
1096         [NCURSES_CHTYPE=$cf_dft_chtype])
1097 AC_MSG_RESULT($NCURSES_CHTYPE)
1098
1099 ###   use option --with-ospeed to override ospeed's type
1100 AC_MSG_CHECKING(for type of ospeed)
1101 AC_ARG_WITH(ospeed,
1102         [  --with-ospeed=TYPE      override type of ospeed variable],
1103         [NCURSES_OSPEED="$withval"],
1104         [NCURSES_OSPEED=short])
1105 AC_MSG_RESULT($NCURSES_OSPEED)
1106 AC_SUBST(NCURSES_OSPEED)
1107
1108 ###   use option --with-mmask-t to override mmask_t's type
1109 AC_MSG_CHECKING(for type of mmask_t)
1110 AC_ARG_WITH(mmask-t,
1111         [  --with-mmask-t=TYPE     override type of mmask_t],
1112         [NCURSES_MMASK_T="$withval"],
1113         [NCURSES_MMASK_T=$cf_dft_mmask_t])
1114 AC_MSG_RESULT($NCURSES_MMASK_T)
1115
1116 ###   use option --with-ccharw-max to override CCHARW_MAX size
1117 AC_MSG_CHECKING(for size CCHARW_MAX)
1118 AC_ARG_WITH(ccharw-max,
1119         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
1120         [NCURSES_CCHARW_MAX="$withval"],
1121         [NCURSES_CCHARW_MAX=$cf_dft_ccharw_max])
1122 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
1123 AC_SUBST(NCURSES_CCHARW_MAX)
1124
1125 AC_CHECK_SIZEOF([signed char])
1126 if test "$ac_cv_sizeof_signed_char" = 1 ; then
1127         NCURSES_SBOOL="signed char"
1128 else
1129         NCURSES_SBOOL="char"
1130 fi
1131 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
1132 AC_ARG_ENABLE(signed-char,
1133         [  --enable-signed-char    compile using signed Boolean's in term.h],
1134         [with_signed_char=$enableval],
1135         [with_signed_char=$cf_dft_signed_char])
1136 AC_MSG_RESULT($with_signed_char)
1137 test "x$with_signed_char" != xyes && NCURSES_SBOOL="char"
1138 AC_SUBST(NCURSES_SBOOL)
1139
1140 ###   use option --with-tparm-arg to override tparm's argument type
1141 AC_MSG_CHECKING(for type of tparm args)
1142 AC_ARG_WITH(tparm-arg,
1143         [  --with-tparm-arg=TYPE   override parameter type of tparm],
1144         [NCURSES_TPARM_ARG="$withval"],
1145         [NCURSES_TPARM_ARG=$cf_dft_tparm_arg])
1146 AC_MSG_RESULT($NCURSES_TPARM_ARG)
1147 AC_SUBST(NCURSES_TPARM_ARG)
1148
1149 ### Enable compiling-in rcs id's
1150 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
1151 AC_ARG_WITH(rcs-ids,
1152         [  --with-rcs-ids          compile-in RCS identifiers],
1153         [with_rcs_ids=$withval],
1154         [with_rcs_ids=no])
1155 AC_MSG_RESULT($with_rcs_ids)
1156 test "x$with_rcs_ids" = xyes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 to compile-in RCS identifiers])
1157
1158 ###############################################################################
1159 CF_MAN_PAGES([ captoinfo clear infocmp infotocap reset tabs tic toe tput tset ])
1160
1161 ###############################################################################
1162 CF_HELP_MESSAGE(Extensions:)
1163
1164 ### Note that some functions (such as const) are normally disabled anyway.
1165 AC_MSG_CHECKING(if you want to build with function extensions)
1166 AC_ARG_ENABLE(ext-funcs,
1167         [  --disable-ext-funcs     disable function-extensions],
1168         [with_ext_funcs=$enableval],
1169         [with_ext_funcs=yes])
1170 AC_MSG_RESULT($with_ext_funcs)
1171 if test "x$with_ext_funcs" = xyes ; then
1172         NCURSES_EXT_FUNCS=1
1173         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 to enable ncurses extended functions])
1174         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS,1,[Define to 1 to enable assume_default_colors() function in test-programs])
1175         AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 to enable curses_version() function in test-programs])
1176         AC_DEFINE(HAVE_HAS_KEY,1,[Define to 1 to enable has_key() function in test-programs])
1177         AC_DEFINE(HAVE_RESIZETERM,1,[Define to 1 to enable resizeterm() function in test-programs])
1178         AC_DEFINE(HAVE_RESIZE_TERM,1,[Define to 1 to enable resize_term() function in test-programs])
1179         AC_DEFINE(HAVE_TERM_ENTRY_H,1,[Define to 1 to enable term_entry() function in test-programs])
1180         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 to enable use_default_colors() function in test-programs])
1181         AC_DEFINE(HAVE_USE_EXTENDED_NAMES,1,[Define to 1 to enable use_extended_names() function in test-programs])
1182         AC_DEFINE(HAVE_USE_SCREEN,1,[Define to 1 to enable use_screen() function in test-programs])
1183         AC_DEFINE(HAVE_USE_WINDOW,1,[Define to 1 to enable use_window() function in test-programs])
1184         AC_DEFINE(HAVE_WRESIZE,1,[Define to 1 to enable wresize() function in test-programs])
1185         GENERATED_EXT_FUNCS=generated
1186         test "x$with_ext_funcs" = xyes || cf_dft_ext_spfuncs=no
1187 else
1188         NCURSES_EXT_FUNCS=0
1189         GENERATED_EXT_FUNCS=
1190 fi
1191 AC_SUBST(NCURSES_EXT_FUNCS)
1192 AC_SUBST(GENERATED_EXT_FUNCS)
1193
1194 AC_MSG_CHECKING(if you want to build with SCREEN extensions)
1195 AC_ARG_ENABLE(sp-funcs,
1196         [  --enable-sp-funcs       enable SCREEN-extensions],
1197         [with_sp_funcs=$enableval],
1198         [with_sp_funcs=$cf_dft_ext_spfuncs])
1199 AC_MSG_RESULT($with_sp_funcs)
1200 if test "x$with_sp_funcs" = xyes ; then
1201         NCURSES_SP_FUNCS=1
1202         AC_DEFINE(NCURSES_SP_FUNCS,1,[Define to 1 to enable SCREEN-extensions])
1203         AC_DEFINE(HAVE_TPUTS_SP,1,[Define to 1 to enable tputs_sp() function in test-programs])
1204         GENERATED_SP_FUNCS=generated
1205 else
1206         NCURSES_SP_FUNCS=0
1207         GENERATED_SP_FUNCS=
1208 fi
1209 AC_SUBST(NCURSES_SP_FUNCS)
1210 AC_SUBST(GENERATED_SP_FUNCS)
1211
1212 AC_MSG_CHECKING(if you want to build with terminal-driver)
1213 AC_ARG_ENABLE(term-driver,
1214         [  --enable-term-driver    enable terminal-driver],
1215         [with_term_driver=$enableval],
1216         [with_term_driver=no])
1217 AC_MSG_RESULT($with_term_driver)
1218 if test "x$with_term_driver" = xyes ; then
1219         AC_DEFINE(USE_TERM_DRIVER,1,[Define to 1 to enable terminal-driver])
1220         if test "x$with_termlib" != xno ; then
1221                 AC_MSG_ERROR(The term-driver option conflicts with the termlib option)
1222         fi
1223         if test "x$with_sp_funcs" != xyes ; then
1224                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
1225         fi
1226 fi
1227
1228 ###   use option --enable-const to turn on use of const beyond that in XSI.
1229 AC_MSG_CHECKING(for extended use of const keyword)
1230 AC_ARG_ENABLE(const,
1231         [  --enable-const          compile with extra/non-standard const],
1232         [with_ext_const=$enableval],
1233         [with_ext_const=$cf_dft_ext_const])
1234 AC_MSG_RESULT($with_ext_const)
1235 NCURSES_CONST='/*nothing*/'
1236 if test "x$with_ext_const" = xyes ; then
1237         NCURSES_CONST=const
1238 fi
1239 AC_SUBST(NCURSES_CONST)
1240
1241 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
1242 AC_MSG_CHECKING(if you want to use extended colors)
1243 AC_ARG_ENABLE(ext-colors,
1244         [  --enable-ext-colors     compile for 256-color support],
1245         [with_ext_colors=$enableval],
1246         [with_ext_colors=$cf_dft_ext_colors])
1247 AC_MSG_RESULT($with_ext_colors)
1248 NCURSES_EXT_COLORS=0
1249 if test "x$with_ext_colors" = xyes ; then
1250         if test "x$with_widec" != xyes ; then
1251                 AC_MSG_WARN(This option applies only to wide-character library)
1252         else
1253                 # cannot be ABI 5 since it changes sizeof(cchar_t)
1254                 CF_NCURSES_ABI_6
1255                 NCURSES_EXT_COLORS=1
1256                 AC_DEFINE(NCURSES_EXT_COLORS,1,[Define to 1 to compile for 256-color support])
1257                 AC_DEFINE(HAVE_ALLOC_PAIR,1,[Define to 1 to enable alloc_pair() function])
1258                 AC_DEFINE(HAVE_INIT_EXTENDED_COLOR,1,[Define to 1 to enable init_extended_color() function in test-programs])
1259                 AC_DEFINE(HAVE_RESET_COLOR_PAIRS,1,[Define to 1 to enable reset_color_pairs() function in test-programs])
1260         fi
1261 fi
1262 AC_SUBST(NCURSES_EXT_COLORS)
1263
1264 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
1265 AC_MSG_CHECKING(if you want to use extended mouse encoding)
1266 AC_ARG_ENABLE(ext-mouse,
1267         [  --enable-ext-mouse      compile for extended mouse-encoding],
1268         [with_ext_mouse=$enableval],
1269         [with_ext_mouse=$cf_dft_ext_mouse])
1270 AC_MSG_RESULT($with_ext_mouse)
1271 if test "x$with_ext_mouse" = xyes ; then
1272         CF_NCURSES_ABI_6
1273 fi
1274
1275 case $cf_cv_abi_default in
1276 (5)
1277         NCURSES_MOUSE_VERSION=1
1278         ;;
1279 (6)
1280         NCURSES_MOUSE_VERSION=2
1281         ;;
1282 ([[789]])
1283         NCURSES_MOUSE_VERSION=3
1284         ;;
1285 esac
1286
1287 AC_SUBST(NCURSES_MOUSE_VERSION)
1288
1289 ###   use option --enable-ext-putwin to turn on extended screendumps
1290 AC_MSG_CHECKING(if you want to use extended putwin/screendump)
1291 AC_ARG_ENABLE(ext-putwin,
1292         [  --enable-ext-putwin     compile with extended putwin/screendump],
1293         [with_ext_putwin=$enableval],
1294         [with_ext_putwin=$cf_dft_ext_putwin])
1295 AC_MSG_RESULT($with_ext_putwin)
1296 if test "x$with_ext_putwin" = xyes ; then
1297         AC_DEFINE(NCURSES_EXT_PUTWIN,1,[Define to 1 to compile with extended putwin/screendump])
1298 fi
1299
1300 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
1301 AC_ARG_ENABLE(no-padding,
1302         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
1303         [with_no_padding=$enableval],
1304         [with_no_padding=$with_ext_funcs])
1305 AC_MSG_RESULT($with_no_padding)
1306 test "x$with_no_padding" = xyes && AC_DEFINE(NCURSES_NO_PADDING,1,[Define to 1 to compile with $NCURSES_NO_PADDING code])
1307
1308 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1309 AC_MSG_CHECKING(if you want SIGWINCH handler)
1310 AC_ARG_ENABLE(sigwinch,
1311         [  --enable-sigwinch       compile with SIGWINCH handler],
1312         [with_sigwinch=$enableval],
1313         [with_sigwinch=$with_ext_funcs])
1314 AC_MSG_RESULT($with_sigwinch)
1315 test "x$with_sigwinch" = xyes && AC_DEFINE(USE_SIGWINCH,1,[Define to 1 to compile with SIGWINCH handler])
1316
1317 ###   use option --enable-tcap-names to allow user to define new capabilities
1318 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1319 AC_ARG_ENABLE(tcap-names,
1320         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1321         [with_tcap_names=$enableval],
1322         [with_tcap_names=$with_ext_funcs])
1323 AC_MSG_RESULT($with_tcap_names)
1324 NCURSES_XNAMES=0
1325 test "x$with_tcap_names" = xyes && NCURSES_XNAMES=1
1326 AC_SUBST(NCURSES_XNAMES)
1327
1328 ##############################################################################
1329 CF_HELP_MESSAGE(Reentrant Code:)
1330 CF_WITH_PTHREAD
1331
1332 if test "x$with_pthread" != xno; then
1333         AC_CHECK_FUNC(pthread_kill,[
1334                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1335                 AC_ARG_ENABLE(pthreads-eintr,
1336                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1337                         [use_pthreads_eintr=$enableval],
1338                         [use_pthreads_eintr=no])
1339                 AC_MSG_RESULT($use_pthreads_eintr)
1340                 if test "x$use_pthreads_eintr" = xyes ; then
1341                         AC_DEFINE(USE_PTHREADS_EINTR,1,[Define to 1 to enable EINTR in wgetch with pthreads])
1342                 fi])
1343
1344         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1345         AC_ARG_ENABLE(weak-symbols,
1346                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1347                 [use_weak_symbols=$enableval],
1348                 [use_weak_symbols=no])
1349         AC_MSG_RESULT($use_weak_symbols)
1350         if test "x$use_weak_symbols" = xyes ; then
1351                 CF_WEAK_SYMBOLS
1352         else
1353                 cf_cv_weak_symbols=no
1354         fi
1355
1356         if test "x$cf_cv_weak_symbols" = xyes ; then
1357                 AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
1358         fi
1359 fi
1360
1361 PTHREAD=
1362 if test "x$with_pthread" = "xyes" ; then
1363         AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use pthreads feature])
1364         enable_reentrant=yes
1365         if test "x$cf_cv_weak_symbols" = xyes ; then
1366                 PTHREAD=-lpthread
1367                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1368         fi
1369 fi
1370 AC_SUBST(PTHREAD)
1371
1372 # Reentrant code has to be opaque; there's little advantage to making ncurses
1373 # opaque outside of that, so there is no --enable-opaque option.  We can use
1374 # this option without --with-pthreads, but this will be always set for
1375 # pthreads.
1376 AC_MSG_CHECKING(if you want reentrant code)
1377 AC_ARG_ENABLE(reentrant,
1378         [  --enable-reentrant      compile with reentrant code],
1379         [with_reentrant=$enableval],
1380         [with_reentrant=no])
1381 AC_MSG_RESULT($with_reentrant)
1382 if test "x$with_reentrant" = xyes ; then
1383         cf_cv_enable_reentrant=1
1384         cf_cv_enable_opaque="NCURSES_INTERNALS"
1385         NCURSES_SIZE_T=int
1386         if test "x$cf_cv_weak_symbols" = xyes ; then
1387                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1388                 CF_ADD_LIB(pthread,TEST_LIBS)
1389                 CF_ADD_LIB(pthread,TEST_LIBS2)
1390                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1391         else
1392                 # when not using weak symbols but with_reentrant,
1393                 # add 't' to the library suffix on all platforms
1394                 # except cygwin, where we only do that if ALSO
1395                 # compiling with full thread support.
1396                 case "$host" in
1397                 (*cygwin* | *msys*)
1398                         if test "$with_pthread" = "yes" ; then
1399                                 if test "x$disable_lib_suffixes" = "xno" ; then
1400                                         LIB_SUFFIX="t${LIB_SUFFIX}"
1401                                 fi
1402                         fi ;;
1403                 (*)
1404                         if test "x$disable_lib_suffixes" = "xno" ; then
1405                                 LIB_SUFFIX="t${LIB_SUFFIX}"
1406                         fi
1407                         ;;
1408                 esac
1409         fi
1410         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to use reentrant feature])
1411         CF_NCURSES_ABI_6
1412 else
1413         cf_cv_enable_reentrant=0
1414         cf_cv_enable_opaque="NCURSES_OPAQUE"
1415         NCURSES_SIZE_T=$cf_dft_ordinate_type
1416 fi
1417 AC_SUBST(cf_cv_enable_reentrant)
1418 AC_SUBST(cf_cv_enable_opaque)
1419
1420 AC_SUBST(NCURSES_SIZE_T)
1421
1422 AC_MSG_CHECKING(if you want opaque curses-library structures)
1423 CF_ARG_ENABLE(opaque-curses,
1424         [  --enable-opaque-curses  make curses WINDOW, etc., "opaque"],
1425         [enable_opaque_curses=yes],[
1426          test "$cf_cv_enable_reentrant" = 1 && enable_opaque_curses=yes
1427          test "$cf_cv_enable_reentrant" = 1 || enable_opaque_curses=$cf_dft_opaque_curses
1428         ])
1429 AC_MSG_RESULT($enable_opaque_curses)
1430
1431 test "$cf_cv_enable_reentrant" = 1 && \
1432 test "$enable_opaque_curses" = no && \
1433 AC_MSG_ERROR(reentrant configuration requires opaque library)
1434
1435 AC_MSG_CHECKING(if you want opaque form-library structures)
1436 AC_ARG_ENABLE(opaque-form,
1437         [  --enable-opaque-form    make form-library structures "opaque"],
1438         [enable_opaque_form=yes],[enable_opaque_form=no])
1439 AC_MSG_RESULT($enable_opaque_form)
1440
1441 AC_MSG_CHECKING(if you want opaque menu-library structures)
1442 AC_ARG_ENABLE(opaque-menu,
1443         [  --enable-opaque-menu    make menu-library structures "opaque"],
1444         [enable_opaque_menu=yes],[enable_opaque_menu=no])
1445 AC_MSG_RESULT($enable_opaque_menu)
1446
1447 AC_MSG_CHECKING(if you want opaque panel-library structures)
1448 AC_ARG_ENABLE(opaque-panel,
1449         [  --enable-opaque-panel   make panel-library structures "opaque"],
1450         [enable_opaque_panel=yes],[enable_opaque_panel=no])
1451 AC_MSG_RESULT($enable_opaque_panel)
1452
1453 NCURSES_OPAQUE=0;               test "$enable_opaque_curses" = yes && NCURSES_OPAQUE=1
1454 NCURSES_OPAQUE_FORM=0;  test "$enable_opaque_form"   = yes && NCURSES_OPAQUE_FORM=1
1455 NCURSES_OPAQUE_MENU=0;  test "$enable_opaque_menu"   = yes && NCURSES_OPAQUE_MENU=1
1456 NCURSES_OPAQUE_PANEL=0; test "$enable_opaque_panel"  = yes && NCURSES_OPAQUE_PANEL=1
1457
1458 AC_SUBST(NCURSES_OPAQUE)
1459 AC_SUBST(NCURSES_OPAQUE_FORM)
1460 AC_SUBST(NCURSES_OPAQUE_MENU)
1461 AC_SUBST(NCURSES_OPAQUE_PANEL)
1462
1463 ### Allow using a different wrap-prefix
1464 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1465         AC_MSG_CHECKING(for prefix used to wrap public variables)
1466         AC_ARG_WITH(wrap-prefix,
1467                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1468                 [NCURSES_WRAP_PREFIX=$withval],
1469                 [NCURSES_WRAP_PREFIX=_nc_])
1470         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1471 else
1472         NCURSES_WRAP_PREFIX=_nc_
1473 fi
1474 AC_SUBST(NCURSES_WRAP_PREFIX)
1475 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ prefix])
1476
1477 ###############################################################################
1478 # These options are relatively safe to experiment with.
1479 CF_HELP_MESSAGE(Development Code:)
1480 AC_MSG_CHECKING(if you want all development code)
1481 AC_ARG_WITH(develop,
1482         [  --without-develop       disable development options],
1483         [with_develop=$withval],
1484         [with_develop=no])
1485 AC_MSG_RESULT($with_develop)
1486
1487 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1488 AC_MSG_CHECKING(if you want hard-tabs code)
1489 AC_ARG_ENABLE(hard-tabs,
1490         [  --enable-hard-tabs      compile with hard-tabs code],,
1491         [enable_hard_tabs=$with_develop])
1492 AC_MSG_RESULT($enable_hard_tabs)
1493 test "x$enable_hard_tabs" = xyes && AC_DEFINE(USE_HARD_TABS,1,[Define to 1 to compile with hard-tabs code])
1494
1495 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1496 AC_MSG_CHECKING(if you want limited support for xmc)
1497 AC_ARG_ENABLE(xmc-glitch,
1498         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1499         [enable_xmc_glitch=$with_develop])
1500 AC_MSG_RESULT($enable_xmc_glitch)
1501 test "x$enable_xmc_glitch" = xyes && AC_DEFINE(USE_XMC_SUPPORT,1,[Define to 1 to compile with support for xmc (magic-cookie)])
1502
1503 ###############################################################################
1504 # These are just experimental, probably should not be in a package:
1505 CF_HELP_MESSAGE(Experimental Code:)
1506
1507 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1508 AC_ARG_ENABLE(assumed-color,
1509         [  --disable-assumed-color do not assume anything about default-colors],
1510         [with_assumed_color=$enableval],
1511         [with_assumed_color=yes])
1512 AC_MSG_RESULT($with_assumed_color)
1513 test "x$with_assumed_color" = xyes && AC_DEFINE(USE_ASSUMED_COLOR,1,[Define to 1 to assume things about default-colors])
1514
1515 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1516 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1517 AC_ARG_ENABLE(hashmap,
1518         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1519         [with_hashmap=$enableval],
1520         [with_hashmap=yes])
1521 AC_MSG_RESULT($with_hashmap)
1522 test "x$with_hashmap" = xyes && AC_DEFINE(USE_HASHMAP,1,[Define to 1 to compile with hashmap scrolling-optimization])
1523
1524 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1525 AC_MSG_CHECKING(if you want colorfgbg code)
1526 AC_ARG_ENABLE(colorfgbg,
1527         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1528         [with_colorfgbg=$enableval],
1529         [with_colorfgbg=no])
1530 AC_MSG_RESULT($with_colorfgbg)
1531 test "x$with_colorfgbg" = xyes && AC_DEFINE(USE_COLORFGBG,1,[Define to 1 to compile-in experimental $COLORFGBG code])
1532
1533 ###   use option --enable-fvisibility to turn on use of gcc-specific feature
1534 AC_MSG_CHECKING(if you want to use gcc -fvisibility option)
1535 AC_ARG_ENABLE(fvisibility,
1536         [  --enable-fvisibility    compile with -fvisibility=hidden],
1537         [cf_with_fvisibility=$enableval],
1538         [cf_with_fvisibility=no])
1539 AC_MSG_RESULT($cf_with_fvisibility)
1540
1541 NCURSES_IMPEXP=
1542 NCURSES_CXX_IMPEXP=
1543 if test "x$cf_with_fvisibility" = xyes; then
1544         CF_CHECK_FVISIBILITY($CC,CFLAGS,cf_cv_fvisibility_hidden)
1545         if test "x$cf_cv_fvisibility_hidden" = xyes
1546         then
1547                 CF_ADD_CFLAGS([-fvisibility=hidden])
1548                 NCURSES_IMPEXP="__attribute__ ((visibility(\"default\")))"
1549         fi
1550         if test -n "$CXX"
1551         then
1552                 AC_LANG_PUSH(C++)
1553                 CF_CHECK_FVISIBILITY($CXX,CXXFLAGS,cf_cv_fvisibility_hidden2)
1554                 if test "x$cf_cv_fvisibility_hidden2" = xyes
1555                 then
1556                         CF_ADD_CXXFLAGS([-fvisibility=hidden])
1557                         NCURSES_CXX_IMPEXP="__attribute__ ((visibility(\"default\")))"
1558                 fi
1559                 AC_LANG_POP
1560         fi
1561 fi
1562 AC_SUBST(NCURSES_IMPEXP)
1563 AC_SUBST(NCURSES_CXX_IMPEXP)
1564
1565 ###   use option --enable-interop to turn on use of bindings used for interop
1566 AC_MSG_CHECKING(if you want interop bindings)
1567 AC_ARG_ENABLE(interop,
1568         [  --enable-interop        compile-in interop bindings],
1569         [with_exp_interop=$enableval],
1570         [with_exp_interop=$cf_dft_interop])
1571 AC_MSG_RESULT($with_exp_interop)
1572
1573 NCURSES_INTEROP_FUNCS=0
1574 test "x$with_exp_interop" = xyes && NCURSES_INTEROP_FUNCS=1
1575 AC_SUBST(NCURSES_INTEROP_FUNCS)
1576
1577
1578 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1579 AC_ARG_ENABLE(safe-sprintf,
1580         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1581         [with_safe_sprintf=$enableval],
1582         [with_safe_sprintf=no])
1583 AC_MSG_RESULT($with_safe_sprintf)
1584
1585 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1586 # when hashmap is used scroll hints are useless
1587 if test "$with_hashmap" = no ; then
1588 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1589 AC_ARG_ENABLE(scroll-hints,
1590         [  --disable-scroll-hints  compile without scroll-hints code],
1591         [with_scroll_hints=$enableval],
1592         [with_scroll_hints=yes])
1593 AC_MSG_RESULT($with_scroll_hints)
1594 test "x$with_scroll_hints" = xyes && AC_DEFINE(USE_SCROLL_HINTS,1,[Define to 1 to compile without scroll-hints code])
1595 fi
1596
1597 AC_MSG_CHECKING(if you want wgetch-events code)
1598 AC_ARG_ENABLE(wgetch-events,
1599         [  --enable-wgetch-events  compile with wgetch-events code],
1600         [with_wgetch_events=$enableval],
1601         [with_wgetch_events=no])
1602 AC_MSG_RESULT($with_wgetch_events)
1603 if test "x$with_wgetch_events" = xyes ; then
1604         AC_DEFINE(NCURSES_WGETCH_EVENTS,1,[Define to 1 to compile with wgetch-events code])
1605         NCURSES_WGETCH_EVENTS=1
1606 else
1607         NCURSES_WGETCH_EVENTS=0
1608 fi
1609 AC_SUBST(NCURSES_WGETCH_EVENTS)
1610
1611 case "$cf_cv_system_name" in
1612 (*mingw32*|*mingw64*|*-msvc*)
1613         AC_MSG_CHECKING(if you want experimental-Windows driver)
1614         AC_ARG_ENABLE(exp-win32,
1615                 [  --enable-exp-win32      compile with experimental-Windows driver],
1616                 [with_exp_win32=$enableval],
1617                 [with_exp_win32=no])
1618         AC_MSG_RESULT($with_exp_win32)
1619         if test "x$with_exp_win32" = xyes
1620         then
1621                 AC_DEFINE(EXP_WIN32_DRIVER,1,[Define to 1 to compile with experimental win32 driver])
1622                 EXP_WIN32_DRIVER=1
1623                 INTERNALS_HDR='[$](INCDIR)/nc_win32.h'
1624         else
1625                 INTERNALS_HDR='[$](INCDIR)/nc_mingw.h'
1626                 EXP_WIN32_DRIVER=0
1627         fi
1628         ;;
1629 (*)
1630         EXP_WIN32_DRIVER=0
1631         INTERNALS_HDR=
1632         ;;
1633 esac
1634 AC_SUBST(EXP_WIN32_DRIVER)
1635 AC_SUBST(INTERNALS_HDR)
1636
1637 ###############################################################################
1638 CF_HELP_MESSAGE(Testing/development Options:)
1639
1640 ###     use option --disable-echo to suppress full display compiling commands
1641 CF_DISABLE_ECHO
1642 if test "x$enable_echo" = xyes; then
1643         ECHO_LINK=
1644 else
1645         ECHO_LINK='@ echo linking $@ ... ;'
1646         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1647         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1648 fi
1649 AC_SUBST(ECHO_LINK)
1650
1651 # --disable-stripping is used for debugging
1652 CF_INSTALL_OPTS
1653
1654 # If we're avoiding relinking of shared libraries during install, that is to
1655 # avoid modifying the build-tree.  For the same reason, avoid doing ranlib if
1656 # the install program has "-p" (for preserving timestamps).
1657 cf_cv_do_reranlib=yes
1658 if test "x$cf_cv_install_p" = xyes
1659 then
1660         if test "x$cf_cv_do_relink" != xyes
1661         then
1662                 cf_cv_do_reranlib=no
1663                 INSTALL_OPT_P="-p"
1664                 INSTALL_LIB="$INSTALL_LIB $INSTALL_OPT_P"
1665         fi
1666 fi
1667 AC_SUBST(INSTALL_OPT_P)
1668
1669 ###     use option --enable-warnings to turn on all gcc warnings
1670 CF_ENABLE_WARNINGS(Wno-unknown-pragmas Wswitch-enum,yes)
1671
1672 if test "x$enable_warnings" = "xyes"; then
1673         CF_ADD_ADAFLAGS(-gnatwa -gnatyg)
1674         if test "x$cf_with_cxx" = xyes ; then
1675                 CF_GXX_WARNINGS(Wno-unused)
1676         fi
1677 fi
1678 CF_ENABLE_STRING_HACKS
1679
1680 ###     use option --enable-assertions to turn on generation of assertion code
1681 AC_MSG_CHECKING(if you want to enable runtime assertions)
1682 AC_ARG_ENABLE(assertions,
1683         [  --enable-assertions     test: turn on generation of assertion code],
1684         [with_assertions=$enableval],
1685         [with_assertions=no])
1686 AC_MSG_RESULT($with_assertions)
1687 if test -n "$GCC"
1688 then
1689         if test "$with_assertions" = no
1690         then
1691                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1692         else
1693                 CF_ADD_ADAFLAGS(-gnata)
1694         fi
1695 fi
1696
1697 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1698 CF_DISABLE_LEAKS
1699 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
1700
1701 ###     use option --enable-expanded to generate certain macros as functions
1702 AC_ARG_ENABLE(expanded,
1703         [  --enable-expanded       test: generate functions for certain macros],
1704         [test "x$enableval" = xyes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 to generate functions for certain macros])])
1705
1706 ###     use option --disable-macros to suppress macros in favor of functions
1707 AC_ARG_ENABLE(macros,
1708         [  --disable-macros        test: use functions rather than macros],
1709         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 to use functions rather than macros])])
1710
1711 # Normally we only add trace() to the debug-library.  Allow this to be
1712 # extended to all models of the ncurses library:
1713 cf_all_traces=no
1714 case "$CFLAGS $CPPFLAGS" in
1715 (*-DTRACE*)
1716         cf_all_traces=yes
1717         ;;
1718 esac
1719
1720 AC_MSG_CHECKING(whether to add trace feature to all models)
1721 AC_ARG_WITH(trace,
1722 [  --with-trace            test: add trace() function to all models of ncurses],
1723 [cf_with_trace=$withval],
1724 [cf_with_trace=$cf_all_traces])
1725 AC_MSG_RESULT($cf_with_trace)
1726
1727 if test "x$cf_with_trace" = xyes ; then
1728         LIB_TRACING=all
1729         ADA_TRACE=TRUE
1730         CF_ADD_CFLAGS(-DTRACE)
1731         AC_DEFINE(HAVE__TRACEF,1,[Define to 1 if we have _tracef function])
1732 else
1733         LIB_TRACING=DEBUG
1734         ADA_TRACE=FALSE
1735 fi
1736
1737 AC_SUBST(ADA_TRACE)
1738
1739 CF_DISABLE_GNAT_PROJECTS
1740
1741 ###     Checks for libraries.
1742 case "$cf_cv_system_name" in
1743 (*mingw32*|*mingw64*)
1744         # Note: WINVER may be a problem with Windows 10
1745         if test "x$with_exp_win32" = xyes ; then
1746                 CPPFLAGS="$CPPFLAGS -DWINVER=0x0600 -DWIN32_LEAN_AND_MEAN"
1747         else
1748                 CPPFLAGS="$CPPFLAGS -DWINVER=0x0501 -DWIN32_LEAN_AND_MEAN"
1749         fi
1750         CF_CHECK_LIBSSP
1751         ;;
1752 (*)
1753         ;;
1754 esac
1755
1756 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
1757 AC_SUBST(MATH_LIB)
1758
1759 ###     Checks for header files.
1760 AC_HEADER_TIME
1761 CF_REGEX
1762
1763 dnl These are some other potentially nonportable headers.
1764 AC_CHECK_HEADERS( \
1765 fcntl.h \
1766 getopt.h \
1767 limits.h \
1768 locale.h \
1769 math.h \
1770 poll.h \
1771 sys/ioctl.h \
1772 sys/param.h \
1773 sys/poll.h \
1774 sys/select.h \
1775 sys/time.h \
1776 sys/times.h \
1777 unistd.h \
1778 wctype.h \
1779 )
1780
1781 CF_GETOPT_HEADER
1782
1783 CF_CHECK_ENVIRON(environ)
1784 CF_CHECK_GETENV
1785 if test "x$cf_cv_consistent_getenv" = xno && \
1786         test "x$cf_with_trace" = xyes
1787 then
1788         AC_MSG_WARN(The NCURSES_TRACE environment variable is not supported with this configuration)
1789 fi
1790
1791 CF_SYS_TIME_SELECT
1792
1793 ###     checks for compiler characteristics
1794 AC_LANG_C
1795 AC_C_CONST
1796 CF_C_INLINE(NCURSES_INLINE,1200)
1797 CF_SIG_ATOMIC_T
1798
1799 if test "$NCURSES_CHTYPE" = auto ; then
1800         CF_TYPEOF_CHTYPE
1801 else
1802         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1803 fi
1804 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1805 AC_SUBST(cf_cv_typeof_chtype)
1806
1807 CF_UNSIGNED_LITERALS
1808 cf_cv_1UL="1"
1809 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1810 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1811 AC_SUBST(cf_cv_1UL)
1812
1813 if test "$NCURSES_MMASK_T" = auto ; then
1814         cf_cv_typeof_mmask_t=long
1815 else
1816         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1817 fi
1818 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1819 AC_SUBST(cf_cv_typeof_mmask_t)
1820
1821 ###     Checks for external-data
1822 CF_ERRNO
1823 CF_LINK_DATAONLY
1824
1825 ###     Checks for library functions.
1826 CF_FUNC_GETTIME
1827 AC_CHECK_FUNCS( \
1828 fpathconf \
1829 getcwd \
1830 getegid \
1831 geteuid \
1832 getopt \
1833 issetugid \
1834 localeconv \
1835 poll \
1836 putenv \
1837 remove \
1838 select \
1839 setbuf \
1840 setbuffer \
1841 setenv \
1842 setfsuid \
1843 setvbuf \
1844 sigaction \
1845 sigvec \
1846 snprintf \
1847 strdup \
1848 strstr \
1849 sysconf \
1850 tcgetpgrp \
1851 times \
1852 tsearch \
1853 vsnprintf \
1854 )
1855
1856 CF_FUNC_GETTTYNAM
1857
1858 if test "x$ac_cv_func_getopt" = xno && \
1859    test "x$cf_with_progs$cf_with_tests" != xnono; then
1860         AC_MSG_ERROR(getopt is required for building programs)
1861 fi
1862
1863 if test "x$with_safe_sprintf" = xyes
1864 then
1865         if test "x$ac_cv_func_vsnprintf" = xyes
1866         then
1867                 AC_MSG_WARN(will use vsnprintf instead of safe-sprintf option)
1868         else
1869                 AC_DEFINE(USE_SAFE_SPRINTF,1,[Define to 1 to compile with experimental safe-sprintf code])
1870         fi
1871 fi
1872
1873 if test "x$with_getcap" = "xyes" ; then
1874         CF_CGETENT
1875 fi
1876
1877 CF_ISASCII
1878 CF_STRUCT_SIGACTION
1879 CF_FUNC_NANOSLEEP
1880 CF_FUNC_TERMIOS
1881 CF_FUNC_VSSCANF
1882 CF_MKSTEMP
1883
1884 # setup for prototype of fallback for vsscanf()
1885 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1886
1887 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1888 if test "x$cross_compiling" = xyes ; then
1889         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1890 else
1891         AC_FUNC_SETVBUF_REVERSED
1892 fi
1893 AC_CHECK_TYPE(intptr_t, long)
1894 AC_CHECK_TYPE(ssize_t, int)
1895 CF_TYPE_SIGACTION
1896 CF_SIZECHANGE
1897 CF_FUNC_MEMMOVE
1898 CF_FUNC_POLL
1899 CF_VA_COPY
1900 AC_FUNC_VFORK
1901 CF_FOPEN_BIN_R
1902
1903 # special check for test/ditto.c
1904 CF_FUNC_OPENPTY
1905 if test "$cf_cv_func_openpty" != no ; then
1906         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
1907         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
1908         if test "x$cf_cv_lib_util" = xyes ; then
1909                 CF_ADD_LIB(util,TEST_LIBS)
1910         fi
1911 fi
1912 AC_SUBST(TEST_LIBS)
1913 AC_SUBST(TEST_LIBS2)
1914
1915 if test "$with_hashed_db" != no ; then
1916         AC_DEFINE(USE_HASHED_DB,1,[Define to 1 if we should build terminfo in hashed database])
1917         CF_HASHED_DB($with_hashed_db)
1918 fi
1919
1920 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1921 if test -z "$cf_user_CFLAGS" && test "$enable_leaks" = yes ; then
1922         CF_STRIP_G_OPT(CFLAGS)
1923         CF_STRIP_G_OPT(CXXFLAGS)
1924 fi
1925
1926 # Just in case, check if the C compiler has a bool type.
1927 CF_BOOL_DECL(cf_cv_cc_bool_type)
1928
1929 # Check for C++ compiler characteristics (and ensure that it's there!)
1930 if test -n "$CXX" ; then
1931         AC_LANG_CPLUSPLUS
1932         CF_STDCPP_LIBRARY
1933         CF_PROG_CC_C_O(CXX,[$CXXFLAGS $CPPFLAGS])
1934
1935         case "$GXX_VERSION" in
1936         (1.*|2.[[0-6]]*|[[1-9]][[0-9]].*)
1937                 cf_cxx_library=yes
1938                 ;;
1939         (*-2.7*|2.7*)
1940                 CF_GPP_LIBRARY
1941                 ;;
1942         (*)
1943                 cf_cxx_library=no
1944                 ;;
1945         esac
1946
1947         AC_CHECK_HEADERS(typeinfo)
1948         CF_CXX_IOSTREAM_NAMESPACE
1949         CF_BOOL_DECL
1950         CF_BOOL_SIZE
1951         CF_ETIP_DEFINES
1952         CF_CPP_OVERRIDE
1953         CF_CPP_PARAM_INIT
1954         CF_CPP_STATIC_CAST
1955         CF_CXX_AR_FLAGS
1956 else
1957         cf_cxx_library=no
1958         cf_cv_builtin_bool=1
1959
1960         # Just because we are not configuring against C++ right now does not
1961         # mean that a user will not want to use C++.  Some distributors disable
1962         # the C++ portion of this configuration as a shortcut (or just to avoid
1963         # compiling the demo in the c++ directory).  So we need a reasonable
1964         # default for the 'bool' type.
1965         #
1966         # Caveat: since the storage of the bool type is not standardized, it
1967         # may change.
1968
1969         if test "$NCURSES_BOOL" != auto ; then
1970                 cf_cv_type_of_bool=$NCURSES_BOOL
1971                 cf_cv_header_stdbool_h=0
1972         else
1973                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1974                         CF_BOOL_SIZE
1975                 else
1976                         AC_MSG_CHECKING(for fallback type of bool)
1977                         case "$host_cpu" in
1978                         (i?86)  cf_cv_type_of_bool=char ;;
1979                         (*)     cf_cv_type_of_bool=int  ;;
1980                         esac
1981                         AC_MSG_RESULT($cf_cv_type_of_bool)
1982                 fi
1983         fi
1984 fi
1985 AC_SUBST(CXXLIBS)
1986
1987 # If the C compiler did not declare bool, and we did not determine that the C++
1988 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1989 # ncurses library use the same type as C++ bool.  Note that this allows one to
1990 # specify the type of bool in a configure-script option and postpone
1991 # integration with the C++ compiler provided that the types are compatible.
1992 USE_CXX_BOOL=1
1993 if test "$cf_cv_cc_bool_type" = 1
1994 then
1995         # oops: C has a bool.  Unlikely, but C++ could differ.
1996         USE_CXX_BOOL=0
1997 elif test "$cf_cv_builtin_bool" = 0
1998 then
1999         # C++ has no bool
2000         USE_CXX_BOOL=0
2001 else
2002         # this is the normal case
2003         USE_CXX_BOOL='defined(__cplusplus)'
2004 fi
2005 AC_SUBST(USE_CXX_BOOL)
2006
2007 CF_HELP_MESSAGE(Ada Binding Options:)
2008
2009 dnl If the Ada95 source-tree is present, add that to the build unless it will
2010 dnl not work, or was not requested.
2011 if test -f "${srcdir}/Ada95/Makefile.in" ; then
2012
2013 dnl libtool does not know anything about GNAT, though a change made in 1998
2014 dnl provided for it "someday".  Disable the ada subtree if we are using
2015 dnl libtool -TD 20070714
2016         if test "$cf_with_ada" != "no" ; then
2017                 if test "$with_libtool" != "no"; then
2018                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
2019                         cf_with_ada=no
2020                 fi
2021         fi
2022
2023 dnl Check for availability of GNU Ada Translator (GNAT).
2024 dnl At the moment we support no other Ada compiler.
2025         if test "$cf_with_ada" != "no" ; then
2026                 CF_PROG_GNAT
2027                 if test "x$cf_cv_prog_gnat_correct" = xyes; then
2028                         CF_ADD_ADAFLAGS(-gnatpn)
2029                         CF_FIXUP_ADAFLAGS
2030
2031                         CF_GNATPREP_OPT_T
2032
2033                         CF_GNAT_GENERICS
2034                         CF_GNAT_SIGINT
2035                         CF_GNAT_PROJECTS
2036
2037                         CF_WITH_ADA_COMPILER
2038
2039                         cf_ada_package=terminal_interface
2040                         AC_SUBST(cf_ada_package)
2041
2042                         CF_WITH_ADA_INCLUDE
2043                         CF_WITH_ADA_OBJECTS
2044                         CF_WITH_ADA_SHAREDLIB
2045
2046                         # allow the Ada binding to be renamed
2047                         CF_WITH_ADA_LIBNAME(AdaCurses)
2048                 fi
2049         fi
2050 else
2051         cf_with_ada=no
2052 fi
2053
2054 # do this "late" to avoid conflict with header-checks
2055 if test "x$with_widec" = xyes ; then
2056         AC_CHECK_SIZEOF(wchar_t)
2057         # cross-compiling to mingw can run into the problem that attempting to
2058         # link with the regex library fails, causing the test to not set this to
2059         # a number.  "recent" autoconf does not address this problem either -TD
2060         if test -z "$ac_cv_sizeof_wchar_t"
2061         then
2062                 CF_VERBOSE(test failed (assume 2))
2063                 sed /SIZEOF_WCHAR_T/d confdefs.h >confdefs.tmp
2064                 mv confdefs.tmp confdefs.h
2065                 echo "#define SIZEOF_WCHAR_T 2" >>confdefs.h
2066         fi
2067 fi
2068
2069 ### Construct the ncurses library-subsets, if any, from this set of keywords:
2070 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
2071 ###
2072 ### ticlib modules may be a separate library, otherwise contained in termlib.
2073 ### termlib modules may be a separate library, otherwise contained in ncurses.
2074 ###
2075 ### The of "+" or " " between the tokens controls the way the script
2076 ### chooses to split module lists into libraries.
2077 ###
2078 ### (see CF_LIB_RULES).
2079 AC_MSG_CHECKING(for library subsets)
2080 LIB_SUBSETS=
2081
2082 if test "x$cf_with_progs" = xyes || test "$with_ticlib" != no || test "$with_termcap" != no; then
2083         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
2084         if test "$with_ticlib" != no ; then
2085                 LIB_SUBSETS="${LIB_SUBSETS} "
2086         else
2087                 LIB_SUBSETS="${LIB_SUBSETS}+"
2088         fi
2089 fi
2090
2091 LIB_SUBSETS="${LIB_SUBSETS}termlib"
2092 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
2093
2094 if test "$with_termlib" != no ; then
2095         LIB_SUBSETS="${LIB_SUBSETS} "
2096 else
2097         LIB_SUBSETS="${LIB_SUBSETS}+"
2098 fi
2099
2100 LIB_SUBSETS="${LIB_SUBSETS}base"
2101
2102 # Most term-driver calls are to tinfo, but some like init_pair are to the
2103 # base library (so it resides in base).
2104 if test "$with_term_driver" != no ; then
2105         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
2106         case "$cf_cv_system_name" in
2107         (*mingw32*|*mingw64*)
2108                 if test "x$with_exp_win32" = xyes ; then
2109                         LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32"
2110                 else
2111                         LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
2112                 fi
2113                 CPPFLAGS="$CPPFLAGS -DUSE_WIN32CON_DRIVER"
2114                 ;;
2115         (*)
2116                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
2117                 ;;
2118         esac
2119 elif test "x$with_exp_win32" = xyes ; then
2120         case "$cf_cv_system_name" in
2121         (*mingw32*|*mingw64*)
2122                 LIB_SUBSETS="${LIB_SUBSETS}+port_win32"
2123                 ;;
2124         (*)
2125                 ;;
2126         esac
2127 fi
2128
2129 test "x$with_widec"     = xyes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
2130 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
2131
2132 AC_MSG_RESULT($LIB_SUBSETS)
2133
2134 ### Construct the list of include-directories to be generated
2135 CF_INCLUDE_DIRS
2136 CF_ADA_INCLUDE_DIRS
2137
2138 ### Build up pieces for makefile rules
2139 AC_MSG_CHECKING(default library suffix)
2140 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
2141 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
2142 AC_MSG_RESULT($DFT_ARG_SUFFIX)
2143
2144 AC_MSG_CHECKING(default library-dependency suffix)
2145 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
2146 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
2147 AC_MSG_RESULT($DFT_DEP_SUFFIX)
2148
2149 AC_MSG_CHECKING(default object directory)
2150 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
2151 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
2152 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
2153
2154 if test "x$cf_with_cxx" = xyes ; then
2155 AC_MSG_CHECKING(c++ library-dependency suffix)
2156 if test "$with_libtool" != "no"; then
2157         # libtool thinks it can make c++ shared libraries (perhaps only g++)
2158         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2159 elif test "$with_shared_cxx" != "no"; then
2160         # also for g++ users...
2161         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2162 else
2163         # we normally make a static library because C/C++ library rules differ
2164         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)
2165 fi
2166 AC_MSG_RESULT($CXX_LIB_SUFFIX)
2167 AC_SUBST(CXX_LIB_SUFFIX)
2168 fi
2169
2170 # do not want -ldl in build except as needed for -lncurses dependency
2171 if test "x$with_dlsym" = xyes ; then
2172 if test "$DFT_LWR_MODEL" = shared || \
2173    test "$DFT_LWR_MODEL" = libtool ; then
2174         CF_REMOVE_LIB(LIBS,$LIBS,dl)
2175 fi
2176 fi
2177 ### Set up low-level terminfo dependencies for makefiles.
2178
2179 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
2180 # do not need libdl
2181 TICS_LIST=
2182 if test "x$with_dlsym" = xyes ; then
2183         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
2184 fi
2185
2186 USE_ARG_SUFFIX="${DFT_ARG_SUFFIX}${EXTRA_SUFFIX}"
2187 USE_LIB_SUFFIX="${LIB_SUFFIX}${EXTRA_SUFFIX}"
2188 USE_CFG_SUFFIX=${DFT_ARG_SUFFIX}${cf_cv_abi_version}
2189 if test -n "$EXTRA_SUFFIX" && test "x$EXTRA_SUFFIX" != "x${cf_cv_abi_version}"
2190 then
2191         USE_CFG_SUFFIX="${USE_CFG_SUFFIX}${EXTRA_SUFFIX}"
2192 fi
2193 AC_SUBST(USE_ARG_SUFFIX)
2194 AC_SUBST(USE_CFG_SUFFIX)
2195 AC_SUBST(USE_LIB_SUFFIX)
2196
2197 if test "$with_ticlib" != no ; then
2198
2199         if test "x$with_ticlib" != xyes ; then
2200                 TICS_NAME=$with_ticlib
2201                 TICS_SUFFIX="`echo "${DFT_LIB_SUFFIX}" |sed -e "s/^${USE_LIB_SUFFIX}//"`"
2202                 TICS_ARG_SUFFIX="${with_ticlib}`echo "${USE_ARG_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2203                 TICS_DEP_SUFFIX="${with_ticlib}`echo "${DFT_DEP_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2204                 TICS_LIB_SUFFIX="${with_ticlib}"
2205         else
2206                 TICS_SUFFIX=${DFT_LIB_SUFFIX}
2207                 TICS_ARG_SUFFIX="${TICS_NAME}${USE_ARG_SUFFIX}"
2208                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
2209                 TICS_LIB_SUFFIX="${TICS_NAME}${USE_LIB_SUFFIX}"
2210         fi
2211         TICS_LDFLAGS="-L${LIB_DIR}"
2212         TICS_LIBS="-l${TICS_ARG_SUFFIX}"
2213 else
2214         TICS_SUFFIX=${DFT_LIB_SUFFIX}
2215         TICS_LDFLAGS="-L${LIB_DIR}"
2216         TICS_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2217 fi
2218 AC_SUBST(TICS_ARG_SUFFIX)
2219 AC_SUBST(TICS_DEP_SUFFIX)
2220 AC_SUBST(TICS_LIB_SUFFIX)
2221 AC_SUBST(TICS_LDFLAGS)
2222 AC_SUBST(TICS_LIBS)
2223
2224 if test "$with_termlib" != no ; then
2225
2226         if test "x$with_termlib" != xyes ; then
2227                 TINFO_NAME=$with_termlib
2228                 TINFO_SUFFIX="`echo "${DFT_LIB_SUFFIX}" |sed -e "s/^${USE_LIB_SUFFIX}//"`"
2229                 TINFO_ARG_SUFFIX="${with_termlib}`echo "${USE_ARG_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2230                 TINFO_DEP_SUFFIX="${with_termlib}`echo "${DFT_DEP_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2231                 TINFO_LIB_SUFFIX="${with_termlib}"
2232         else
2233                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2234                 TINFO_ARG_SUFFIX="${TINFO_NAME}${USE_ARG_SUFFIX}"
2235                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
2236                 TINFO_LIB_SUFFIX="${TINFO_NAME}${USE_LIB_SUFFIX}"
2237         fi
2238
2239         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2240         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2241         if test "$DFT_LWR_MODEL" = "libtool"; then
2242                 TEST_ARGS="${TEST_DEPS}"
2243                 TEST_ARG2="${TEST_DEP2}"
2244                 TINFO_LDFLAGS="-L${LIB_DIR}"
2245                 TINFO_LIBS="$TEST_ARGS"
2246                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
2247                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
2248         else
2249                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
2250                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
2251                 if test "x$with_term_driver" != xno ; then
2252                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2253                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${USE_ARG_SUFFIX}"
2254                         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
2255                 else
2256                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2257                         TINFO_LIBS="$TEST_ARGS"
2258                 fi
2259                 TINFO_LDFLAGS="-L${LIB_DIR}"
2260                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2261         fi
2262 else
2263         # the next lines are needed for linking libtic over libncurses
2264         TINFO_NAME=${LIB_NAME}
2265         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2266         TINFO_ARG_SUFFIX=${LIB_NAME}${USE_ARG_SUFFIX}
2267         if test "x$with_tic_depends" = xyes ; then
2268                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2269         else
2270                 TICS_LIST="$SHLIB_LIST"
2271         fi
2272
2273         TINFO_LDFLAGS="-L${LIB_DIR}"
2274         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2275 fi
2276
2277 if test "$DFT_LWR_MODEL" = shared ; then
2278         case "$cf_cv_system_name" in
2279         (cygwin*|msys*)
2280                 # "lib" files have ".dll.a" suffix, "cyg"or "msys-" files have ".dll"
2281                 TINFO_SUFFIX=.dll
2282                 ;;
2283         esac
2284 fi
2285
2286 AC_SUBST(TINFO_ARG_SUFFIX)
2287 AC_SUBST(TINFO_DEP_SUFFIX)
2288 AC_SUBST(TINFO_LIB_SUFFIX)
2289 AC_SUBST(TINFO_LDFLAGS)
2290 AC_SUBST(TINFO_LIBS)
2291
2292 if test "x$with_dlsym" = xyes ; then
2293         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
2294 fi
2295
2296 if test "$DFT_LWR_MODEL" = "libtool"; then
2297         OBJEXT=lo
2298 fi
2299
2300 # needed for Ada95
2301 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
2302 AC_SUBST(TINFO_LDFLAGS2)
2303
2304 case "$DFT_LWR_MODEL" in
2305 (normal|debug|profile)
2306         CF_LDFLAGS_STATIC
2307         ;;
2308 esac
2309
2310 AC_MSG_CHECKING(where we will install curses.h)
2311 AC_SUBST(includesubdir)
2312 includesubdir=
2313 if test "$with_overwrite" = no && \
2314  { test "x$includedir" = 'x${prefix}/include' || \
2315    test "x$includedir" = "x${prefix}/include"; }
2316 then
2317         includesubdir="/ncurses${USE_LIB_SUFFIX}"
2318 fi
2319 AC_MSG_RESULT(${includedir}${includesubdir})
2320
2321 ### Resolve a conflict between normal and wide-curses by forcing applications
2322 ### that will need libutf8 to add it to their configure script.
2323 if test "$with_overwrite" != no ; then
2324 if test "$NCURSES_LIBUTF8" = 1 ; then
2325         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
2326         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
2327 fi
2328 fi
2329 WITH_OVERWRITE=$with_overwrite
2330
2331 ### At least on MinGW a shared library build without libtool
2332 ### requires adding the additional libs to the link list.
2333 case "$cf_cv_system_name" in
2334 (*mingw32*|*mingw64*)
2335         if test "$DFT_LWR_MODEL" != "libtool"; then
2336            SHLIB_LIST="$SHLIB_LIST ${LIBS}"
2337         fi
2338         ;;
2339 *)      ;;
2340 esac
2341
2342 AC_SUBST(WITH_OVERWRITE)
2343 AC_SUBST(TICS_LIST)
2344 AC_SUBST(TINFO_LIST)
2345 AC_SUBST(SHLIB_LIST)
2346
2347 # used to separate tack out of the tree
2348 NCURSES_TREE=
2349 AC_SUBST(NCURSES_TREE)
2350
2351 ### predefined stuff for the test programs
2352 AC_DEFINE(HAVE_SLK_COLOR,1,[Define to 1 if we have slk_color for test-programs])
2353
2354 # pkgsrc uses these
2355 CF_WITH_LIB_BASENAME(FORM_NAME,form)
2356 CF_WITH_LIB_BASENAME(MENU_NAME,menu)
2357 CF_WITH_LIB_BASENAME(PANEL_NAME,panel)
2358 CF_WITH_LIB_BASENAME(CXX_NAME,cxx,ncurses++)
2359
2360 ### Construct the list of subdirectories for which we'll customize makefiles
2361 ### with the appropriate compile-rules.
2362
2363 CF_SRC_MODULES($modules_to_build)
2364
2365 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2366    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/src/library.gpr:Ada95/src/library.gpr.in"
2367    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${USE_CFG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
2368    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${USE_CFG_SUFFIX}-config.1:man/MKada_config.in"
2369 fi
2370
2371 CF_DIRS_TO_MAKE
2372
2373 # symbols that differ when compiling Ada95 by itself.
2374 NCURSES_SHLIB2=$SHELL' $(top_srcdir)/misc/shlib'
2375 AC_SUBST(NCURSES_SHLIB2)
2376
2377 # values to use as strings
2378 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as library path-separator])
2379
2380 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}",[Define to 1 if machine has ample memory for tic])
2381
2382 ### Define substitutions for header files to avoid name-pollution
2383 CF_SUBST_IF(["x$cf_cv_have_tcgetattr" = xyes], HAVE_TCGETATTR, 1, 0)
2384 CF_SUBST_IF(["x$ac_cv_header_stdint_h" = xyes], HAVE_STDINT_H, 1, 0)
2385 CF_SUBST_IF(["x$ac_cv_header_termio_h" = xyes], HAVE_TERMIO_H, 1, 0)
2386 CF_SUBST_IF(["x$ac_cv_header_termios_h" = xyes], HAVE_TERMIOS_H, 1, 0)
2387
2388 ################################################################################
2389 test "x$use_database" = xyes && \
2390 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
2391
2392 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
2393 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${USE_CFG_SUFFIX}-config.1:man/MKncu_config.in"
2394
2395 if test "x$enable_pc_files" = xyes && test -z "$MAKE_PC_FILES" ; then
2396 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
2397 fi
2398 AC_SUBST(cross_compiling)
2399
2400 if test "x$cf_with_tests" != xno ; then
2401         MAKE_TESTS=
2402 else
2403         MAKE_TESTS="#"
2404 fi
2405 AC_SUBST(MAKE_TESTS)
2406
2407 ADAHTML_DIR=../../doc/html/ada
2408 AC_SUBST(ADAHTML_DIR)
2409
2410 # workaround for OS/2 (20151017)
2411 case "$cf_cv_system_name" in
2412 (os2*)
2413         LIBTOOL_OPTS_CXX="-os2dllname ncurs++"
2414         ;;
2415 (*)
2416         LIBTOOL_OPTS_CXX=
2417         ;;
2418 esac
2419 AC_SUBST(LIBTOOL_OPTS_CXX)
2420
2421 # workaround for g++ versus Solaris (20131116)
2422 case "$cf_cv_system_name" in
2423 (solaris2*)
2424         case "x$CPPFLAGS" in
2425         (*-D_XOPEN_SOURCE_EXTENDED*)
2426                 CF_VERBOSE(moving _XOPEN_SOURCE_EXTENDED to work around g++ problem)
2427                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
2428                 CPPFLAGS=`echo "x$CPPFLAGS" | sed -e  's/^.//' -e 's/-D_XOPEN_SOURCE_EXTENDED//'`
2429                 ;;
2430         esac
2431         ;;
2432 esac
2433
2434 # Help to automatically enable the extended curses features when using either
2435 # the *-config or the ".pc" files by adding defines.
2436 AC_MSG_CHECKING(for defines to add to ncurses${USE_CFG_SUFFIX}-config script)
2437 PKG_CFLAGS=
2438 for cf_loop1 in $CPPFLAGS_after_XOPEN
2439 do
2440         cf_found=no
2441         for cf_loop2 in $CPPFLAGS_before_XOPEN
2442         do
2443                 if test "x$cf_loop1" = "x$cf_loop2"
2444                 then
2445                         cf_found=yes
2446                         break
2447                 fi
2448         done
2449         test "$cf_found" = no && PKG_CFLAGS="$PKG_CFLAGS $cf_loop1"
2450 done
2451 AC_MSG_RESULT($PKG_CFLAGS)
2452 AC_SUBST(PKG_CFLAGS)
2453
2454 # AC_CHECK_SIZEOF demands a literal parameter, no variables.  So we do this.
2455 case "x$NCURSES_OSPEED" in
2456 (*short*)
2457         cf_compatible=1
2458         ;;
2459 (*)
2460         cf_compatible=0
2461         ;;
2462 esac
2463 AC_DEFINE_UNQUOTED(NCURSES_OSPEED_COMPAT,$cf_compatible,[Define to 1 if termcap variable ospeed is short])
2464
2465 case "x$cf_cv_typeof_chtype" in
2466 (xshort|xint|xlong)
2467         cf_cv_typeof_chtype="unsigned $cf_cv_typeof_chtype"
2468         ;;
2469 esac
2470
2471 case "x$cf_cv_typeof_mmask_t" in
2472 (xshort|xint|xlong)
2473         cf_cv_typeof_mmask_t="unsigned $cf_cv_typeof_mmask_t"
2474         ;;
2475 esac
2476
2477 # substitute into misc/Makefile to suppress
2478 # (un)install.data from the
2479 # (un)install rules.
2480 if test "x$cf_with_db_install" = "xno"; then
2481         MISC_INSTALL_DATA=
2482         MISC_UNINSTALL_DATA=
2483 else
2484         MISC_INSTALL_DATA=install.data
2485         MISC_UNINSTALL_DATA=uninstall.data
2486 fi
2487 AC_SUBST(MISC_INSTALL_DATA)
2488 AC_SUBST(MISC_UNINSTALL_DATA)
2489
2490 if test "x$cf_with_db_install" = "xno" || test "x$TERMINFO_SRC" = "xno"; then
2491         MAKE_DATABASE="#"
2492 else
2493         MAKE_DATABASE="$MAKE_TERMINFO"
2494 fi
2495 AC_SUBST(MAKE_DATABASE)
2496
2497 dnl Override the package used for exported symbols
2498 if test -n "$PACKAGE"
2499 then
2500         PACKAGE="${PACKAGE}${DFT_ARG_SUFFIX}"
2501         export PACKAGE
2502         echo "package: $PACKAGE"
2503 fi
2504
2505 UNALTERED_SYMS=
2506 cf_filter_syms=no
2507
2508 if test -n "$RESULTING_SYMS"
2509 then
2510         cf_filter_syms=$cf_dft_filter_syms
2511         CF_VERBOSE(will map symbols to ABI=$cf_cv_abi_default)
2512 fi
2513
2514 if test "x$WILDCARD_SYMS" = xno
2515 then
2516         cf_filter_syms=yes
2517 fi
2518
2519 test "x$cf_with_trace" = xyes && NCURSES_INLINE=
2520
2521 UNALTERED_SYMS=`echo "$RESULTING_SYMS" | sed -e 's/\\$/\\\\$/g'`
2522 if test "$cf_filter_syms" = yes
2523 then
2524         RESULTING_SYMS=resulting.map
2525 fi
2526 AC_SUBST(UNALTERED_SYMS)
2527
2528 if test "x$cross_compiling" = xyes ; then
2529         ADAGEN_LDFLAGS='$(CROSS_LDFLAGS)'
2530         CHECK_BUILD="#"
2531 else
2532         ADAGEN_LDFLAGS='$(NATIVE_LDFLAGS)'
2533         CHECK_BUILD=
2534 fi
2535 AC_SUBST(ADAGEN_LDFLAGS)
2536 AC_SUBST(CHECK_BUILD)
2537 AC_SUBST(PRIVATE_LIBS)
2538
2539 # This is used for the *-config script and *.pc data files.
2540 CF_LD_SEARCHPATH
2541
2542 AC_DEFINE(HAVE_CURSES_DATA_BOOLNAMES,1,[definition needed for in-tree build of tack])
2543
2544 AC_OUTPUT( \
2545         include/MKterm.h.awk \
2546         include/curses.head:include/curses.h.in \
2547         include/ncurses_dll.h \
2548         include/termcap.h \
2549         include/unctrl.h \
2550         man/man_db.renames \
2551         $SUB_MAKEFILES \
2552         Makefile,[
2553 if test "x$cf_with_tests" != xno ; then
2554         CF_PRG_RULES(["$srcdir/test/mk-test.awk" INSTALL=no ECHO_LINK="$ECHO_LD"], test)
2555 fi
2556 CF_LIB_RULES($SRC_SUBDIRS)
2557 CF_OUTPUT_MANPAGE_RENAMES
2558
2559 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2560 if test -z "$USE_OLD_MAKERULES" ; then
2561         $AWK -f "$srcdir/Ada95/mk-1st.awk" <"$srcdir/Ada95/src/modules" >>Ada95/src/Makefile
2562 fi
2563 fi
2564 ],[
2565 ### Special initialization commands, used to pass information from the
2566 ### configuration-run into config.status
2567
2568 ALTERNATE_SYMS="$ALTERNATE_SYMS"
2569 AWK="$AWK"
2570 CXX_NAME="$CXX_NAME"
2571 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
2572 DFT_LWR_MODEL="$DFT_LWR_MODEL"
2573 ECHO_LD="$ECHO_LD"
2574 EXTRA_SUFFIX="$EXTRA_SUFFIX"
2575 FORM_NAME="$FORM_NAME"
2576 LDCONFIG="$LDCONFIG"
2577 LIBTOOL_VERSION="$LIBTOOL_VERSION"
2578 LIB_NAME="$LIB_NAME"
2579 LIB_PREFIX="$LIB_PREFIX"
2580 LIB_SUBSETS="$LIB_SUBSETS"
2581 LIB_SUFFIX="$LIB_SUFFIX"
2582 LIB_TRACING="$LIB_TRACING"
2583 LN_S="$LN_S"
2584 MAKE_TERMINFO="$MAKE_TERMINFO"
2585 MANPAGE_RENAMES="$MANPAGE_RENAMES"
2586 MENU_NAME="$MENU_NAME"
2587 NCURSES_MAJOR="$NCURSES_MAJOR"
2588 NCURSES_MINOR="$NCURSES_MINOR"
2589 NCURSES_OSPEED="$NCURSES_OSPEED"
2590 NCURSES_PATCH="$NCURSES_PATCH"
2591 PANEL_NAME="$PANEL_NAME"
2592 SRC_SUBDIRS="$SRC_SUBDIRS"
2593 TERMINFO="$TERMINFO"
2594 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
2595 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
2596 TICS_NAME="$TICS_NAME"
2597 TICS_SUFFIX="$TICS_SUFFIX"
2598 TIC_PATH="$TIC_PATH"
2599 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
2600 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
2601 TINFO_NAME="$TINFO_NAME"
2602 TINFO_SUFFIX="$TINFO_SUFFIX"
2603 UNALTERED_SYMS="$UNALTERED_SYMS"
2604 USE_ARG_SUFFIX="$USE_ARG_SUFFIX"
2605 USE_CFG_SUFFIX="$USE_CFG_SUFFIX"
2606 USE_LIB_SUFFIX="$USE_LIB_SUFFIX"
2607 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
2608 WILDCARD_SYMS="$WILDCARD_SYMS"
2609 WITH_CURSES_H="$with_curses_h"
2610 WITH_ECHO="${enable_echo:=yes}"
2611 WITH_OVERWRITE="$with_overwrite"
2612 cf_LIST_MODELS="$cf_list_models"
2613 cf_cv_VERSION_GNATMAKE=$cf_cv_VERSION_GNATMAKE
2614 cf_cv_VERSION_GPRBUILD=$cf_cv_VERSION_GPRBUILD
2615 cf_cv_abi_default="$cf_cv_abi_default"
2616 cf_cv_abi_version="$cf_cv_abi_version"
2617 cf_cv_do_relink="$cf_cv_do_relink"
2618 cf_cv_do_reranlib="$cf_cv_do_reranlib"
2619 cf_cv_do_symlinks="$cf_cv_do_symlinks"
2620 cf_cv_enable_lp64="$cf_cv_enable_lp64"
2621 cf_cv_enable_opaque="$cf_cv_enable_opaque"
2622 cf_cv_make_PHONY="$cf_cv_make_PHONY"
2623 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
2624 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
2625 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
2626 cf_cv_rel_version="$cf_cv_rel_version"
2627 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
2628 cf_cv_shared_soname='$cf_cv_shared_soname'
2629 cf_cv_shlib_version="$cf_cv_shlib_version"
2630 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
2631 cf_cv_system_name="$cf_cv_system_name"
2632 cf_cv_term_driver="$with_term_driver"
2633 cf_with_ada="$cf_with_ada"
2634 cf_with_cxx_binding="$cf_with_cxx_binding"
2635 cf_with_db_install="$cf_with_db_install"
2636 cf_with_manpages="$cf_with_manpages"
2637 cf_with_tests="$cf_with_tests"
2638 host="$host"
2639 target="$target"
2640 verbose="$verbose"
2641 with_shared_cxx="$with_shared_cxx"
2642
2643 ],cat)dnl
2644 ${MAKE:-make} preinstall