ncurses 6.0 - patch 20170826
[ncurses.git] / test / configure.in
1 dnl***************************************************************************
2 dnl Copyright (c) 1998-2016,2017 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey 1996-on
30 dnl
31 dnl $Id: configure.in,v 1.135 2017/08/20 16:38:29 tom Exp $
32 dnl This is a simple configuration-script for the ncurses test programs that
33 dnl allows the test-directory to be separately configured against a reference
34 dnl system (i.e., sysvr4 curses)
35 dnl
36 dnl If you're configuring ncurses, you shouldn't need to use this script.
37 dnl It's only for testing purposes.
38 dnl
39 dnl For additional information, see
40 dnl             http://invisible-island.net/autoconf/
41 dnl             http://invisible-island.net/ncurses/ncurses-examples.html
42 dnl ---------------------------------------------------------------------------
43 AC_PREREQ(2.52.20170501)
44 AC_INIT(ncurses.c)
45 AC_CONFIG_HEADER(ncurses_cfg.h:ncurses_tst.hin)
46
47 CF_INHERIT_SCRIPT(config.guess)
48 CF_INHERIT_SCRIPT(config.sub)
49 CF_CHECK_CACHE
50
51 AC_ARG_PROGRAM
52
53 AC_PROG_MAKE_SET
54 CF_PROG_CC
55 AC_PROG_CPP
56 AC_PROG_AWK
57 CF_PROG_INSTALL
58 CF_PROG_LINT
59 CF_MAKE_TAGS
60
61 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
62 AC_SUBST(MATH_LIB)
63
64 dnl Things that we don't need (or must override) if we're not building ncurses
65 CF_TOP_BUILDDIR
66 CC_G_OPT="-g"                                   AC_SUBST(CC_G_OPT)
67 CC_SHARED_OPTS=unknown                  AC_SUBST(CC_SHARED_OPTS)
68 CPPFLAGS="$CPPFLAGS"                    AC_SUBST(CPPFLAGS)
69 DFT_DEP_SUFFIX=""                               AC_SUBST(DFT_DEP_SUFFIX)
70 DFT_OBJ_SUBDIR=`pwd|sed -e's:.*/::'`    AC_SUBST(DFT_OBJ_SUBDIR)
71 DFT_UPR_MODEL="NORMAL"                  AC_SUBST(DFT_UPR_MODEL)
72 LD="ld"                                                 AC_SUBST(LD)
73 LDFLAGS_SHARED=""                               AC_SUBST(LDFLAGS_SHARED)
74 LDFLAGS_STATIC=""                               AC_SUBST(LDFLAGS_STATIC)
75 LD_MODEL=""                                             AC_SUBST(LD_MODEL)
76 LD_SHARED_OPTS=""                               AC_SUBST(LD_SHARED_OPTS)
77 LIBTOOL=""                                              AC_SUBST(LIBTOOL)
78 LIBTOOL_OPTS=""                                 AC_SUBST(LIBTOOL_OPTS)
79 LIB_CLEAN=""                                    AC_SUBST(LIB_CLEAN)
80 LIB_COMPILE=""                                  AC_SUBST(LIB_COMPILE)
81 LIB_LINK='${CC}'                                AC_SUBST(LIB_LINK)
82 LINK_TESTS=""                                   AC_SUBST(LINK_TESTS)
83 LOCAL_LDFLAGS=""                                AC_SUBST(LOCAL_LDFLAGS)
84 PACKAGE="ncurses-examples"              AC_SUBST(PACKAGE)
85 PTHREAD="-lm"                                   AC_SUBST(PTHREAD)
86 TEST_ARGS=""                                    AC_SUBST(TEST_ARGS)
87 TEST_DEPS=""                                    AC_SUBST(TEST_DEPS)
88 TEST_LIBS=""                                    AC_SUBST(TEST_LIBS)
89 TINFO_LDFLAGS=''                                AC_SUBST(TINFO_LDFLAGS)
90 TINFO_LIBS='$(LIBS_CURSES)'             AC_SUBST(TINFO_LIBS)
91 cf_cv_abi_version=""                    AC_SUBST(cf_cv_abi_version)
92 cf_cv_rel_version=""                    AC_SUBST(cf_cv_rel_version)
93 includesubdir=""                                AC_SUBST(includesubdir)
94
95 cf_cv_screen=curses
96 cf_cv_libtype=
97
98 AC_EXEEXT
99 AC_OBJEXT
100
101 CF_GCC_ATTRIBUTES
102 CF_ENABLE_STRING_HACKS
103 CF_XOPEN_SOURCE
104 CF_SIG_ATOMIC_T
105
106 # Work around breakage on OS X
107 CF_SIGWINCH
108
109 # Checks for CODESET support.
110 AM_LANGINFO_CODESET
111
112 dnl ---------------------------------------------------------------------------
113 CF_HELP_MESSAGE(General Options:)
114 CF_PKG_CONFIG
115 CF_DISABLE_ECHO
116
117 dnl ---------------------------------------------------------------------------
118 CF_HELP_MESSAGE(Curses Version-dependent Options:)
119 CF_NCURSES_WRAP_PREFIX
120
121 AC_MSG_CHECKING(if you want to check for wide-character functions)
122 CF_ARG_DISABLE(widec,
123         [  --disable-widec         disable checks for wide-character functions],
124         cf_enable_widec=no,
125         cf_enable_widec=yes,
126         yes)
127 AC_MSG_RESULT($cf_enable_widec)
128
129 dnl ---------------------------------------------------------------------------
130 CF_HELP_MESSAGE(Curses Version-dependent Options:)
131 CF_WITH_NCURSES_ETC
132
133 case $cf_cv_screen in
134 (ncurses*)
135         cf_cv_libtype=`echo "$cf_cv_screen" | sed -e 's/^ncurses//'`
136         ;;
137 esac
138
139 dnl If we've not specified a library, assume we're using sysvr4 libraries
140 dnl installed conventionally (e.g., SunOS 5.x - solaris).
141
142 dnl Autoconf builds up the $LIBS in reverse order
143
144 cf_curses_headers=
145
146 case $cf_cv_screen in
147 (pdcurses)
148         cf_default_panel=no
149         cf_default_form=no
150         cf_default_menu=no
151         cf_default_tinfo=no
152         ;;
153 (xcurses|bsdcurses)
154         cf_default_panel=no
155         cf_default_form=no
156         cf_default_menu=no
157         cf_default_tinfo=yes
158         ;;
159 (*)
160         cf_default_panel=yes
161         cf_default_form=yes
162         cf_default_menu=yes
163         cf_default_tinfo=yes
164         case $cf_cv_screen in
165         (ncurses*)
166                 cf_curses_headers="nc_alloc.h nomacros.h term_entry.h"
167                 ;;
168         esac
169         ;;
170 esac
171
172 AC_MSG_CHECKING(if you want to check for panel functions)
173 CF_ARG_DISABLE(panel,
174         [  --disable-panel         disable checks for panel functions],
175         cf_enable_panel=no,
176         cf_enable_panel=$cf_default_panel,
177         yes)
178 AC_MSG_RESULT($cf_enable_panel)
179 if test $cf_enable_panel = yes
180 then
181         CF_CHECK_CURSES_LIB(panel,$cf_cv_libtype,new_panel)
182         cf_curses_headers="$cf_curses_headers panel.h"
183 fi
184
185 AC_MSG_CHECKING(if you want to check for menu functions)
186 CF_ARG_DISABLE(menu,
187         [  --disable-menu          disable checks for menu functions],
188         cf_enable_menu=no,
189         cf_enable_menu=$cf_default_menu,
190         yes)
191 AC_MSG_RESULT($cf_enable_menu)
192 if test $cf_enable_menu = yes
193 then
194         case $cf_cv_screen in
195         (ncurses*)
196                 ;;
197         (curses*)
198                 CF_NETBSD_MENU_H
199                 ;;
200         esac
201         CF_CHECK_CURSES_LIB(menu,$cf_cv_libtype,menu_driver)
202         cf_curses_headers="$cf_curses_headers menu.h"
203 fi
204
205 AC_MSG_CHECKING(if you want to check for form functions)
206 CF_ARG_DISABLE(form,
207         [  --disable-form          disable checks for form functions],
208         cf_enable_form=no,
209         cf_enable_form=$cf_default_form,
210         yes)
211 AC_MSG_RESULT($cf_enable_form)
212 if test $cf_enable_form = yes
213 then
214         case $cf_cv_screen in
215         (ncurses*)
216                 ;;
217         (curses*)
218                 CF_NETBSD_FORM_H
219                 ;;
220         esac
221         CF_CHECK_CURSES_LIB(form,$cf_cv_libtype,form_driver)
222         cf_curses_headers="$cf_curses_headers form.h"
223 fi
224
225 # look for curses-related headers
226 AC_CHECK_HEADERS( $cf_curses_headers )
227
228 AC_STDC_HEADERS
229 AC_HEADER_TIME
230 AC_CHECK_HEADERS( \
231 getopt.h \
232 locale.h \
233 math.h \
234 stdarg.h \
235 stdint.h \
236 sys/ioctl.h \
237 sys/select.h \
238 sys/time.h \
239 termios.h \
240 unistd.h \
241 )
242
243 CF_GETOPT_HEADER
244
245 AC_CHECK_FUNCS( \
246 getopt \
247 gettimeofday \
248 tdestroy \
249 tsearch \
250 )
251
252 if test "x$ac_cv_func_getopt" = xno; then
253         AC_MSG_ERROR(getopt is required for building programs)
254 fi
255
256 if test "$cf_enable_widec" = yes; then
257 AC_CHECK_FUNCS( \
258 mblen \
259 mbrlen \
260 mbrtowc \
261 mbsrtowcs \
262 mbstowcs \
263 mbtowc \
264 wcsrtombs \
265 wcstombs \
266 )
267 fi
268
269 CF_CURSES_FUNCS( \
270 alloc_pair \
271 assume_default_colors \
272 chgat \
273 color_content \
274 color_set \
275 filter \
276 getbegx \
277 getcurx \
278 getmaxx \
279 getnstr \
280 getparx \
281 getwin \
282 init_extended_color \
283 mvvline \
284 mvwvline \
285 napms \
286 putwin \
287 resize_term \
288 resizeterm \
289 restartterm \
290 ripoffline \
291 scr_dump \
292 setupterm \
293 slk_color \
294 slk_init \
295 termattrs \
296 tgetent \
297 tigetnum \
298 tigetstr \
299 tputs_sp \
300 typeahead \
301 use_default_colors \
302 use_env \
303 use_extended_names \
304 use_screen \
305 use_window \
306 vid_puts \
307 vidputs \
308 vsscanf \
309 vw_printw \
310 wchgat \
311 winsstr \
312 wresize \
313 wsyncdown \
314 _tracef \
315 )
316
317 CF_TPUTS_PROTO
318 CF_NCURSES_EXT_FUNCS
319
320 if test "$cf_enable_widec" = yes
321 then
322         # workaround for systems with ncurses before 20111029, due to change of
323         # feature test macro from _XPG5 to _XOPEN_SOURCE
324         if test -n "$cf_cv_ncurses_version" && test "x$cf_cv_ncurses_version" != xno
325         then
326                 cf_define_xpg5=no
327                 AC_MSG_CHECKING(if _XPG5 should be defined to enable wide-characters)
328
329                 AC_TRY_COMPILE([
330 #include <${cf_cv_ncurses_header:-curses.h}>],
331                         [int x = _XPG5],,
332                         [cf_save_cppflags="$CPPFLAGS"
333                          CPPFLAGS="$CPPFLAGS -D_XPG5"
334                          AC_TRY_COMPILE([
335 #include <${cf_cv_ncurses_header:-curses.h}>],
336                                 [int x = _XPG5],
337                                 [cf_define_xpg5=yes])
338                          CPPFLAGS="$cf_save_cppflags"])
339                 AC_MSG_RESULT($cf_define_xpg5)
340
341                 if test "$cf_define_xpg5" = yes
342                 then
343                         CPPFLAGS="$CPPFLAGS -D_XPG5"
344                 fi
345         fi
346
347         AC_CACHE_CHECK(for wide-character functions,cf_cv_widechar_funcs,[
348         AC_TRY_LINK([
349 #include <${cf_cv_ncurses_header:-curses.h}>],
350         [
351                 static wchar_t src_wchar[2];
352                 static cchar_t dst_cchar;
353                 setcchar(&dst_cchar, src_wchar, A_NORMAL, 0, (void *) 0);
354                 ],
355                 [cf_cv_widechar_funcs=yes],
356                 [cf_cv_widechar_funcs=no])
357         ])
358         if test "$cf_cv_widechar_funcs" != no ; then
359                 AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to enable wide-character support in (n)curses])
360         else
361                 AC_DEFINE(USE_WIDEC_SUPPORT,0)
362         fi
363 else
364         AC_DEFINE(USE_WIDEC_SUPPORT,0)
365 fi
366
367 AC_CACHE_CHECK(if $cf_cv_screen library uses pthreads,cf_cv_use_pthreads,[
368 AC_TRY_LINK([
369 #include <${cf_cv_ncurses_header:-curses.h}>
370 extern void _nc_init_pthreads(void);
371 ],
372 [
373         initscr();
374         _nc_init_pthreads();
375         ],
376         [cf_cv_use_pthreads=yes],
377         [cf_cv_use_pthreads=no])
378 ])
379 test $cf_cv_use_pthreads = yes && AC_DEFINE(USE_PTHREADS)
380
381 CF_SYS_TIME_SELECT
382
383 # special check for test/ditto.c
384 CF_FUNC_OPENPTY
385 if test "$cf_cv_func_openpty" != no ; then
386         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
387         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
388         if test "x$cf_cv_lib_util" = xyes ; then
389                 CF_ADD_LIB(util,TEST_LIBS)
390         fi
391 fi
392
393 CF_FUNC_CURSES_VERSION
394
395 CF_CURSES_ACS_MAP
396 if test "$cf_enable_widec" = yes; then
397         CF_CURSES_WACS_MAP
398         CF_CURSES_WACS_SYMBOLS
399 fi
400
401 CF_CURSES_CHECK_TYPE(attr_t,long)
402
403 if test "$cf_enable_widec" = yes; then
404         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T, NCURSES_OK_MBSTATE_T)
405         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
406         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
407
408         if test "$NCURSES_OK_MBSTATE_T" = 0 ; then
409                 CF_CURSES_CHECK_TYPE(mbstate_t,long)
410         fi
411
412         if test "$NCURSES_OK_WCHAR_T" = 0 ; then
413                 CF_CURSES_CHECK_TYPE(wchar_t,long)
414         fi
415
416         if test "$NCURSES_OK_WINT_T" = 0 ; then
417                 CF_CURSES_CHECK_TYPE(wint_t,long)
418         fi
419 fi
420
421 CF_CURSES_CHECK_DATA(curscr)
422 CF_CURSES_CHECK_DATA(ospeed)
423 CF_CURSES_CHECK_DATA(boolnames)
424 CF_CURSES_CHECK_DATA(boolfnames)
425 CF_CURSES_CHECK_DATA(ttytype)
426
427 dnl ---------------------------------------------------------------------------
428 CF_HELP_MESSAGE(Testing/development Options:)
429 CF_ENABLE_WARNINGS
430 CF_DISABLE_LEAKS
431 CF_DISABLE_RPATH_HACK
432
433 TEST_ARGS="$LIBS"
434 LIBS=
435
436 dnl ---------------------------------------------------------------------------
437
438 AC_OUTPUT(Makefile,[
439 CF_PRG_RULES([$srcdir/mk-test.awk INSTALL=yes ECHO_LINK="$ECHO_LD"], .)
440         cat >>Makefile <<TEST_EOF
441
442 # These rules are generated so we do not rely on suffix rules, which do not
443 # work consistently for different make-programs (the '\$(MODEL)/' confuses
444 # some, and the '\$x' confuses others).
445 TEST_EOF
446
447 LIST=`sed -e 's/[[      ]].*//' -e '/^[[#@]]/d' $srcdir/modules`
448 for N in $LIST
449 do
450         cat >>Makefile <<TEST_EOF
451
452 \$(MODEL)/$N.o : \$(srcdir)/$N.c \\
453         \$(srcdir)/test.priv.h \\
454         ncurses_cfg.h
455         $SHOW_CC
456         $ECHO_CC\$(CC) -c \$(CFLAGS_DEFAULT) \$(srcdir)/$N.c
457 TEST_EOF
458 done
459
460 if test -f ../config.guess && test -f ../config.sub
461 then
462         cat >>Makefile <<TEST_EOF
463
464 # if we used CF_INHERIT for getting these files, we can remove them
465 distclean::
466         rm -f config.guess config.sub
467 TEST_EOF
468 fi
469 ],[
470 AWK="$AWK"
471 ECHO_CC="$ECHO_CC"
472 ECHO_LD="$ECHO_LD"
473 SHOW_CC="$SHOW_LD"
474 ],cat)