test/aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2022,2023 Thomas E. Dickey                                *
   3 dnl Copyright 2003-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl $Id: aclocal.m4,v 1.210 2023/01/11 09:05:23 tom Exp $
  31 dnl
  32 dnl Author: Thomas E. Dickey
  33 dnl
  34 dnl Macros used in NCURSES test programs auto-configuration script.
  35 dnl
  36 dnl These macros are maintained separately from NCURSES.  The copyright on
  37 dnl this file applies to the aggregation of macros and does not affect use of
  38 dnl these macros in other applications.
  39 dnl
  40 dnl See these pages for additional information:
  41 dnl             https://invisible-island.net/autoconf/
  42 dnl             https://invisible-island.net/autoconf/my-autoconf.html
  43 dnl
  44 dnl ---------------------------------------------------------------------------
  45 dnl ---------------------------------------------------------------------------
  46 dnl AM_LANGINFO_CODESET version: 7 updated: 2023/01/11 04:05:23
  47 dnl -------------------
  48 dnl Inserted as requested by gettext 0.10.40
  49 dnl File from /usr/share/aclocal
  50 dnl codeset.m4
  51 dnl ====================
  52 dnl serial AM1
  53 dnl
  54 dnl From Bruno Haible.
  55 AC_DEFUN([AM_LANGINFO_CODESET],
  56 [
  57 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  58         [AC_TRY_LINK([
  59 $ac_includes_default
  60 #include <langinfo.h>],
  61         [char* cs = nl_langinfo(CODESET); (void)cs],
  62         am_cv_langinfo_codeset=yes,
  63         am_cv_langinfo_codeset=no)
  64         ])
  65         if test "$am_cv_langinfo_codeset" = yes; then
  66                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  67                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  68         fi
  69 ])dnl
  70 dnl ---------------------------------------------------------------------------
  71 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
  72 dnl ------------------
  73 dnl Conditionally generate script according to whether we're using a given autoconf.
  74 dnl
  75 dnl $1 = version to compare against
  76 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  77 dnl $3 = code to use if AC_ACVERSION is older than $1.
  78 define([CF_ACVERSION_CHECK],
  79 [
  80 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
  81 ifdef([m4_version_compare],
  82 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  83 [CF_ACVERSION_COMPARE(
  84 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  85 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  86 dnl ---------------------------------------------------------------------------
  87 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
  88 dnl --------------------
  89 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  90 dnl                      MAJOR2, MINOR2, TERNARY2,
  91 dnl                      PRINTABLE2, not FOUND, FOUND)
  92 define([CF_ACVERSION_COMPARE],
  93 [ifelse(builtin([eval], [$2 < $5]), 1,
  94 [ifelse([$8], , ,[$8])],
  95 [ifelse([$9], , ,[$9])])])dnl
  96 dnl ---------------------------------------------------------------------------
  97 dnl CF_ADD_CFLAGS version: 15 updated: 2020/12/31 10:54:15
  98 dnl -------------
  99 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 100 dnl $1 = flags to add
 101 dnl $2 = if given makes this macro verbose.
 102 dnl
 103 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 104 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 105 dnl confused by the quotes (which require backslashes to keep them usable).
 106 AC_DEFUN([CF_ADD_CFLAGS],
 107 [
 108 cf_fix_cppflags=no
 109 cf_new_cflags=
 110 cf_new_cppflags=
 111 cf_new_extra_cppflags=
 112
 113 for cf_add_cflags in $1
 114 do
 115 case "$cf_fix_cppflags" in
 116 (no)
 117         case "$cf_add_cflags" in
 118         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 119                 case "$cf_add_cflags" in
 120                 (-D*)
 121                         cf_tst_cflags=`echo "${cf_add_cflags}" |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 122
 123                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 124                                 && test -z "${cf_tst_cflags}" \
 125                                 && cf_fix_cppflags=yes
 126
 127                         if test "$cf_fix_cppflags" = yes ; then
 128                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 129                                 continue
 130                         elif test "${cf_tst_cflags}" = "\"'" ; then
 131                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 132                                 continue
 133                         fi
 134                         ;;
 135                 esac
 136                 case "$CPPFLAGS" in
 137                 (*$cf_add_cflags)
 138                         ;;
 139                 (*)
 140                         case "$cf_add_cflags" in
 141                         (-D*)
 142                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 143                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 144                                 ;;
 145                         esac
 146                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
 147                         ;;
 148                 esac
 149                 ;;
 150         (*)
 151                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
 152                 ;;
 153         esac
 154         ;;
 155 (yes)
 156         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 157
 158         cf_tst_cflags=`echo "${cf_add_cflags}" |sed -e 's/^[[^"]]*"'\''//'`
 159
 160         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 161                 && test -z "${cf_tst_cflags}" \
 162                 && cf_fix_cppflags=no
 163         ;;
 164 esac
 165 done
 166
 167 if test -n "$cf_new_cflags" ; then
 168         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 169         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
 170 fi
 171
 172 if test -n "$cf_new_cppflags" ; then
 173         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 174         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
 175 fi
 176
 177 if test -n "$cf_new_extra_cppflags" ; then
 178         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 179         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
 180 fi
 181
 182 AC_SUBST(EXTRA_CPPFLAGS)
 183
 184 ])dnl
 185 dnl ---------------------------------------------------------------------------
 186 dnl CF_ADD_INCDIR version: 17 updated: 2021/09/04 06:35:04
 187 dnl -------------
 188 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it is
 189 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 190 dnl but old versions (and some misinstalled ones) need that.  To make things
 191 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 192 dnl the include-path).
 193 AC_DEFUN([CF_ADD_INCDIR],
 194 [
 195 if test -n "$1" ; then
 196   for cf_add_incdir in $1
 197   do
 198         while test "$cf_add_incdir" != /usr/include
 199         do
 200           if test -d "$cf_add_incdir"
 201           then
 202                 cf_have_incdir=no
 203                 if test -n "$CFLAGS$CPPFLAGS" ; then
 204                   # a loop is needed to ensure we can add subdirs of existing dirs
 205                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 206                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 207                           cf_have_incdir=yes; break
 208                         fi
 209                   done
 210                 fi
 211
 212                 if test "$cf_have_incdir" = no ; then
 213                   if test "$cf_add_incdir" = /usr/local/include ; then
 214                         if test "$GCC" = yes
 215                         then
 216                           cf_save_CPPFLAGS=$CPPFLAGS
 217                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
 218                           AC_TRY_COMPILE([#include <stdio.h>],
 219                                   [printf("Hello")],
 220                                   [],
 221                                   [cf_have_incdir=yes])
 222                           CPPFLAGS=$cf_save_CPPFLAGS
 223                         fi
 224                   fi
 225                 fi
 226
 227                 if test "$cf_have_incdir" = no ; then
 228                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 229                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 230
 231                   cf_top_incdir=`echo "$cf_add_incdir" | sed -e 's%/include/.*$%/include%'`
 232                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 233                   cf_add_incdir="$cf_top_incdir"
 234                 else
 235                   break
 236                 fi
 237           else
 238                 break
 239           fi
 240         done
 241   done
 242 fi
 243 ])dnl
 244 dnl ---------------------------------------------------------------------------
 245 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 246 dnl ----------
 247 dnl Add a library, used to enforce consistency.
 248 dnl
 249 dnl $1 = library to add, without the "-l"
 250 dnl $2 = variable to update (default $LIBS)
 251 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 252 dnl ---------------------------------------------------------------------------
 253 dnl CF_ADD_LIBDIR version: 11 updated: 2020/12/31 20:19:42
 254 dnl -------------
 255 dnl     Adds to the library-path
 256 dnl
 257 dnl     Some machines have trouble with multiple -L options.
 258 dnl
 259 dnl $1 is the (list of) directory(s) to add
 260 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 261 dnl
 262 AC_DEFUN([CF_ADD_LIBDIR],
 263 [
 264 if test -n "$1" ; then
 265         for cf_add_libdir in $1
 266         do
 267                 if test "$cf_add_libdir" = /usr/lib ; then
 268                         :
 269                 elif test -d "$cf_add_libdir"
 270                 then
 271                         cf_have_libdir=no
 272                         if test -n "$LDFLAGS$LIBS" ; then
 273                                 # a loop is needed to ensure we can add subdirs of existing dirs
 274                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 275                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 276                                                 cf_have_libdir=yes; break
 277                                         fi
 278                                 done
 279                         fi
 280                         if test "$cf_have_libdir" = no ; then
 281                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 282                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 283                         fi
 284                 fi
 285         done
 286 fi
 287 ])dnl
 288 dnl ---------------------------------------------------------------------------
 289 dnl CF_ADD_LIBS version: 3 updated: 2019/11/02 16:47:33
 290 dnl -----------
 291 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 292 dnl prepended to an existing list, since their dependencies are assumed to
 293 dnl already exist in the list.
 294 dnl
 295 dnl $1 = libraries to add, with the "-l", etc.
 296 dnl $2 = variable to update (default $LIBS)
 297 AC_DEFUN([CF_ADD_LIBS],[
 298 cf_add_libs="[$]ifelse($2,,LIBS,[$2])"
 299 # reverse order
 300 cf_add_0lib=
 301 for cf_add_1lib in $1; do cf_add_0lib="$cf_add_1lib $cf_add_0lib"; done
 302 # filter duplicates
 303 for cf_add_1lib in $cf_add_0lib; do
 304         for cf_add_2lib in $cf_add_libs; do
 305                 if test "x$cf_add_1lib" = "x$cf_add_2lib"; then
 306                         cf_add_1lib=
 307                         break
 308                 fi
 309         done
 310         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_1lib $cf_add_libs"
 311 done
 312 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 313 ])dnl
 314 dnl ---------------------------------------------------------------------------
 315 dnl CF_ADD_LIB_AFTER version: 3 updated: 2013/07/09 21:27:22
 316 dnl ----------------
 317 dnl Add a given library after another, e.g., following the one it satisfies a
 318 dnl dependency for.
 319 dnl
 320 dnl $1 = the first library
 321 dnl $2 = its dependency
 322 AC_DEFUN([CF_ADD_LIB_AFTER],[
 323 CF_VERBOSE(...before $LIBS)
 324 LIBS=`echo "$LIBS" | sed -e "s/[[       ]][[    ]]*/ /g" -e "s%$1 %$1 $2 %" -e 's%  % %g'`
 325 CF_VERBOSE(...after  $LIBS)
 326 ])dnl
 327 dnl ---------------------------------------------------------------------------
 328 dnl CF_ADD_SUBDIR_PATH version: 5 updated: 2020/12/31 20:19:42
 329 dnl ------------------
 330 dnl Append to a search-list for a nonstandard header/lib-file
 331 dnl     $1 = the variable to return as result
 332 dnl     $2 = the package name
 333 dnl     $3 = the subdirectory, e.g., bin, include or lib
 334 dnl $4 = the directory under which we will test for subdirectories
 335 dnl $5 = a directory that we do not want $4 to match
 336 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 337 [
 338 test "x$4" != "x$5" && \
 339 test -d "$4" && \
 340 ifelse([$5],NONE,,[{ test -z "$5" || test "x$5" = xNONE || test "x$4" != "x$5"; } &&]) {
 341         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 342         test -d "$4/$3" &&          $1="[$]$1 $4/$3"
 343         test -d "$4/$3/$2" &&       $1="[$]$1 $4/$3/$2"
 344         test -d "$4/$3/$2/$3" &&    $1="[$]$1 $4/$3/$2/$3"
 345         test -d "$4/$2/$3" &&       $1="[$]$1 $4/$2/$3"
 346         test -d "$4/$2/$3/$2" &&    $1="[$]$1 $4/$2/$3/$2"
 347 }
 348 ])dnl
 349 dnl ---------------------------------------------------------------------------
 350 dnl CF_APPEND_CFLAGS version: 3 updated: 2021/09/05 17:25:40
 351 dnl ----------------
 352 dnl Use CF_ADD_CFLAGS after first checking for potential redefinitions.
 353 dnl $1 = flags to add
 354 dnl $2 = if given makes this macro verbose.
 355 define([CF_APPEND_CFLAGS],
 356 [
 357 for cf_add_cflags in $1
 358 do
 359         case "x$cf_add_cflags" in
 360         (x-[[DU]]*)
 361                 CF_REMOVE_CFLAGS($cf_add_cflags,CFLAGS,[$2])
 362                 CF_REMOVE_CFLAGS($cf_add_cflags,CPPFLAGS,[$2])
 363                 ;;
 364         esac
 365         CF_ADD_CFLAGS([$cf_add_cflags],[$2])
 366 done
 367 ])dnl
 368 dnl ---------------------------------------------------------------------------
 369 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
 370 dnl --------------
 371 dnl use this macro for appending text without introducing an extra blank at
 372 dnl the beginning
 373 define([CF_APPEND_TEXT],
 374 [
 375         test -n "[$]$1" && $1="[$]$1 "
 376         $1="[$]{$1}$2"
 377 ])dnl
 378 dnl ---------------------------------------------------------------------------
 379 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 380 dnl --------------
 381 dnl Allow user to disable a normally-on option.
 382 AC_DEFUN([CF_ARG_DISABLE],
 383 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 384 dnl ---------------------------------------------------------------------------
 385 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
 386 dnl -------------
 387 dnl Allow user to enable a normally-off option.
 388 AC_DEFUN([CF_ARG_ENABLE],
 389 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
 390 dnl ---------------------------------------------------------------------------
 391 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 392 dnl -------------
 393 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 394 dnl values.
 395 dnl
 396 dnl Parameters:
 397 dnl $1 = option name
 398 dnl $2 = help-string
 399 dnl $3 = action to perform if option is not default
 400 dnl $4 = action if perform if option is default
 401 dnl $5 = default option value (either 'yes' or 'no')
 402 AC_DEFUN([CF_ARG_OPTION],
 403 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 404         if test "$enableval" != "$5" ; then
 405 ifelse([$3],,[    :]dnl
 406 ,[    $3]) ifelse([$4],,,[
 407         else
 408                 $4])
 409         fi],[enableval=$5 ifelse([$4],,,[
 410         $4
 411 ])dnl
 412 ])])dnl
 413 dnl ---------------------------------------------------------------------------
 414 dnl CF_C11_NORETURN version: 3 updated: 2021/03/28 11:36:23
 415 dnl ---------------
 416 AC_DEFUN([CF_C11_NORETURN],
 417 [
 418 AC_MSG_CHECKING(if you want to use C11 _Noreturn feature)
 419 CF_ARG_ENABLE(stdnoreturn,
 420         [  --enable-stdnoreturn    enable C11 _Noreturn feature for diagnostics],
 421         [enable_stdnoreturn=yes],
 422         [enable_stdnoreturn=no])
 423 AC_MSG_RESULT($enable_stdnoreturn)
 424
 425 if test $enable_stdnoreturn = yes; then
 426 AC_CACHE_CHECK([for C11 _Noreturn feature], cf_cv_c11_noreturn,
 427         [AC_TRY_COMPILE([
 428 #include <stdio.h>
 429 #include <stdlib.h>
 430 #include <stdnoreturn.h>
 431 static _Noreturn void giveup(void) { exit(0); }
 432         ],
 433         [if (feof(stdin)) giveup()],
 434         cf_cv_c11_noreturn=yes,
 435         cf_cv_c11_noreturn=no)
 436         ])
 437 else
 438         cf_cv_c11_noreturn=no,
 439 fi
 440
 441 if test "$cf_cv_c11_noreturn" = yes; then
 442         AC_DEFINE(HAVE_STDNORETURN_H, 1,[Define if <stdnoreturn.h> header is available and working])
 443         AC_DEFINE_UNQUOTED(STDC_NORETURN,_Noreturn,[Define if C11 _Noreturn keyword is supported])
 444         HAVE_STDNORETURN_H=1
 445 else
 446         HAVE_STDNORETURN_H=0
 447 fi
 448
 449 AC_SUBST(HAVE_STDNORETURN_H)
 450 AC_SUBST(STDC_NORETURN)
 451 ])dnl
 452 dnl ---------------------------------------------------------------------------
 453 dnl CF_CC_ENV_FLAGS version: 10 updated: 2020/12/31 18:40:20
 454 dnl ---------------
 455 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 456 dnl into CC.  This will not help with broken scripts that wrap the compiler
 457 dnl with options, but eliminates a more common category of user confusion.
 458 dnl
 459 dnl In particular, it addresses the problem of being able to run the C
 460 dnl preprocessor in a consistent manner.
 461 dnl
 462 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 463 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 464 dnl outweighs that limitation.
 465 AC_DEFUN([CF_CC_ENV_FLAGS],
 466 [
 467 # This should have been defined by AC_PROG_CC
 468 : "${CC:=cc}"
 469
 470 AC_MSG_CHECKING(\$CFLAGS variable)
 471 case "x$CFLAGS" in
 472 (*-[[IUD]]*)
 473         AC_MSG_RESULT(broken)
 474         AC_MSG_WARN(your environment uses the CFLAGS variable to hold CPPFLAGS options)
 475         cf_flags="$CFLAGS"
 476         CFLAGS=
 477         for cf_arg in $cf_flags
 478         do
 479                 CF_ADD_CFLAGS($cf_arg)
 480         done
 481         ;;
 482 (*)
 483         AC_MSG_RESULT(ok)
 484         ;;
 485 esac
 486
 487 AC_MSG_CHECKING(\$CC variable)
 488 case "$CC" in
 489 (*[[\ \ ]]-*)
 490         AC_MSG_RESULT(broken)
 491         AC_MSG_WARN(your environment uses the CC variable to hold CFLAGS/CPPFLAGS options)
 492         # humor him...
 493         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
 494         cf_flags=`echo "$CC" | ${AWK:-awk} -v prog="$cf_prog" '{ printf("%s", [substr]([$]0,1+length(prog))); }'`
 495         CC="$cf_prog"
 496         for cf_arg in $cf_flags
 497         do
 498                 case "x$cf_arg" in
 499                 (x-[[IUDfgOW]]*)
 500                         CF_ADD_CFLAGS($cf_arg)
 501                         ;;
 502                 (*)
 503                         CC="$CC $cf_arg"
 504                         ;;
 505                 esac
 506         done
 507         CF_VERBOSE(resulting CC: '$CC')
 508         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 509         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 510         ;;
 511 (*)
 512         AC_MSG_RESULT(ok)
 513         ;;
 514 esac
 515 ])dnl
 516 dnl ---------------------------------------------------------------------------
 517 dnl CF_CHECK_CACHE version: 13 updated: 2020/12/31 10:54:15
 518 dnl --------------
 519 dnl Check if we're accidentally using a cache from a different machine.
 520 dnl Derive the system name, as a check for reusing the autoconf cache.
 521 dnl
 522 dnl If we've packaged config.guess and config.sub, run that (since it does a
 523 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 524 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 525 dnl which is useful in cross-compiles.
 526 dnl
 527 dnl Note: we would use $ac_config_sub, but that is one of the places where
 528 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 529 AC_DEFUN([CF_CHECK_CACHE],
 530 [
 531 if test -f "$srcdir/config.guess" || test -f "$ac_aux_dir/config.guess" ; then
 532         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 533         system_name="$host_os"
 534 else
 535         system_name="`(uname -s -r) 2>/dev/null`"
 536         if test -z "$system_name" ; then
 537                 system_name="`(hostname) 2>/dev/null`"
 538         fi
 539 fi
 540 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 541 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 542
 543 test -z "$system_name" && system_name="$cf_cv_system_name"
 544 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 545
 546 if test ".$system_name" != ".$cf_cv_system_name" ; then
 547         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 548         AC_MSG_ERROR("Please remove config.cache and try again.")
 549 fi
 550 ])dnl
 551 dnl ---------------------------------------------------------------------------
 552 dnl CF_CHECK_CFLAGS version: 4 updated: 2021/01/02 19:22:58
 553 dnl ---------------
 554 dnl Conditionally add to $CFLAGS and $CPPFLAGS values which are derived from
 555 dnl a build-configuration such as imake.  These have the pitfall that they
 556 dnl often contain compiler-specific options which we cannot use, mixed with
 557 dnl preprocessor options that we usually can.
 558 AC_DEFUN([CF_CHECK_CFLAGS],
 559 [
 560 CF_VERBOSE(checking additions to CFLAGS)
 561 cf_check_cflags="$CFLAGS"
 562 cf_check_cppflags="$CPPFLAGS"
 563 CF_ADD_CFLAGS($1,yes)
 564 if test "x$cf_check_cflags" != "x$CFLAGS" ; then
 565 AC_TRY_LINK([#include <stdio.h>],[printf("Hello world");],,
 566         [CF_VERBOSE(test-compile failed.  Undoing change to \$CFLAGS)
 567          if test "x$cf_check_cppflags" != "x$CPPFLAGS" ; then
 568                  CF_VERBOSE(but keeping change to \$CPPFLAGS)
 569          fi
 570          CFLAGS="$cf_check_cflags"])
 571 fi
 572 ])dnl
 573 dnl ---------------------------------------------------------------------------
 574 dnl CF_CHECK_CURSES_LIB version: 4 updated: 2021/09/05 17:25:40
 575 dnl -------------------
 576 dnl $1 = nominal library name, used also for header lookup
 577 dnl $2 = suffix to append to library name
 578 dnl $3 = function to check for using AC_CHECK_LIB
 579 dnl $4 = optional parameter list for $3
 580 AC_DEFUN([CF_CHECK_CURSES_LIB],
 581 [
 582 AC_REQUIRE([CF_PKG_CONFIG])
 583
 584 cf_have_curses_lib=no
 585
 586 : ${NCURSES_CONFIG_PKG:=none}
 587 if test "x${NCURSES_CONFIG_PKG}" = xnone; then
 588         :
 589 elif test "x${PKG_CONFIG:=none}" != xnone; then
 590         AC_MSG_CHECKING(pkg-config for $1$2)
 591         if "$PKG_CONFIG" --exists "$1$2" ; then
 592                 AC_MSG_RESULT(yes)
 593
 594                 AC_MSG_CHECKING(if the $1$2 package files work)
 595
 596                 cf_save_CFLAGS="$CFLAGS"
 597                 cf_save_CPPFLAGS="$CPPFLAGS"
 598                 cf_save_LIBS="$LIBS"
 599
 600                 CF_APPEND_CFLAGS(`$PKG_CONFIG --cflags "$1$2"`)
 601                 CF_ADD_LIBS(`$PKG_CONFIG --libs "$1$2"`)
 602
 603                 AC_TRY_LINK([#include <$1.h>],
 604                         [(void) $3 ( ]ifelse([$4],,,[[$4]])[ );],
 605                         [AC_TRY_RUN([#include <$1.h>
 606                                 int main(void)
 607                                 { (void) $3 ( ]ifelse([$4],,,[[$4]])[ ); return 0; }],
 608                                 [cf_have_curses_lib=yes],
 609                                 [cf_have_curses_lib=no],
 610                                 [cf_have_curses_lib=maybe])],
 611                         [cf_have_curses_lib=no])
 612                 AC_MSG_RESULT($cf_have_curses_lib)
 613                 test "$cf_have_curses_lib" = maybe && cf_have_curses_lib=yes
 614                 if test "$cf_have_curses_lib" = "yes"
 615                 then
 616                         CF_UPPER(cf_upper,have_lib$1)
 617                         AC_DEFINE_UNQUOTED($cf_upper,1)
 618                 else
 619                         CFLAGS="$cf_save_CFLAGS"
 620                         CPPFLAGS="$cf_save_CPPFLAGS"
 621                         LIBS="$cf_save_LIBS"
 622                 fi
 623         fi
 624 fi
 625 if test "$cf_have_curses_lib" = no; then
 626         AC_CHECK_LIB($1$2,$3,[
 627                 CF_UPPER(cf_upper,have_lib$1)
 628                 CF_ADD_LIBS(-l$1$2)
 629                 AC_DEFINE_UNQUOTED($cf_upper,1)])
 630 fi
 631 ])dnl
 632 dnl ---------------------------------------------------------------------------
 633 dnl CF_CLANG_COMPILER version: 8 updated: 2021/01/01 13:31:04
 634 dnl -----------------
 635 dnl Check if the given compiler is really clang.  clang's C driver defines
 636 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
 637 dnl not ignore some gcc options.
 638 dnl
 639 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
 640 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
 641 dnl the wrappers for gcc and g++ warnings.
 642 dnl
 643 dnl $1 = GCC (default) or GXX
 644 dnl $2 = CLANG_COMPILER (default)
 645 dnl $3 = CFLAGS (default) or CXXFLAGS
 646 AC_DEFUN([CF_CLANG_COMPILER],[
 647 ifelse([$2],,CLANG_COMPILER,[$2])=no
 648
 649 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
 650         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
 651         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
 652         AC_TRY_COMPILE([],[
 653 #ifdef __clang__
 654 #else
 655 make an error
 656 #endif
 657 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
 658 ],[])
 659         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
 660         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
 661 fi
 662
 663 CLANG_VERSION=none
 664
 665 if test "x$ifelse([$2],,CLANG_COMPILER,[$2])" = "xyes" ; then
 666         case "$CC" in
 667         (c[[1-9]][[0-9]]|*/c[[1-9]][[0-9]])
 668                 AC_MSG_WARN(replacing broken compiler alias $CC)
 669                 CFLAGS="$CFLAGS -std=`echo "$CC" | sed -e 's%.*/%%'`"
 670                 CC=clang
 671                 ;;
 672         esac
 673
 674         AC_MSG_CHECKING(version of $CC)
 675         CLANG_VERSION="`$CC --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(CLANG[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
 676         test -z "$CLANG_VERSION" && CLANG_VERSION=unknown
 677         AC_MSG_RESULT($CLANG_VERSION)
 678
 679         for cf_clang_opt in \
 680                 -Qunused-arguments \
 681                 -Wno-error=implicit-function-declaration
 682         do
 683                 AC_MSG_CHECKING(if option $cf_clang_opt works)
 684                 cf_save_CFLAGS="$CFLAGS"
 685                 CFLAGS="$CFLAGS $cf_clang_opt"
 686                 AC_TRY_LINK([
 687                         #include <stdio.h>],[
 688                         printf("hello!\\n");],[
 689                         cf_clang_optok=yes],[
 690                         cf_clang_optok=no])
 691                 AC_MSG_RESULT($cf_clang_optok)
 692                 CFLAGS="$cf_save_CFLAGS"
 693                 if test "$cf_clang_optok" = yes; then
 694                         CF_VERBOSE(adding option $cf_clang_opt)
 695                         CF_APPEND_TEXT(CFLAGS,$cf_clang_opt)
 696                 fi
 697         done
 698 fi
 699 ])
 700 dnl ---------------------------------------------------------------------------
 701 dnl CF_CONST_X_STRING version: 7 updated: 2021/06/07 17:39:17
 702 dnl -----------------
 703 dnl The X11R4-X11R6 Xt specification uses an ambiguous String type for most
 704 dnl character-strings.
 705 dnl
 706 dnl It is ambiguous because the specification accommodated the pre-ANSI
 707 dnl compilers bundled by more than one vendor in lieu of providing a standard C
 708 dnl compiler other than by costly add-ons.  Because of this, the specification
 709 dnl did not take into account the use of const for telling the compiler that
 710 dnl string literals would be in readonly memory.
 711 dnl
 712 dnl As a workaround, one could (starting with X11R5) define XTSTRINGDEFINES, to
 713 dnl let the compiler decide how to represent Xt's strings which were #define'd.
 714 dnl That does not solve the problem of using the block of Xt's strings which
 715 dnl are compiled into the library (and is less efficient than one might want).
 716 dnl
 717 dnl Xt specification 7 introduces the _CONST_X_STRING symbol which is used both
 718 dnl when compiling the library and compiling using the library, to tell the
 719 dnl compiler that String is const.
 720 AC_DEFUN([CF_CONST_X_STRING],
 721 [
 722 AC_REQUIRE([AC_PATH_XTRA])
 723
 724 CF_SAVE_XTRA_FLAGS([CF_CONST_X_STRING])
 725
 726 AC_TRY_COMPILE(
 727 [
 728 #include <stdlib.h>
 729 #include <X11/Intrinsic.h>
 730 ],
 731 [String foo = malloc(1); free((void*)foo)],[
 732
 733 AC_CACHE_CHECK(for X11/Xt const-feature,cf_cv_const_x_string,[
 734         AC_TRY_COMPILE(
 735                 [
 736 #define _CONST_X_STRING /* X11R7.8 (perhaps) */
 737 #undef  XTSTRINGDEFINES /* X11R5 and later */
 738 #include <stdlib.h>
 739 #include <X11/Intrinsic.h>
 740                 ],[String foo = malloc(1); *foo = 0],[
 741                         cf_cv_const_x_string=no
 742                 ],[
 743                         cf_cv_const_x_string=yes
 744                 ])
 745 ])
 746
 747 CF_RESTORE_XTRA_FLAGS([CF_CONST_X_STRING])
 748
 749 case "$cf_cv_const_x_string" in
 750 (no)
 751         CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
 752         ;;
 753 (*)
 754         CF_APPEND_TEXT(CPPFLAGS,-D_CONST_X_STRING)
 755         ;;
 756 esac
 757
 758 ])
 759 ])dnl
 760 dnl ---------------------------------------------------------------------------
 761 dnl CF_CURSES_ACS_MAP version: 8 updated: 2021/01/04 19:45:09
 762 dnl -----------------
 763 dnl Check for likely values of acs_map[]:
 764 AC_DEFUN([CF_CURSES_ACS_MAP],
 765 [
 766 AC_REQUIRE([CF_NCURSES_WRAP_PREFIX])dnl
 767 AC_CACHE_CHECK(for alternate character set array, cf_cv_curses_acs_map,[
 768 cf_cv_curses_acs_map=unknown
 769 for name in acs_map _acs_map __acs_map ${NCURSES_WRAP_PREFIX}acs_map
 770 do
 771 AC_TRY_LINK([
 772 #include <${cf_cv_ncurses_header:-curses.h}>
 773 ],[
 774 ${name}['k'] = ACS_PLUS
 775 ],[cf_cv_curses_acs_map=$name; break])
 776 done
 777 ])
 778
 779 test "$cf_cv_curses_acs_map" != unknown && AC_DEFINE_UNQUOTED(CURSES_ACS_ARRAY,$cf_cv_curses_acs_map,[Define as needed to override ncurses prefix _nc_])
 780 ])
 781 dnl ---------------------------------------------------------------------------
 782 dnl CF_CURSES_CHECK_DATA version: 10 updated: 2021/01/04 19:45:09
 783 dnl --------------------
 784 dnl Check if curses.h defines the given data/variable.
 785 dnl Use this after CF_NCURSES_CONFIG or CF_CURSES_CONFIG.
 786 dnl
 787 dnl $1 = data item(s) to check for
 788 dnl $2 = action on success, e.g., "break" to quit checking a series of choices
 789 AC_DEFUN([CF_CURSES_CHECK_DATA],
 790 [
 791 for cf_data in $1
 792 do
 793 AC_MSG_CHECKING(for data $cf_data declaration in ${cf_cv_ncurses_header:-curses.h})
 794
 795 AC_TRY_COMPILE(CF__CURSES_HEAD,
 796 CF__CURSES_DATA(foo,$cf_data)
 797 ,[cf_result=yes
 798 ],[cf_result=no])
 799 AC_MSG_RESULT($cf_result)
 800
 801 if test "$cf_result" = yes ; then
 802         CF_UPPER(cf_result,have_curses_data_$cf_data)
 803         AC_DEFINE_UNQUOTED($cf_result)
 804         ifelse($2,,,[$2])
 805 else
 806         AC_MSG_CHECKING(for data $cf_data in library)
 807         # BSD linkers insist on making weak linkage, but resolve at runtime.
 808         AC_TRY_RUN(CF__CURSES_HEAD
 809 [
 810 extern char $cf_data;
 811 int main(void)
 812 {
 813         ]CF__CURSES_DATA(foo,$cf_data)[
 814         ${cf_cv_main_return:-return}(foo == 0);
 815 }],[cf_result=yes
 816 ],[cf_result=no],[
 817         # cross-compiling
 818         AC_TRY_LINK(CF__CURSES_HEAD
 819 [extern char $cf_data;],[
 820         do {
 821                 ]CF__CURSES_DATA(foo,$cf_data)[
 822                 ${cf_cv_main_return:-return}(foo == 0);
 823         } while (0)
 824 ],[cf_result=yes],[cf_result=no])
 825 ])
 826         AC_MSG_RESULT($cf_result)
 827         if test "$cf_result" = yes ; then
 828                 CF_UPPER(cf_result,decl_curses_data_$cf_data)
 829                 AC_DEFINE_UNQUOTED($cf_result)
 830                 # do not exit loop here, since we prefer system's declarations
 831         fi
 832 fi
 833 done
 834 ])dnl
 835 dnl ---------------------------------------------------------------------------
 836 dnl CF_CURSES_CHECK_TYPE version: 5 updated: 2021/01/04 19:45:09
 837 dnl --------------------
 838 dnl Check if curses.h defines the given type
 839 AC_DEFUN([CF_CURSES_CHECK_TYPE],
 840 [
 841 AC_MSG_CHECKING(for type $1 in ${cf_cv_ncurses_header:-curses.h})
 842 AC_TRY_COMPILE([
 843 #ifndef _XOPEN_SOURCE_EXTENDED
 844 #define _XOPEN_SOURCE_EXTENDED
 845 #endif
 846 #include <${cf_cv_ncurses_header:-curses.h}>],[
 847 $1 foo
 848 ],cf_result=yes,cf_result=no)
 849 AC_MSG_RESULT($cf_result)
 850 if test "$cf_result" = yes ; then
 851         CF_UPPER(cf_result,have_type_$1)
 852         AC_DEFINE_UNQUOTED($cf_result,1,[Define to 1 if we have type $1])
 853 else
 854         AC_DEFINE_UNQUOTED($1,$2,[Define to appropriate type if $1 is not declared])
 855 fi
 856 ])dnl
 857 dnl ---------------------------------------------------------------------------
 858 dnl CF_CURSES_CONFIG version: 2 updated: 2006/10/29 11:06:27
 859 dnl ----------------
 860 dnl Tie together the configure-script macros for curses.  It may be ncurses,
 861 dnl but unless asked, we do not make a special search for ncurses.  However,
 862 dnl still check for the ncurses version number, for use in other macros.
 863 AC_DEFUN([CF_CURSES_CONFIG],
 864 [
 865 CF_CURSES_CPPFLAGS
 866 CF_NCURSES_VERSION
 867 CF_CURSES_LIBS
 868 ])dnl
 869 dnl ---------------------------------------------------------------------------
 870 dnl CF_CURSES_CPPFLAGS version: 14 updated: 2021/01/02 09:31:20
 871 dnl ------------------
 872 dnl Look for the curses headers.
 873 AC_DEFUN([CF_CURSES_CPPFLAGS],[
 874
 875 AC_CACHE_CHECK(for extra include directories,cf_cv_curses_incdir,[
 876 cf_cv_curses_incdir=no
 877 case "$host_os" in
 878 (hpux10.*)
 879         if test "x$cf_cv_screen" = "xcurses_colr"
 880         then
 881                 test -d /usr/include/curses_colr && \
 882                 cf_cv_curses_incdir="-I/usr/include/curses_colr"
 883         fi
 884         ;;
 885 (sunos3*|sunos4*)
 886         if test "x$cf_cv_screen" = "xcurses_5lib"
 887         then
 888                 test -d /usr/5lib && \
 889                 test -d /usr/5include && \
 890                 cf_cv_curses_incdir="-I/usr/5include"
 891         fi
 892         ;;
 893 esac
 894 ])
 895 if test "$cf_cv_curses_incdir" != no
 896 then
 897         CF_APPEND_TEXT(CPPFLAGS,$cf_cv_curses_incdir)
 898 fi
 899
 900 CF_CURSES_HEADER
 901 CF_TERM_HEADER
 902 ])dnl
 903 dnl ---------------------------------------------------------------------------
 904 dnl CF_CURSES_FUNCS version: 20 updated: 2020/12/31 20:19:42
 905 dnl ---------------
 906 dnl Curses-functions are a little complicated, since a lot of them are macros.
 907 AC_DEFUN([CF_CURSES_FUNCS],
 908 [
 909 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
 910 AC_REQUIRE([CF_XOPEN_CURSES])
 911 AC_REQUIRE([CF_CURSES_TERM_H])
 912 AC_REQUIRE([CF_CURSES_UNCTRL_H])
 913 for cf_func in $1
 914 do
 915         CF_UPPER(cf_tr_func,$cf_func)
 916         AC_MSG_CHECKING(for ${cf_func})
 917         CF_MSG_LOG(${cf_func})
 918         AC_CACHE_VAL(cf_cv_func_$cf_func,[
 919                 eval cf_result='$ac_cv_func_'$cf_func
 920                 if test ".$cf_result" != ".no"; then
 921                         AC_TRY_LINK(CF__CURSES_HEAD,
 922                         [
 923 #ifndef ${cf_func}
 924 long foo = (long)(&${cf_func});
 925 fprintf(stderr, "testing linkage of $cf_func:%p\\n", (void *)foo);
 926 if (foo + 1234L > 5678L)
 927         ${cf_cv_main_return:-return}(foo != 0);
 928 #endif
 929                         ],
 930                         [cf_result=yes],
 931                         [cf_result=no])
 932                 fi
 933                 eval 'cf_cv_func_'$cf_func'="$cf_result"'
 934         ])
 935         # use the computed/retrieved cache-value:
 936         eval 'cf_result=$cf_cv_func_'$cf_func
 937         AC_MSG_RESULT($cf_result)
 938         if test "$cf_result" != no; then
 939                 AC_DEFINE_UNQUOTED(HAVE_${cf_tr_func})
 940         fi
 941 done
 942 ])dnl
 943 dnl ---------------------------------------------------------------------------
 944 dnl CF_CURSES_HEADER version: 6 updated: 2022/12/02 20:06:52
 945 dnl ----------------
 946 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
 947 dnl variations of ncurses' installs.
 948 dnl
 949 dnl $1 = ncurses when looking for ncurses, or is empty
 950 AC_DEFUN([CF_CURSES_HEADER],[
 951 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
 952 cf_cv_ncurses_header=none
 953 for cf_header in \
 954         ncurses.h ifelse($1,,,[$1/ncurses.h]) \
 955         curses.h ifelse($1,,,[$1/curses.h]) ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
 956 do
 957 AC_TRY_COMPILE([#include <${cf_header}>],
 958         [initscr(); endwin()],
 959         [cf_cv_ncurses_header=$cf_header; break],[])
 960 done
 961 ])
 962
 963 if test "$cf_cv_ncurses_header" = none ; then
 964         AC_MSG_ERROR(No curses header-files found)
 965 fi
 966
 967 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
 968 AC_CHECK_HEADERS($cf_cv_ncurses_header)
 969 ])dnl
 970 dnl ---------------------------------------------------------------------------
 971 dnl CF_CURSES_LIBS version: 45 updated: 2022/12/02 20:06:52
 972 dnl --------------
 973 dnl Look for the curses libraries.  Older curses implementations may require
 974 dnl termcap/termlib to be linked as well.  Call CF_CURSES_CPPFLAGS first.
 975 AC_DEFUN([CF_CURSES_LIBS],[
 976
 977 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
 978 AC_MSG_CHECKING(if we have identified curses libraries)
 979 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
 980         [initscr(); endwin()],
 981         cf_result=yes,
 982         cf_result=no)
 983 AC_MSG_RESULT($cf_result)
 984
 985 if test "$cf_result" = no ; then
 986 case "$host_os" in
 987 (freebsd*)
 988         AC_CHECK_LIB(mytinfo,tgoto,[CF_ADD_LIBS(-lmytinfo)])
 989         ;;
 990 (hpux10.*)
 991         # Looking at HPUX 10.20, the Hcurses library is the oldest (1997), cur_colr
 992         # next (1998), and xcurses "newer" (2000).  There is no header file for
 993         # Hcurses; the subdirectory curses_colr has the headers (curses.h and
 994         # term.h) for cur_colr
 995         if test "x$cf_cv_screen" = "xcurses_colr"
 996         then
 997                 AC_CHECK_LIB(cur_colr,initscr,[
 998                         CF_ADD_LIBS(-lcur_colr)
 999                         ac_cv_func_initscr=yes
1000                         ],[
1001                 AC_CHECK_LIB(Hcurses,initscr,[
1002                         # HP's header uses __HP_CURSES, but user claims _HP_CURSES.
1003                         CF_ADD_LIBS(-lHcurses)
1004                         CF_APPEND_TEXT(CPPFLAGS,-D__HP_CURSES -D_HP_CURSES)
1005                         ac_cv_func_initscr=yes
1006                         ])])
1007         fi
1008         ;;
1009 (linux*)
1010         case `arch 2>/dev/null` in
1011         (x86_64)
1012                 if test -d /lib64
1013                 then
1014                         CF_ADD_LIBDIR(/lib64)
1015                 else
1016                         CF_ADD_LIBDIR(/lib)
1017                 fi
1018                 ;;
1019         (*)
1020                 CF_ADD_LIBDIR(/lib)
1021                 ;;
1022         esac
1023         ;;
1024 (sunos3*|sunos4*)
1025         if test "x$cf_cv_screen" = "xcurses_5lib"
1026         then
1027                 if test -d /usr/5lib ; then
1028                         CF_ADD_LIBDIR(/usr/5lib)
1029                         CF_ADD_LIBS(-lcurses -ltermcap)
1030                 fi
1031         fi
1032         ac_cv_func_initscr=yes
1033         ;;
1034 esac
1035
1036 if test ".$ac_cv_func_initscr" != .yes ; then
1037         cf_save_LIBS="$LIBS"
1038
1039         if test ".${cf_cv_ncurses_version:-no}" != .no
1040         then
1041                 cf_check_list="ncurses curses cursesX"
1042         else
1043                 cf_check_list="cursesX curses ncurses"
1044         fi
1045
1046         # Check for library containing tgoto.  Do this before curses library
1047         # because it may be needed to link the test-case for initscr.
1048         if test "x$cf_term_lib" = x
1049         then
1050                 AC_CHECK_FUNC(tgoto,[cf_term_lib=predefined],[
1051                         for cf_term_lib in $cf_check_list otermcap termcap tinfo termlib unknown
1052                         do
1053                                 AC_CHECK_LIB($cf_term_lib,tgoto,[
1054                                         : "${cf_nculib_root:=$cf_term_lib}"
1055                                         break
1056                                 ])
1057                         done
1058                 ])
1059         fi
1060
1061         # Check for library containing initscr
1062         test "$cf_term_lib" != predefined && test "$cf_term_lib" != unknown && LIBS="-l$cf_term_lib $cf_save_LIBS"
1063         if test "x$cf_curs_lib" = x
1064         then
1065                 for cf_curs_lib in $cf_check_list xcurses jcurses pdcurses unknown
1066                 do
1067                         LIBS="-l$cf_curs_lib $cf_save_LIBS"
1068                         if test "$cf_term_lib" = unknown || test "$cf_term_lib" = "$cf_curs_lib" ; then
1069                                 AC_MSG_CHECKING(if we can link with $cf_curs_lib library)
1070                                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
1071                                         [initscr()],
1072                                         [cf_result=yes],
1073                                         [cf_result=no])
1074                                 AC_MSG_RESULT($cf_result)
1075                                 test "$cf_result" = yes && break
1076                         elif test "$cf_curs_lib" = "$cf_term_lib" ; then
1077                                 cf_result=no
1078                         elif test "$cf_term_lib" != predefined ; then
1079                                 AC_MSG_CHECKING(if we need both $cf_curs_lib and $cf_term_lib libraries)
1080                                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
1081                                         [initscr(); endwin();],
1082                                         [cf_result=no],
1083                                         [
1084                                         LIBS="-l$cf_curs_lib -l$cf_term_lib $cf_save_LIBS"
1085                                         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
1086                                                 [initscr()],
1087                                                 [cf_result=yes],
1088                                                 [cf_result=error])
1089                                         ])
1090                                 AC_MSG_RESULT($cf_result)
1091                                 test "$cf_result" != error && break
1092                         fi
1093                 done
1094         fi
1095         test "$cf_curs_lib" = unknown && AC_MSG_ERROR(no curses library found)
1096 fi
1097 fi
1098
1099 ])dnl
1100 dnl ---------------------------------------------------------------------------
1101 dnl CF_CURSES_TERM_H version: 15 updated: 2021/01/02 09:31:20
1102 dnl ----------------
1103 dnl SVr4 curses should have term.h as well (where it puts the definitions of
1104 dnl the low-level interface).  This may not be true in old/broken implementations,
1105 dnl as well as in misconfigured systems (e.g., gcc configured for Solaris 2.4
1106 dnl running with Solaris 2.5.1).
1107 AC_DEFUN([CF_CURSES_TERM_H],
1108 [
1109 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
1110
1111 AC_CACHE_CHECK(for term.h, cf_cv_term_header,[
1112
1113 # If we found <ncurses/curses.h>, look for <ncurses/term.h>, but always look
1114 # for <term.h> if we do not find the variant.
1115
1116 cf_header_list="term.h ncurses/term.h ncursesw/term.h"
1117
1118 case "${cf_cv_ncurses_header:-curses.h}" in
1119 (*/*)
1120         cf_header_item=`echo "${cf_cv_ncurses_header:-curses.h}" | sed -e 's%\..*%%' -e 's%/.*%/%'`term.h
1121         cf_header_list="$cf_header_item $cf_header_list"
1122         ;;
1123 esac
1124
1125 for cf_header in $cf_header_list
1126 do
1127         AC_TRY_COMPILE([
1128 #include <${cf_cv_ncurses_header:-curses.h}>
1129 #include <${cf_header}>],
1130         [WINDOW *x; (void)x],
1131         [cf_cv_term_header=$cf_header
1132          break],
1133         [cf_cv_term_header=no])
1134 done
1135
1136 case "$cf_cv_term_header" in
1137 (no)
1138         # If curses is ncurses, some packagers still mess it up by trying to make
1139         # us use GNU termcap.  This handles the most common case.
1140         for cf_header in ncurses/term.h ncursesw/term.h
1141         do
1142                 AC_TRY_COMPILE([
1143 #include <${cf_cv_ncurses_header:-curses.h}>
1144 #ifdef NCURSES_VERSION
1145 #include <${cf_header}>
1146 #else
1147 make an error
1148 #endif],
1149                         [WINDOW *x; (void)x],
1150                         [cf_cv_term_header=$cf_header
1151                          break],
1152                         [cf_cv_term_header=no])
1153         done
1154         ;;
1155 esac
1156 ])
1157
1158 case "$cf_cv_term_header" in
1159 (term.h)
1160         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
1161         ;;
1162 (ncurses/term.h)
1163         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
1164         ;;
1165 (ncursesw/term.h)
1166         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
1167         ;;
1168 esac
1169 ])dnl
1170 dnl ---------------------------------------------------------------------------
1171 dnl CF_CURSES_UNCTRL_H version: 8 updated: 2021/01/02 09:31:20
1172 dnl ------------------
1173 dnl Any X/Open curses implementation must have unctrl.h, but ncurses packages
1174 dnl may put it in a subdirectory (along with ncurses' other headers, of
1175 dnl course).  Packages which put the headers in inconsistent locations are
1176 dnl broken).
1177 AC_DEFUN([CF_CURSES_UNCTRL_H],
1178 [
1179 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
1180
1181 AC_CACHE_CHECK(for unctrl.h, cf_cv_unctrl_header,[
1182
1183 # If we found <ncurses/curses.h>, look for <ncurses/unctrl.h>, but always look
1184 # for <unctrl.h> if we do not find the variant.
1185
1186 cf_header_list="unctrl.h ncurses/unctrl.h ncursesw/unctrl.h"
1187
1188 case "${cf_cv_ncurses_header:-curses.h}" in
1189 (*/*)
1190         cf_header_item=`echo "${cf_cv_ncurses_header:-curses.h}" | sed -e 's%\..*%%' -e 's%/.*%/%'`unctrl.h
1191         cf_header_list="$cf_header_item $cf_header_list"
1192         ;;
1193 esac
1194
1195 for cf_header in $cf_header_list
1196 do
1197         AC_TRY_COMPILE([
1198 #include <${cf_cv_ncurses_header:-curses.h}>
1199 #include <${cf_header}>],
1200         [WINDOW *x; (void)x],
1201         [cf_cv_unctrl_header=$cf_header
1202          break],
1203         [cf_cv_unctrl_header=no])
1204 done
1205 ])
1206
1207 case "$cf_cv_unctrl_header" in
1208 (no)
1209         AC_MSG_WARN(unctrl.h header not found)
1210         ;;
1211 esac
1212
1213 case "$cf_cv_unctrl_header" in
1214 (unctrl.h)
1215         AC_DEFINE(HAVE_UNCTRL_H,1,[Define to 1 if we have unctrl.h])
1216         ;;
1217 (ncurses/unctrl.h)
1218         AC_DEFINE(HAVE_NCURSES_UNCTRL_H,1,[Define to 1 if we have ncurses/unctrl.h])
1219         ;;
1220 (ncursesw/unctrl.h)
1221         AC_DEFINE(HAVE_NCURSESW_UNCTRL_H,1,[Define to 1 if we have ncursesw/unctrl.h])
1222         ;;
1223 esac
1224 ])dnl
1225 dnl ---------------------------------------------------------------------------
1226 dnl CF_CURSES_WACS_MAP version: 8 updated: 2021/01/04 19:45:09
1227 dnl ------------------
1228 dnl Check for likely values of wacs_map[].
1229 AC_DEFUN([CF_CURSES_WACS_MAP],
1230 [
1231 AC_CACHE_CHECK(for wide alternate character set array, cf_cv_curses_wacs_map,[
1232         cf_cv_curses_wacs_map=unknown
1233         for name in wacs_map _wacs_map __wacs_map _nc_wacs _wacs_char
1234         do
1235         AC_TRY_LINK([
1236 #ifndef _XOPEN_SOURCE_EXTENDED
1237 #define _XOPEN_SOURCE_EXTENDED
1238 #endif
1239 #include <${cf_cv_ncurses_header:-curses.h}>],
1240         [void *foo = &(${name}['k']); (void)foo],
1241         [cf_cv_curses_wacs_map=$name
1242          break])
1243         done])
1244
1245 test "$cf_cv_curses_wacs_map" != unknown && AC_DEFINE_UNQUOTED(CURSES_WACS_ARRAY,$cf_cv_curses_wacs_map,[Define to name of (n)curses wide-character array])
1246 ])dnl
1247 dnl ---------------------------------------------------------------------------
1248 dnl CF_CURSES_WACS_SYMBOLS version: 4 updated: 2021/01/04 19:45:09
1249 dnl ----------------------
1250 dnl Do a check to see if the WACS_xxx constants are defined compatibly with
1251 dnl X/Open Curses.  In particular, NetBSD's implementation of the WACS_xxx
1252 dnl constants is broken since those constants do not point to cchar_t's.
1253 AC_DEFUN([CF_CURSES_WACS_SYMBOLS],
1254 [
1255 AC_REQUIRE([CF_CURSES_WACS_MAP])
1256
1257 AC_CACHE_CHECK(for wide alternate character constants, cf_cv_curses_wacs_symbols,[
1258 cf_cv_curses_wacs_symbols=no
1259 if test "$cf_cv_curses_wacs_map" != unknown
1260 then
1261         AC_TRY_LINK([
1262 #ifndef _XOPEN_SOURCE_EXTENDED
1263 #define _XOPEN_SOURCE_EXTENDED
1264 #endif
1265 #include <${cf_cv_ncurses_header:-curses.h}>],
1266         [cchar_t *foo = WACS_PLUS;
1267          ${cf_cv_curses_wacs_map}['k'] = *WACS_PLUS; (void)foo],
1268         [cf_cv_curses_wacs_symbols=yes])
1269 else
1270         AC_TRY_LINK([
1271 #ifndef _XOPEN_SOURCE_EXTENDED
1272 #define _XOPEN_SOURCE_EXTENDED
1273 #endif
1274 #include <${cf_cv_ncurses_header:-curses.h}>],
1275         [cchar_t *foo = WACS_PLUS; (void)foo],
1276         [cf_cv_curses_wacs_symbols=yes])
1277 fi
1278 ])
1279
1280 test "$cf_cv_curses_wacs_symbols" != no && AC_DEFINE(CURSES_WACS_SYMBOLS,1,[Define to 1 if (n)curses supports wide-character WACS_ symbols])
1281 ])dnl
1282 dnl ---------------------------------------------------------------------------
1283 dnl CF_DIRNAME version: 5 updated: 2020/12/31 20:19:42
1284 dnl ----------
1285 dnl "dirname" is not portable, so we fake it with a shell script.
1286 AC_DEFUN([CF_DIRNAME],[$1=`echo "$2" | sed -e 's%/[[^/]]*$%%'`])dnl
1287 dnl ---------------------------------------------------------------------------
1288 dnl CF_DISABLE_ECHO version: 14 updated: 2021/09/04 06:35:04
1289 dnl ---------------
1290 dnl You can always use "make -n" to see the actual options, but it is hard to
1291 dnl pick out/analyze warning messages when the compile-line is long.
1292 dnl
1293 dnl Sets:
1294 dnl     ECHO_LT - symbol to control if libtool is verbose
1295 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1296 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1297 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1298 dnl     ECHO_CC - symbol to put before any "cc" line
1299 dnl
1300 AC_DEFUN([CF_DISABLE_ECHO],[
1301 AC_MSG_CHECKING(if you want to see long compiling messages)
1302 CF_ARG_DISABLE(echo,
1303         [  --disable-echo          do not display "compiling" commands],
1304         [
1305         ECHO_LT='--silent'
1306         ECHO_LD='@echo linking [$]@;'
1307         RULE_CC='@echo compiling [$]<'
1308         SHOW_CC='@echo compiling [$]@'
1309         ECHO_CC='@'
1310 ],[
1311         ECHO_LT=''
1312         ECHO_LD=''
1313         RULE_CC=''
1314         SHOW_CC=''
1315         ECHO_CC=''
1316 ])
1317 AC_MSG_RESULT($enableval)
1318 AC_SUBST(ECHO_LT)
1319 AC_SUBST(ECHO_LD)
1320 AC_SUBST(RULE_CC)
1321 AC_SUBST(SHOW_CC)
1322 AC_SUBST(ECHO_CC)
1323 ])dnl
1324 dnl ---------------------------------------------------------------------------
1325 dnl CF_DISABLE_LEAKS version: 9 updated: 2021/04/03 16:41:50
1326 dnl ----------------
1327 dnl Combine no-leak checks with the libraries or tools that are used for the
1328 dnl checks.
1329 AC_DEFUN([CF_DISABLE_LEAKS],[
1330
1331 AC_REQUIRE([CF_WITH_DMALLOC])
1332 AC_REQUIRE([CF_WITH_DBMALLOC])
1333 AC_REQUIRE([CF_WITH_VALGRIND])
1334
1335 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1336 AC_ARG_ENABLE(leaks,
1337         [  --disable-leaks         test: free permanent memory, analyze leaks],
1338         [enable_leaks=$enableval],
1339         [enable_leaks=yes])
1340 dnl with_no_leaks is more readable...
1341 if test "x$enable_leaks" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi
1342 AC_MSG_RESULT($with_no_leaks)
1343
1344 if test "$enable_leaks" = no ; then
1345         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1346         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1347 fi
1348 ])dnl
1349 dnl ---------------------------------------------------------------------------
1350 dnl CF_DISABLE_RPATH_HACK version: 3 updated: 2021/01/05 20:14:44
1351 dnl ---------------------
1352 dnl The rpath-hack makes it simpler to build programs, particularly with the
1353 dnl *BSD ports which may have essential libraries in unusual places.  But it
1354 dnl can interfere with building an executable for the base system.  Use this
1355 dnl option in that case.
1356 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1357 [
1358 AC_MSG_CHECKING(if rpath-hack should be disabled)
1359 CF_ARG_DISABLE(rpath-hack,
1360         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1361         [enable_rpath_hack=no],
1362         [enable_rpath_hack=yes])
1363 dnl TODO - drop cf_disable_rpath_hack
1364 if test "x$enable_rpath_hack" = xno; then cf_disable_rpath_hack=yes; else cf_disable_rpath_hack=no; fi
1365 AC_MSG_RESULT($cf_disable_rpath_hack)
1366
1367 if test "$enable_rpath_hack" = yes ; then
1368         CF_RPATH_HACK
1369 fi
1370 ])
1371 dnl ---------------------------------------------------------------------------
1372 dnl CF_ENABLE_STRING_HACKS version: 6 updated: 2021/01/05 19:23:48
1373 dnl ----------------------
1374 dnl On a few platforms, the compiler and/or loader nags with untruthful
1375 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1376 dnl and implying that most uses of the recommended alternatives are correct.
1377 dnl
1378 dnl Factually speaking, no one has actually counted the number of uses of these
1379 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1380 dnl instances are meaningless compared to the hundreds of millions of lines of
1381 dnl existing C code.
1382 dnl
1383 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1384 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1385 dnl standard - but evolved through phases, and older implementations are likely
1386 dnl to yield surprising results, as documented in manpages on various systems.
1387 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1388 [
1389 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1390 AC_ARG_ENABLE(string-hacks,
1391         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1392         [enable_string_hacks=$enableval],
1393         [enable_string_hacks=no])
1394 AC_MSG_RESULT($enable_string_hacks)
1395
1396 if test "x$enable_string_hacks" = "xyes"; then
1397         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1398         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1399         AC_CHECK_FUNC(strlcat,[
1400                 AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1401                 ],[
1402                 AC_CHECK_LIB(bsd,strlcat,[
1403                         CF_ADD_LIB(bsd)
1404                         AC_CHECK_HEADERS(bsd/string.h)
1405                         AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1406                         ])
1407                 ])
1408         AC_CHECK_FUNCS( strlcpy snprintf )
1409 fi
1410 ])dnl
1411 dnl ---------------------------------------------------------------------------
1412 dnl CF_ENABLE_WARNINGS version: 9 updated: 2021/01/05 19:40:50
1413 dnl ------------------
1414 dnl Configure-option to enable gcc warnings
1415 dnl
1416 dnl $1 = extra options to add, if supported
1417 dnl $2 = option for checking attributes.  By default, this is done when
1418 dnl      warnings are enabled.  For other values:
1419 dnl      yes: always do this, e.g., to use in generated library-headers
1420 dnl      no: never do this
1421 AC_DEFUN([CF_ENABLE_WARNINGS],[
1422 if test "$GCC" = yes || test "$GXX" = yes
1423 then
1424 CF_FIX_WARNINGS(CFLAGS)
1425 CF_FIX_WARNINGS(CPPFLAGS)
1426 CF_FIX_WARNINGS(LDFLAGS)
1427 AC_MSG_CHECKING(if you want to turn on gcc warnings)
1428 CF_ARG_ENABLE(warnings,
1429         [  --enable-warnings       test: turn on gcc compiler warnings],
1430         [enable_warnings=yes],
1431         [enable_warnings=no])
1432 AC_MSG_RESULT($enable_warnings)
1433 if test "$enable_warnings" = "yes"
1434 then
1435         ifelse($2,,[CF_GCC_ATTRIBUTES])
1436         CF_GCC_WARNINGS($1)
1437 fi
1438 ifelse($2,yes,[CF_GCC_ATTRIBUTES])
1439 fi
1440 ])dnl
1441 dnl ---------------------------------------------------------------------------
1442 dnl CF_FIND_LIBRARY version: 11 updated: 2021/01/02 09:31:20
1443 dnl ---------------
1444 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
1445 dnl prefer a standard location, and use -L options only if we do not find the
1446 dnl library in the standard library location(s).
1447 dnl     $1 = library name
1448 dnl     $2 = library class, usually the same as library name
1449 dnl     $3 = includes
1450 dnl     $4 = code fragment to compile/link
1451 dnl     $5 = corresponding function-name
1452 dnl     $6 = flag, nonnull if failure should not cause an error-exit
1453 dnl
1454 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
1455 dnl to use a -L option.
1456 AC_DEFUN([CF_FIND_LIBRARY],
1457 [
1458         eval 'cf_cv_have_lib_'"$1"'=no'
1459         cf_libdir=""
1460         AC_CHECK_FUNC($5,
1461                 eval 'cf_cv_have_lib_'"$1"'=yes',[
1462                 cf_save_LIBS="$LIBS"
1463                 AC_MSG_CHECKING(for $5 in -l$1)
1464                 LIBS="-l$1 $LIBS"
1465                 AC_TRY_LINK([$3],[$4],
1466                         [AC_MSG_RESULT(yes)
1467                          eval 'cf_cv_have_lib_'"$1"'=yes'
1468                         ],
1469                         [AC_MSG_RESULT(no)
1470                         CF_LIBRARY_PATH(cf_search,$2)
1471                         for cf_libdir in $cf_search
1472                         do
1473                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
1474                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
1475                                 AC_TRY_LINK([$3],[$4],
1476                                         [AC_MSG_RESULT(yes)
1477                                          eval 'cf_cv_have_lib_'"$1"'=yes'
1478                                          break],
1479                                         [AC_MSG_RESULT(no)
1480                                          LIBS="$cf_save_LIBS"])
1481                         done
1482                         ])
1483                 ])
1484 eval 'cf_found_library="[$]cf_cv_have_lib_'"$1"\"
1485 ifelse($6,,[
1486 if test "$cf_found_library" = no ; then
1487         AC_MSG_ERROR(Cannot link $1 library)
1488 fi
1489 ])
1490 ])dnl
1491 dnl ---------------------------------------------------------------------------
1492 dnl CF_FIND_LINKAGE version: 22 updated: 2020/12/31 20:19:42
1493 dnl ---------------
1494 dnl Find a library (specifically the linkage used in the code fragment),
1495 dnl searching for it if it is not already in the library path.
1496 dnl See also CF_ADD_SEARCHPATH.
1497 dnl
1498 dnl Parameters (4-on are optional):
1499 dnl     $1 = headers for library entrypoint
1500 dnl     $2 = code fragment for library entrypoint
1501 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1502 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1503 dnl     $5 = action to perform if not successful
1504 dnl     $6 = module name, if not the same as the library name
1505 dnl     $7 = extra libraries
1506 dnl
1507 dnl Sets these variables:
1508 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1509 dnl     $cf_cv_header_path_$3 - include-directory if needed
1510 dnl     $cf_cv_library_path_$3 - library-directory if needed
1511 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1512 AC_DEFUN([CF_FIND_LINKAGE],[
1513
1514 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1515 # will be set on completion of the AC_TRY_LINK below.
1516 cf_cv_header_path_$3=
1517 cf_cv_library_path_$3=
1518
1519 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1520
1521 cf_save_LIBS="$LIBS"
1522
1523 AC_TRY_LINK([$1],[$2],[
1524         cf_cv_find_linkage_$3=yes
1525         cf_cv_header_path_$3=/usr/include
1526         cf_cv_library_path_$3=/usr/lib
1527 ],[
1528
1529 LIBS="-l$3 $7 $cf_save_LIBS"
1530
1531 AC_TRY_LINK([$1],[$2],[
1532         cf_cv_find_linkage_$3=yes
1533         cf_cv_header_path_$3=/usr/include
1534         cf_cv_library_path_$3=/usr/lib
1535         cf_cv_library_file_$3="-l$3"
1536 ],[
1537         cf_cv_find_linkage_$3=no
1538         LIBS="$cf_save_LIBS"
1539
1540         CF_VERBOSE(find linkage for $3 library)
1541         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1542
1543         cf_save_CPPFLAGS="$CPPFLAGS"
1544         cf_test_CPPFLAGS="$CPPFLAGS"
1545
1546         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1547         for cf_cv_header_path_$3 in $cf_search
1548         do
1549                 if test -d "$cf_cv_header_path_$3" ; then
1550                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1551                         CPPFLAGS="$cf_save_CPPFLAGS"
1552                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
1553                         AC_TRY_COMPILE([$1],[$2],[
1554                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1555                                 cf_cv_find_linkage_$3=maybe
1556                                 cf_test_CPPFLAGS="$CPPFLAGS"
1557                                 break],[
1558                                 CPPFLAGS="$cf_save_CPPFLAGS"
1559                                 ])
1560                 fi
1561         done
1562
1563         if test "$cf_cv_find_linkage_$3" = maybe ; then
1564
1565                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1566
1567                 cf_save_LIBS="$LIBS"
1568                 cf_save_LDFLAGS="$LDFLAGS"
1569
1570                 ifelse([$6],,,[
1571                 CPPFLAGS="$cf_test_CPPFLAGS"
1572                 LIBS="-l$3 $7 $cf_save_LIBS"
1573                 AC_TRY_LINK([$1],[$2],[
1574                         CF_VERBOSE(... found $3 library in system)
1575                         cf_cv_find_linkage_$3=yes])
1576                         CPPFLAGS="$cf_save_CPPFLAGS"
1577                         LIBS="$cf_save_LIBS"
1578                         ])
1579
1580                 if test "$cf_cv_find_linkage_$3" != yes ; then
1581                         CF_LIBRARY_PATH(cf_search,$3)
1582                         for cf_cv_library_path_$3 in $cf_search
1583                         do
1584                                 if test -d "$cf_cv_library_path_$3" ; then
1585                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
1586                                         CPPFLAGS="$cf_test_CPPFLAGS"
1587                                         LIBS="-l$3 $7 $cf_save_LIBS"
1588                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1589                                         AC_TRY_LINK([$1],[$2],[
1590                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1591                                         cf_cv_find_linkage_$3=yes
1592                                         cf_cv_library_file_$3="-l$3"
1593                                         break],[
1594                                         CPPFLAGS="$cf_save_CPPFLAGS"
1595                                         LIBS="$cf_save_LIBS"
1596                                         LDFLAGS="$cf_save_LDFLAGS"
1597                                         ])
1598                                 fi
1599                         done
1600                         CPPFLAGS="$cf_save_CPPFLAGS"
1601                         LDFLAGS="$cf_save_LDFLAGS"
1602                 fi
1603
1604         else
1605                 cf_cv_find_linkage_$3=no
1606         fi
1607         ],$7)
1608 ])
1609
1610 LIBS="$cf_save_LIBS"
1611
1612 if test "$cf_cv_find_linkage_$3" = yes ; then
1613 ifelse([$4],,[
1614         CF_ADD_INCDIR($cf_cv_header_path_$3)
1615         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1616         CF_ADD_LIB($3)
1617 ],[$4])
1618 else
1619 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1620 fi
1621 ])dnl
1622 dnl ---------------------------------------------------------------------------
1623 dnl CF_FIX_WARNINGS version: 4 updated: 2021/12/16 18:22:31
1624 dnl ---------------
1625 dnl Warning flags do not belong in CFLAGS, CPPFLAGS, etc.  Any of gcc's
1626 dnl "-Werror" flags can interfere with configure-checks.  Those go into
1627 dnl EXTRA_CFLAGS.
1628 dnl
1629 dnl $1 = variable name to repair
1630 define([CF_FIX_WARNINGS],[
1631 if test "$GCC" = yes || test "$GXX" = yes
1632 then
1633         case [$]$1 in
1634         (*-Werror=*)
1635                 cf_temp_flags=
1636                 for cf_temp_scan in [$]$1
1637                 do
1638                         case "x$cf_temp_scan" in
1639                         (x-Werror=format*)
1640                                 CF_APPEND_TEXT(cf_temp_flags,$cf_temp_scan)
1641                                 ;;
1642                         (x-Werror=*)
1643                                 CF_APPEND_TEXT(EXTRA_CFLAGS,$cf_temp_scan)
1644                                 ;;
1645                         (*)
1646                                 CF_APPEND_TEXT(cf_temp_flags,$cf_temp_scan)
1647                                 ;;
1648                         esac
1649                 done
1650                 if test "x[$]$1" != "x$cf_temp_flags"
1651                 then
1652                         CF_VERBOSE(repairing $1: [$]$1)
1653                         $1="$cf_temp_flags"
1654                         CF_VERBOSE(... fixed [$]$1)
1655                         CF_VERBOSE(... extra $EXTRA_CFLAGS)
1656                 fi
1657                 ;;
1658         esac
1659 fi
1660 AC_SUBST(EXTRA_CFLAGS)
1661 ])dnl
1662 dnl ---------------------------------------------------------------------------
1663 dnl CF_FUNC_CURSES_VERSION version: 9 updated: 2023/01/05 18:06:10
1664 dnl ----------------------
1665 dnl Solaris has a data item 'curses_version', which confuses AC_CHECK_FUNCS.
1666 dnl It's a character string "SVR4", not documented.
1667 AC_DEFUN([CF_FUNC_CURSES_VERSION],
1668 [
1669 AC_CACHE_CHECK(for function curses_version, cf_cv_func_curses_version,[
1670 AC_TRY_RUN([
1671 $ac_includes_default
1672
1673 #include <${cf_cv_ncurses_header:-curses.h}>
1674
1675 int main(void)
1676 {
1677         char temp[1024];
1678         sprintf(temp, "%.999s\\n", curses_version());
1679         ${cf_cv_main_return:-return}(0);
1680 }]
1681 ,[cf_cv_func_curses_version=yes]
1682 ,[cf_cv_func_curses_version=no]
1683 ,[cf_cv_func_curses_version=unknown])
1684 rm -f core])
1685 test "$cf_cv_func_curses_version" = yes && AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 if we have curses_version function])
1686 ])
1687 dnl ---------------------------------------------------------------------------
1688 dnl CF_FUNC_OPENPTY version: 6 updated: 2021/01/01 13:31:04
1689 dnl ---------------
1690 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1691 dnl "util" library as well.
1692 AC_DEFUN([CF_FUNC_OPENPTY],
1693 [
1694 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1695 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1696         cf_save_LIBS="$LIBS"
1697         test "$cf_cv_lib_util" = yes && { CF_ADD_LIB(util) }
1698         for cf_header in pty.h libutil.h util.h
1699         do
1700         AC_TRY_LINK([
1701 #include <$cf_header>
1702 ],[
1703         int x = openpty((int *)0, (int *)0, (char *)0,
1704                                    (struct termios *)0, (struct winsize *)0);
1705 ],[
1706                 cf_cv_func_openpty=$cf_header
1707                 break
1708 ],[
1709                 cf_cv_func_openpty=no
1710 ])
1711         done
1712         LIBS="$cf_save_LIBS"
1713 ])
1714 ])dnl
1715 dnl ---------------------------------------------------------------------------
1716 dnl CF_GCC_ATTRIBUTES version: 24 updated: 2021/03/20 12:00:25
1717 dnl -----------------
1718 dnl Test for availability of useful gcc __attribute__ directives to quiet
1719 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1720 dnl to documentation, unrecognized directives cause older compilers to barf.
1721 AC_DEFUN([CF_GCC_ATTRIBUTES],
1722 [AC_REQUIRE([AC_PROG_FGREP])dnl
1723 AC_REQUIRE([CF_C11_NORETURN])dnl
1724
1725 if test "$GCC" = yes || test "$GXX" = yes
1726 then
1727 cat > conftest.i <<EOF
1728 #ifndef GCC_PRINTF
1729 #define GCC_PRINTF 0
1730 #endif
1731 #ifndef GCC_SCANF
1732 #define GCC_SCANF 0
1733 #endif
1734 #ifndef GCC_NORETURN
1735 #define GCC_NORETURN /* nothing */
1736 #endif
1737 #ifndef GCC_UNUSED
1738 #define GCC_UNUSED /* nothing */
1739 #endif
1740 EOF
1741 if test "$GCC" = yes
1742 then
1743         AC_CHECKING([for $CC __attribute__ directives])
1744 cat > "conftest.$ac_ext" <<EOF
1745 #line __oline__ "${as_me:-configure}"
1746 #include <stdio.h>
1747 #include "confdefs.h"
1748 #include "conftest.h"
1749 #include "conftest.i"
1750 #if     GCC_PRINTF
1751 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1752 #else
1753 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1754 #endif
1755 #if     GCC_SCANF
1756 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1757 #else
1758 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1759 #endif
1760 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1761 extern GCC_NORETURN void oops(char *,...) GCC_PRINTFLIKE(1,2);
1762 extern GCC_NORETURN void foo(void);
1763 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { (void)argc; (void)argv; return 0; }
1764 EOF
1765         cf_printf_attribute=no
1766         cf_scanf_attribute=no
1767         for cf_attribute in scanf printf unused noreturn
1768         do
1769                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1770                 cf_directive="__attribute__(($cf_attribute))"
1771                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1772
1773                 case "$cf_attribute" in
1774                 (printf)
1775                         cf_printf_attribute=yes
1776                         cat >conftest.h <<EOF
1777 #define GCC_$cf_ATTRIBUTE 1
1778 EOF
1779                         ;;
1780                 (scanf)
1781                         cf_scanf_attribute=yes
1782                         cat >conftest.h <<EOF
1783 #define GCC_$cf_ATTRIBUTE 1
1784 EOF
1785                         ;;
1786                 (*)
1787                         cat >conftest.h <<EOF
1788 #define GCC_$cf_ATTRIBUTE $cf_directive
1789 EOF
1790                         ;;
1791                 esac
1792
1793                 if AC_TRY_EVAL(ac_compile); then
1794                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1795                         cat conftest.h >>confdefs.h
1796                         case "$cf_attribute" in
1797                         (noreturn)
1798                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1799                                 ;;
1800                         (printf)
1801                                 cf_value='/* nothing */'
1802                                 if test "$cf_printf_attribute" != no ; then
1803                                         cf_value='__attribute__((format(printf,fmt,var)))'
1804                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1805                                 fi
1806                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1807                                 ;;
1808                         (scanf)
1809                                 cf_value='/* nothing */'
1810                                 if test "$cf_scanf_attribute" != no ; then
1811                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1812                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1813                                 fi
1814                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1815                                 ;;
1816                         (unused)
1817                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1818                                 ;;
1819                         esac
1820                 fi
1821         done
1822 else
1823         ${FGREP-fgrep} define conftest.i >>confdefs.h
1824 fi
1825 rm -rf ./conftest*
1826 fi
1827 ])dnl
1828 dnl ---------------------------------------------------------------------------
1829 dnl CF_GCC_VERSION version: 8 updated: 2019/09/07 13:38:36
1830 dnl --------------
1831 dnl Find version of gcc, and (because icc/clang pretend to be gcc without being
1832 dnl compatible), attempt to determine if icc/clang is actually used.
1833 AC_DEFUN([CF_GCC_VERSION],[
1834 AC_REQUIRE([AC_PROG_CC])
1835 GCC_VERSION=none
1836 if test "$GCC" = yes ; then
1837         AC_MSG_CHECKING(version of $CC)
1838         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1839         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1840         AC_MSG_RESULT($GCC_VERSION)
1841 fi
1842 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1843 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
1844 ])dnl
1845 dnl ---------------------------------------------------------------------------
1846 dnl CF_GCC_WARNINGS version: 41 updated: 2021/01/01 16:53:59
1847 dnl ---------------
1848 dnl Check if the compiler supports useful warning options.  There's a few that
1849 dnl we don't use, simply because they're too noisy:
1850 dnl
1851 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1852 dnl     -Winline (usually not worthwhile)
1853 dnl     -Wredundant-decls (system headers make this too noisy)
1854 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1855 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1856 dnl             is enabled for ncurses using "--enable-const".
1857 dnl     -pedantic
1858 dnl
1859 dnl Parameter:
1860 dnl     $1 is an optional list of gcc warning flags that a particular
1861 dnl             application might want to use, e.g., "no-unused" for
1862 dnl             -Wno-unused
1863 dnl Special:
1864 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1865 dnl
1866 AC_DEFUN([CF_GCC_WARNINGS],
1867 [
1868 AC_REQUIRE([CF_GCC_VERSION])
1869 if test "x$have_x" = xyes; then CF_CONST_X_STRING fi
1870 cat > "conftest.$ac_ext" <<EOF
1871 #line __oline__ "${as_me:-configure}"
1872 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1873 EOF
1874 if test "$INTEL_COMPILER" = yes
1875 then
1876 # The "-wdXXX" options suppress warnings:
1877 # remark #1419: external declaration in primary source file
1878 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1879 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1880 # remark #193: zero used for undefined preprocessing identifier
1881 # remark #593: variable "curs_sb_left_arrow" was set but never used
1882 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1883 # remark #869: parameter "tw" was never referenced
1884 # remark #981: operands are evaluated in unspecified order
1885 # warning #279: controlling expression is constant
1886
1887         AC_CHECKING([for $CC warning options])
1888         cf_save_CFLAGS="$CFLAGS"
1889         EXTRA_CFLAGS="$EXTRA_CFLAGS -Wall"
1890         for cf_opt in \
1891                 wd1419 \
1892                 wd1683 \
1893                 wd1684 \
1894                 wd193 \
1895                 wd593 \
1896                 wd279 \
1897                 wd810 \
1898                 wd869 \
1899                 wd981
1900         do
1901                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1902                 if AC_TRY_EVAL(ac_compile); then
1903                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1904                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1905                 fi
1906         done
1907         CFLAGS="$cf_save_CFLAGS"
1908 elif test "$GCC" = yes && test "$GCC_VERSION" != "unknown"
1909 then
1910         AC_CHECKING([for $CC warning options])
1911         cf_save_CFLAGS="$CFLAGS"
1912         cf_warn_CONST=""
1913         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1914         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
1915         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
1916         for cf_opt in W Wall \
1917                 Wbad-function-cast \
1918                 Wcast-align \
1919                 Wcast-qual \
1920                 Wdeclaration-after-statement \
1921                 Wextra \
1922                 Winline \
1923                 Wmissing-declarations \
1924                 Wmissing-prototypes \
1925                 Wnested-externs \
1926                 Wpointer-arith \
1927                 Wshadow \
1928                 Wstrict-prototypes \
1929                 Wundef Wno-inline $cf_gcc_warnings $cf_warn_CONST $1
1930         do
1931                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1932                 if AC_TRY_EVAL(ac_compile); then
1933                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1934                         case "$cf_opt" in
1935                         (Winline)
1936                                 case "$GCC_VERSION" in
1937                                 ([[34]].*)
1938                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1939                                         continue;;
1940                                 esac
1941                                 ;;
1942                         (Wpointer-arith)
1943                                 case "$GCC_VERSION" in
1944                                 ([[12]].*)
1945                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1946                                         continue;;
1947                                 esac
1948                                 ;;
1949                         esac
1950                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1951                 fi
1952         done
1953         CFLAGS="$cf_save_CFLAGS"
1954 fi
1955 rm -rf ./conftest*
1956
1957 AC_SUBST(EXTRA_CFLAGS)
1958 ])dnl
1959 dnl ---------------------------------------------------------------------------
1960 dnl CF_GETOPT_HEADER version: 8 updated: 2021/06/19 19:16:16
1961 dnl ----------------
1962 dnl Check for getopt's variables which are commonly defined in stdlib.h,
1963 dnl unistd.h or (nonstandard) in getopt.h
1964 AC_DEFUN([CF_GETOPT_HEADER],
1965 [
1966 AC_HAVE_HEADERS(unistd.h getopt.h)
1967 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
1968 cf_cv_getopt_header=none
1969 for cf_header in stdio.h stdlib.h unistd.h getopt.h
1970 do
1971 AC_TRY_COMPILE([
1972 #include <$cf_header>],
1973 [int x = optind; char *y = optarg; (void)x; (void)y],
1974 [cf_cv_getopt_header=$cf_header
1975  break])
1976 done
1977 ])
1978 if test "$cf_cv_getopt_header" != none ; then
1979         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
1980 fi
1981 if test "$cf_cv_getopt_header" = getopt.h ; then
1982         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
1983 fi
1984 ])dnl
1985 dnl ---------------------------------------------------------------------------
1986 dnl CF_GNU_SOURCE version: 10 updated: 2018/12/10 20:09:41
1987 dnl -------------
1988 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1989 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1990 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1991 dnl since it is interwoven with GNU extensions.
1992 dnl
1993 dnl Well, yes we could work around it...
1994 dnl
1995 dnl Parameters:
1996 dnl     $1 is the nominal value for _XOPEN_SOURCE
1997 AC_DEFUN([CF_GNU_SOURCE],
1998 [
1999 cf_gnu_xopen_source=ifelse($1,,500,$1)
2000
2001 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
2002 AC_TRY_COMPILE([#include <sys/types.h>],[
2003         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
2004                 return 0;
2005         #elif __NEWLIB__ > 0 && __NEWLIB_MINOR__ >= 0
2006                 return 0;
2007         #else
2008         #       error not GNU C library
2009         #endif],
2010         [cf_cv_gnu_library=yes],
2011         [cf_cv_gnu_library=no])
2012 ])
2013
2014 if test x$cf_cv_gnu_library = xyes; then
2015
2016         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
2017         # was changed to help a little.  newlib incorporated the change about 4
2018         # years later.
2019         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
2020                 cf_save="$CPPFLAGS"
2021                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
2022                 AC_TRY_COMPILE([#include <sys/types.h>],[
2023                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
2024                                 return 0;
2025                         #elif (__NEWLIB__ == 2 && __NEWLIB_MINOR__ >= 4) || (__GLIBC__ > 3)
2026                                 return 0;
2027                         #else
2028                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
2029                         #endif],
2030                         [cf_cv_gnu_library_219=yes],
2031                         [cf_cv_gnu_library_219=no])
2032                 CPPFLAGS="$cf_save"
2033         ])
2034
2035         if test "x$cf_cv_gnu_library_219" = xyes; then
2036                 cf_save="$CPPFLAGS"
2037                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
2038                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
2039                         AC_TRY_COMPILE([
2040                                 #include <limits.h>
2041                                 #include <sys/types.h>
2042                                 ],[
2043                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
2044                                         return 0;
2045                                 #else
2046                                 #       error GNU C library is too old
2047                                 #endif],
2048                                 [cf_cv_gnu_dftsrc_219=yes],
2049                                 [cf_cv_gnu_dftsrc_219=no])
2050                         ])
2051                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
2052         else
2053                 cf_cv_gnu_dftsrc_219=maybe
2054         fi
2055
2056         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
2057
2058                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2059                 AC_TRY_COMPILE([#include <sys/types.h>],[
2060                         #ifndef _XOPEN_SOURCE
2061                         #error  expected _XOPEN_SOURCE to be defined
2062                         #endif],
2063                         [cf_cv_gnu_source=no],
2064                         [cf_save="$CPPFLAGS"
2065                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
2066                          AC_TRY_COMPILE([#include <sys/types.h>],[
2067                                 #ifdef _XOPEN_SOURCE
2068                                 #error  expected _XOPEN_SOURCE to be undefined
2069                                 #endif],
2070                                 [cf_cv_gnu_source=no],
2071                                 [cf_cv_gnu_source=yes])
2072                         CPPFLAGS="$cf_save"
2073                         ])
2074                 ])
2075
2076                 if test "$cf_cv_gnu_source" = yes
2077                 then
2078                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
2079                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
2080                         AC_TRY_COMPILE([#include <sys/types.h>],[
2081                                 #ifdef _DEFAULT_SOURCE
2082                                 #error  expected _DEFAULT_SOURCE to be undefined
2083                                 #endif],
2084                                 [cf_cv_default_source=no],
2085                                 [cf_cv_default_source=yes])
2086                         ])
2087                         if test "$cf_cv_default_source" = yes
2088                         then
2089                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
2090                         fi
2091                 fi
2092         fi
2093
2094 fi
2095 ])dnl
2096 dnl ---------------------------------------------------------------------------
2097 dnl CF_HEADER_PATH version: 15 updated: 2021/01/01 13:31:04
2098 dnl --------------
2099 dnl Construct a search-list of directories for a nonstandard header-file
2100 dnl
2101 dnl Parameters
2102 dnl     $1 = the variable to return as result
2103 dnl     $2 = the package name
2104 AC_DEFUN([CF_HEADER_PATH],
2105 [
2106 $1=
2107
2108 # collect the current set of include-directories from compiler flags
2109 cf_header_path_list=""
2110 if test -n "${CFLAGS}${CPPFLAGS}" ; then
2111         for cf_header_path in $CPPFLAGS $CFLAGS
2112         do
2113                 case "$cf_header_path" in
2114                 (-I*)
2115                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
2116                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
2117                         cf_header_path_list="$cf_header_path_list [$]$1"
2118                         ;;
2119                 esac
2120         done
2121 fi
2122
2123 # add the variations for the package we are looking for
2124 CF_SUBDIR_PATH($1,$2,include)
2125
2126 test "$includedir" != NONE && \
2127 test "$includedir" != "/usr/include" && \
2128 test -d "$includedir" && {
2129         test -d "$includedir" &&    $1="[$]$1 $includedir"
2130         test -d "$includedir/$2" && $1="[$]$1 $includedir/$2"
2131 }
2132
2133 test "$oldincludedir" != NONE && \
2134 test "$oldincludedir" != "/usr/include" && \
2135 test -d "$oldincludedir" && {
2136         test -d "$oldincludedir"    && $1="[$]$1 $oldincludedir"
2137         test -d "$oldincludedir/$2" && $1="[$]$1 $oldincludedir/$2"
2138 }
2139
2140 $1="[$]$1 $cf_header_path_list"
2141 ])dnl
2142 dnl ---------------------------------------------------------------------------
2143 dnl CF_HELP_MESSAGE version: 4 updated: 2019/12/31 08:53:54
2144 dnl ---------------
2145 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
2146 AC_DEFUN([CF_HELP_MESSAGE],
2147 [CF_ACVERSION_CHECK(2.53,[],[
2148 AC_DIVERT_HELP($1)])dnl
2149 ])dnl
2150 dnl ---------------------------------------------------------------------------
2151 dnl CF_INHERIT_SCRIPT version: 2 updated: 2003/03/01 23:50:42
2152 dnl -----------------
2153 dnl If we do not have a given script, look for it in the parent directory.
2154 AC_DEFUN([CF_INHERIT_SCRIPT],
2155 [
2156 test -f $1 || ( test -f ../$1 && cp ../$1 ./ )
2157 ])dnl
2158 dnl ---------------------------------------------------------------------------
2159 dnl CF_INSTALL_OPTS version: 2 updated: 2018/08/18 12:19:21
2160 dnl ---------------
2161 dnl prompt for/fill-in useful install-program options
2162 AC_DEFUN([CF_INSTALL_OPTS],
2163 [
2164 CF_INSTALL_OPT_S
2165 CF_INSTALL_OPT_P
2166 CF_INSTALL_OPT_O
2167 ])dnl
2168 dnl ---------------------------------------------------------------------------
2169 dnl CF_INSTALL_OPT_O version: 3 updated: 2020/12/31 20:19:42
2170 dnl ----------------
2171 dnl Almost all "install" programs default to the current user's ownership.
2172 dnl Almost - MINIX is an exception.
2173 AC_DEFUN([CF_INSTALL_OPT_O],
2174 [
2175 AC_MSG_CHECKING(if install needs to be told about ownership)
2176 case `$ac_config_guess` in
2177 (*minix)
2178         with_install_o=yes
2179         ;;
2180 (*)
2181         with_install_o=no
2182         ;;
2183 esac
2184
2185 AC_MSG_RESULT($with_install_o)
2186 if test "x$with_install_o" = xyes
2187 then
2188         INSTALL_OPT_O="`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`"
2189 else
2190         INSTALL_OPT_O=
2191 fi
2192
2193 AC_SUBST(INSTALL_OPT_O)
2194 ])dnl
2195 dnl ---------------------------------------------------------------------------
2196 dnl CF_INSTALL_OPT_P version: 3 updated: 2021/01/01 13:31:04
2197 dnl ----------------
2198 dnl Some install-programs accept a "-p" option to preserve file modification
2199 dnl timestamps.  That can be useful as an install option, as well as a way to
2200 dnl avoid the need for ranlib after copying a static archive.
2201 AC_DEFUN([CF_INSTALL_OPT_P],
2202 [
2203 : "${INSTALL:=install}"
2204 AC_CACHE_CHECK(if install accepts -p option, cf_cv_install_p,[
2205         rm -rf ./conftest*
2206         date >conftest.in
2207         mkdir conftest.out
2208         sleep 3
2209         if $INSTALL -p conftest.in conftest.out 2>/dev/null
2210         then
2211                 if test -f conftest.out/conftest.in
2212                 then
2213                         test conftest.in -nt conftest.out/conftest.in 2>conftest.err && \
2214                         test conftest.out/conftest.in -nt conftest.in 2>conftest.err
2215                         if test -s conftest.err
2216                         then
2217                                 cf_cv_install_p=no
2218                         else
2219                                 cf_cv_install_p=yes
2220                         fi
2221                 else
2222                         cf_cv_install_p=no
2223                 fi
2224         else
2225                 cf_cv_install_p=no
2226         fi
2227         rm -rf ./conftest*
2228 ])
2229 ])dnl
2230 dnl ---------------------------------------------------------------------------
2231 dnl CF_INSTALL_OPT_S version: 3 updated: 2021/01/05 19:23:48
2232 dnl ----------------
2233 dnl By default, we should strip executables which are installed, but leave the
2234 dnl ability to suppress that for unit-testing.
2235 AC_DEFUN([CF_INSTALL_OPT_S],
2236 [
2237 AC_MSG_CHECKING(if you want to install stripped executables)
2238 CF_ARG_DISABLE(stripping,
2239         [  --disable-stripping     do not strip (debug info) installed executables],
2240         [enable_stripping=no],
2241         [enable_stripping=yes])
2242 AC_MSG_RESULT($enable_stripping)
2243
2244 if test "$enable_stripping" = yes
2245 then
2246         INSTALL_OPT_S="-s"
2247 else
2248         INSTALL_OPT_S=
2249 fi
2250 AC_SUBST(INSTALL_OPT_S)
2251 ])dnl
2252 dnl ---------------------------------------------------------------------------
2253 dnl CF_INTEL_COMPILER version: 8 updated: 2021/01/01 16:53:59
2254 dnl -----------------
2255 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2256 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2257 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2258 dnl
2259 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2260 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2261 dnl the wrappers for gcc and g++ warnings.
2262 dnl
2263 dnl $1 = GCC (default) or GXX
2264 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2265 dnl $3 = CFLAGS (default) or CXXFLAGS
2266 AC_DEFUN([CF_INTEL_COMPILER],[
2267 AC_REQUIRE([AC_CANONICAL_HOST])
2268 ifelse([$2],,INTEL_COMPILER,[$2])=no
2269
2270 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2271         case "$host_os" in
2272         (linux*|gnu*)
2273                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2274                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2275                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2276                 AC_TRY_COMPILE([],[
2277 #ifdef __INTEL_COMPILER
2278 #else
2279 make an error
2280 #endif
2281 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2282 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
2283 ],[])
2284                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2285                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2286                 ;;
2287         esac
2288 fi
2289 ])dnl
2290 dnl ---------------------------------------------------------------------------
2291 dnl CF_LD_RPATH_OPT version: 9 updated: 2021/01/01 13:31:04
2292 dnl ---------------
2293 dnl For the given system and compiler, find the compiler flags to pass to the
2294 dnl loader to use the "rpath" feature.
2295 AC_DEFUN([CF_LD_RPATH_OPT],
2296 [
2297 AC_REQUIRE([CF_CHECK_CACHE])
2298
2299 LD_RPATH_OPT=
2300 if test "x$cf_cv_enable_rpath" != xno
2301 then
2302         AC_MSG_CHECKING(for an rpath option)
2303         case "$cf_cv_system_name" in
2304         (irix*)
2305                 if test "$GCC" = yes; then
2306                         LD_RPATH_OPT="-Wl,-rpath,"
2307                 else
2308                         LD_RPATH_OPT="-rpath "
2309                 fi
2310                 ;;
2311         (linux*|gnu*|k*bsd*-gnu|freebsd*)
2312                 LD_RPATH_OPT="-Wl,-rpath,"
2313                 ;;
2314         (openbsd[[2-9]].*|mirbsd*)
2315                 LD_RPATH_OPT="-Wl,-rpath,"
2316                 ;;
2317         (dragonfly*)
2318                 LD_RPATH_OPT="-rpath "
2319                 ;;
2320         (netbsd*)
2321                 LD_RPATH_OPT="-Wl,-rpath,"
2322                 ;;
2323         (osf*|mls+*)
2324                 LD_RPATH_OPT="-rpath "
2325                 ;;
2326         (solaris2*)
2327                 LD_RPATH_OPT="-R"
2328                 ;;
2329         (*)
2330                 ;;
2331         esac
2332         AC_MSG_RESULT($LD_RPATH_OPT)
2333
2334         case "x$LD_RPATH_OPT" in
2335         (x-R*)
2336                 AC_MSG_CHECKING(if we need a space after rpath option)
2337                 cf_save_LIBS="$LIBS"
2338                 CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
2339                 AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
2340                 LIBS="$cf_save_LIBS"
2341                 AC_MSG_RESULT($cf_rpath_space)
2342                 test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
2343                 ;;
2344         esac
2345 fi
2346 ])dnl
2347 dnl ---------------------------------------------------------------------------
2348 dnl CF_LIBRARY_PATH version: 11 updated: 2021/01/01 13:31:04
2349 dnl ---------------
2350 dnl Construct a search-list of directories for a nonstandard library-file
2351 dnl
2352 dnl Parameters
2353 dnl     $1 = the variable to return as result
2354 dnl     $2 = the package name
2355 AC_DEFUN([CF_LIBRARY_PATH],
2356 [
2357 $1=
2358 cf_library_path_list=""
2359 if test -n "${LDFLAGS}${LIBS}" ; then
2360         for cf_library_path in $LDFLAGS $LIBS
2361         do
2362                 case "$cf_library_path" in
2363                 (-L*)
2364                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
2365                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
2366                         cf_library_path_list="$cf_library_path_list [$]$1"
2367                         ;;
2368                 esac
2369         done
2370 fi
2371
2372 CF_SUBDIR_PATH($1,$2,lib)
2373
2374 $1="$cf_library_path_list [$]$1"
2375 ])dnl
2376 dnl ---------------------------------------------------------------------------
2377 dnl CF_MAKE_PHONY version: 3 updated: 2021/01/08 16:08:21
2378 dnl -------------
2379 dnl Check if the make-program handles a ".PHONY" target, e.g,. a target which
2380 dnl acts as a placeholder.
2381 dnl
2382 dnl The ".PHONY" feature was proposed in 2011 here
2383 dnl     https://www.austingroupbugs.net/view.php?id=523
2384 dnl and is scheduled for release in P1003.1 Issue 8 (late 2022).
2385 dnl
2386 dnl This is not supported by SVr4 make (or SunOS 4, 4.3SD, etc), but works with
2387 dnl a few others (i.e., GNU make and the non-POSIX "BSD" make):
2388 dnl
2389 dnl + This is a GNU make feature (since April 1988, but in turn from binutils,
2390 dnl   date unspecified).
2391 dnl
2392 dnl + It was adopted in NetBSD make in June 1995.
2393 dnl
2394 dnl + The other BSD make programs are derived from the NetBSD make (and for
2395 dnl   that reason are not actually different "implementations").
2396 dnl
2397 dnl + Some features of NetBSD make were actually adapted from pmake, which
2398 dnl   began as a modified GNU make starting in 1993.
2399 dnl
2400 dnl + Version 3.8 of the dmake program in January 1992 also implemented this
2401 dnl   GNU make extension, but is less well known than the BSD make.
2402 AC_DEFUN([CF_MAKE_PHONY],[
2403 AC_CACHE_CHECK(for \".PHONY\" make-support, cf_cv_make_PHONY,[
2404         rm -rf conftest*
2405         (
2406                 mkdir conftest || exit 1
2407                 cd conftest
2408                 cat >makefile <<'CF_EOF'
2409 .PHONY: always
2410 DATA=0
2411 always: always.out
2412         @echo "** making [$]@ [$](DATA)"
2413 once: once.out
2414         @echo "** making [$]@ [$](DATA)"
2415 always.out:
2416         @echo "** making [$]@ [$](DATA)"
2417         echo [$](DATA) > [$]@
2418 once.out:
2419         @echo "** making [$]@ [$](DATA)"
2420         echo [$](DATA) > [$]@
2421 CF_EOF
2422                 for cf_data in 1 2 3
2423                 do
2424                         ${MAKE:-make} always DATA=$cf_data
2425                         ${MAKE:-make} once   DATA=$cf_data
2426                         ${MAKE:-make} -t always once
2427                         if test -f always ; then
2428                                 echo "no (case 1)" > ../conftest.tmp
2429                         elif test ! -f always.out ; then
2430                                 echo "no (case 2)" > ../conftest.tmp
2431                         elif test ! -f once.out ; then
2432                                 echo "no (case 3)" > ../conftest.tmp
2433                         elif ! cmp -s always.out once.out ; then
2434                                 echo "no (case 4)" > ../conftest.tmp
2435                                 diff always.out once.out
2436                         else
2437                                 cf_check="`cat always.out`"
2438                                 if test "x$cf_check" != "x$cf_data" ; then
2439                                         echo "no (case 5)" > ../conftest.tmp
2440                                 else
2441                                         echo yes > ../conftest.tmp
2442                                         rm -f ./*.out
2443                                         continue
2444                                 fi
2445                         fi
2446                         break
2447                 done
2448         ) >&AC_FD_CC 2>&1
2449         cf_cv_make_PHONY="`cat conftest.tmp`"
2450         rm -rf conftest*
2451 ])
2452 MAKE_NO_PHONY="#"
2453 MAKE_PHONY="#"
2454 test "x$cf_cv_make_PHONY" = xyes && MAKE_PHONY=
2455 test "x$cf_cv_make_PHONY" != xyes && MAKE_NO_PHONY=
2456 AC_SUBST(MAKE_NO_PHONY)
2457 AC_SUBST(MAKE_PHONY)
2458 ])dnl
2459 dnl ---------------------------------------------------------------------------
2460 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
2461 dnl ------------
2462 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
2463 dnl a monocase filesystem.
2464 AC_DEFUN([CF_MAKE_TAGS],[
2465 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
2466
2467 AC_CHECK_PROGS(CTAGS, exctags ctags)
2468 AC_CHECK_PROGS(ETAGS, exetags etags)
2469
2470 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
2471
2472 if test "$cf_cv_mixedcase" = yes ; then
2473         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
2474 else
2475         MAKE_UPPER_TAGS=no
2476 fi
2477
2478 if test "$MAKE_UPPER_TAGS" = yes ; then
2479         MAKE_UPPER_TAGS=
2480 else
2481         MAKE_UPPER_TAGS="#"
2482 fi
2483
2484 if test "$MAKE_LOWER_TAGS" = yes ; then
2485         MAKE_LOWER_TAGS=
2486 else
2487         MAKE_LOWER_TAGS="#"
2488 fi
2489
2490 AC_SUBST(CTAGS)
2491 AC_SUBST(ETAGS)
2492
2493 AC_SUBST(MAKE_UPPER_TAGS)
2494 AC_SUBST(MAKE_LOWER_TAGS)
2495 ])dnl
2496 dnl ---------------------------------------------------------------------------
2497 dnl CF_MATH_LIB version: 11 updated: 2022/07/27 19:01:48
2498 dnl -----------
2499 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
2500 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
2501 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
2502 AC_DEFUN([CF_MATH_LIB],
2503 [
2504 AC_CACHE_CHECK(if -lm needed for math functions,
2505         cf_cv_need_libm,[
2506         AC_TRY_LINK([
2507                 #include <stdio.h>
2508                 #include <stdlib.h>
2509                 #include <math.h>
2510         ],
2511         [double x = rand(); printf("result = %g\\n", ]ifelse([$2],,sin(x),$2)[)],
2512         [cf_cv_need_libm=no],
2513         [cf_cv_need_libm=yes])])
2514
2515 if test "$cf_cv_need_libm" = yes
2516 then
2517
2518         cf_save_LIBS="$LIBS"
2519         LIBS="$LIBS -lm"
2520         AC_CACHE_CHECK(if -lm is available for math functions,
2521         cf_cv_have_libm,[
2522         AC_TRY_LINK([
2523                 #include <stdio.h>
2524                 #include <stdlib.h>
2525                 #include <math.h>
2526         ],
2527         [double x = rand(); printf("result = %g\\n", ]ifelse([$2],,sin(x),$2)[)],
2528         [cf_cv_have_libm=yes],
2529         [cf_cv_have_libm=no])])
2530         LIBS="$cf_save_LIBS"
2531
2532         if test "$cf_cv_have_libm" = yes
2533         then
2534                 ifelse($1,,[CF_ADD_LIB(m)],[$1=-lm])
2535         fi
2536 else
2537         cf_cv_have_libm=yes
2538 fi
2539
2540 if test "$cf_cv_have_libm" = yes
2541 then
2542         AC_DEFINE(HAVE_MATH_FUNCS,1,[Define to 1 if math functions are available])
2543 fi
2544 ])
2545 dnl ---------------------------------------------------------------------------
2546 dnl CF_MIXEDCASE_FILENAMES version: 9 updated: 2021/01/01 16:53:59
2547 dnl ----------------------
2548 dnl Check if the file-system supports mixed-case filenames.  If we're able to
2549 dnl create a lowercase name and see it as uppercase, it doesn't support that.
2550 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
2551 [
2552 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
2553 if test "$cross_compiling" = yes ; then
2554         case "$target_alias" in
2555         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*|darwin*)
2556                 cf_cv_mixedcase=no
2557                 ;;
2558         (*)
2559                 cf_cv_mixedcase=yes
2560                 ;;
2561         esac
2562 else
2563         rm -f conftest CONFTEST
2564         echo test >conftest
2565         if test -f CONFTEST ; then
2566                 cf_cv_mixedcase=no
2567         else
2568                 cf_cv_mixedcase=yes
2569         fi
2570         rm -f conftest CONFTEST
2571 fi
2572 ])
2573 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
2574 ])dnl
2575 dnl ---------------------------------------------------------------------------
2576 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
2577 dnl ----------
2578 dnl Write a debug message to config.log, along with the line number in the
2579 dnl configure script.
2580 AC_DEFUN([CF_MSG_LOG],[
2581 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
2582 ])dnl
2583 dnl ---------------------------------------------------------------------------
2584 dnl CF_NCURSES_CC_CHECK version: 5 updated: 2020/12/31 20:19:42
2585 dnl -------------------
2586 dnl Check if we can compile with ncurses' header file
2587 dnl $1 is the cache variable to set
2588 dnl $2 is the header-file to include
2589 dnl $3 is the root name (ncurses or ncursesw)
2590 AC_DEFUN([CF_NCURSES_CC_CHECK],[
2591         AC_TRY_COMPILE([
2592 ]ifelse($3,ncursesw,[
2593 #define _XOPEN_SOURCE_EXTENDED
2594 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
2595 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
2596 ])[
2597 #include <$2>],[
2598 #ifdef NCURSES_VERSION
2599 ]ifelse($3,ncursesw,[
2600 #ifndef WACS_BSSB
2601         make an error
2602 #endif
2603 ])[
2604 printf("%s\\n", NCURSES_VERSION);
2605 #else
2606 #ifdef __NCURSES_H
2607 printf("old\\n");
2608 #else
2609         make an error
2610 #endif
2611 #endif
2612         ]
2613         ,[$1=$2]
2614         ,[$1=no])
2615 ])dnl
2616 dnl ---------------------------------------------------------------------------
2617 dnl CF_NCURSES_CONFIG version: 28 updated: 2021/08/28 15:20:37
2618 dnl -----------------
2619 dnl Tie together the configure-script macros for ncurses, preferring these in
2620 dnl order:
2621 dnl a) ".pc" files for pkg-config, using $NCURSES_CONFIG_PKG
2622 dnl b) the "-config" script from ncurses, using $NCURSES_CONFIG
2623 dnl c) just plain libraries
2624 dnl
2625 dnl $1 is the root library name (default: "ncurses")
2626 AC_DEFUN([CF_NCURSES_CONFIG],[
2627 AC_REQUIRE([CF_PKG_CONFIG])
2628 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
2629 cf_have_ncuconfig=no
2630
2631 if test "x${PKG_CONFIG:=none}" != xnone; then
2632         AC_MSG_CHECKING(pkg-config for $cf_ncuconfig_root)
2633         if "$PKG_CONFIG" --exists $cf_ncuconfig_root ; then
2634                 AC_MSG_RESULT(yes)
2635
2636                 AC_MSG_CHECKING(if the $cf_ncuconfig_root package files work)
2637                 cf_have_ncuconfig=unknown
2638
2639                 cf_save_CFLAGS="$CFLAGS"
2640                 cf_save_CPPFLAGS="$CPPFLAGS"
2641                 cf_save_LIBS="$LIBS"
2642
2643                 cf_pkg_cflags="`$PKG_CONFIG --cflags $cf_ncuconfig_root`"
2644                 cf_pkg_libs="`$PKG_CONFIG --libs $cf_ncuconfig_root`"
2645
2646                 # while -W for passing linker flags is prevalent, it is not "standard".
2647                 # At least one wrapper for c89/c99 (in Apple's xcode) has its own
2648                 # incompatible _and_ non-standard -W option which gives an error.  Work
2649                 # around that pitfall.
2650                 case "x${CC}@@${cf_pkg_libs}@${cf_pkg_cflags}" in
2651                 (x*c[[89]]9@@*-W*)
2652                         CF_ADD_CFLAGS($cf_pkg_cflags)
2653                         CF_ADD_LIBS($cf_pkg_libs)
2654
2655                         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2656                                 [initscr(); mousemask(0,0); tigetstr((char *)0);],
2657                                 [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
2658                                         int main(void)
2659                                         { const char *xx = curses_version(); return (xx == 0); }],
2660                                         [cf_test_ncuconfig=yes],
2661                                         [cf_test_ncuconfig=no],
2662                                         [cf_test_ncuconfig=maybe])],
2663                                 [cf_test_ncuconfig=no])
2664
2665                         CFLAGS="$cf_save_CFLAGS"
2666                         CPPFLAGS="$cf_save_CPPFLAGS"
2667                         LIBS="$cf_save_LIBS"
2668
2669                         if test "x$cf_test_ncuconfig" != xyes; then
2670                                 cf_temp=`echo "x$cf_pkg_cflags" | sed -e s/^x// -e 's/-W[[^     ]]*//g'`
2671                                 cf_pkg_cflags="$cf_temp"
2672                                 cf_temp=`echo "x$cf_pkg_libs" | sed -e s/^x// -e 's/-W[[^       ]]*//g'`
2673                                 cf_pkg_libs="$cf_temp"
2674                         fi
2675                         ;;
2676                 esac
2677
2678                 CF_APPEND_CFLAGS($cf_pkg_cflags)
2679                 CF_ADD_LIBS($cf_pkg_libs)
2680
2681                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2682                         [initscr(); mousemask(0,0); tigetstr((char *)0);],
2683                         [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
2684                                 int main(void)
2685                                 { const char *xx = curses_version(); return (xx == 0); }],
2686                                 [cf_have_ncuconfig=yes],
2687                                 [cf_have_ncuconfig=no],
2688                                 [cf_have_ncuconfig=maybe])],
2689                         [cf_have_ncuconfig=no])
2690                 AC_MSG_RESULT($cf_have_ncuconfig)
2691                 test "$cf_have_ncuconfig" = maybe && cf_have_ncuconfig=yes
2692                 if test "$cf_have_ncuconfig" != "yes"
2693                 then
2694                         CPPFLAGS="$cf_save_CPPFLAGS"
2695                         LIBS="$cf_save_LIBS"
2696                         NCURSES_CONFIG_PKG=none
2697                 else
2698                         AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2699                         NCURSES_CONFIG_PKG=$cf_ncuconfig_root
2700                         CF_TERM_HEADER
2701                 fi
2702
2703         else
2704                 AC_MSG_RESULT(no)
2705                 NCURSES_CONFIG_PKG=none
2706         fi
2707 else
2708         NCURSES_CONFIG_PKG=none
2709 fi
2710
2711 if test "x$cf_have_ncuconfig" = "xno"; then
2712         cf_ncurses_config="${cf_ncuconfig_root}${NCURSES_CONFIG_SUFFIX}-config"; echo "Looking for ${cf_ncurses_config}"
2713
2714         CF_ACVERSION_CHECK(2.52,
2715                 [AC_CHECK_TOOLS(NCURSES_CONFIG, ${cf_ncurses_config} ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)],
2716                 [AC_PATH_PROGS(NCURSES_CONFIG,  ${cf_ncurses_config} ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)])
2717
2718         if test "$NCURSES_CONFIG" != none ; then
2719
2720                 CF_APPEND_CFLAGS(`$NCURSES_CONFIG --cflags`)
2721                 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
2722
2723                 # even with config script, some packages use no-override for curses.h
2724                 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
2725
2726                 dnl like CF_NCURSES_CPPFLAGS
2727                 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2728
2729                 dnl like CF_NCURSES_LIBS
2730                 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
2731                 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2732
2733                 dnl like CF_NCURSES_VERSION
2734                 cf_cv_ncurses_version="`$NCURSES_CONFIG --version`"
2735
2736         else
2737
2738                 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
2739                 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
2740
2741         fi
2742 else
2743         NCURSES_CONFIG=none
2744 fi
2745 ])dnl
2746 dnl ---------------------------------------------------------------------------
2747 dnl CF_NCURSES_CPPFLAGS version: 22 updated: 2021/01/02 09:31:20
2748 dnl -------------------
2749 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
2750 dnl the CPPFLAGS variable so we can include its header.
2751 dnl
2752 dnl The header files may be installed as either curses.h, or ncurses.h (would
2753 dnl be obsolete, except that some packagers prefer this name to distinguish it
2754 dnl from a "native" curses implementation).  If not installed for overwrite,
2755 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
2756 dnl /usr/include/ncurses), but someone may have installed overwriting the
2757 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
2758 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
2759 dnl the header.
2760 dnl
2761 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
2762 dnl is already in the include-path, don't even bother with this, since we cannot
2763 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
2764 dnl
2765 dnl The optional parameter gives the root name of the library, in case it is
2766 dnl not installed as the default curses library.  That is how the
2767 dnl wide-character version of ncurses is installed.
2768 AC_DEFUN([CF_NCURSES_CPPFLAGS],
2769 [AC_REQUIRE([CF_WITH_CURSES_DIR])
2770
2771 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
2772 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
2773
2774 test -n "$cf_cv_curses_dir" && \
2775 test "$cf_cv_curses_dir" != "no" && { \
2776   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
2777 }
2778
2779 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
2780         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
2781         { test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw; } && cf_header_list="$cf_header_list curses.h ncurses.h"
2782         for cf_header in $cf_header_list
2783         do
2784                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
2785                 test "$cf_cv_ncurses_h" != no && break
2786         done
2787 ])
2788
2789 CF_NCURSES_HEADER
2790 CF_TERM_HEADER
2791
2792 # some applications need this, but should check for NCURSES_VERSION
2793 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2794
2795 CF_NCURSES_VERSION
2796 ])dnl
2797 dnl ---------------------------------------------------------------------------
2798 dnl CF_NCURSES_EXT_FUNCS version: 4 updated: 2012/10/06 16:39:58
2799 dnl --------------------
2800 dnl Since 2007/11/17, ncurses has defined NCURSES_EXT_FUNCS; earlier versions
2801 dnl may provide these functions.  Define the symbol if it is not defined, and
2802 dnl if it is valid.
2803 AC_DEFUN([CF_NCURSES_EXT_FUNCS],
2804 [
2805 AC_CACHE_CHECK(for ncurses extended functions,cf_cv_ncurses_ext_funcs,[
2806 AC_TRY_COMPILE([
2807 #include <${cf_cv_ncurses_header:-curses.h}>],
2808 [
2809 int x = NCURSES_EXT_FUNCS
2810 ],[cf_cv_ncurses_ext_funcs=defined],[
2811 AC_TRY_LINK([
2812 #include <${cf_cv_ncurses_header:-curses.h}>],
2813 [
2814         (void) assume_default_colors (0, 0);
2815         (void) curses_version ();
2816         (void) define_key (0, 0);
2817         (void) is_term_resized (0, 0);
2818         (void) key_defined (0);
2819         (void) keybound (0, 0);
2820         (void) keyok (0, 0);
2821         (void) resize_term (0, 0);
2822         (void) resizeterm (0, 0);
2823         (void) use_default_colors ();
2824         (void) use_extended_names (0);
2825         (void) wresize (0, 0, 0);],
2826         [cf_cv_ncurses_ext_funcs=yes],
2827         [cf_cv_ncurses_ext_funcs=no])
2828 ])
2829 ])
2830 test "$cf_cv_ncurses_ext_funcs" = yes && AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 if we have ncurses extensions])
2831 ])dnl
2832 dnl ---------------------------------------------------------------------------
2833 dnl CF_NCURSES_HEADER version: 7 updated: 2021/01/04 19:33:05
2834 dnl -----------------
2835 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
2836 dnl variations of ncurses' installs.
2837 dnl
2838 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
2839 AC_DEFUN([CF_NCURSES_HEADER],[
2840
2841 if test "$cf_cv_ncurses_h" != no ; then
2842         cf_cv_ncurses_header=$cf_cv_ncurses_h
2843 else
2844
2845 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
2846         test -n "$verbose" && echo
2847         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
2848         test -n "$verbose" && echo "search path $cf_search"
2849         cf_save2_CPPFLAGS="$CPPFLAGS"
2850         for cf_incdir in $cf_search
2851         do
2852                 CF_ADD_INCDIR($cf_incdir)
2853                 for cf_header in \
2854                         ncurses.h \
2855                         curses.h
2856                 do
2857                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
2858                         if test "$cf_cv_ncurses_h2" != no ; then
2859                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
2860                                 test -n "$verbose" && echo $ECHO_N "    ... found $ECHO_C" 1>&AC_FD_MSG
2861                                 break
2862                         fi
2863                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
2864                 done
2865                 CPPFLAGS="$cf_save2_CPPFLAGS"
2866                 test "$cf_cv_ncurses_h2" != no && break
2867         done
2868         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
2869         ])
2870
2871         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
2872         cf_cv_ncurses_header="`basename "$cf_cv_ncurses_h2"`"
2873         if test "`basename "$cf_1st_incdir"`" = "$cf_ncuhdr_root" ; then
2874                 cf_cv_ncurses_header="$cf_ncuhdr_root/$cf_cv_ncurses_header"
2875         fi
2876         CF_ADD_INCDIR($cf_1st_incdir)
2877
2878 fi
2879
2880 # Set definitions to allow ifdef'ing for ncurses.h
2881
2882 case "$cf_cv_ncurses_header" in
2883 (*ncurses.h)
2884         AC_DEFINE(HAVE_NCURSES_H,1,[Define to 1 if we have ncurses.h])
2885         ;;
2886 esac
2887
2888 case "$cf_cv_ncurses_header" in
2889 (ncurses/curses.h|ncurses/ncurses.h)
2890         AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Define to 1 if we have ncurses/ncurses.h])
2891         ;;
2892 (ncursesw/curses.h|ncursesw/ncurses.h)
2893         AC_DEFINE(HAVE_NCURSESW_NCURSES_H,1,[Define to 1 if we have ncursesw/ncurses.h])
2894         ;;
2895 esac
2896
2897 ])dnl
2898 dnl ---------------------------------------------------------------------------
2899 dnl CF_NCURSES_LIBS version: 21 updated: 2021/09/04 06:37:12
2900 dnl ---------------
2901 dnl Look for the ncurses library.  This is a little complicated on Linux,
2902 dnl because it may be linked with the gpm (general purpose mouse) library.
2903 dnl Some distributions have gpm linked with (bsd) curses, which makes it
2904 dnl unusable with ncurses.  However, we don't want to link with gpm unless
2905 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
2906 dnl and the linker will record a dependency.
2907 dnl
2908 dnl The optional parameter gives the root name of the library, in case it is
2909 dnl not installed as the default curses library.  That is how the
2910 dnl wide-character version of ncurses is installed.
2911 AC_DEFUN([CF_NCURSES_LIBS],
2912 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
2913
2914 cf_nculib_root=ifelse($1,,ncurses,$1)
2915         # This works, except for the special case where we find gpm, but
2916         # ncurses is in a nonstandard location via $LIBS, and we really want
2917         # to link gpm.
2918 cf_ncurses_LIBS=""
2919 cf_ncurses_SAVE="$LIBS"
2920 AC_CHECK_LIB(gpm,Gpm_Open,
2921         [AC_CHECK_LIB(gpm,initscr,
2922                 [LIBS="$cf_ncurses_SAVE"],
2923                 [cf_ncurses_LIBS="-lgpm"])])
2924
2925 case "$host_os" in
2926 (freebsd*)
2927         # This is only necessary if you are linking against an obsolete
2928         # version of ncurses (but it should do no harm, since it is static).
2929         if test "$cf_nculib_root" = ncurses ; then
2930                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
2931         fi
2932         ;;
2933 esac
2934
2935 CF_ADD_LIBS($cf_ncurses_LIBS)
2936
2937 if test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no"
2938 then
2939         CF_ADD_LIBS(-l$cf_nculib_root)
2940 else
2941         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
2942                 [#include <${cf_cv_ncurses_header:-curses.h}>],
2943                 [initscr()],
2944                 initscr)
2945 fi
2946
2947 if test -n "$cf_ncurses_LIBS" ; then
2948         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
2949         cf_ncurses_SAVE="$LIBS"
2950         for p in $cf_ncurses_LIBS ; do
2951                 q=`echo "$LIBS" | sed -e "s%$p %%" -e "s%$p$%%"`
2952                 if test "$q" != "$LIBS" ; then
2953                         LIBS="$q"
2954                 fi
2955         done
2956         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2957                 [initscr(); mousemask(0,0); tigetstr((char *)0);],
2958                 [AC_MSG_RESULT(yes)],
2959                 [AC_MSG_RESULT(no)
2960                  LIBS="$cf_ncurses_SAVE"])
2961 fi
2962
2963 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
2964 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2965 ])dnl
2966 dnl ---------------------------------------------------------------------------
2967 dnl CF_NCURSES_PTHREADS version: 2 updated: 2016/04/22 05:07:41
2968 dnl -------------------
2969 dnl Use this followup check to ensure that we link with pthreads if ncurses
2970 dnl uses it.
2971 AC_DEFUN([CF_NCURSES_PTHREADS],[
2972 : ${cf_nculib_root:=ifelse($1,,ncurses,$1)}
2973 AC_CHECK_LIB($cf_nculib_root,_nc_init_pthreads,
2974         cf_cv_ncurses_pthreads=yes,
2975         cf_cv_ncurses_pthreads=no)
2976 if test "$cf_cv_ncurses_pthreads" = yes
2977 then
2978         CF_ADD_LIBS(-lpthread)
2979 fi
2980 ])dnl
2981 dnl ---------------------------------------------------------------------------
2982 dnl CF_NCURSES_VERSION version: 17 updated: 2023/01/05 18:54:02
2983 dnl ------------------
2984 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
2985 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
2986 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
2987 AC_DEFUN([CF_NCURSES_VERSION],
2988 [
2989 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
2990 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
2991         cf_cv_ncurses_version=no
2992         cf_tempfile=out$$
2993         rm -f "$cf_tempfile"
2994         AC_TRY_RUN([
2995 $ac_includes_default
2996
2997 #include <${cf_cv_ncurses_header:-curses.h}>
2998
2999 int main(void)
3000 {
3001         FILE *fp = fopen("$cf_tempfile", "w");
3002 #ifdef NCURSES_VERSION
3003 # ifdef NCURSES_VERSION_PATCH
3004         fprintf(fp, "%s.%d\\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
3005 # else
3006         fprintf(fp, "%s\\n", NCURSES_VERSION);
3007 # endif
3008 #else
3009 # ifdef __NCURSES_H
3010         fprintf(fp, "old\\n");
3011 # else
3012         make an error
3013 # endif
3014 #endif
3015         ${cf_cv_main_return:-return}(0);
3016 }],[
3017         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
3018
3019         # This will not work if the preprocessor splits the line after the
3020         # Autoconf token.  The 'unproto' program does that.
3021         cat > "conftest.$ac_ext" <<EOF
3022 #include <${cf_cv_ncurses_header:-curses.h}>
3023 #undef Autoconf
3024 #ifdef NCURSES_VERSION
3025 Autoconf NCURSES_VERSION
3026 #else
3027 #ifdef __NCURSES_H
3028 Autoconf "old"
3029 #endif
3030 ;
3031 #endif
3032 EOF
3033         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
3034         AC_TRY_EVAL(cf_try)
3035         if test -f conftest.out ; then
3036                 cf_out=`sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%' conftest.out`
3037                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
3038                 rm -f conftest.out
3039         fi
3040 ])
3041         rm -f "$cf_tempfile"
3042 ])
3043 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
3044 ])dnl
3045 dnl ---------------------------------------------------------------------------
3046 dnl CF_NCURSES_WRAP_PREFIX version: 1 updated: 2009/03/28 16:08:10
3047 dnl ----------------------
3048 dnl Check for ncurses "wrap-prefix" used for public variables which have been
3049 dnl wrapped with a function to help with concurrency control.
3050 AC_DEFUN([CF_NCURSES_WRAP_PREFIX],
3051 [
3052 AC_MSG_CHECKING(for ncurses wrap-prefix)
3053 AC_ARG_WITH(ncurses-wrap-prefix,
3054         [  --with-ncurses-wrap-prefix naming-prefix for ncurses wrapped-variables],
3055         [NCURSES_WRAP_PREFIX=$withval],
3056         [NCURSES_WRAP_PREFIX=_nc_])
3057 AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
3058
3059 AC_SUBST(NCURSES_WRAP_PREFIX)
3060 ])
3061 dnl ---------------------------------------------------------------------------
3062 dnl CF_NETBSD_FORM_H version: 2 updated: 2012/10/06 16:39:58
3063 dnl ----------------
3064 dnl Check for NetBSD's form.h, which is incompatible with SVr4 and ncurses.
3065 dnl Some workarounds are needed in client programs to allow them to compile.
3066 AC_DEFUN([CF_NETBSD_FORM_H],[
3067 AC_CACHE_CHECK(for NetBSD form.h,cf_cv_netbsd_form_h,[
3068 AC_TRY_COMPILE([
3069 #include <${cf_cv_ncurses_header:-curses.h}>
3070 #include <form.h>
3071 ],[
3072         FORM *form;
3073         int y = current_field(form)->cursor_ypos;
3074         int x = current_field(form)->cursor_xpos;
3075 ],[cf_cv_netbsd_form_h=yes
3076 ],[cf_cv_netbsd_form_h=no])
3077 ])
3078
3079 test "$cf_cv_netbsd_form_h" = yes && AC_DEFINE(HAVE_NETBSD_FORM_H,1,[Define to 1 if we appear to be using NetBSD form.h])
3080 ])dnl
3081 dnl ---------------------------------------------------------------------------
3082 dnl CF_NETBSD_MENU_H version: 2 updated: 2012/10/06 16:39:58
3083 dnl ----------------
3084 dnl Check for NetBSD's menu.h, which is incompatible with SVr4 and ncurses.
3085 dnl Some workarounds are needed in client programs to allow them to compile.
3086 AC_DEFUN([CF_NETBSD_MENU_H],[
3087 AC_CACHE_CHECK(for NetBSD menu.h,cf_cv_netbsd_menu_h,[
3088 AC_TRY_COMPILE([
3089 #include <${cf_cv_ncurses_header:-curses.h}>
3090 #include <menu.h>
3091 ],[
3092         MENU *menu;
3093         int y = menu->max_item_width;
3094 ],[cf_cv_netbsd_menu_h=yes
3095 ],[cf_cv_netbsd_menu_h=no])
3096 ])
3097
3098 test "$cf_cv_netbsd_menu_h" = yes && AC_DEFINE(HAVE_NETBSD_MENU_H,1,[Define to 1 if we appear to be using NetBSD menu.h])
3099 ])dnl
3100 dnl ---------------------------------------------------------------------------
3101 dnl CF_NO_LEAKS_OPTION version: 9 updated: 2021/06/13 19:45:41
3102 dnl ------------------
3103 dnl see CF_WITH_NO_LEAKS
3104 dnl
3105 dnl $1 = option/name
3106 dnl $2 = help-text
3107 dnl $3 = symbol to define if the option is set
3108 dnl $4 = additional actions to take if the option is set
3109 AC_DEFUN([CF_NO_LEAKS_OPTION],[
3110 AC_MSG_CHECKING(if you want to use $1 for testing)
3111 AC_ARG_WITH($1,
3112         [$2],
3113         [case "x$withval" in
3114         (x|xno) ;;
3115         (*)
3116                 : "${with_cflags:=-g}"
3117                 : "${enable_leaks:=no}"
3118                 with_$1=yes
3119                 AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
3120          $4
3121 ])
3122                 ;;
3123         esac],
3124         [with_$1=])
3125 AC_MSG_RESULT(${with_$1:-no})
3126
3127 case ".$with_cflags" in
3128 (.*-g*)
3129         case .$CFLAGS in
3130         (.*-g*)
3131                 ;;
3132         (*)
3133                 CF_ADD_CFLAGS([-g])
3134                 ;;
3135         esac
3136         ;;
3137 esac
3138 ])dnl
3139 dnl ---------------------------------------------------------------------------
3140 dnl CF_PATH_SYNTAX version: 18 updated: 2020/12/31 18:40:20
3141 dnl --------------
3142 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
3143 dnl begins with one of the prefix/exec_prefix variables, and then again if the
3144 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
3145 dnl delayed evaluation of those symbols.
3146 AC_DEFUN([CF_PATH_SYNTAX],[
3147 if test "x$prefix" != xNONE; then
3148         cf_path_syntax="$prefix"
3149 else
3150         cf_path_syntax="$ac_default_prefix"
3151 fi
3152
3153 case ".[$]$1" in
3154 (.\[$]\(*\)*|.\'*\'*)
3155         ;;
3156 (..|./*|.\\*)
3157         ;;
3158 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
3159         ;;
3160 (.\[$]\{*prefix\}*|.\[$]\{*dir\}*)
3161         eval $1="[$]$1"
3162         case ".[$]$1" in
3163         (.NONE/*)
3164                 $1=`echo "[$]$1" | sed -e s%NONE%$cf_path_syntax%`
3165                 ;;
3166         esac
3167         ;;
3168 (.no|.NONE/*)
3169         $1=`echo "[$]$1" | sed -e s%NONE%$cf_path_syntax%`
3170         ;;
3171 (*)
3172         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
3173         ;;
3174 esac
3175 ])dnl
3176 dnl ---------------------------------------------------------------------------
3177 dnl CF_PDCURSES_X11 version: 15 updated: 2021/01/02 09:31:20
3178 dnl ---------------
3179 dnl Configure for PDCurses' X11 library
3180 AC_DEFUN([CF_PDCURSES_X11],[
3181 AC_REQUIRE([CF_X_ATHENA])
3182
3183 CF_ACVERSION_CHECK(2.52,
3184         [AC_CHECK_TOOLS(XCURSES_CONFIG, xcurses-config, none)],
3185         [AC_PATH_PROGS(XCURSES_CONFIG, xcurses-config, none)])
3186
3187 if test "$XCURSES_CONFIG" != none ; then
3188
3189 CF_ADD_CFLAGS(`$XCURSES_CONFIG --cflags`)
3190 CF_ADD_LIBS(`$XCURSES_CONFIG --libs`)
3191
3192 cf_cv_lib_XCurses=yes
3193
3194 else
3195
3196 LDFLAGS="$LDFLAGS $X_LIBS"
3197 CF_CHECK_CFLAGS($X_CFLAGS)
3198 AC_CHECK_LIB(X11,XOpenDisplay,
3199         [CF_ADD_LIBS(-lX11)],,
3200         [$X_PRE_LIBS $LIBS $X_EXTRA_LIBS])
3201 AC_CACHE_CHECK(for XCurses library,cf_cv_lib_XCurses,[
3202 CF_ADD_LIBS(-lXCurses)
3203 AC_TRY_LINK([
3204 #include <xcurses.h>
3205 char *XCursesProgramName = "test";
3206 ],[XCursesExit();],
3207 [cf_cv_lib_XCurses=yes],
3208 [cf_cv_lib_XCurses=no])
3209 ])
3210
3211 fi
3212
3213 if test "$cf_cv_lib_XCurses" = yes ; then
3214         AC_DEFINE(UNIX,1,[Define to 1 if using PDCurses on Unix])
3215         AC_DEFINE(XCURSES,1,[Define to 1 if using PDCurses on Unix])
3216         AC_CHECK_HEADER(xcurses.h, AC_DEFINE(HAVE_XCURSES,1,[Define to 1 if using PDCurses on Unix]))
3217 else
3218         AC_MSG_ERROR(Cannot link with XCurses)
3219 fi
3220 ])dnl
3221 dnl ---------------------------------------------------------------------------
3222 dnl CF_PKG_CONFIG version: 12 updated: 2021/10/10 20:18:09
3223 dnl -------------
3224 dnl Check for the package-config program, unless disabled by command-line.
3225 dnl
3226 dnl Sets $PKG_CONFIG to the pathname of the pkg-config program.
3227 AC_DEFUN([CF_PKG_CONFIG],
3228 [
3229 AC_MSG_CHECKING(if you want to use pkg-config)
3230 AC_ARG_WITH(pkg-config,
3231         [  --with-pkg-config{=path} enable/disable use of pkg-config],
3232         [cf_pkg_config=$withval],
3233         [cf_pkg_config=yes])
3234 AC_MSG_RESULT($cf_pkg_config)
3235
3236 case "$cf_pkg_config" in
3237 (no)
3238         PKG_CONFIG=none
3239         ;;
3240 (yes)
3241         CF_ACVERSION_CHECK(2.52,
3242                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
3243                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
3244         ;;
3245 (*)
3246         PKG_CONFIG=$withval
3247         ;;
3248 esac
3249
3250 test -z "$PKG_CONFIG" && PKG_CONFIG=none
3251 if test "$PKG_CONFIG" != none ; then
3252         CF_PATH_SYNTAX(PKG_CONFIG)
3253 elif test "x$cf_pkg_config" != xno ; then
3254         AC_MSG_WARN(pkg-config is not installed)
3255 fi
3256
3257 AC_SUBST(PKG_CONFIG)
3258 ])dnl
3259 dnl ---------------------------------------------------------------------------
3260 dnl CF_POSIX_C_SOURCE version: 11 updated: 2018/12/31 20:46:17
3261 dnl -----------------
3262 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
3263 dnl
3264 dnl     POSIX.1-1990                            _POSIX_SOURCE
3265 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
3266 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
3267 dnl             Bindings Option
3268 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
3269 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
3270 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
3271 dnl
3272 dnl Parameters:
3273 dnl     $1 is the nominal value for _POSIX_C_SOURCE
3274 AC_DEFUN([CF_POSIX_C_SOURCE],
3275 [AC_REQUIRE([CF_POSIX_VISIBLE])dnl
3276
3277 if test "$cf_cv_posix_visible" = no; then
3278
3279 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
3280
3281 cf_save_CFLAGS="$CFLAGS"
3282 cf_save_CPPFLAGS="$CPPFLAGS"
3283
3284 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
3285 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
3286
3287 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
3288         CF_MSG_LOG(if the symbol is already defined go no further)
3289         AC_TRY_COMPILE([#include <sys/types.h>],[
3290 #ifndef _POSIX_C_SOURCE
3291 make an error
3292 #endif],
3293         [cf_cv_posix_c_source=no],
3294         [cf_want_posix_source=no
3295          case .$cf_POSIX_C_SOURCE in
3296          (.[[12]]??*)
3297                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
3298                 ;;
3299          (.2)
3300                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
3301                 cf_want_posix_source=yes
3302                 ;;
3303          (.*)
3304                 cf_want_posix_source=yes
3305                 ;;
3306          esac
3307          if test "$cf_want_posix_source" = yes ; then
3308                 AC_TRY_COMPILE([#include <sys/types.h>],[
3309 #ifdef _POSIX_SOURCE
3310 make an error
3311 #endif],[],
3312                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
3313          fi
3314          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
3315          CFLAGS="$cf_trim_CFLAGS"
3316          CPPFLAGS="$cf_trim_CPPFLAGS"
3317          CF_APPEND_TEXT(CPPFLAGS,$cf_cv_posix_c_source)
3318          CF_MSG_LOG(if the second compile does not leave our definition intact error)
3319          AC_TRY_COMPILE([#include <sys/types.h>],[
3320 #ifndef _POSIX_C_SOURCE
3321 make an error
3322 #endif],,
3323          [cf_cv_posix_c_source=no])
3324          CFLAGS="$cf_save_CFLAGS"
3325          CPPFLAGS="$cf_save_CPPFLAGS"
3326         ])
3327 ])
3328
3329 if test "$cf_cv_posix_c_source" != no ; then
3330         CFLAGS="$cf_trim_CFLAGS"
3331         CPPFLAGS="$cf_trim_CPPFLAGS"
3332         CF_ADD_CFLAGS($cf_cv_posix_c_source)
3333 fi
3334
3335 fi # cf_cv_posix_visible
3336
3337 ])dnl
3338 dnl ---------------------------------------------------------------------------
3339 dnl CF_POSIX_VISIBLE version: 1 updated: 2018/12/31 20:46:17
3340 dnl ----------------
3341 dnl POSIX documents test-macros which an application may set before any system
3342 dnl headers are included to make features available.
3343 dnl
3344 dnl Some BSD platforms (originally FreeBSD, but copied by a few others)
3345 dnl diverged from POSIX in 2002 by setting symbols which make all of the most
3346 dnl recent features visible in the system header files unless the application
3347 dnl overrides the corresponding test-macros.  Doing that introduces portability
3348 dnl problems.
3349 dnl
3350 dnl This macro makes a special check for the symbols used for this, to avoid a
3351 dnl conflicting definition.
3352 AC_DEFUN([CF_POSIX_VISIBLE],
3353 [
3354 AC_CACHE_CHECK(if the POSIX test-macros are already defined,cf_cv_posix_visible,[
3355 AC_TRY_COMPILE([#include <stdio.h>],[
3356 #if defined(__POSIX_VISIBLE) && ((__POSIX_VISIBLE - 0L) > 0) \
3357         && defined(__XSI_VISIBLE) && ((__XSI_VISIBLE - 0L) > 0) \
3358         && defined(__BSD_VISIBLE) && ((__BSD_VISIBLE - 0L) > 0) \
3359         && defined(__ISO_C_VISIBLE) && ((__ISO_C_VISIBLE - 0L) > 0)
3360 #error conflicting symbols found
3361 #endif
3362 ],[cf_cv_posix_visible=no],[cf_cv_posix_visible=yes])
3363 ])
3364 ])dnl
3365 dnl ---------------------------------------------------------------------------
3366 dnl CF_PRG_RULES version: 2 updated: 2021/01/01 13:31:04
3367 dnl ------------
3368 dnl Append definitions and rules for the given programs to the subdirectory
3369 dnl Makefiles, and the recursion rule for the top-level Makefile.
3370 dnl
3371 dnl parameters
3372 dnl     $1 = script to run
3373 dnl     $2 = list of subdirectories
3374 dnl
3375 dnl variables
3376 dnl     $AWK
3377 AC_DEFUN([CF_PRG_RULES],
3378 [
3379 for cf_dir in $2
3380 do
3381         if test ! -d "$srcdir/$cf_dir" ; then
3382                 continue
3383         elif test -f "$srcdir/$cf_dir/programs" ; then
3384                 $AWK -f $1 "$srcdir/$cf_dir/programs" >>$cf_dir/Makefile
3385         fi
3386 done
3387
3388 ])dnl
3389 dnl ---------------------------------------------------------------------------
3390 dnl CF_PROG_CC version: 5 updated: 2019/12/31 08:53:54
3391 dnl ----------
3392 dnl standard check for CC, plus followup sanity checks
3393 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
3394 AC_DEFUN([CF_PROG_CC],[
3395 CF_ACVERSION_CHECK(2.53,
3396         [AC_MSG_WARN(this will incorrectly handle gnatgcc choice)
3397          AC_REQUIRE([AC_PROG_CC])],
3398         [])
3399 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
3400 CF_GCC_VERSION
3401 CF_ACVERSION_CHECK(2.52,
3402         [AC_PROG_CC_STDC],
3403         [CF_ANSI_CC_REQD])
3404 CF_CC_ENV_FLAGS
3405 ])dnl
3406 dnl ---------------------------------------------------------------------------
3407 dnl CF_PROG_INSTALL version: 10 updated: 2021/01/04 19:33:05
3408 dnl ---------------
3409 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
3410 dnl misc/tabset install won't work properly.  Usually this happens only when
3411 dnl using the fallback mkinstalldirs script
3412 AC_DEFUN([CF_PROG_INSTALL],
3413 [AC_PROG_INSTALL
3414 case $INSTALL in
3415 (/*)
3416         ;;
3417 (*)
3418         CF_DIRNAME(cf_dir,$INSTALL)
3419         test -z "$cf_dir" && cf_dir=.
3420         INSTALL="`cd \"$cf_dir\" && pwd`"/"`echo "$INSTALL" | sed -e 's%^.*/%%'`"
3421         ;;
3422 esac
3423 ])dnl
3424 dnl ---------------------------------------------------------------------------
3425 dnl CF_PROG_LINT version: 5 updated: 2022/08/20 15:44:13
3426 dnl ------------
3427 AC_DEFUN([CF_PROG_LINT],
3428 [
3429 AC_CHECK_PROGS(LINT, lint cppcheck splint)
3430 case "x$LINT" in
3431 (xcppcheck|x*/cppcheck)
3432         test -z "$LINT_OPTS" && LINT_OPTS="--enable=all"
3433         ;;
3434 esac
3435 AC_SUBST(LINT_OPTS)
3436 AC_SUBST(LINT_LIBS)
3437 ])dnl
3438 dnl ---------------------------------------------------------------------------
3439 dnl CF_REMOVE_CFLAGS version: 3 updated: 2021/09/05 17:25:40
3440 dnl ----------------
3441 dnl Remove a given option from CFLAGS/CPPFLAGS
3442 dnl $1 = option to remove
3443 dnl $2 = variable to update
3444 dnl $3 = nonempty to allow verbose message
3445 define([CF_REMOVE_CFLAGS],
3446 [
3447 cf_tmp_cflag=`echo "x$1" | sed -e 's/^.//' -e 's/=.*//'`
3448 while true
3449 do
3450         cf_old_cflag=`echo "x[$]$2" | sed -e 's/^.//' -e 's/[[  ]][[    ]]*-/ -/g' -e "s%$cf_tmp_cflag\\(=[[^   ]][[^   ]]*\\)\?%%" -e 's/^[[   ]]*//' -e 's%[[ ]][[ ]]*-D% -D%g' -e 's%[[ ]][[ ]]*-I% -I%g'`
3451         test "[$]$2" != "$cf_old_cflag" || break
3452         ifelse([$3],,,[CF_VERBOSE(removing old option $1 from $2)])
3453         $2="$cf_old_cflag"
3454 done
3455 ])dnl
3456 dnl ---------------------------------------------------------------------------
3457 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
3458 dnl ----------------
3459 dnl Remove all -U and -D options that refer to the given symbol from a list
3460 dnl of C compiler options.  This works around the problem that not all
3461 dnl compilers process -U and -D options from left-to-right, so a -U option
3462 dnl cannot be used to cancel the effect of a preceding -D option.
3463 dnl
3464 dnl $1 = target (which could be the same as the source variable)
3465 dnl $2 = source (including '$')
3466 dnl $3 = symbol to remove
3467 define([CF_REMOVE_DEFINE],
3468 [
3469 $1=`echo "$2" | \
3470         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
3471                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
3472 ])dnl
3473 dnl ---------------------------------------------------------------------------
3474 dnl CF_RESTORE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:47:45
3475 dnl ---------------------
3476 dnl Restore flags saved in CF_SAVE_XTRA_FLAGS
3477 dnl $1 = name of current macro
3478 define([CF_RESTORE_XTRA_FLAGS],
3479 [
3480 LIBS="$cf_save_LIBS_$1"
3481 CFLAGS="$cf_save_CFLAGS_$1"
3482 CPPFLAGS="$cf_save_CPPFLAGS_$1"
3483 ])dnl
3484 dnl ---------------------------------------------------------------------------
3485 dnl CF_RPATH_HACK version: 13 updated: 2021/01/03 18:30:50
3486 dnl -------------
3487 AC_DEFUN([CF_RPATH_HACK],
3488 [AC_REQUIRE([AC_PROG_FGREP])dnl
3489 AC_REQUIRE([CF_LD_RPATH_OPT])dnl
3490
3491 AC_MSG_CHECKING(for updated LDFLAGS)
3492 if test -n "$LD_RPATH_OPT" ; then
3493         AC_MSG_RESULT(maybe)
3494
3495         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
3496         cf_rpath_list="/usr/lib /lib"
3497         if test "$cf_ldd_prog" != no
3498         then
3499                 cf_rpath_oops=
3500
3501 AC_TRY_LINK([#include <stdio.h>],
3502                 [printf("Hello");],
3503                 [cf_rpath_oops=`"$cf_ldd_prog" "conftest$ac_exeext" | ${FGREP-fgrep} ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
3504                  cf_rpath_list=`"$cf_ldd_prog" "conftest$ac_exeext" | ${FGREP-fgrep} / | sed -e 's%^.*[[        ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
3505
3506                 # If we passed the link-test, but get a "not found" on a given library,
3507                 # this could be due to inept reconfiguration of gcc to make it only
3508                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
3509                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
3510                 # /usr/local libraries.
3511                 if test -n "$cf_rpath_oops"
3512                 then
3513                         for cf_rpath_src in $cf_rpath_oops
3514                         do
3515                                 for cf_rpath_dir in \
3516                                         /usr/local \
3517                                         /usr/pkg \
3518                                         /opt/sfw
3519                                 do
3520                                         if test -f "$cf_rpath_dir/lib/$cf_rpath_src"
3521                                         then
3522                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
3523                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
3524                                                 break
3525                                         fi
3526                                 done
3527                         done
3528                 fi
3529         fi
3530
3531         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
3532
3533         CF_RPATH_HACK_2(LDFLAGS)
3534         CF_RPATH_HACK_2(LIBS)
3535
3536         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
3537 else
3538         AC_MSG_RESULT(no)
3539 fi
3540 AC_SUBST(EXTRA_LDFLAGS)
3541 ])dnl
3542 dnl ---------------------------------------------------------------------------
3543 dnl CF_RPATH_HACK_2 version: 8 updated: 2021/01/01 13:31:04
3544 dnl ---------------
3545 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
3546 dnl EXTRA_LDFLAGS for each -L option found.
3547 dnl
3548 dnl $cf_rpath_list contains a list of directories to ignore.
3549 dnl
3550 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
3551 dnl      but LIBS often has misplaced -L options.
3552 AC_DEFUN([CF_RPATH_HACK_2],
3553 [
3554 CF_VERBOSE(...checking $1 [$]$1)
3555
3556 cf_rpath_dst=
3557 for cf_rpath_src in [$]$1
3558 do
3559         case "$cf_rpath_src" in
3560         (-L*)
3561
3562                 # check if this refers to a directory which we will ignore
3563                 cf_rpath_skip=no
3564                 if test -n "$cf_rpath_list"
3565                 then
3566                         for cf_rpath_item in $cf_rpath_list
3567                         do
3568                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
3569                                 then
3570                                         cf_rpath_skip=yes
3571                                         break
3572                                 fi
3573                         done
3574                 fi
3575
3576                 if test "$cf_rpath_skip" = no
3577                 then
3578                         # transform the option
3579                         if test "$LD_RPATH_OPT" = "-R " ; then
3580                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
3581                         else
3582                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
3583                         fi
3584
3585                         # if we have not already added this, add it now
3586                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
3587                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
3588                         then
3589                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
3590                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
3591                         fi
3592                 fi
3593                 ;;
3594         esac
3595         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
3596 done
3597 $1=$cf_rpath_dst
3598
3599 CF_VERBOSE(...checked $1 [$]$1)
3600 AC_SUBST(EXTRA_LDFLAGS)
3601 ])dnl
3602 dnl ---------------------------------------------------------------------------
3603 dnl CF_SAVE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:46:44
3604 dnl ------------------
3605 dnl Use this macro to save CFLAGS/CPPFLAGS/LIBS before checks against X headers
3606 dnl and libraries which do not update those variables.
3607 dnl
3608 dnl $1 = name of current macro
3609 define([CF_SAVE_XTRA_FLAGS],
3610 [
3611 cf_save_LIBS_$1="$LIBS"
3612 cf_save_CFLAGS_$1="$CFLAGS"
3613 cf_save_CPPFLAGS_$1="$CPPFLAGS"
3614 LIBS="$LIBS ${X_PRE_LIBS} ${X_LIBS} ${X_EXTRA_LIBS}"
3615 for cf_X_CFLAGS in $X_CFLAGS
3616 do
3617         case "x$cf_X_CFLAGS" in
3618         x-[[IUD]]*)
3619                 CPPFLAGS="$CPPFLAGS $cf_X_CFLAGS"
3620                 ;;
3621         *)
3622                 CFLAGS="$CFLAGS $cf_X_CFLAGS"
3623                 ;;
3624         esac
3625 done
3626 ])dnl
3627 dnl ---------------------------------------------------------------------------
3628 dnl CF_SIGWINCH version: 6 updated: 2021/01/01 13:31:04
3629 dnl -----------
3630 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
3631 dnl programs need this test).
3632 dnl
3633 dnl This is really a Mac OS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
3634 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
3635 dnl winsize declaration is left alone - we may revisit this if Apple choose to
3636 dnl break that part of the interface as well.
3637 AC_DEFUN([CF_SIGWINCH],
3638 [
3639 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
3640         AC_TRY_COMPILE([
3641 #include <sys/types.h>
3642 #include <sys/signal.h>
3643 ],[int x = SIGWINCH; (void)x],
3644         [cf_cv_define_sigwinch=yes],
3645         [AC_TRY_COMPILE([
3646 #undef _XOPEN_SOURCE
3647 #undef _POSIX_SOURCE
3648 #undef _POSIX_C_SOURCE
3649 #include <sys/types.h>
3650 #include <sys/signal.h>
3651 ],[int x = SIGWINCH; (void)x],
3652         [cf_cv_define_sigwinch=maybe],
3653         [cf_cv_define_sigwinch=no])
3654 ])
3655 ])
3656
3657 if test "$cf_cv_define_sigwinch" = maybe ; then
3658 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
3659 cf_cv_fixup_sigwinch=unknown
3660 cf_sigwinch=32
3661 while test "$cf_sigwinch" != 1
3662 do
3663         AC_TRY_COMPILE([
3664 #undef _XOPEN_SOURCE
3665 #undef _POSIX_SOURCE
3666 #undef _POSIX_C_SOURCE
3667 #include <sys/types.h>
3668 #include <sys/signal.h>
3669 ],[
3670 #if SIGWINCH != $cf_sigwinch
3671 make an error
3672 #endif
3673 int x = SIGWINCH; (void)x],
3674         [cf_cv_fixup_sigwinch=$cf_sigwinch
3675          break])
3676
3677 cf_sigwinch="`expr "$cf_sigwinch" - 1`"
3678 done
3679 ])
3680
3681         if test "$cf_cv_fixup_sigwinch" != unknown ; then
3682                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
3683         fi
3684 fi
3685 ])dnl
3686 dnl ---------------------------------------------------------------------------
3687 dnl CF_SIG_ATOMIC_T version: 5 updated: 2020/03/10 18:53:47
3688 dnl ---------------
3689 dnl signal handler, but there are some gcc dependencies in that recommendation.
3690 dnl Try anyway.
3691 AC_DEFUN([CF_SIG_ATOMIC_T],
3692 [
3693 AC_MSG_CHECKING(for signal global datatype)
3694 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
3695         for cf_type in \
3696                 "volatile sig_atomic_t" \
3697                 "sig_atomic_t" \
3698                 "int"
3699         do
3700         AC_TRY_COMPILE([
3701 #include <sys/types.h>
3702 #include <signal.h>
3703 #include <stdio.h>
3704
3705 extern $cf_type x;
3706 $cf_type x;
3707 static void handler(int sig)
3708 {
3709         (void)sig;
3710         x = 5;
3711 }],
3712                 [signal(SIGINT, handler);
3713                  x = 1],
3714                 [cf_cv_sig_atomic_t=$cf_type],
3715                 [cf_cv_sig_atomic_t=no])
3716                 test "$cf_cv_sig_atomic_t" != no && break
3717         done
3718         ])
3719 AC_MSG_RESULT($cf_cv_sig_atomic_t)
3720 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
3721 ])dnl
3722 dnl ---------------------------------------------------------------------------
3723 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
3724 dnl --------------
3725 dnl Construct a search-list for a nonstandard header/lib-file
3726 dnl     $1 = the variable to return as result
3727 dnl     $2 = the package name
3728 dnl     $3 = the subdirectory, e.g., bin, include or lib
3729 AC_DEFUN([CF_SUBDIR_PATH],
3730 [
3731 $1=
3732
3733 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
3734
3735 for cf_subdir_prefix in \
3736         /usr \
3737         /usr/local \
3738         /usr/pkg \
3739         /opt \
3740         /opt/local \
3741         [$]HOME
3742 do
3743         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
3744 done
3745 ])dnl
3746 dnl ---------------------------------------------------------------------------
3747 dnl CF_SYS_TIME_SELECT version: 6 updated: 2015/04/18 08:56:57
3748 dnl ------------------
3749 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
3750 dnl older SCO configurations.
3751 AC_DEFUN([CF_SYS_TIME_SELECT],
3752 [
3753 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
3754 AC_CACHE_VAL(cf_cv_sys_time_select,[
3755 AC_TRY_COMPILE([
3756 #include <sys/types.h>
3757 #ifdef HAVE_SYS_TIME_H
3758 #include <sys/time.h>
3759 #endif
3760 #ifdef HAVE_SYS_SELECT_H
3761 #include <sys/select.h>
3762 #endif
3763 ],[],[cf_cv_sys_time_select=yes],
3764          [cf_cv_sys_time_select=no])
3765          ])
3766 AC_MSG_RESULT($cf_cv_sys_time_select)
3767 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
3768 ])dnl
3769 dnl ---------------------------------------------------------------------------
3770 dnl CF_TERM_HEADER version: 6 updated: 2021/01/02 09:31:20
3771 dnl --------------
3772 dnl Look for term.h, which is part of X/Open curses.  It defines the interface
3773 dnl to terminfo database.  Usually it is in the same include-path as curses.h,
3774 dnl but some packagers change this, breaking various applications.
3775 AC_DEFUN([CF_TERM_HEADER],[
3776 AC_CACHE_CHECK(for terminfo header, cf_cv_term_header,[
3777 case "${cf_cv_ncurses_header}" in
3778 (*/ncurses.h|*/ncursesw.h)
3779         cf_term_header=`echo "$cf_cv_ncurses_header" | sed -e 's%ncurses[[^.]]*\.h$%term.h%'`
3780         ;;
3781 (*)
3782         cf_term_header=term.h
3783         ;;
3784 esac
3785
3786 for cf_test in $cf_term_header "ncurses/term.h" "ncursesw/term.h"
3787 do
3788 AC_TRY_COMPILE([#include <stdio.h>
3789 #include <${cf_cv_ncurses_header:-curses.h}>
3790 #include <$cf_test>
3791 ],[int x = auto_left_margin; (void)x],[
3792         cf_cv_term_header="$cf_test"],[
3793         cf_cv_term_header=unknown
3794         ])
3795         test "$cf_cv_term_header" != unknown && break
3796 done
3797 ])
3798
3799 # Set definitions to allow ifdef'ing to accommodate subdirectories
3800
3801 case "$cf_cv_term_header" in
3802 (*term.h)
3803         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
3804         ;;
3805 esac
3806
3807 case "$cf_cv_term_header" in
3808 (ncurses/term.h)
3809         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
3810         ;;
3811 (ncursesw/term.h)
3812         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
3813         ;;
3814 esac
3815 ])dnl
3816 dnl ---------------------------------------------------------------------------
3817 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
3818 dnl ---------------
3819 dnl Define a top_builddir symbol, for applications that need an absolute path.
3820 AC_DEFUN([CF_TOP_BUILDDIR],
3821 [
3822 top_builddir=ifelse($1,,`pwd`,$1)
3823 AC_SUBST(top_builddir)
3824 ])dnl
3825 dnl ---------------------------------------------------------------------------
3826 dnl CF_TPUTS_PROTO version: 4 updated: 2021/01/04 19:45:09
3827 dnl --------------
3828 dnl Check for type of function-pointer passed to tputs.  Some old
3829 dnl implementations used functions that had different prototypes, making it
3830 dnl hard to compile portable programs using tputs.
3831 AC_DEFUN([CF_TPUTS_PROTO],[
3832 CF_CURSES_FUNCS(tputs)
3833 if test "x$cf_cv_func_tputs" = xyes
3834 then
3835         cf_done=no
3836         for cf_arg in int char
3837         do
3838                 for cf_ret in int void
3839                 do
3840                         if test "$cf_ret" = void
3841                         then
3842                                 cf_return="/* nothing */"
3843                         else
3844                                 cf_return="return value"
3845                         fi
3846                         AC_TRY_COMPILE([
3847 #include <${cf_cv_ncurses_header:-curses.h}>
3848 #include <$cf_cv_term_header>
3849
3850 static $cf_ret outc($cf_arg value) { $cf_return; }
3851 ],[
3852         tputs("hello", 0, outc);
3853         ${cf_cv_main_return:-return}(0);
3854 ],[
3855                 CF_VERBOSE([prototype $cf_ret func($cf_arg value)])
3856                 cat >>confdefs.h <<EOF
3857 #define TPUTS_ARG               $cf_arg
3858 #define TPUTS_PROTO(func,value) $cf_ret func(TPUTS_ARG value)
3859 #define TPUTS_RETURN(value)     $cf_return
3860 EOF
3861                 cf_done=yes
3862                 break
3863 ])
3864                 done
3865                 test "$cf_done" = yes && break
3866         done
3867 fi
3868 ])dnl
3869 dnl ---------------------------------------------------------------------------
3870 dnl CF_TRIM_X_LIBS version: 3 updated: 2015/04/12 15:39:00
3871 dnl --------------
3872 dnl Trim extra base X libraries added as a workaround for inconsistent library
3873 dnl dependencies returned by "new" pkg-config files.
3874 AC_DEFUN([CF_TRIM_X_LIBS],[
3875         for cf_trim_lib in Xmu Xt X11
3876         do
3877                 case "$LIBS" in
3878                 (*-l$cf_trim_lib\ *-l$cf_trim_lib*)
3879                         LIBS=`echo "$LIBS " | sed -e 's/  / /g' -e 's%-l'"$cf_trim_lib"' %%' -e 's/ $//'`
3880                         CF_VERBOSE(..trimmed $LIBS)
3881                         ;;
3882                 esac
3883         done
3884 ])
3885 dnl ---------------------------------------------------------------------------
3886 dnl CF_TRY_PKG_CONFIG version: 6 updated: 2020/12/31 10:54:15
3887 dnl -----------------
3888 dnl This is a simple wrapper to use for pkg-config, for libraries which may be
3889 dnl available in that form.
3890 dnl
3891 dnl $1 = package name, which may be a shell variable
3892 dnl $2 = extra logic to use, if any, after updating CFLAGS and LIBS
3893 dnl $3 = logic to use if pkg-config does not have the package
3894 AC_DEFUN([CF_TRY_PKG_CONFIG],[
3895 AC_REQUIRE([CF_PKG_CONFIG])
3896
3897 if test "$PKG_CONFIG" != none && "$PKG_CONFIG" --exists "$1"; then
3898         CF_VERBOSE(found package $1)
3899         cf_pkgconfig_incs="`$PKG_CONFIG --cflags "$1" 2>/dev/null`"
3900         cf_pkgconfig_libs="`$PKG_CONFIG --libs   "$1" 2>/dev/null`"
3901         CF_VERBOSE(package $1 CFLAGS: $cf_pkgconfig_incs)
3902         CF_VERBOSE(package $1 LIBS: $cf_pkgconfig_libs)
3903         CF_ADD_CFLAGS($cf_pkgconfig_incs)
3904         CF_ADD_LIBS($cf_pkgconfig_libs)
3905         ifelse([$2],,:,[$2])
3906 else
3907         cf_pkgconfig_incs=
3908         cf_pkgconfig_libs=
3909         ifelse([$3],,:,[$3])
3910 fi
3911 ])
3912 dnl ---------------------------------------------------------------------------
3913 dnl CF_TRY_XOPEN_SOURCE version: 4 updated: 2022/09/10 15:16:16
3914 dnl -------------------
3915 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
3916 dnl can define it successfully.
3917 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
3918 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
3919         AC_TRY_COMPILE(CF__XOPEN_SOURCE_HEAD,CF__XOPEN_SOURCE_BODY,
3920         [cf_cv_xopen_source=no],
3921         [cf_save="$CPPFLAGS"
3922          CF_APPEND_TEXT(CPPFLAGS,-D_XOPEN_SOURCE=$cf_XOPEN_SOURCE)
3923          AC_TRY_COMPILE(CF__XOPEN_SOURCE_HEAD,CF__XOPEN_SOURCE_BODY,
3924                 [cf_cv_xopen_source=no],
3925                 [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
3926                 CPPFLAGS="$cf_save"
3927         ])
3928 ])
3929
3930 if test "$cf_cv_xopen_source" != no ; then
3931         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
3932         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
3933         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
3934         CF_APPEND_CFLAGS($cf_temp_xopen_source)
3935 fi
3936 ])
3937 dnl ---------------------------------------------------------------------------
3938 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
3939 dnl --------
3940 dnl Make an uppercase version of a variable
3941 dnl $1=uppercase($2)
3942 AC_DEFUN([CF_UPPER],
3943 [
3944 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
3945 ])dnl
3946 dnl ---------------------------------------------------------------------------
3947 dnl CF_UTF8_LIB version: 10 updated: 2023/01/11 04:05:23
3948 dnl -----------
3949 dnl Check for multibyte support, and if not found, utf8 compatibility library
3950 AC_DEFUN([CF_UTF8_LIB],
3951 [
3952 AC_HAVE_HEADERS(wchar.h)
3953 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
3954         cf_save_LIBS="$LIBS"
3955         AC_TRY_LINK([
3956 $ac_includes_default
3957 #ifdef HAVE_WCHAR_H
3958 #include <wchar.h>
3959 #endif
3960 ],[putwc(0,0);],
3961         [cf_cv_utf8_lib=yes],
3962         [CF_FIND_LINKAGE([
3963 #include <libutf8.h>],[putwc(0,0);],utf8,
3964                 [cf_cv_utf8_lib=add-on],
3965                 [cf_cv_utf8_lib=no])
3966 ])])
3967
3968 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
3969 # ncurses/ncursesw:
3970 if test "$cf_cv_utf8_lib" = "add-on" ; then
3971         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
3972         CF_ADD_INCDIR($cf_cv_header_path_utf8)
3973         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
3974         CF_ADD_LIBS($cf_cv_library_file_utf8)
3975 fi
3976 ])dnl
3977 dnl ---------------------------------------------------------------------------
3978 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
3979 dnl ----------
3980 dnl Use AC_VERBOSE w/o the warnings
3981 AC_DEFUN([CF_VERBOSE],
3982 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
3983 CF_MSG_LOG([$1])
3984 ])dnl
3985 dnl ---------------------------------------------------------------------------
3986 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
3987 dnl -------------
3988 dnl Check if type wide-character type $1 is declared, and if so, which header
3989 dnl file is needed.  The second parameter is used to set a shell variable when
3990 dnl the type is not found.  The first parameter sets a shell variable for the
3991 dnl opposite sense.
3992 AC_DEFUN([CF_WCHAR_TYPE],
3993 [
3994 # This is needed on Tru64 5.0 to declare $1
3995 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
3996 AC_TRY_COMPILE([
3997 #include <stdlib.h>
3998 #include <stdarg.h>
3999 #include <stdio.h>
4000 #ifdef HAVE_LIBUTF8_H
4001 #include <libutf8.h>
4002 #endif],
4003         [$1 state],
4004         [cf_cv_$1=no],
4005         [AC_TRY_COMPILE([
4006 #include <stdlib.h>
4007 #include <stdarg.h>
4008 #include <stdio.h>
4009 #include <wchar.h>
4010 #ifdef HAVE_LIBUTF8_H
4011 #include <libutf8.h>
4012 #endif],
4013         [$1 value],
4014         [cf_cv_$1=yes],
4015         [cf_cv_$1=unknown])])])
4016
4017 if test "$cf_cv_$1" = yes ; then
4018         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
4019         NEED_WCHAR_H=1
4020 fi
4021
4022 ifelse([$2],,,[
4023 # if we do not find $1 in either place, use substitution to provide a fallback.
4024 if test "$cf_cv_$1" = unknown ; then
4025         $2=1
4026 fi
4027 ])
4028 ifelse($3,,,[
4029 # if we find $1 in either place, use substitution to provide a fallback.
4030 if test "$cf_cv_$1" != unknown ; then
4031         $3=1
4032 fi
4033 ])
4034 ])dnl
4035 dnl ---------------------------------------------------------------------------
4036 dnl CF_WITH_CURSES_DIR version: 4 updated: 2021/01/02 19:22:58
4037 dnl ------------------
4038 dnl Wrapper for AC_ARG_WITH to specify directory under which to look for curses
4039 dnl libraries.
4040 AC_DEFUN([CF_WITH_CURSES_DIR],[
4041
4042 AC_MSG_CHECKING(for specific curses-directory)
4043 AC_ARG_WITH(curses-dir,
4044         [  --with-curses-dir=DIR   directory in which (n)curses is installed],
4045         [cf_cv_curses_dir=$withval],
4046         [cf_cv_curses_dir=no])
4047 AC_MSG_RESULT($cf_cv_curses_dir)
4048
4049 if test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no"
4050 then
4051         CF_PATH_SYNTAX(withval)
4052         if test -d "$cf_cv_curses_dir"
4053         then
4054                 CF_ADD_INCDIR($cf_cv_curses_dir/include)
4055                 CF_ADD_LIBDIR($cf_cv_curses_dir/lib)
4056         fi
4057 fi
4058 ])dnl
4059 dnl ---------------------------------------------------------------------------
4060 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
4061 dnl ----------------
4062 dnl Configure-option for dbmalloc.  The optional parameter is used to override
4063 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
4064 AC_DEFUN([CF_WITH_DBMALLOC],[
4065 CF_NO_LEAKS_OPTION(dbmalloc,
4066         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
4067         [USE_DBMALLOC])
4068
4069 if test "$with_dbmalloc" = yes ; then
4070         AC_CHECK_HEADER(dbmalloc.h,
4071                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
4072 fi
4073 ])dnl
4074 dnl ---------------------------------------------------------------------------
4075 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
4076 dnl ---------------
4077 dnl Configure-option for dmalloc.  The optional parameter is used to override
4078 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
4079 AC_DEFUN([CF_WITH_DMALLOC],[
4080 CF_NO_LEAKS_OPTION(dmalloc,
4081         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
4082         [USE_DMALLOC])
4083
4084 if test "$with_dmalloc" = yes ; then
4085         AC_CHECK_HEADER(dmalloc.h,
4086                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
4087 fi
4088 ])dnl
4089 dnl ---------------------------------------------------------------------------
4090 dnl CF_WITH_LIB_BASENAME version: 1 updated: 2020/03/07 20:05:14
4091 dnl --------------------
4092 dnl Allow for overriding the basename of a library, i.e., the part to which
4093 dnl prefixes/suffixes are attached.
4094 dnl
4095 dnl $1 = variable to set
4096 dnl $2 = option name
4097 dnl $3 = default basename for library, if omitted use $2
4098 AC_DEFUN([CF_WITH_LIB_BASENAME],
4099 [
4100 AC_MSG_CHECKING(for desired basename for $2 library)
4101 AC_ARG_WITH($2-libname,
4102         [  --with-$2-libname=XXX override ifelse($3,,$2,$3) basename of library],
4103         [with_lib_basename=$withval],
4104         [with_lib_basename=ifelse($3,,$2,$3)])
4105 $1="$with_lib_basename"
4106
4107 case "x[$]$1" in
4108 (x|xno|xnone|xyes)
4109         $1=ifelse($3,,$2,$3)
4110         ;;
4111 (*)
4112         ;;
4113 esac
4114
4115 AC_MSG_RESULT([$]$1)
4116 AC_SUBST($1)
4117 ])dnl
4118 dnl ---------------------------------------------------------------------------
4119 dnl CF_WITH_NCURSES_ETC version: 5 updated: 2016/02/20 19:23:20
4120 dnl -------------------
4121 dnl Use this macro for programs which use any variant of "curses", e.g.,
4122 dnl "ncurses", and "PDCurses".  Programs that can use curses and some unrelated
4123 dnl library (such as slang) should use a "--with-screen=XXX" option.
4124 dnl
4125 dnl This does not use AC_DEFUN, because that would tell autoconf to run each
4126 dnl of the macros inside this one - before this macro.
4127 define([CF_WITH_NCURSES_ETC],[
4128 CF_WITH_CURSES_DIR
4129
4130 cf_cv_screen=curses
4131
4132 AC_MSG_CHECKING(for specified curses library type)
4133 AC_ARG_WITH(screen,
4134         [  --with-screen=XXX       use specified curses-libraries],
4135         [cf_cv_screen=$withval],[
4136
4137 AC_ARG_WITH(ncursesw,
4138         [  --with-ncursesw         use wide ncurses-libraries],
4139         [cf_cv_screen=ncursesw],[
4140
4141 AC_ARG_WITH(ncurses,
4142         [  --with-ncurses          use ncurses-libraries],
4143         [cf_cv_screen=ncurses],[
4144
4145 AC_ARG_WITH(pdcurses,
4146         [  --with-pdcurses         compile/link with pdcurses X11 library],
4147         [cf_cv_screen=pdcurses],[
4148
4149 AC_ARG_WITH(curses-colr,
4150         [  --with-curses-colr      compile/link with HPUX 10.x color-curses],
4151         [cf_cv_screen=curses_colr],[
4152
4153 AC_ARG_WITH(curses-5lib,
4154         [  --with-curses-5lib      compile/link with SunOS 5lib curses],
4155         [cf_cv_screen=curses_5lib])])])])])])
4156
4157 AC_MSG_RESULT($cf_cv_screen)
4158
4159 case $cf_cv_screen in
4160 (curses|curses_*)
4161         CF_CURSES_CONFIG
4162         ;;
4163 (ncursesw*)
4164         CF_UTF8_LIB
4165         CF_NCURSES_CONFIG($cf_cv_screen)
4166         ;;
4167 (ncurses*)
4168         CF_NCURSES_CONFIG($cf_cv_screen)
4169         ;;
4170 (pdcurses)
4171         CF_PDCURSES_X11
4172         ;;
4173 (*)
4174         AC_MSG_ERROR(unexpected screen-value: $cf_cv_screen)
4175         ;;
4176 esac
4177
4178 CF_NCURSES_PTHREADS($cf_cv_screen)
4179
4180 ])dnl
4181 dnl ---------------------------------------------------------------------------
4182 dnl CF_WITH_SCREEN_PDCURSES version: 1 updated: 2020/08/28 16:56:27
4183 dnl -----------------------
4184 dnl Call this macro before CF_ENABLE_WARNINGS for configure scripts which use
4185 dnl the "--with-screen=pdcurses" selection.  Doing that allows the configure
4186 dnl script to search for the X11/Xt header files to declare (or not) the
4187 dnl symbol needed to enable "const" in those header files.  If that configure
4188 dnl option is not used, then those checks are unnecessary.
4189 AC_DEFUN([CF_WITH_SCREEN_PDCURSES],[
4190 AC_PROVIDE([AC_PATH_XTRA])
4191 AC_PROVIDE([AC_PATH_X])
4192 if test -n "$with_screen" && test "x$with_screen" = "xpdcurses"
4193 then
4194         AC_PATH_X
4195         AC_PATH_XTRA
4196 fi
4197 ])dnl
4198 dnl ---------------------------------------------------------------------------
4199 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
4200 dnl ----------------
4201 AC_DEFUN([CF_WITH_VALGRIND],[
4202 CF_NO_LEAKS_OPTION(valgrind,
4203         [  --with-valgrind         test: use valgrind],
4204         [USE_VALGRIND])
4205 ])dnl
4206 dnl ---------------------------------------------------------------------------
4207 dnl CF_WITH_X11_RGB version: 2 updated: 2019/12/31 08:53:54
4208 dnl ---------------
4209 dnl Handle configure option "--with-x11-rgb", setting these shell
4210 dnl variables:
4211 dnl
4212 dnl $RGB_PATH is the option value, used for finding the X11 rgb file.
4213 dnl $no_x11_rgb is a "#" (comment) if "--without-x11-rgb" is given.
4214 dnl
4215 dnl Most Linux's use this:
4216 dnl     /usr/share/X11/rgb.txt
4217 dnl Debian uses this:
4218 dnl     /etc/X11/rgb.txt
4219 dnl DragonFlyBSD ports uses this:
4220 dnl     /usr/pkg/lib/X11/rgb.txt
4221 dnl FreeBSD ports use these:
4222 dnl     /usr/local/lib/X11/rgb.txt
4223 dnl     /usr/local/share/X11/rgb.txt
4224 dnl Mandriva has these:
4225 dnl     /usr/lib/X11/rgb.txt
4226 dnl     /usr/lib64/X11/rgb.txt
4227 dnl NetBSD has these
4228 dnl     /usr/X11R7/lib/X11/rgb.txt
4229 dnl OpenSolaris uses
4230 dnl     32-bit:
4231 dnl     /usr/X11/etc/X11/rgb.txt
4232 dnl     /usr/X11/share/X11/rgb.txt
4233 dnl     /usr/X11/lib/X11/rgb.txt
4234 dnl OSX uses
4235 dnl             /opt/local/share/X11/rgb.txt (MacPorts)
4236 dnl             /opt/X11/share/X11/rgb.txt (non-ports)
4237 dnl     64-bit:
4238 dnl     /usr/X11/etc/X11/rgb.txt
4239 dnl     /usr/X11/share/X11/rgb.txt (perhaps)
4240 dnl     /usr/X11/lib/amd64/X11/rgb.txt
4241 dnl Solaris10 uses (in this order):
4242 dnl     /usr/openwin/lib/X11/rgb.txt
4243 dnl     /usr/X11/lib/X11/rgb.txt
4244 AC_DEFUN([CF_WITH_X11_RGB],[
4245 AC_MSG_CHECKING(for X11 rgb file)
4246 AC_ARG_WITH(x11-rgb,
4247         [  --with-x11-rgb=FILE   file containing X11 rgb information (EPREFIX/lib/X11/rgb.txt)],
4248         [RGB_PATH=$withval],
4249         [RGB_PATH=auto])
4250
4251 if test "x[$]RGB_PATH" = xauto
4252 then
4253         RGB_PATH='${exec_prefix}/lib/X11/rgb.txt'
4254         for cf_path in \
4255                 /opt/local/share/X11/rgb.txt \
4256                 /opt/X11/share/X11/rgb.txt \
4257                 /usr/share/X11/rgb.txt \
4258                 /usr/X11/share/X11/rgb.txt \
4259                 /usr/X11/lib/X11/rgb.txt \
4260                 /usr/lib/X11/rgb.txt \
4261                 /etc/X11/rgb.txt \
4262                 /usr/pkg/lib/X11/rgb.txt \
4263                 /usr/X11R7/lib/X11/rgb.txt \
4264                 /usr/X11R6/lib/X11/rgb.txt \
4265                 /usr/X11R5/lib/X11/rgb.txt \
4266                 /usr/X11R4/lib/X11/rgb.txt \
4267                 /usr/local/lib/X11/rgb.txt \
4268                 /usr/local/share/X11/rgb.txt \
4269                 /usr/lib64/X11/rgb.txt
4270         do
4271                 if test -f "$cf_path" ; then
4272                         RGB_PATH="$cf_path"
4273                         break
4274                 fi
4275         done
4276 else
4277         cf_path=$RGB_PATH
4278         CF_PATH_SYNTAX(cf_path)
4279 fi
4280
4281 AC_MSG_RESULT($RGB_PATH)
4282 AC_SUBST(RGB_PATH)
4283 AC_DEFINE_UNQUOTED(RGB_PATH,"$cf_path",[Define to the full pathname of rgb.txt])
4284
4285 no_x11_rgb=
4286 if test "$RGB_PATH" = no
4287 then
4288         no_x11_rgb="#"
4289 fi
4290 AC_SUBST(no_x11_rgb)
4291 ])dnl
4292 dnl ---------------------------------------------------------------------------
4293 dnl CF_XOPEN_CURSES version: 18 updated: 2023/01/11 04:05:23
4294 dnl ---------------
4295 dnl Test if we should define X/Open source for curses, needed on Digital Unix
4296 dnl 4.x, to see the extended functions, but breaks on IRIX 6.x.
4297 dnl
4298 dnl The getbegyx() check is needed for HPUX, which omits legacy macros such
4299 dnl as getbegy().  The latter is better design, but the former is standard.
4300 AC_DEFUN([CF_XOPEN_CURSES],
4301 [
4302 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
4303 AC_CACHE_CHECK(definition to turn on extended curses functions,cf_cv_need_xopen_extension,[
4304 cf_cv_need_xopen_extension=unknown
4305 AC_TRY_LINK([
4306 $ac_includes_default
4307 #include <${cf_cv_ncurses_header:-curses.h}>],[
4308 #if defined(NCURSES_VERSION_PATCH)
4309 #if (NCURSES_VERSION_PATCH < 20100501) && (NCURSES_VERSION_PATCH >= 20100403)
4310         make an error
4311 #endif
4312 #endif
4313 #ifdef NCURSES_WIDECHAR
4314 make an error   /* prefer to fall-through on the second checks */
4315 #endif
4316         cchar_t check;
4317         int check2 = curs_set((int)sizeof(check));
4318         long x = winnstr(stdscr, "", 0);
4319         int x1, y1;
4320         (void)check2;
4321         getbegyx(stdscr, y1, x1);
4322         (void)x;
4323         (void)y1;
4324         (void)x1;
4325         ],
4326         [cf_cv_need_xopen_extension=none],
4327         [
4328         for cf_try_xopen_extension in _XOPEN_SOURCE_EXTENDED NCURSES_WIDECHAR
4329         do
4330                 AC_TRY_LINK([
4331 #define $cf_try_xopen_extension 1
4332 $ac_includes_default
4333 #include <${cf_cv_ncurses_header:-curses.h}>],[
4334                 cchar_t check;
4335                 int check2 = curs_set((int)sizeof(check));
4336                 long x = winnstr(stdscr, "", 0);
4337                 int x1, y1;
4338                 getbegyx(stdscr, y1, x1);
4339                 (void)check2;
4340                 (void)x;
4341                 (void)y1;
4342                 (void)x1;
4343                 ],
4344                 [cf_cv_need_xopen_extension=$cf_try_xopen_extension; break])
4345         done
4346         ])
4347 ])
4348
4349 case "$cf_cv_need_xopen_extension" in
4350 (*_*)
4351         CF_APPEND_TEXT(CPPFLAGS,-D$cf_cv_need_xopen_extension)
4352         ;;
4353 esac
4354
4355 ])dnl
4356 dnl ---------------------------------------------------------------------------
4357 dnl CF_XOPEN_SOURCE version: 63 updated: 2022/12/29 10:10:26
4358 dnl ---------------
4359 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
4360 dnl or adapt to the vendor's definitions to get equivalent functionality,
4361 dnl without losing the common non-POSIX features.
4362 dnl
4363 dnl Parameters:
4364 dnl     $1 is the nominal value for _XOPEN_SOURCE
4365 dnl     $2 is the nominal value for _POSIX_C_SOURCE
4366 AC_DEFUN([CF_XOPEN_SOURCE],[
4367 AC_REQUIRE([AC_CANONICAL_HOST])
4368 AC_REQUIRE([CF_POSIX_VISIBLE])
4369
4370 if test "$cf_cv_posix_visible" = no; then
4371
4372 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
4373 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
4374 cf_xopen_source=
4375
4376 case "$host_os" in
4377 (aix[[4-7]]*)
4378         cf_xopen_source="-D_ALL_SOURCE"
4379         ;;
4380 (msys)
4381         cf_XOPEN_SOURCE=600
4382         ;;
4383 (darwin[[0-8]].*)
4384         cf_xopen_source="-D_APPLE_C_SOURCE"
4385         ;;
4386 (darwin*)
4387         cf_xopen_source="-D_DARWIN_C_SOURCE"
4388         cf_XOPEN_SOURCE=
4389         ;;
4390 (freebsd*|dragonfly*|midnightbsd*)
4391         # 5.x headers associate
4392         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
4393         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
4394         cf_POSIX_C_SOURCE=200112L
4395         cf_XOPEN_SOURCE=600
4396         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
4397         ;;
4398 (hpux11*)
4399         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
4400         ;;
4401 (hpux*)
4402         cf_xopen_source="-D_HPUX_SOURCE"
4403         ;;
4404 (irix[[56]].*)
4405         cf_xopen_source="-D_SGI_SOURCE"
4406         cf_XOPEN_SOURCE=
4407         ;;
4408 (linux*gnu|linux*gnuabi64|linux*gnuabin32|linux*gnueabi|linux*gnueabihf|linux*gnux32|uclinux*|gnu*|mint*|k*bsd*-gnu|cygwin)
4409         CF_GNU_SOURCE($cf_XOPEN_SOURCE)
4410         ;;
4411 (minix*)
4412         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
4413         ;;
4414 (mirbsd*)
4415         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
4416         cf_XOPEN_SOURCE=
4417         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
4418         ;;
4419 (netbsd*)
4420         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
4421         ;;
4422 (openbsd[[6-9]]*)
4423         # OpenBSD 6.x has broken locale support, both compile-time and runtime.
4424         # see https://www.mail-archive.com/bugs@openbsd.org/msg13200.html
4425         # Abusing the conformance level is a workaround.
4426         AC_MSG_WARN(this system does not provide usable locale support)
4427         cf_xopen_source="-D_BSD_SOURCE"
4428         cf_XOPEN_SOURCE=700
4429         ;;
4430 (openbsd[[4-5]]*)
4431         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
4432         cf_xopen_source="-D_BSD_SOURCE"
4433         cf_XOPEN_SOURCE=600
4434         ;;
4435 (openbsd*)
4436         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
4437         ;;
4438 (osf[[45]]*)
4439         cf_xopen_source="-D_OSF_SOURCE"
4440         ;;
4441 (nto-qnx*)
4442         cf_xopen_source="-D_QNX_SOURCE"
4443         ;;
4444 (sco*)
4445         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
4446         ;;
4447 (solaris2.*)
4448         cf_xopen_source="-D__EXTENSIONS__"
4449         cf_cv_xopen_source=broken
4450         ;;
4451 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
4452         cf_XOPEN_SOURCE=
4453         cf_POSIX_C_SOURCE=
4454         ;;
4455 (*)
4456         CF_TRY_XOPEN_SOURCE
4457         cf_save_xopen_cppflags="$CPPFLAGS"
4458         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
4459         # Some of these niche implementations use copy/paste, double-check...
4460         if test "$cf_cv_xopen_source" != no ; then
4461                 CF_VERBOSE(checking if _POSIX_C_SOURCE inteferes)
4462                 AC_TRY_COMPILE(CF__XOPEN_SOURCE_HEAD,CF__XOPEN_SOURCE_BODY,,[
4463                         AC_MSG_WARN(_POSIX_C_SOURCE definition is not usable)
4464                         CPPFLAGS="$cf_save_xopen_cppflags"])
4465         fi
4466         ;;
4467 esac
4468
4469 if test -n "$cf_xopen_source" ; then
4470         CF_APPEND_CFLAGS($cf_xopen_source,true)
4471 fi
4472
4473 dnl In anything but the default case, we may have system-specific setting
4474 dnl which is still not guaranteed to provide all of the entrypoints that
4475 dnl _XOPEN_SOURCE would yield.
4476 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
4477         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
4478         AC_TRY_COMPILE([#include <stdlib.h>],[
4479 #ifndef _XOPEN_SOURCE
4480 make an error
4481 #endif],
4482         [cf_XOPEN_SOURCE_set=yes],
4483         [cf_XOPEN_SOURCE_set=no])
4484         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
4485         if test "$cf_XOPEN_SOURCE_set" = yes
4486         then
4487                 AC_TRY_COMPILE([#include <stdlib.h>],[
4488 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
4489 make an error
4490 #endif],
4491                 [cf_XOPEN_SOURCE_set_ok=yes],
4492                 [cf_XOPEN_SOURCE_set_ok=no])
4493                 if test "$cf_XOPEN_SOURCE_set_ok" = no
4494                 then
4495                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
4496                 fi
4497         else
4498                 CF_TRY_XOPEN_SOURCE
4499         fi
4500 fi
4501 fi # cf_cv_posix_visible
4502 ])
4503 dnl ---------------------------------------------------------------------------
4504 dnl CF_X_ATHENA version: 25 updated: 2023/01/11 04:05:23
4505 dnl -----------
4506 dnl Check for Xaw (Athena) libraries
4507 dnl
4508 dnl Sets $cf_x_athena according to the flavor of Xaw which is used.
4509 AC_DEFUN([CF_X_ATHENA],
4510 [
4511 cf_x_athena=${cf_x_athena:-Xaw}
4512
4513 AC_MSG_CHECKING(if you want to link with Xaw 3d library)
4514 withval=
4515 AC_ARG_WITH(Xaw3d,
4516         [  --with-Xaw3d            link with Xaw 3d library])
4517 if test "$withval" = yes ; then
4518         cf_x_athena=Xaw3d
4519         AC_MSG_RESULT(yes)
4520 else
4521         AC_MSG_RESULT(no)
4522 fi
4523
4524 AC_MSG_CHECKING(if you want to link with Xaw 3d xft library)
4525 withval=
4526 AC_ARG_WITH(Xaw3dxft,
4527         [  --with-Xaw3dxft         link with Xaw 3d xft library])
4528 if test "$withval" = yes ; then
4529         cf_x_athena=Xaw3dxft
4530         AC_MSG_RESULT(yes)
4531 else
4532         AC_MSG_RESULT(no)
4533 fi
4534
4535 AC_MSG_CHECKING(if you want to link with neXT Athena library)
4536 withval=
4537 AC_ARG_WITH(neXtaw,
4538         [  --with-neXtaw           link with neXT Athena library])
4539 if test "$withval" = yes ; then
4540         cf_x_athena=neXtaw
4541         AC_MSG_RESULT(yes)
4542 else
4543         AC_MSG_RESULT(no)
4544 fi
4545
4546 AC_MSG_CHECKING(if you want to link with Athena-Plus library)
4547 withval=
4548 AC_ARG_WITH(XawPlus,
4549         [  --with-XawPlus          link with Athena-Plus library])
4550 if test "$withval" = yes ; then
4551         cf_x_athena=XawPlus
4552         AC_MSG_RESULT(yes)
4553 else
4554         AC_MSG_RESULT(no)
4555 fi
4556
4557 cf_x_athena_lib=""
4558
4559 if test "$PKG_CONFIG" != none ; then
4560         cf_athena_list=
4561         test "$cf_x_athena" = Xaw && cf_athena_list="xaw8 xaw7 xaw6"
4562         for cf_athena_pkg in \
4563                 $cf_athena_list \
4564                 ${cf_x_athena} \
4565                 ${cf_x_athena}-devel \
4566                 lib${cf_x_athena} \
4567                 lib${cf_x_athena}-devel
4568         do
4569                 CF_TRY_PKG_CONFIG($cf_athena_pkg,[
4570                         cf_x_athena_lib="$cf_pkgconfig_libs"
4571                         CF_UPPER(cf_x_athena_LIBS,HAVE_LIB_$cf_x_athena)
4572                         AC_DEFINE_UNQUOTED($cf_x_athena_LIBS)
4573
4574                         CF_TRIM_X_LIBS
4575
4576 AC_CACHE_CHECK(for usable $cf_x_athena/Xmu package,cf_cv_xaw_compat,[
4577 AC_TRY_LINK([
4578 $ac_includes_default
4579 #include <X11/Xmu/CharSet.h>
4580 ],[
4581 int check = XmuCompareISOLatin1("big", "small");
4582 (void)check;
4583 ],[cf_cv_xaw_compat=yes],[cf_cv_xaw_compat=no])])
4584
4585                         if test "$cf_cv_xaw_compat" = no
4586                         then
4587                                 # workaround for broken ".pc" files...
4588                                 case "$cf_x_athena_lib" in
4589                                 (*-lXmu*)
4590                                         ;;
4591                                 (*)
4592                                         CF_VERBOSE(work around broken package)
4593                                         cf_save_xmu="$LIBS"
4594                                         cf_first_lib=`echo "$cf_save_xmu" | sed -e 's/^[ ][ ]*//' -e 's/ .*//'`
4595                                         CF_TRY_PKG_CONFIG(xmu,[
4596                                                         LIBS="$cf_save_xmu"
4597                                                         CF_ADD_LIB_AFTER($cf_first_lib,$cf_pkgconfig_libs)
4598                                                 ],[
4599                                                         CF_ADD_LIB_AFTER($cf_first_lib,-lXmu)
4600                                                 ])
4601                                         CF_TRIM_X_LIBS
4602                                         ;;
4603                                 esac
4604                         fi
4605
4606                         break])
4607         done
4608 fi
4609
4610 if test -z "$cf_x_athena_lib" ; then
4611         CF_X_EXT
4612         CF_X_TOOLKIT
4613         CF_X_ATHENA_CPPFLAGS($cf_x_athena)
4614         CF_X_ATHENA_LIBS($cf_x_athena)
4615 fi
4616 ])dnl
4617 dnl ---------------------------------------------------------------------------
4618 dnl CF_X_ATHENA_CPPFLAGS version: 9 updated: 2020/12/31 10:54:15
4619 dnl --------------------
4620 dnl Normally invoked by CF_X_ATHENA, with $1 set to the appropriate flavor of
4621 dnl the Athena widgets, e.g., Xaw, Xaw3d, neXtaw.
4622 AC_DEFUN([CF_X_ATHENA_CPPFLAGS],
4623 [
4624 AC_REQUIRE([AC_PATH_XTRA])
4625 cf_x_athena_root=ifelse([$1],,Xaw,[$1])
4626 cf_x_athena_inc=""
4627
4628 for cf_path in default \
4629         /usr/contrib/X11R6 \
4630         /usr/contrib/X11R5 \
4631         /usr/lib/X11R5 \
4632         /usr/local
4633 do
4634         if test -z "$cf_x_athena_inc" ; then
4635                 CF_SAVE_XTRA_FLAGS([CF_X_ATHENA_CPPFLAGS])
4636                 cf_test=X11/$cf_x_athena_root/SimpleMenu.h
4637                 if test "$cf_path" != default ; then
4638                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_path/include)
4639                         AC_MSG_CHECKING(for $cf_test in $cf_path)
4640                 else
4641                         AC_MSG_CHECKING(for $cf_test)
4642                 fi
4643                 AC_TRY_COMPILE([
4644 #include <X11/Intrinsic.h>
4645 #include <$cf_test>],[],
4646                         [cf_result=yes],
4647                         [cf_result=no])
4648                 AC_MSG_RESULT($cf_result)
4649                 CF_RESTORE_XTRA_FLAGS([CF_X_ATHENA_CPPFLAGS])
4650                 if test "$cf_result" = yes ; then
4651                         test "$cf_path"  = default && cf_x_athena_inc=default
4652                         test "$cf_path" != default && cf_x_athena_inc="$cf_path/include"
4653                         break
4654                 fi
4655         fi
4656 done
4657
4658 if test -z "$cf_x_athena_inc" ; then
4659         AC_MSG_WARN([Unable to find Athena header files])
4660 elif test "$cf_x_athena_inc" != default ; then
4661         CF_APPEND_TEXT(CPPFLAGS,-I$cf_x_athena_inc)
4662 fi
4663 ])
4664 dnl ---------------------------------------------------------------------------
4665 dnl CF_X_ATHENA_LIBS version: 14 updated: 2023/01/11 04:05:23
4666 dnl ----------------
4667 dnl Normally invoked by CF_X_ATHENA, with $1 set to the appropriate flavor of
4668 dnl the Athena widgets, e.g., Xaw, Xaw3d, neXtaw.
4669 AC_DEFUN([CF_X_ATHENA_LIBS],
4670 [AC_REQUIRE([CF_X_TOOLKIT])
4671 cf_x_athena_root=ifelse([$1],,Xaw,[$1])
4672 cf_x_athena_lib=""
4673
4674 for cf_path in default \
4675         /usr/contrib/X11R6 \
4676         /usr/contrib/X11R5 \
4677         /usr/lib/X11R5 \
4678         /usr/local
4679 do
4680         for cf_lib in \
4681                 ${cf_x_athena_root} \
4682                 ${cf_x_athena_root}7 \
4683                 ${cf_x_athena_root}6
4684         do
4685         for cf_libs in \
4686                 "-l$cf_lib -lXmu" \
4687                 "-l$cf_lib -lXpm -lXmu" \
4688                 "-l${cf_lib}_s -lXmu_s"
4689         do
4690                 test -n "$cf_x_athena_lib" && break
4691
4692                 CF_SAVE_XTRA_FLAGS([CF_X_ATHENA_LIBS])
4693                 cf_test=XawSimpleMenuAddGlobalActions
4694                 test "$cf_path" != default && cf_libs="-L$cf_path/lib $cf_libs"
4695                 CF_ADD_LIBS($cf_libs)
4696                 AC_MSG_CHECKING(for $cf_test in $cf_libs)
4697                 AC_TRY_LINK([
4698 $ac_includes_default
4699 #include <X11/Intrinsic.h>
4700 #include <X11/$cf_x_athena_root/SimpleMenu.h>
4701 ],[
4702 $cf_test((XtAppContext) 0)],
4703                         [cf_result=yes],
4704                         [cf_result=no])
4705                 AC_MSG_RESULT($cf_result)
4706                 CF_RESTORE_XTRA_FLAGS([CF_X_ATHENA_LIBS])
4707
4708                 if test "$cf_result" = yes ; then
4709                         cf_x_athena_lib="$cf_libs"
4710                         break
4711                 fi
4712         done # cf_libs
4713                 test -n "$cf_x_athena_lib" && break
4714         done # cf_lib
4715 done
4716
4717 if test -z "$cf_x_athena_lib" ; then
4718         AC_MSG_ERROR(
4719 [Unable to successfully link Athena library (-l$cf_x_athena_root) with test program])
4720 fi
4721
4722 CF_ADD_LIBS($cf_x_athena_lib)
4723 CF_UPPER(cf_x_athena_LIBS,HAVE_LIB_$cf_x_athena)
4724 AC_DEFINE_UNQUOTED($cf_x_athena_LIBS)
4725 ])
4726 dnl ---------------------------------------------------------------------------
4727 dnl CF_X_EXT version: 3 updated: 2010/06/02 05:03:05
4728 dnl --------
4729 AC_DEFUN([CF_X_EXT],[
4730 CF_TRY_PKG_CONFIG(Xext,,[
4731         AC_CHECK_LIB(Xext,XextCreateExtension,
4732                 [CF_ADD_LIB(Xext)])])
4733 ])dnl
4734 dnl ---------------------------------------------------------------------------
4735 dnl CF_X_TOOLKIT version: 27 updated: 2023/01/11 04:05:23
4736 dnl ------------
4737 dnl Check for X Toolkit libraries
4738 AC_DEFUN([CF_X_TOOLKIT],
4739 [
4740 AC_REQUIRE([AC_PATH_XTRA])
4741 AC_REQUIRE([CF_CHECK_CACHE])
4742
4743 # OSX is schizoid about who owns /usr/X11 (old) versus /opt/X11 (new) (and
4744 # in some cases has installed dummy files in the former, other cases replaced
4745 # it with a link to the new location).  This complicates the configure script.
4746 # Check for that pitfall, and recover using pkg-config
4747 #
4748 # If none of these are set, the configuration is almost certainly broken.
4749 if test -z "${X_CFLAGS}${X_PRE_LIBS}${X_LIBS}${X_EXTRA_LIBS}"
4750 then
4751         CF_TRY_PKG_CONFIG(x11,,[AC_MSG_WARN(unable to find X11 library)])
4752         CF_TRY_PKG_CONFIG(ice,,[AC_MSG_WARN(unable to find ICE library)])
4753         CF_TRY_PKG_CONFIG(sm,,[AC_MSG_WARN(unable to find SM library)])
4754         CF_TRY_PKG_CONFIG(xt,,[AC_MSG_WARN(unable to find Xt library)])
4755 else
4756         LIBS="$X_PRE_LIBS $LIBS $X_EXTRA_LIBS"
4757 fi
4758
4759 cf_have_X_LIBS=no
4760
4761 CF_TRY_PKG_CONFIG(xt,[
4762
4763         case "x$LIBS" in
4764         (*-lX11*)
4765                 ;;
4766         (*)
4767 # we have an "xt" package, but it may omit Xt's dependency on X11
4768 AC_CACHE_CHECK(for usable X dependency,cf_cv_xt_x11_compat,[
4769 AC_TRY_LINK([
4770 $ac_includes_default
4771 #include <X11/Xlib.h>
4772 ],[
4773         int rc1 = XDrawLine((Display*) 0, (Drawable) 0, (GC) 0, 0, 0, 0, 0);
4774         int rc2 = XClearWindow((Display*) 0, (Window) 0);
4775         int rc3 = XMoveWindow((Display*) 0, (Window) 0, 0, 0);
4776         int rc4 = XMoveResizeWindow((Display*)0, (Window)0, 0, 0, 0, 0);
4777 ],[cf_cv_xt_x11_compat=yes],[cf_cv_xt_x11_compat=no])])
4778                 if test "$cf_cv_xt_x11_compat" = no
4779                 then
4780                         CF_VERBOSE(work around broken X11 dependency)
4781                         # 2010/11/19 - good enough until a working Xt on Xcb is delivered.
4782                         CF_TRY_PKG_CONFIG(x11,,[CF_ADD_LIB_AFTER(-lXt,-lX11)])
4783                 fi
4784                 ;;
4785         esac
4786
4787 AC_CACHE_CHECK(for usable X Toolkit package,cf_cv_xt_ice_compat,[
4788 AC_TRY_LINK([
4789 $ac_includes_default
4790 #include <X11/Shell.h>
4791 ],[int num = IceConnectionNumber(0); (void) num
4792 ],[cf_cv_xt_ice_compat=yes],[cf_cv_xt_ice_compat=no])])
4793
4794         if test "$cf_cv_xt_ice_compat" = no
4795         then
4796                 # workaround for broken ".pc" files used for X Toolkit.
4797                 case "x$X_PRE_LIBS" in
4798                 (*-lICE*)
4799                         case "x$LIBS" in
4800                         (*-lICE*)
4801                                 ;;
4802                         (*)
4803                                 CF_VERBOSE(work around broken ICE dependency)
4804                                 CF_TRY_PKG_CONFIG(ice,
4805                                         [CF_TRY_PKG_CONFIG(sm)],
4806                                         [CF_ADD_LIB_AFTER(-lXt,$X_PRE_LIBS)])
4807                                 ;;
4808                         esac
4809                         ;;
4810                 esac
4811         fi
4812
4813         cf_have_X_LIBS=yes
4814 ],[
4815
4816         LDFLAGS="$X_LIBS $LDFLAGS"
4817         CF_CHECK_CFLAGS($X_CFLAGS)
4818
4819         AC_CHECK_FUNC(XOpenDisplay,,[
4820         AC_CHECK_LIB(X11,XOpenDisplay,
4821                 [CF_ADD_LIB(X11)])])
4822
4823         AC_CHECK_FUNC(XtAppInitialize,,[
4824         AC_CHECK_LIB(Xt, XtAppInitialize,
4825                 [AC_DEFINE(HAVE_LIBXT,1,[Define to 1 if we can compile with the Xt library])
4826                  cf_have_X_LIBS=Xt
4827                  LIBS="-lXt $LIBS"])])
4828 ])
4829
4830 if test "$cf_have_X_LIBS" = no ; then
4831         AC_MSG_WARN(
4832 [Unable to successfully link X Toolkit library (-lXt) with
4833 test program.  You will have to check and add the proper libraries by hand
4834 to makefile.])
4835 fi
4836 ])dnl
4837 dnl ---------------------------------------------------------------------------
4838 dnl CF__CURSES_DATA version: 3 updated: 2021/01/04 19:45:09
4839 dnl ---------------
4840 dnl Attempt to make a copy of a curses data item.  This is needed in the
4841 dnl check-data configure tests when using ncurses, because the symbol may be
4842 dnl actually a function return-value.  That could happen if the linker is
4843 dnl broken (does not resolve data-only references), or if ncurses is configured
4844 dnl to support re-entrant code.
4845 dnl $1 = target
4846 dnl $2 = source
4847 define([CF__CURSES_DATA],[
4848 #if defined($2) && ((defined(NCURSES_WRAPPED_VAR) && (NCURSES_VERSION_PATCH < 20200208)) || defined(NCURSES_BROKEN_LINKER) || defined(NCURSES_REENTRANT))
4849         const void *$1 = (const void *)($2);
4850 #else
4851         const void *$1 = &($2);
4852 #endif
4853         fprintf(stderr, "testing linkage of $2:%p\\n", (const void *)$1);
4854 ])dnl
4855 dnl ---------------------------------------------------------------------------
4856 dnl CF__CURSES_HEAD version: 2 updated: 2010/10/23 15:54:49
4857 dnl ---------------
4858 dnl Define a reusable chunk which includes <curses.h> and <term.h> when they
4859 dnl are both available.
4860 define([CF__CURSES_HEAD],[
4861 #ifdef HAVE_XCURSES
4862 #include <xcurses.h>
4863 char * XCursesProgramName = "test";
4864 #else
4865 #include <${cf_cv_ncurses_header:-curses.h}>
4866 #if defined(NCURSES_VERSION) && defined(HAVE_NCURSESW_TERM_H)
4867 #include <ncursesw/term.h>
4868 #elif defined(NCURSES_VERSION) && defined(HAVE_NCURSES_TERM_H)
4869 #include <ncurses/term.h>
4870 #elif defined(HAVE_TERM_H)
4871 #include <term.h>
4872 #endif
4873 #endif
4874 ])
4875 dnl ---------------------------------------------------------------------------
4876 dnl CF__XOPEN_SOURCE_BODY version: 1 updated: 2022/09/10 15:17:35
4877 dnl ---------------------
4878 dnl body of test when test-compiling for _XOPEN_SOURCE check
4879 define([CF__XOPEN_SOURCE_BODY],
4880 [
4881 #ifndef _XOPEN_SOURCE
4882 make an error
4883 #endif
4884 ])
4885 dnl ---------------------------------------------------------------------------
4886 dnl CF__XOPEN_SOURCE_HEAD version: 1 updated: 2022/09/10 15:17:03
4887 dnl ---------------------
4888 dnl headers to include when test-compiling for _XOPEN_SOURCE check
4889 define([CF__XOPEN_SOURCE_HEAD],
4890 [
4891 #include <stdlib.h>
4892 #include <string.h>
4893 #include <sys/types.h>
4894 ])