ncurses 5.9 - patch 20131116
[ncurses.git] / test / aclocal.m4
1 dnl***************************************************************************
2 dnl Copyright (c) 2003-2012,2013 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl $Id: aclocal.m4,v 1.92 2013/11/16 20:05:42 tom Exp $
30 dnl
31 dnl Author: Thomas E. Dickey
32 dnl
33 dnl Macros used in NCURSES test programs auto-configuration script.
34 dnl
35 dnl These macros are maintained separately from NCURSES.  The copyright on
36 dnl this file applies to the aggregation of macros and does not affect use of
37 dnl these macros in other applications.
38 dnl
39 dnl See http://invisible-island.net/autoconf/ for additional information.
40 dnl
41 dnl ---------------------------------------------------------------------------
42 dnl ---------------------------------------------------------------------------
43 dnl CF_ACVERSION_CHECK version: 4 updated: 2013/03/04 19:52:56
44 dnl ------------------
45 dnl Conditionally generate script according to whether we're using a given autoconf.
46 dnl
47 dnl $1 = version to compare against
48 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
49 dnl $3 = code to use if AC_ACVERSION is older than $1.
50 define([CF_ACVERSION_CHECK],
51 [
52 ifdef([AC_ACVERSION], ,[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])dnl
53 ifdef([m4_version_compare],
54 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
55 [CF_ACVERSION_COMPARE(
56 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
57 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
58 dnl ---------------------------------------------------------------------------
59 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
60 dnl --------------------
61 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
62 dnl                      MAJOR2, MINOR2, TERNARY2,
63 dnl                      PRINTABLE2, not FOUND, FOUND)
64 define([CF_ACVERSION_COMPARE],
65 [ifelse(builtin([eval], [$2 < $5]), 1,
66 [ifelse([$8], , ,[$8])],
67 [ifelse([$9], , ,[$9])])])dnl
68 dnl ---------------------------------------------------------------------------
69 dnl CF_ADD_CFLAGS version: 10 updated: 2010/05/26 05:38:42
70 dnl -------------
71 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
72 dnl The second parameter if given makes this macro verbose.
73 dnl
74 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
75 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
76 dnl confused by the quotes (which require backslashes to keep them usable).
77 AC_DEFUN([CF_ADD_CFLAGS],
78 [
79 cf_fix_cppflags=no
80 cf_new_cflags=
81 cf_new_cppflags=
82 cf_new_extra_cppflags=
83
84 for cf_add_cflags in $1
85 do
86 case $cf_fix_cppflags in
87 no)
88         case $cf_add_cflags in #(vi
89         -undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C) #(vi
90                 case $cf_add_cflags in
91                 -D*)
92                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
93
94                         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
95                                 && test -z "${cf_tst_cflags}" \
96                                 && cf_fix_cppflags=yes
97
98                         if test $cf_fix_cppflags = yes ; then
99                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
100                                 continue
101                         elif test "${cf_tst_cflags}" = "\"'" ; then
102                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
103                                 continue
104                         fi
105                         ;;
106                 esac
107                 case "$CPPFLAGS" in
108                 *$cf_add_cflags) #(vi
109                         ;;
110                 *) #(vi
111                         case $cf_add_cflags in #(vi
112                         -D*)
113                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
114                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
115                                 ;;
116                         esac
117                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
118                         ;;
119                 esac
120                 ;;
121         *)
122                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
123                 ;;
124         esac
125         ;;
126 yes)
127         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
128
129         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
130
131         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
132                 && test -z "${cf_tst_cflags}" \
133                 && cf_fix_cppflags=no
134         ;;
135 esac
136 done
137
138 if test -n "$cf_new_cflags" ; then
139         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
140         CFLAGS="$CFLAGS $cf_new_cflags"
141 fi
142
143 if test -n "$cf_new_cppflags" ; then
144         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
145         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
146 fi
147
148 if test -n "$cf_new_extra_cppflags" ; then
149         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
150         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
151 fi
152
153 AC_SUBST(EXTRA_CPPFLAGS)
154
155 ])dnl
156 dnl ---------------------------------------------------------------------------
157 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
158 dnl -------------
159 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
160 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
161 dnl but old versions (and some misinstalled ones) need that.  To make things
162 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
163 dnl the include-path).
164 AC_DEFUN([CF_ADD_INCDIR],
165 [
166 if test -n "$1" ; then
167   for cf_add_incdir in $1
168   do
169         while test $cf_add_incdir != /usr/include
170         do
171           if test -d $cf_add_incdir
172           then
173                 cf_have_incdir=no
174                 if test -n "$CFLAGS$CPPFLAGS" ; then
175                   # a loop is needed to ensure we can add subdirs of existing dirs
176                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
177                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
178                           cf_have_incdir=yes; break
179                         fi
180                   done
181                 fi
182
183                 if test "$cf_have_incdir" = no ; then
184                   if test "$cf_add_incdir" = /usr/local/include ; then
185                         if test "$GCC" = yes
186                         then
187                           cf_save_CPPFLAGS=$CPPFLAGS
188                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
189                           AC_TRY_COMPILE([#include <stdio.h>],
190                                   [printf("Hello")],
191                                   [],
192                                   [cf_have_incdir=yes])
193                           CPPFLAGS=$cf_save_CPPFLAGS
194                         fi
195                   fi
196                 fi
197
198                 if test "$cf_have_incdir" = no ; then
199                   CF_VERBOSE(adding $cf_add_incdir to include-path)
200                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
201
202                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
203                   test "$cf_top_incdir" = "$cf_add_incdir" && break
204                   cf_add_incdir="$cf_top_incdir"
205                 else
206                   break
207                 fi
208           fi
209         done
210   done
211 fi
212 ])dnl
213 dnl ---------------------------------------------------------------------------
214 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
215 dnl ----------
216 dnl Add a library, used to enforce consistency.
217 dnl
218 dnl $1 = library to add, without the "-l"
219 dnl $2 = variable to update (default $LIBS)
220 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
221 dnl ---------------------------------------------------------------------------
222 dnl CF_ADD_LIBDIR version: 9 updated: 2010/05/26 16:44:57
223 dnl -------------
224 dnl     Adds to the library-path
225 dnl
226 dnl     Some machines have trouble with multiple -L options.
227 dnl
228 dnl $1 is the (list of) directory(s) to add
229 dnl $2 is the optional name of the variable to update (default LDFLAGS)
230 dnl
231 AC_DEFUN([CF_ADD_LIBDIR],
232 [
233 if test -n "$1" ; then
234   for cf_add_libdir in $1
235   do
236     if test $cf_add_libdir = /usr/lib ; then
237       :
238     elif test -d $cf_add_libdir
239     then
240       cf_have_libdir=no
241       if test -n "$LDFLAGS$LIBS" ; then
242         # a loop is needed to ensure we can add subdirs of existing dirs
243         for cf_test_libdir in $LDFLAGS $LIBS ; do
244           if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
245             cf_have_libdir=yes; break
246           fi
247         done
248       fi
249       if test "$cf_have_libdir" = no ; then
250         CF_VERBOSE(adding $cf_add_libdir to library-path)
251         ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
252       fi
253     fi
254   done
255 fi
256 ])dnl
257 dnl ---------------------------------------------------------------------------
258 dnl CF_ADD_LIBS version: 1 updated: 2010/06/02 05:03:05
259 dnl -----------
260 dnl Add one or more libraries, used to enforce consistency.
261 dnl
262 dnl $1 = libraries to add, with the "-l", etc.
263 dnl $2 = variable to update (default $LIBS)
264 AC_DEFUN([CF_ADD_LIBS],[ifelse($2,,LIBS,[$2])="$1 [$]ifelse($2,,LIBS,[$2])"])dnl
265 dnl ---------------------------------------------------------------------------
266 dnl CF_ADD_LIB_AFTER version: 3 updated: 2013/07/09 21:27:22
267 dnl ----------------
268 dnl Add a given library after another, e.g., following the one it satisfies a
269 dnl dependency for.
270 dnl
271 dnl $1 = the first library
272 dnl $2 = its dependency
273 AC_DEFUN([CF_ADD_LIB_AFTER],[
274 CF_VERBOSE(...before $LIBS)
275 LIBS=`echo "$LIBS" | sed -e "s/[[       ]][[    ]]*/ /g" -e "s%$1 %$1 $2 %" -e 's%  % %g'`
276 CF_VERBOSE(...after  $LIBS)
277 ])dnl
278 dnl ---------------------------------------------------------------------------
279 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
280 dnl ------------------
281 dnl Append to a search-list for a nonstandard header/lib-file
282 dnl     $1 = the variable to return as result
283 dnl     $2 = the package name
284 dnl     $3 = the subdirectory, e.g., bin, include or lib
285 dnl $4 = the directory under which we will test for subdirectories
286 dnl $5 = a directory that we do not want $4 to match
287 AC_DEFUN([CF_ADD_SUBDIR_PATH],
288 [
289 test "x$4" != "x$5" && \
290 test -d "$4" && \
291 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
292         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
293         test -d $4/$3 &&          $1="[$]$1 $4/$3"
294         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
295         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
296         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
297         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
298 }
299 ])dnl
300 dnl ---------------------------------------------------------------------------
301 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
302 dnl --------------
303 dnl Allow user to disable a normally-on option.
304 AC_DEFUN([CF_ARG_DISABLE],
305 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
306 dnl ---------------------------------------------------------------------------
307 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
308 dnl -------------
309 dnl Allow user to enable a normally-off option.
310 AC_DEFUN([CF_ARG_ENABLE],
311 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
312 dnl ---------------------------------------------------------------------------
313 dnl CF_ARG_OPTION version: 4 updated: 2010/05/26 05:38:42
314 dnl -------------
315 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
316 dnl values.
317 dnl
318 dnl Parameters:
319 dnl $1 = option name
320 dnl $2 = help-string
321 dnl $3 = action to perform if option is not default
322 dnl $4 = action if perform if option is default
323 dnl $5 = default option value (either 'yes' or 'no')
324 AC_DEFUN([CF_ARG_OPTION],
325 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
326   if test "$enableval" != "$5" ; then
327 ifelse([$3],,[    :]dnl
328 ,[    $3]) ifelse([$4],,,[
329   else
330     $4])
331   fi],[enableval=$5 ifelse([$4],,,[
332   $4
333 ])dnl
334   ])])dnl
335 dnl ---------------------------------------------------------------------------
336 dnl CF_CC_ENV_FLAGS version: 1 updated: 2012/10/03 05:25:49
337 dnl ---------------
338 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
339 dnl into CC.  This will not help with broken scripts that wrap the compiler with
340 dnl options, but eliminates a more common category of user confusion.
341 AC_DEFUN([CF_CC_ENV_FLAGS],
342 [
343 # This should have been defined by AC_PROG_CC
344 : ${CC:=cc}
345
346 AC_MSG_CHECKING(\$CC variable)
347 case "$CC" in #(vi
348 *[[\ \  ]]-[[IUD]]*)
349         AC_MSG_RESULT(broken)
350         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
351         # humor him...
352         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
353         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
354         CF_ADD_CFLAGS($cf_flags)
355         ;;
356 *)
357         AC_MSG_RESULT(ok)
358         ;;
359 esac
360 ])dnl
361 dnl ---------------------------------------------------------------------------
362 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
363 dnl --------------
364 dnl Check if we're accidentally using a cache from a different machine.
365 dnl Derive the system name, as a check for reusing the autoconf cache.
366 dnl
367 dnl If we've packaged config.guess and config.sub, run that (since it does a
368 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
369 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
370 dnl which is useful in cross-compiles.
371 dnl
372 dnl Note: we would use $ac_config_sub, but that is one of the places where
373 dnl autoconf 2.5x broke compatibility with autoconf 2.13
374 AC_DEFUN([CF_CHECK_CACHE],
375 [
376 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
377         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
378         system_name="$host_os"
379 else
380         system_name="`(uname -s -r) 2>/dev/null`"
381         if test -z "$system_name" ; then
382                 system_name="`(hostname) 2>/dev/null`"
383         fi
384 fi
385 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
386 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
387
388 test -z "$system_name" && system_name="$cf_cv_system_name"
389 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
390
391 if test ".$system_name" != ".$cf_cv_system_name" ; then
392         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
393         AC_MSG_ERROR("Please remove config.cache and try again.")
394 fi
395 ])dnl
396 dnl ---------------------------------------------------------------------------
397 dnl CF_CHECK_CFLAGS version: 2 updated: 2001/12/30 19:09:58
398 dnl ---------------
399 dnl Conditionally add to $CFLAGS and $CPPFLAGS values which are derived from
400 dnl a build-configuration such as imake.  These have the pitfall that they
401 dnl often contain compiler-specific options which we cannot use, mixed with
402 dnl preprocessor options that we usually can.
403 AC_DEFUN([CF_CHECK_CFLAGS],
404 [
405 CF_VERBOSE(checking additions to CFLAGS)
406 cf_check_cflags="$CFLAGS"
407 cf_check_cppflags="$CPPFLAGS"
408 CF_ADD_CFLAGS($1,yes)
409 if test "$cf_check_cflags" != "$CFLAGS" ; then
410 AC_TRY_LINK([#include <stdio.h>],[printf("Hello world");],,
411         [CF_VERBOSE(test-compile failed.  Undoing change to \$CFLAGS)
412          if test "$cf_check_cppflags" != "$CPPFLAGS" ; then
413                  CF_VERBOSE(but keeping change to \$CPPFLAGS)
414          fi
415          CFLAGS="$cf_check_flags"])
416 fi
417 ])dnl
418 dnl ---------------------------------------------------------------------------
419 dnl CF_CLANG_COMPILER version: 1 updated: 2012/06/16 14:55:39
420 dnl -----------------
421 dnl Check if the given compiler is really clang.  clang's C driver defines
422 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
423 dnl not ignore some gcc options.
424 dnl
425 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
426 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
427 dnl the wrappers for gcc and g++ warnings.
428 dnl
429 dnl $1 = GCC (default) or GXX
430 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
431 dnl $3 = CFLAGS (default) or CXXFLAGS
432 AC_DEFUN([CF_CLANG_COMPILER],[
433 ifelse([$2],,CLANG_COMPILER,[$2])=no
434
435 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
436         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
437         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
438         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
439         AC_TRY_COMPILE([],[
440 #ifdef __clang__
441 #else
442 make an error
443 #endif
444 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
445 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
446 ],[])
447         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
448         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
449 fi
450 ])
451 dnl ---------------------------------------------------------------------------
452 dnl CF_CURSES_ACS_MAP version: 7 updated: 2012/10/06 16:39:58
453 dnl -----------------
454 dnl Check for likely values of acs_map[]:
455 AC_DEFUN([CF_CURSES_ACS_MAP],
456 [
457 AC_REQUIRE([CF_NCURSES_WRAP_PREFIX])dnl
458 AC_CACHE_CHECK(for alternate character set array, cf_cv_curses_acs_map,[
459 cf_cv_curses_acs_map=unknown
460 for name in acs_map _acs_map __acs_map ${NCURSES_WRAP_PREFIX}acs_map
461 do
462 AC_TRY_LINK([
463 #include <${cf_cv_ncurses_header:-curses.h}>
464 ],[
465 $name['k'] = ACS_PLUS
466 ],[cf_cv_curses_acs_map=$name; break])
467 done
468 ])
469
470 test "$cf_cv_curses_acs_map" != unknown && AC_DEFINE_UNQUOTED(CURSES_ACS_ARRAY,$cf_cv_curses_acs_map,[Define as needed to override ncurses prefix _nc_])
471 ])
472 dnl ---------------------------------------------------------------------------
473 dnl CF_CURSES_CHECK_DATA version: 4 updated: 2011/01/15 16:39:24
474 dnl --------------------
475 dnl Check if curses.h defines the given data/variable.
476 dnl Use this after CF_NCURSES_CONFIG or CF_CURSES_CONFIG.
477 AC_DEFUN([CF_CURSES_CHECK_DATA],
478 [
479 AC_MSG_CHECKING(for data $1 declaration in ${cf_cv_ncurses_header:-curses.h})
480
481 AC_TRY_COMPILE(CF__CURSES_HEAD,[
482 void *foo = &($1)
483 ],cf_result=yes,cf_result=no)
484 AC_MSG_RESULT($cf_result)
485
486 if test $cf_result = yes ; then
487         CF_UPPER(cf_result,have_curses_data_$1)
488         AC_DEFINE_UNQUOTED($cf_result)
489 else
490         AC_MSG_CHECKING(for data $1 in library)
491         # BSD linkers insist on making weak linkage, but resolve at runtime.
492         AC_TRY_RUN(CF__CURSES_HEAD
493 [
494 extern char $1;
495 int main(void)
496 {
497         void *foo = &($1);
498         ${cf_cv_main_return:-return}(foo == 0);
499 }],[cf_result=yes],[cf_result=no],[
500         # cross-compiling
501         AC_TRY_LINK(CF__CURSES_HEAD
502 [extern char $1;],[
503         do {
504                 void *foo = &($1);
505                 ${cf_cv_main_return:-return}(foo == 0);
506         } while (0)
507 ],[cf_result=yes],[cf_result=no])
508 ])
509         AC_MSG_RESULT($cf_result)
510         if test $cf_result = yes ; then
511                 CF_UPPER(cf_result,decl_curses_data_$1)
512                 AC_DEFINE_UNQUOTED($cf_result)
513         fi
514 fi
515 ])dnl
516 dnl ---------------------------------------------------------------------------
517 dnl CF_CURSES_CHECK_TYPE version: 4 updated: 2012/10/06 16:39:58
518 dnl --------------------
519 dnl Check if curses.h defines the given type
520 AC_DEFUN([CF_CURSES_CHECK_TYPE],
521 [
522 AC_MSG_CHECKING(for type $1 in ${cf_cv_ncurses_header:-curses.h})
523 AC_TRY_COMPILE([
524 #ifndef _XOPEN_SOURCE_EXTENDED
525 #define _XOPEN_SOURCE_EXTENDED
526 #endif
527 #include <${cf_cv_ncurses_header:-curses.h}>],[
528 $1 foo
529 ],cf_result=yes,cf_result=no)
530 AC_MSG_RESULT($cf_result)
531 if test $cf_result = yes ; then
532         CF_UPPER(cf_result,have_type_$1)
533         AC_DEFINE_UNQUOTED($cf_result,1,[Define to 1 if we have type $1])
534 else
535         AC_DEFINE_UNQUOTED($1,$2,[Define to appropriate type if $1 is not declared])
536 fi
537 ])dnl
538 dnl ---------------------------------------------------------------------------
539 dnl CF_CURSES_CONFIG version: 2 updated: 2006/10/29 11:06:27
540 dnl ----------------
541 dnl Tie together the configure-script macros for curses.  It may be ncurses,
542 dnl but unless asked, we do not make a special search for ncurses.  However,
543 dnl still check for the ncurses version number, for use in other macros.
544 AC_DEFUN([CF_CURSES_CONFIG],
545 [
546 CF_CURSES_CPPFLAGS
547 CF_NCURSES_VERSION
548 CF_CURSES_LIBS
549 ])dnl
550 dnl ---------------------------------------------------------------------------
551 dnl CF_CURSES_CPPFLAGS version: 11 updated: 2011/04/09 14:51:08
552 dnl ------------------
553 dnl Look for the curses headers.
554 AC_DEFUN([CF_CURSES_CPPFLAGS],[
555
556 AC_CACHE_CHECK(for extra include directories,cf_cv_curses_incdir,[
557 cf_cv_curses_incdir=no
558 case $host_os in #(vi
559 hpux10.*) #(vi
560         if test "x$cf_cv_screen" = "xcurses_colr"
561         then
562                 test -d /usr/include/curses_colr && \
563                 cf_cv_curses_incdir="-I/usr/include/curses_colr"
564         fi
565         ;;
566 sunos3*|sunos4*)
567         if test "x$cf_cv_screen" = "xcurses_5lib"
568         then
569                 test -d /usr/5lib && \
570                 test -d /usr/5include && \
571                 cf_cv_curses_incdir="-I/usr/5include"
572         fi
573         ;;
574 esac
575 ])
576 test "$cf_cv_curses_incdir" != no && CPPFLAGS="$CPPFLAGS $cf_cv_curses_incdir"
577
578 CF_CURSES_HEADER
579 CF_TERM_HEADER
580 ])dnl
581 dnl ---------------------------------------------------------------------------
582 dnl CF_CURSES_FUNCS version: 17 updated: 2011/05/14 16:07:29
583 dnl ---------------
584 dnl Curses-functions are a little complicated, since a lot of them are macros.
585 AC_DEFUN([CF_CURSES_FUNCS],
586 [
587 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
588 AC_REQUIRE([CF_XOPEN_CURSES])
589 AC_REQUIRE([CF_CURSES_TERM_H])
590 AC_REQUIRE([CF_CURSES_UNCTRL_H])
591 for cf_func in $1
592 do
593         CF_UPPER(cf_tr_func,$cf_func)
594         AC_MSG_CHECKING(for ${cf_func})
595         CF_MSG_LOG(${cf_func})
596         AC_CACHE_VAL(cf_cv_func_$cf_func,[
597                 eval cf_result='$ac_cv_func_'$cf_func
598                 if test ".$cf_result" != ".no"; then
599                         AC_TRY_LINK(CF__CURSES_HEAD,
600                         [
601 #ifndef ${cf_func}
602 long foo = (long)(&${cf_func});
603 if (foo + 1234 > 5678)
604         ${cf_cv_main_return:-return}(foo);
605 #endif
606                         ],
607                         [cf_result=yes],
608                         [cf_result=no])
609                 fi
610                 eval 'cf_cv_func_'$cf_func'=$cf_result'
611         ])
612         # use the computed/retrieved cache-value:
613         eval 'cf_result=$cf_cv_func_'$cf_func
614         AC_MSG_RESULT($cf_result)
615         if test $cf_result != no; then
616                 AC_DEFINE_UNQUOTED(HAVE_${cf_tr_func})
617         fi
618 done
619 ])dnl
620 dnl ---------------------------------------------------------------------------
621 dnl CF_CURSES_HEADER version: 3 updated: 2011/05/01 19:47:45
622 dnl ----------------
623 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
624 dnl variations of ncurses' installs.
625 dnl
626 dnl $1 = ncurses when looking for ncurses, or is empty
627 AC_DEFUN([CF_CURSES_HEADER],[
628 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
629 cf_cv_ncurses_header=none
630 for cf_header in ifelse($1,,,[ \
631     $1/ncurses.h \
632         $1/curses.h]) \
633         ncurses.h \
634         curses.h ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
635 do
636 AC_TRY_COMPILE([#include <${cf_header}>],
637         [initscr(); tgoto("?", 0,0)],
638         [cf_cv_ncurses_header=$cf_header; break],[])
639 done
640 ])
641
642 if test "$cf_cv_ncurses_header" = none ; then
643         AC_MSG_ERROR(No curses header-files found)
644 fi
645
646 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
647 AC_CHECK_HEADERS($cf_cv_ncurses_header)
648 ])dnl
649 dnl ---------------------------------------------------------------------------
650 dnl CF_CURSES_LIBS version: 37 updated: 2013/02/09 17:33:50
651 dnl --------------
652 dnl Look for the curses libraries.  Older curses implementations may require
653 dnl termcap/termlib to be linked as well.  Call CF_CURSES_CPPFLAGS first.
654 AC_DEFUN([CF_CURSES_LIBS],[
655
656 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
657 AC_MSG_CHECKING(if we have identified curses libraries)
658 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
659     [initscr(); tgoto("?", 0,0)],
660     cf_result=yes,
661     cf_result=no)
662 AC_MSG_RESULT($cf_result)
663
664 if test "$cf_result" = no ; then
665 case $host_os in #(vi
666 freebsd*) #(vi
667     AC_CHECK_LIB(mytinfo,tgoto,[CF_ADD_LIBS(-lmytinfo)])
668     ;;
669 hpux10.*) #(vi
670         # Looking at HPUX 10.20, the Hcurses library is the oldest (1997), cur_colr
671         # next (1998), and xcurses "newer" (2000).  There is no header file for
672         # Hcurses; the subdirectory curses_colr has the headers (curses.h and
673         # term.h) for cur_colr
674         if test "x$cf_cv_screen" = "xcurses_colr"
675         then
676                 AC_CHECK_LIB(cur_colr,initscr,[
677                         CF_ADD_LIBS(-lcur_colr)
678                         ac_cv_func_initscr=yes
679                         ],[
680                 AC_CHECK_LIB(Hcurses,initscr,[
681                         # HP's header uses __HP_CURSES, but user claims _HP_CURSES.
682                         CF_ADD_LIBS(-lHcurses)
683                         CPPFLAGS="$CPPFLAGS -D__HP_CURSES -D_HP_CURSES"
684                         ac_cv_func_initscr=yes
685                         ])])
686         fi
687         ;;
688 linux*)
689         case `arch 2>/dev/null` in
690         x86_64)
691                 if test -d /lib64
692                 then
693                         CF_ADD_LIBDIR(/lib64)
694                 else
695                         CF_ADD_LIBDIR(/lib)
696                 fi
697                 ;;
698         *)
699                 CF_ADD_LIBDIR(/lib)
700                 ;;
701         esac
702         ;;
703 sunos3*|sunos4*)
704         if test "x$cf_cv_screen" = "xcurses_5lib"
705         then
706                 if test -d /usr/5lib ; then
707                         CF_ADD_LIBDIR(/usr/5lib)
708                         CF_ADD_LIBS(-lcurses -ltermcap)
709                 fi
710     fi
711     ac_cv_func_initscr=yes
712     ;;
713 esac
714
715 if test ".$ac_cv_func_initscr" != .yes ; then
716         cf_save_LIBS="$LIBS"
717
718         if test ".${cf_cv_ncurses_version:-no}" != .no
719         then
720                 cf_check_list="ncurses curses cursesX"
721         else
722                 cf_check_list="cursesX curses ncurses"
723         fi
724
725         # Check for library containing tgoto.  Do this before curses library
726         # because it may be needed to link the test-case for initscr.
727         if test "x$cf_term_lib" = x
728         then
729                 AC_CHECK_FUNC(tgoto,[cf_term_lib=predefined],[
730                         for cf_term_lib in $cf_check_list otermcap termcap tinfo termlib unknown
731                         do
732                                 AC_CHECK_LIB($cf_term_lib,tgoto,[break])
733                         done
734                 ])
735         fi
736
737         # Check for library containing initscr
738         test "$cf_term_lib" != predefined && test "$cf_term_lib" != unknown && LIBS="-l$cf_term_lib $cf_save_LIBS"
739         if test "x$cf_curs_lib" = x
740         then
741                 for cf_curs_lib in $cf_check_list xcurses jcurses pdcurses unknown
742                 do
743                         AC_CHECK_LIB($cf_curs_lib,initscr,[break])
744                 done
745         fi
746         test $cf_curs_lib = unknown && AC_MSG_ERROR(no curses library found)
747
748         LIBS="-l$cf_curs_lib $cf_save_LIBS"
749         if test "$cf_term_lib" = unknown ; then
750                 AC_MSG_CHECKING(if we can link with $cf_curs_lib library)
751                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
752                         [initscr()],
753                         [cf_result=yes],
754                         [cf_result=no])
755                 AC_MSG_RESULT($cf_result)
756                 test $cf_result = no && AC_MSG_ERROR(Cannot link curses library)
757         elif test "$cf_curs_lib" = "$cf_term_lib" ; then
758                 :
759         elif test "$cf_term_lib" != predefined ; then
760                 AC_MSG_CHECKING(if we need both $cf_curs_lib and $cf_term_lib libraries)
761                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
762                         [initscr(); tgoto((char *)0, 0, 0);],
763                         [cf_result=no],
764                         [
765                         LIBS="-l$cf_curs_lib -l$cf_term_lib $cf_save_LIBS"
766                         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
767                                 [initscr()],
768                                 [cf_result=yes],
769                                 [cf_result=error])
770                         ])
771                 AC_MSG_RESULT($cf_result)
772         fi
773 fi
774 fi
775
776 ])dnl
777 dnl ---------------------------------------------------------------------------
778 dnl CF_CURSES_TERM_H version: 10 updated: 2012/10/06 08:57:51
779 dnl ----------------
780 dnl SVr4 curses should have term.h as well (where it puts the definitions of
781 dnl the low-level interface).  This may not be true in old/broken implementations,
782 dnl as well as in misconfigured systems (e.g., gcc configured for Solaris 2.4
783 dnl running with Solaris 2.5.1).
784 AC_DEFUN([CF_CURSES_TERM_H],
785 [
786 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
787
788 AC_CACHE_CHECK(for term.h, cf_cv_term_header,[
789
790 # If we found <ncurses/curses.h>, look for <ncurses/term.h>, but always look
791 # for <term.h> if we do not find the variant.
792
793 cf_header_list="term.h ncurses/term.h ncursesw/term.h"
794
795 case ${cf_cv_ncurses_header:-curses.h} in #(vi
796 */*)
797         cf_header_item=`echo ${cf_cv_ncurses_header:-curses.h} | sed -e 's%\..*%%' -e 's%/.*%/%'`term.h
798         cf_header_list="$cf_header_item $cf_header_list"
799         ;;
800 esac
801
802 for cf_header in $cf_header_list
803 do
804         AC_TRY_COMPILE([
805 #include <${cf_cv_ncurses_header:-curses.h}>
806 #include <${cf_header}>],
807         [WINDOW *x],
808         [cf_cv_term_header=$cf_header
809          break],
810         [cf_cv_term_header=no])
811 done
812
813 case $cf_cv_term_header in #(vi
814 no)
815         # If curses is ncurses, some packagers still mess it up by trying to make
816         # us use GNU termcap.  This handles the most common case.
817         for cf_header in ncurses/term.h ncursesw/term.h
818         do
819                 AC_TRY_COMPILE([
820 #include <${cf_cv_ncurses_header:-curses.h}>
821 #ifdef NCURSES_VERSION
822 #include <${cf_header}>
823 #else
824 make an error
825 #endif],
826                         [WINDOW *x],
827                         [cf_cv_term_header=$cf_header
828                          break],
829                         [cf_cv_term_header=no])
830         done
831         ;;
832 esac
833 ])
834
835 case $cf_cv_term_header in #(vi
836 term.h) #(vi
837         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
838         ;;
839 ncurses/term.h) #(vi
840         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
841         ;;
842 ncursesw/term.h)
843         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
844         ;;
845 esac
846 ])dnl
847 dnl ---------------------------------------------------------------------------
848 dnl CF_CURSES_UNCTRL_H version: 3 updated: 2013/11/03 06:26:10
849 dnl ------------------
850 dnl Any X/Open curses implementation must have unctrl.h, but ncurses packages
851 dnl may put it in a subdirectory (along with ncurses' other headers, of
852 dnl course).  Packages which put the headers in inconsistent locations are
853 dnl broken).
854 AC_DEFUN([CF_CURSES_UNCTRL_H],
855 [
856 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
857
858 AC_CACHE_CHECK(for unctrl.h, cf_cv_unctrl_header,[
859
860 # If we found <ncurses/curses.h>, look for <ncurses/unctrl.h>, but always look
861 # for <unctrl.h> if we do not find the variant.
862
863 cf_header_list="unctrl.h ncurses/unctrl.h ncursesw/unctrl.h"
864
865 case ${cf_cv_ncurses_header:-curses.h} in #(vi
866 */*)
867         cf_header_item=`echo ${cf_cv_ncurses_header:-curses.h} | sed -e 's%\..*%%' -e 's%/.*%/%'`unctrl.h
868         cf_header_list="$cf_header_item $cf_header_list"
869         ;;
870 esac
871
872 for cf_header in $cf_header_list
873 do
874         AC_TRY_COMPILE([
875 #include <${cf_cv_ncurses_header:-curses.h}>
876 #include <${cf_header}>],
877         [WINDOW *x],
878         [cf_cv_unctrl_header=$cf_header
879          break],
880         [cf_cv_unctrl_header=no])
881 done
882 ])
883
884 case $cf_cv_unctrl_header in #(vi
885 no)
886         AC_MSG_WARN(unctrl.h header not found)
887         ;;
888 esac
889
890 case $cf_cv_unctrl_header in #(vi
891 unctrl.h) #(vi
892         AC_DEFINE(HAVE_UNCTRL_H,1,[Define to 1 if we have unctrl.h])
893         ;;
894 ncurses/unctrl.h) #(vi
895         AC_DEFINE(HAVE_NCURSES_UNCTRL_H,1,[Define to 1 if we have ncurses/unctrl.h])
896         ;;
897 ncursesw/unctrl.h)
898         AC_DEFINE(HAVE_NCURSESW_UNCTRL_H,1,[Define to 1 if we have ncursesw/unctrl.h])
899         ;;
900 esac
901 ])dnl
902 dnl ---------------------------------------------------------------------------
903 dnl CF_CURSES_WACS_MAP version: 6 updated: 2012/10/06 08:57:51
904 dnl ------------------
905 dnl Check for likely values of wacs_map[].
906 AC_DEFUN([CF_CURSES_WACS_MAP],
907 [
908 AC_CACHE_CHECK(for wide alternate character set array, cf_cv_curses_wacs_map,[
909         cf_cv_curses_wacs_map=unknown
910         for name in wacs_map _wacs_map __wacs_map _nc_wacs _wacs_char
911         do
912         AC_TRY_LINK([
913 #ifndef _XOPEN_SOURCE_EXTENDED
914 #define _XOPEN_SOURCE_EXTENDED
915 #endif
916 #include <${cf_cv_ncurses_header:-curses.h}>],
917         [void *foo = &($name['k'])],
918         [cf_cv_curses_wacs_map=$name
919          break])
920         done])
921
922 test "$cf_cv_curses_wacs_map" != unknown && AC_DEFINE_UNQUOTED(CURSES_WACS_ARRAY,$cf_cv_curses_wacs_map,[Define to name of (n)curses wide-character array])
923 ])dnl
924 dnl ---------------------------------------------------------------------------
925 dnl CF_CURSES_WACS_SYMBOLS version: 2 updated: 2012/10/06 08:57:51
926 dnl ----------------------
927 dnl Do a check to see if the WACS_xxx constants are defined compatibly with
928 dnl X/Open Curses.  In particular, NetBSD's implementation of the WACS_xxx
929 dnl constants is broken since those constants do not point to cchar_t's.
930 AC_DEFUN([CF_CURSES_WACS_SYMBOLS],
931 [
932 AC_REQUIRE([CF_CURSES_WACS_MAP])
933
934 AC_CACHE_CHECK(for wide alternate character constants, cf_cv_curses_wacs_symbols,[
935 cf_cv_curses_wacs_symbols=no
936 if test "$cf_cv_curses_wacs_map" != unknown
937 then
938         AC_TRY_LINK([
939 #ifndef _XOPEN_SOURCE_EXTENDED
940 #define _XOPEN_SOURCE_EXTENDED
941 #endif
942 #include <${cf_cv_ncurses_header:-curses.h}>],
943         [cchar_t *foo = WACS_PLUS;
944          $cf_cv_curses_wacs_map['k'] = *WACS_PLUS],
945         [cf_cv_curses_wacs_symbols=yes])
946 else
947         AC_TRY_LINK([
948 #ifndef _XOPEN_SOURCE_EXTENDED
949 #define _XOPEN_SOURCE_EXTENDED
950 #endif
951 #include <${cf_cv_ncurses_header:-curses.h}>],
952         [cchar_t *foo = WACS_PLUS],
953         [cf_cv_curses_wacs_symbols=yes])
954 fi
955 ])
956
957 test "$cf_cv_curses_wacs_symbols" != no && AC_DEFINE(CURSES_WACS_SYMBOLS,1,[Define to 1 if (n)curses supports wide-character WACS_ symbols])
958 ])dnl
959 dnl ---------------------------------------------------------------------------
960 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
961 dnl ----------
962 dnl "dirname" is not portable, so we fake it with a shell script.
963 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
964 dnl ---------------------------------------------------------------------------
965 dnl CF_DISABLE_ECHO version: 12 updated: 2012/10/06 16:30:28
966 dnl ---------------
967 dnl You can always use "make -n" to see the actual options, but it's hard to
968 dnl pick out/analyze warning messages when the compile-line is long.
969 dnl
970 dnl Sets:
971 dnl     ECHO_LT - symbol to control if libtool is verbose
972 dnl     ECHO_LD - symbol to prefix "cc -o" lines
973 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
974 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
975 dnl     ECHO_CC - symbol to put before any "cc" line
976 dnl
977 AC_DEFUN([CF_DISABLE_ECHO],[
978 AC_MSG_CHECKING(if you want to see long compiling messages)
979 CF_ARG_DISABLE(echo,
980         [  --disable-echo          do not display "compiling" commands],
981         [
982     ECHO_LT='--silent'
983     ECHO_LD='@echo linking [$]@;'
984     RULE_CC='@echo compiling [$]<'
985     SHOW_CC='@echo compiling [$]@'
986     ECHO_CC='@'
987 ],[
988     ECHO_LT=''
989     ECHO_LD=''
990     RULE_CC=''
991     SHOW_CC=''
992     ECHO_CC=''
993 ])
994 AC_MSG_RESULT($enableval)
995 AC_SUBST(ECHO_LT)
996 AC_SUBST(ECHO_LD)
997 AC_SUBST(RULE_CC)
998 AC_SUBST(SHOW_CC)
999 AC_SUBST(ECHO_CC)
1000 ])dnl
1001 dnl ---------------------------------------------------------------------------
1002 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1003 dnl ----------------
1004 dnl Combine no-leak checks with the libraries or tools that are used for the
1005 dnl checks.
1006 AC_DEFUN([CF_DISABLE_LEAKS],[
1007
1008 AC_REQUIRE([CF_WITH_DMALLOC])
1009 AC_REQUIRE([CF_WITH_DBMALLOC])
1010 AC_REQUIRE([CF_WITH_VALGRIND])
1011
1012 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1013 AC_ARG_ENABLE(leaks,
1014         [  --disable-leaks         test: free permanent memory, analyze leaks],
1015         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1016         : ${with_no_leaks:=no})
1017 AC_MSG_RESULT($with_no_leaks)
1018
1019 if test "$with_no_leaks" = yes ; then
1020         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1021         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1022 fi
1023 ])dnl
1024 dnl ---------------------------------------------------------------------------
1025 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1026 dnl ---------------------
1027 dnl The rpath-hack makes it simpler to build programs, particularly with the
1028 dnl *BSD ports which may have essential libraries in unusual places.  But it
1029 dnl can interfere with building an executable for the base system.  Use this
1030 dnl option in that case.
1031 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1032 [
1033 AC_MSG_CHECKING(if rpath-hack should be disabled)
1034 CF_ARG_DISABLE(rpath-hack,
1035         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1036         [cf_disable_rpath_hack=yes],
1037         [cf_disable_rpath_hack=no])
1038 AC_MSG_RESULT($cf_disable_rpath_hack)
1039 if test "$cf_disable_rpath_hack" = no ; then
1040         CF_RPATH_HACK
1041 fi
1042 ])
1043 dnl ---------------------------------------------------------------------------
1044 dnl CF_ENABLE_WARNINGS version: 4 updated: 2009/07/26 17:53:03
1045 dnl ------------------
1046 dnl Configure-option to enable gcc warnings
1047 AC_DEFUN([CF_ENABLE_WARNINGS],[
1048 if ( test "$GCC" = yes || test "$GXX" = yes )
1049 then
1050 AC_MSG_CHECKING(if you want to turn on gcc warnings)
1051 CF_ARG_ENABLE(warnings,
1052         [  --enable-warnings       test: turn on gcc compiler warnings],
1053         [with_warnings=yes],
1054         [with_warnings=no])
1055 AC_MSG_RESULT($with_warnings)
1056 if test "$with_warnings" = "yes"
1057 then
1058         CF_GCC_ATTRIBUTES
1059         CF_GCC_WARNINGS
1060 fi
1061 fi
1062 ])dnl
1063 dnl ---------------------------------------------------------------------------
1064 dnl CF_FIND_LIBRARY version: 9 updated: 2008/03/23 14:48:54
1065 dnl ---------------
1066 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
1067 dnl prefer a standard location, and use -L options only if we do not find the
1068 dnl library in the standard library location(s).
1069 dnl     $1 = library name
1070 dnl     $2 = library class, usually the same as library name
1071 dnl     $3 = includes
1072 dnl     $4 = code fragment to compile/link
1073 dnl     $5 = corresponding function-name
1074 dnl     $6 = flag, nonnull if failure should not cause an error-exit
1075 dnl
1076 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
1077 dnl to use a -L option.
1078 AC_DEFUN([CF_FIND_LIBRARY],
1079 [
1080         eval 'cf_cv_have_lib_'$1'=no'
1081         cf_libdir=""
1082         AC_CHECK_FUNC($5,
1083                 eval 'cf_cv_have_lib_'$1'=yes',[
1084                 cf_save_LIBS="$LIBS"
1085                 AC_MSG_CHECKING(for $5 in -l$1)
1086                 LIBS="-l$1 $LIBS"
1087                 AC_TRY_LINK([$3],[$4],
1088                         [AC_MSG_RESULT(yes)
1089                          eval 'cf_cv_have_lib_'$1'=yes'
1090                         ],
1091                         [AC_MSG_RESULT(no)
1092                         CF_LIBRARY_PATH(cf_search,$2)
1093                         for cf_libdir in $cf_search
1094                         do
1095                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
1096                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
1097                                 AC_TRY_LINK([$3],[$4],
1098                                         [AC_MSG_RESULT(yes)
1099                                          eval 'cf_cv_have_lib_'$1'=yes'
1100                                          break],
1101                                         [AC_MSG_RESULT(no)
1102                                          LIBS="$cf_save_LIBS"])
1103                         done
1104                         ])
1105                 ])
1106 eval 'cf_found_library=[$]cf_cv_have_lib_'$1
1107 ifelse($6,,[
1108 if test $cf_found_library = no ; then
1109         AC_MSG_ERROR(Cannot link $1 library)
1110 fi
1111 ])
1112 ])dnl
1113 dnl ---------------------------------------------------------------------------
1114 dnl CF_FIND_LINKAGE version: 19 updated: 2010/05/29 16:31:02
1115 dnl ---------------
1116 dnl Find a library (specifically the linkage used in the code fragment),
1117 dnl searching for it if it is not already in the library path.
1118 dnl See also CF_ADD_SEARCHPATH.
1119 dnl
1120 dnl Parameters (4-on are optional):
1121 dnl     $1 = headers for library entrypoint
1122 dnl     $2 = code fragment for library entrypoint
1123 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1124 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1125 dnl     $5 = action to perform if not successful
1126 dnl     $6 = module name, if not the same as the library name
1127 dnl     $7 = extra libraries
1128 dnl
1129 dnl Sets these variables:
1130 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1131 dnl     $cf_cv_header_path_$3 - include-directory if needed
1132 dnl     $cf_cv_library_path_$3 - library-directory if needed
1133 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1134 AC_DEFUN([CF_FIND_LINKAGE],[
1135
1136 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1137 # will be set on completion of the AC_TRY_LINK below.
1138 cf_cv_header_path_$3=
1139 cf_cv_library_path_$3=
1140
1141 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1142
1143 cf_save_LIBS="$LIBS"
1144
1145 AC_TRY_LINK([$1],[$2],[
1146         cf_cv_find_linkage_$3=yes
1147         cf_cv_header_path_$3=/usr/include
1148         cf_cv_library_path_$3=/usr/lib
1149 ],[
1150
1151 LIBS="-l$3 $7 $cf_save_LIBS"
1152
1153 AC_TRY_LINK([$1],[$2],[
1154         cf_cv_find_linkage_$3=yes
1155         cf_cv_header_path_$3=/usr/include
1156         cf_cv_library_path_$3=/usr/lib
1157         cf_cv_library_file_$3="-l$3"
1158 ],[
1159         cf_cv_find_linkage_$3=no
1160         LIBS="$cf_save_LIBS"
1161
1162     CF_VERBOSE(find linkage for $3 library)
1163     CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1164
1165     cf_save_CPPFLAGS="$CPPFLAGS"
1166     cf_test_CPPFLAGS="$CPPFLAGS"
1167
1168     CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1169     for cf_cv_header_path_$3 in $cf_search
1170     do
1171       if test -d $cf_cv_header_path_$3 ; then
1172         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1173         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1174         AC_TRY_COMPILE([$1],[$2],[
1175             CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1176             cf_cv_find_linkage_$3=maybe
1177             cf_test_CPPFLAGS="$CPPFLAGS"
1178             break],[
1179             CPPFLAGS="$cf_save_CPPFLAGS"
1180             ])
1181       fi
1182     done
1183
1184     if test "$cf_cv_find_linkage_$3" = maybe ; then
1185
1186       CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1187
1188       cf_save_LIBS="$LIBS"
1189       cf_save_LDFLAGS="$LDFLAGS"
1190
1191       ifelse([$6],,,[
1192         CPPFLAGS="$cf_test_CPPFLAGS"
1193         LIBS="-l$3 $7 $cf_save_LIBS"
1194         AC_TRY_LINK([$1],[$2],[
1195             CF_VERBOSE(... found $3 library in system)
1196             cf_cv_find_linkage_$3=yes])
1197             CPPFLAGS="$cf_save_CPPFLAGS"
1198             LIBS="$cf_save_LIBS"
1199             ])
1200
1201       if test "$cf_cv_find_linkage_$3" != yes ; then
1202         CF_LIBRARY_PATH(cf_search,$3)
1203         for cf_cv_library_path_$3 in $cf_search
1204         do
1205           if test -d $cf_cv_library_path_$3 ; then
1206             CF_VERBOSE(... testing $cf_cv_library_path_$3)
1207             CPPFLAGS="$cf_test_CPPFLAGS"
1208             LIBS="-l$3 $7 $cf_save_LIBS"
1209             LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1210             AC_TRY_LINK([$1],[$2],[
1211                 CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1212                 cf_cv_find_linkage_$3=yes
1213                 cf_cv_library_file_$3="-l$3"
1214                 break],[
1215                 CPPFLAGS="$cf_save_CPPFLAGS"
1216                 LIBS="$cf_save_LIBS"
1217                 LDFLAGS="$cf_save_LDFLAGS"
1218                 ])
1219           fi
1220         done
1221         CPPFLAGS="$cf_save_CPPFLAGS"
1222         LDFLAGS="$cf_save_LDFLAGS"
1223       fi
1224
1225     else
1226       cf_cv_find_linkage_$3=no
1227     fi
1228     ],$7)
1229 ])
1230
1231 LIBS="$cf_save_LIBS"
1232
1233 if test "$cf_cv_find_linkage_$3" = yes ; then
1234 ifelse([$4],,[
1235         CF_ADD_INCDIR($cf_cv_header_path_$3)
1236         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1237         CF_ADD_LIB($3)
1238 ],[$4])
1239 else
1240 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1241 fi
1242 ])dnl
1243 dnl ---------------------------------------------------------------------------
1244 dnl CF_FUNC_CURSES_VERSION version: 6 updated: 2012/10/06 16:39:58
1245 dnl ----------------------
1246 dnl Solaris has a data item 'curses_version', which confuses AC_CHECK_FUNCS.
1247 dnl It's a character string "SVR4", not documented.
1248 AC_DEFUN([CF_FUNC_CURSES_VERSION],
1249 [
1250 AC_CACHE_CHECK(for function curses_version, cf_cv_func_curses_version,[
1251 AC_TRY_RUN([
1252 #include <${cf_cv_ncurses_header:-curses.h}>
1253 int main()
1254 {
1255         char temp[1024];
1256         sprintf(temp, "%s\n", curses_version());
1257         ${cf_cv_main_return:-return}(0);
1258 }]
1259 ,[cf_cv_func_curses_version=yes]
1260 ,[cf_cv_func_curses_version=no]
1261 ,[cf_cv_func_curses_version=unknown])
1262 rm -f core])
1263 test "$cf_cv_func_curses_version" = yes && AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 if we have curses_version function])
1264 ])
1265 dnl ---------------------------------------------------------------------------
1266 dnl CF_GCC_ATTRIBUTES version: 16 updated: 2012/10/02 20:55:03
1267 dnl -----------------
1268 dnl Test for availability of useful gcc __attribute__ directives to quiet
1269 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1270 dnl to documentation, unrecognized directives cause older compilers to barf.
1271 AC_DEFUN([CF_GCC_ATTRIBUTES],
1272 [
1273 if test "$GCC" = yes
1274 then
1275 cat > conftest.i <<EOF
1276 #ifndef GCC_PRINTF
1277 #define GCC_PRINTF 0
1278 #endif
1279 #ifndef GCC_SCANF
1280 #define GCC_SCANF 0
1281 #endif
1282 #ifndef GCC_NORETURN
1283 #define GCC_NORETURN /* nothing */
1284 #endif
1285 #ifndef GCC_UNUSED
1286 #define GCC_UNUSED /* nothing */
1287 #endif
1288 EOF
1289 if test "$GCC" = yes
1290 then
1291         AC_CHECKING([for $CC __attribute__ directives])
1292 cat > conftest.$ac_ext <<EOF
1293 #line __oline__ "${as_me:-configure}"
1294 #include "confdefs.h"
1295 #include "conftest.h"
1296 #include "conftest.i"
1297 #if     GCC_PRINTF
1298 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1299 #else
1300 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1301 #endif
1302 #if     GCC_SCANF
1303 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1304 #else
1305 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1306 #endif
1307 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1308 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1309 extern void foo(void) GCC_NORETURN;
1310 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1311 EOF
1312         cf_printf_attribute=no
1313         cf_scanf_attribute=no
1314         for cf_attribute in scanf printf unused noreturn
1315         do
1316                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1317                 cf_directive="__attribute__(($cf_attribute))"
1318                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1319
1320                 case $cf_attribute in #(vi
1321                 printf) #(vi
1322                         cf_printf_attribute=yes
1323                         cat >conftest.h <<EOF
1324 #define GCC_$cf_ATTRIBUTE 1
1325 EOF
1326                         ;;
1327                 scanf) #(vi
1328                         cf_scanf_attribute=yes
1329                         cat >conftest.h <<EOF
1330 #define GCC_$cf_ATTRIBUTE 1
1331 EOF
1332                         ;;
1333                 *) #(vi
1334                         cat >conftest.h <<EOF
1335 #define GCC_$cf_ATTRIBUTE $cf_directive
1336 EOF
1337                         ;;
1338                 esac
1339
1340                 if AC_TRY_EVAL(ac_compile); then
1341                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1342                         cat conftest.h >>confdefs.h
1343                         case $cf_attribute in #(vi
1344                         noreturn) #(vi
1345                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1346                                 ;;
1347                         printf) #(vi
1348                                 cf_value='/* nothing */'
1349                                 if test "$cf_printf_attribute" != no ; then
1350                                         cf_value='__attribute__((format(printf,fmt,var)))'
1351                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1352                                 fi
1353                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1354                                 ;;
1355                         scanf) #(vi
1356                                 cf_value='/* nothing */'
1357                                 if test "$cf_scanf_attribute" != no ; then
1358                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1359                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1360                                 fi
1361                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1362                                 ;;
1363                         unused) #(vi
1364                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1365                                 ;;
1366                         esac
1367                 fi
1368         done
1369 else
1370         fgrep define conftest.i >>confdefs.h
1371 fi
1372 rm -rf conftest*
1373 fi
1374 ])dnl
1375 dnl ---------------------------------------------------------------------------
1376 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
1377 dnl --------------
1378 dnl Find version of gcc
1379 AC_DEFUN([CF_GCC_VERSION],[
1380 AC_REQUIRE([AC_PROG_CC])
1381 GCC_VERSION=none
1382 if test "$GCC" = yes ; then
1383         AC_MSG_CHECKING(version of $CC)
1384         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1385         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1386         AC_MSG_RESULT($GCC_VERSION)
1387 fi
1388 ])dnl
1389 dnl ---------------------------------------------------------------------------
1390 dnl CF_GCC_WARNINGS version: 30 updated: 2013/11/16 13:56:26
1391 dnl ---------------
1392 dnl Check if the compiler supports useful warning options.  There's a few that
1393 dnl we don't use, simply because they're too noisy:
1394 dnl
1395 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1396 dnl     -Wredundant-decls (system headers make this too noisy)
1397 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1398 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1399 dnl             is enabled for ncurses using "--enable-const".
1400 dnl     -pedantic
1401 dnl
1402 dnl Parameter:
1403 dnl     $1 is an optional list of gcc warning flags that a particular
1404 dnl             application might want to use, e.g., "no-unused" for
1405 dnl             -Wno-unused
1406 dnl Special:
1407 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1408 dnl
1409 AC_DEFUN([CF_GCC_WARNINGS],
1410 [
1411 AC_REQUIRE([CF_GCC_VERSION])
1412 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1413 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
1414
1415 cat > conftest.$ac_ext <<EOF
1416 #line __oline__ "${as_me:-configure}"
1417 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1418 EOF
1419
1420 if test "$INTEL_COMPILER" = yes
1421 then
1422 # The "-wdXXX" options suppress warnings:
1423 # remark #1419: external declaration in primary source file
1424 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1425 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1426 # remark #193: zero used for undefined preprocessing identifier
1427 # remark #593: variable "curs_sb_left_arrow" was set but never used
1428 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1429 # remark #869: parameter "tw" was never referenced
1430 # remark #981: operands are evaluated in unspecified order
1431 # warning #279: controlling expression is constant
1432
1433         AC_CHECKING([for $CC warning options])
1434         cf_save_CFLAGS="$CFLAGS"
1435         EXTRA_CFLAGS="-Wall"
1436         for cf_opt in \
1437                 wd1419 \
1438                 wd1683 \
1439                 wd1684 \
1440                 wd193 \
1441                 wd593 \
1442                 wd279 \
1443                 wd810 \
1444                 wd869 \
1445                 wd981
1446         do
1447                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1448                 if AC_TRY_EVAL(ac_compile); then
1449                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1450                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1451                 fi
1452         done
1453         CFLAGS="$cf_save_CFLAGS"
1454
1455 elif test "$GCC" = yes
1456 then
1457         AC_CHECKING([for $CC warning options])
1458         cf_save_CFLAGS="$CFLAGS"
1459         EXTRA_CFLAGS=
1460         cf_warn_CONST=""
1461         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1462         for cf_opt in W Wall \
1463                 Wbad-function-cast \
1464                 Wcast-align \
1465                 Wcast-qual \
1466                 Wdeclaration-after-statement \
1467                 Wextra \
1468                 Wignored-qualifiers \
1469                 Winline \
1470                 Wlogical-op \
1471                 Wmissing-declarations \
1472                 Wmissing-prototypes \
1473                 Wnested-externs \
1474                 Wpointer-arith \
1475                 Wshadow \
1476                 Wstrict-prototypes \
1477                 Wundef \
1478                 Wvarargs $cf_warn_CONST $1
1479         do
1480                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1481                 if AC_TRY_EVAL(ac_compile); then
1482                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1483                         case $cf_opt in #(vi
1484                         Wcast-qual) #(vi
1485                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
1486                                 ;;
1487                         Winline) #(vi
1488                                 case $GCC_VERSION in
1489                                 [[34]].*)
1490                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1491                                         continue;;
1492                                 esac
1493                                 ;;
1494                         Wpointer-arith) #(vi
1495                                 case $GCC_VERSION in
1496                                 [[12]].*)
1497                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1498                                         continue;;
1499                                 esac
1500                                 ;;
1501                         esac
1502                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1503                 fi
1504         done
1505         CFLAGS="$cf_save_CFLAGS"
1506 fi
1507 rm -rf conftest*
1508
1509 AC_SUBST(EXTRA_CFLAGS)
1510 ])dnl
1511 dnl ---------------------------------------------------------------------------
1512 dnl CF_GETOPT_HEADER version: 5 updated: 2012/10/06 16:39:58
1513 dnl ----------------
1514 dnl Check for getopt's variables which are commonly defined in stdlib.h,
1515 dnl unistd.h or (nonstandard) in getopt.h
1516 AC_DEFUN([CF_GETOPT_HEADER],
1517 [
1518 AC_HAVE_HEADERS(unistd.h getopt.h)
1519 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
1520 cf_cv_getopt_header=none
1521 for cf_header in stdio.h stdlib.h unistd.h getopt.h
1522 do
1523 AC_TRY_COMPILE([
1524 #include <$cf_header>],
1525 [int x = optind; char *y = optarg],
1526 [cf_cv_getopt_header=$cf_header
1527  break])
1528 done
1529 ])
1530 if test $cf_cv_getopt_header != none ; then
1531         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if we need to include getopt.h])
1532 fi
1533 ])dnl
1534 dnl ---------------------------------------------------------------------------
1535 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
1536 dnl -------------
1537 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1538 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1539 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1540 dnl since it is interwoven with GNU extensions.
1541 dnl
1542 dnl Well, yes we could work around it...
1543 AC_DEFUN([CF_GNU_SOURCE],
1544 [
1545 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
1546 AC_TRY_COMPILE([#include <sys/types.h>],[
1547 #ifndef _XOPEN_SOURCE
1548 make an error
1549 #endif],
1550         [cf_cv_gnu_source=no],
1551         [cf_save="$CPPFLAGS"
1552          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1553          AC_TRY_COMPILE([#include <sys/types.h>],[
1554 #ifdef _XOPEN_SOURCE
1555 make an error
1556 #endif],
1557         [cf_cv_gnu_source=no],
1558         [cf_cv_gnu_source=yes])
1559         CPPFLAGS="$cf_save"
1560         ])
1561 ])
1562 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1563 ])dnl
1564 dnl ---------------------------------------------------------------------------
1565 dnl CF_HEADER_PATH version: 12 updated: 2010/05/05 05:22:40
1566 dnl --------------
1567 dnl Construct a search-list of directories for a nonstandard header-file
1568 dnl
1569 dnl Parameters
1570 dnl     $1 = the variable to return as result
1571 dnl     $2 = the package name
1572 AC_DEFUN([CF_HEADER_PATH],
1573 [
1574 $1=
1575
1576 # collect the current set of include-directories from compiler flags
1577 cf_header_path_list=""
1578 if test -n "${CFLAGS}${CPPFLAGS}" ; then
1579         for cf_header_path in $CPPFLAGS $CFLAGS
1580         do
1581                 case $cf_header_path in #(vi
1582                 -I*)
1583                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
1584                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
1585                         cf_header_path_list="$cf_header_path_list [$]$1"
1586                         ;;
1587                 esac
1588         done
1589 fi
1590
1591 # add the variations for the package we are looking for
1592 CF_SUBDIR_PATH($1,$2,include)
1593
1594 test "$includedir" != NONE && \
1595 test "$includedir" != "/usr/include" && \
1596 test -d "$includedir" && {
1597         test -d $includedir &&    $1="[$]$1 $includedir"
1598         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
1599 }
1600
1601 test "$oldincludedir" != NONE && \
1602 test "$oldincludedir" != "/usr/include" && \
1603 test -d "$oldincludedir" && {
1604         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
1605         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
1606 }
1607
1608 $1="[$]$1 $cf_header_path_list"
1609 ])dnl
1610 dnl ---------------------------------------------------------------------------
1611 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
1612 dnl ---------------
1613 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
1614 AC_DEFUN([CF_HELP_MESSAGE],
1615 [AC_DIVERT_HELP([$1])dnl
1616 ])dnl
1617 dnl ---------------------------------------------------------------------------
1618 dnl CF_INHERIT_SCRIPT version: 2 updated: 2003/03/01 23:50:42
1619 dnl -----------------
1620 dnl If we do not have a given script, look for it in the parent directory.
1621 AC_DEFUN([CF_INHERIT_SCRIPT],
1622 [
1623 test -f $1 || ( test -f ../$1 && cp ../$1 ./ )
1624 ])dnl
1625 dnl ---------------------------------------------------------------------------
1626 dnl CF_INTEL_COMPILER version: 5 updated: 2013/02/10 10:41:05
1627 dnl -----------------
1628 dnl Check if the given compiler is really the Intel compiler for Linux.  It
1629 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
1630 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
1631 dnl
1632 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1633 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1634 dnl the wrappers for gcc and g++ warnings.
1635 dnl
1636 dnl $1 = GCC (default) or GXX
1637 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
1638 dnl $3 = CFLAGS (default) or CXXFLAGS
1639 AC_DEFUN([CF_INTEL_COMPILER],[
1640 AC_REQUIRE([AC_CANONICAL_HOST])
1641 ifelse([$2],,INTEL_COMPILER,[$2])=no
1642
1643 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1644         case $host_os in
1645         linux*|gnu*)
1646                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
1647                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1648                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
1649                 AC_TRY_COMPILE([],[
1650 #ifdef __INTEL_COMPILER
1651 #else
1652 make an error
1653 #endif
1654 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
1655 cf_save_CFLAGS="$cf_save_CFLAGS -we147 -no-gcc"
1656 ],[])
1657                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1658                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
1659                 ;;
1660         esac
1661 fi
1662 ])dnl
1663 dnl ---------------------------------------------------------------------------
1664 dnl CF_LD_RPATH_OPT version: 5 updated: 2011/07/17 14:48:41
1665 dnl ---------------
1666 dnl For the given system and compiler, find the compiler flags to pass to the
1667 dnl loader to use the "rpath" feature.
1668 AC_DEFUN([CF_LD_RPATH_OPT],
1669 [
1670 AC_REQUIRE([CF_CHECK_CACHE])
1671
1672 LD_RPATH_OPT=
1673 AC_MSG_CHECKING(for an rpath option)
1674 case $cf_cv_system_name in #(vi
1675 irix*) #(vi
1676         if test "$GCC" = yes; then
1677                 LD_RPATH_OPT="-Wl,-rpath,"
1678         else
1679                 LD_RPATH_OPT="-rpath "
1680         fi
1681         ;;
1682 linux*|gnu*|k*bsd*-gnu) #(vi
1683         LD_RPATH_OPT="-Wl,-rpath,"
1684         ;;
1685 openbsd[[2-9]].*|mirbsd*) #(vi
1686         LD_RPATH_OPT="-Wl,-rpath,"
1687         ;;
1688 dragonfly*|freebsd*) #(vi
1689         LD_RPATH_OPT="-rpath "
1690         ;;
1691 netbsd*) #(vi
1692         LD_RPATH_OPT="-Wl,-rpath,"
1693         ;;
1694 osf*|mls+*) #(vi
1695         LD_RPATH_OPT="-rpath "
1696         ;;
1697 solaris2*) #(vi
1698         LD_RPATH_OPT="-R"
1699         ;;
1700 *)
1701         ;;
1702 esac
1703 AC_MSG_RESULT($LD_RPATH_OPT)
1704
1705 case "x$LD_RPATH_OPT" in #(vi
1706 x-R*)
1707         AC_MSG_CHECKING(if we need a space after rpath option)
1708         cf_save_LIBS="$LIBS"
1709         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
1710         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
1711         LIBS="$cf_save_LIBS"
1712         AC_MSG_RESULT($cf_rpath_space)
1713         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
1714         ;;
1715 esac
1716 ])dnl
1717 dnl ---------------------------------------------------------------------------
1718 dnl CF_LIBRARY_PATH version: 9 updated: 2010/03/28 12:52:50
1719 dnl ---------------
1720 dnl Construct a search-list of directories for a nonstandard library-file
1721 dnl
1722 dnl Parameters
1723 dnl     $1 = the variable to return as result
1724 dnl     $2 = the package name
1725 AC_DEFUN([CF_LIBRARY_PATH],
1726 [
1727 $1=
1728 cf_library_path_list=""
1729 if test -n "${LDFLAGS}${LIBS}" ; then
1730         for cf_library_path in $LDFLAGS $LIBS
1731         do
1732                 case $cf_library_path in #(vi
1733                 -L*)
1734                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
1735                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
1736                         cf_library_path_list="$cf_library_path_list [$]$1"
1737                         ;;
1738                 esac
1739         done
1740 fi
1741
1742 CF_SUBDIR_PATH($1,$2,lib)
1743
1744 $1="$cf_library_path_list [$]$1"
1745 ])dnl
1746 dnl ---------------------------------------------------------------------------
1747 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
1748 dnl ------------
1749 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
1750 dnl a monocase filesystem.
1751 AC_DEFUN([CF_MAKE_TAGS],[
1752 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
1753
1754 AC_CHECK_PROGS(CTAGS, exctags ctags)
1755 AC_CHECK_PROGS(ETAGS, exetags etags)
1756
1757 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
1758
1759 if test "$cf_cv_mixedcase" = yes ; then
1760         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
1761 else
1762         MAKE_UPPER_TAGS=no
1763 fi
1764
1765 if test "$MAKE_UPPER_TAGS" = yes ; then
1766         MAKE_UPPER_TAGS=
1767 else
1768         MAKE_UPPER_TAGS="#"
1769 fi
1770
1771 if test "$MAKE_LOWER_TAGS" = yes ; then
1772         MAKE_LOWER_TAGS=
1773 else
1774         MAKE_LOWER_TAGS="#"
1775 fi
1776
1777 AC_SUBST(CTAGS)
1778 AC_SUBST(ETAGS)
1779
1780 AC_SUBST(MAKE_UPPER_TAGS)
1781 AC_SUBST(MAKE_LOWER_TAGS)
1782 ])dnl
1783 dnl ---------------------------------------------------------------------------
1784 dnl CF_MATH_LIB version: 8 updated: 2010/05/29 16:31:02
1785 dnl -----------
1786 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
1787 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
1788 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
1789 AC_DEFUN([CF_MATH_LIB],
1790 [
1791 AC_CACHE_CHECK(if -lm needed for math functions,
1792         cf_cv_need_libm,[
1793         AC_TRY_LINK([
1794         #include <stdio.h>
1795         #include <math.h>
1796         ],
1797         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
1798         [cf_cv_need_libm=no],
1799         [cf_cv_need_libm=yes])])
1800 if test "$cf_cv_need_libm" = yes
1801 then
1802 ifelse($1,,[
1803         CF_ADD_LIB(m)
1804 ],[$1=-lm])
1805 fi
1806 ])
1807 dnl ---------------------------------------------------------------------------
1808 dnl CF_MIXEDCASE_FILENAMES version: 6 updated: 2013/10/08 17:47:05
1809 dnl ----------------------
1810 dnl Check if the file-system supports mixed-case filenames.  If we're able to
1811 dnl create a lowercase name and see it as uppercase, it doesn't support that.
1812 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
1813 [
1814 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
1815 if test "$cross_compiling" = yes ; then
1816         case $target_alias in #(vi
1817         *-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*) #(vi
1818                 cf_cv_mixedcase=no
1819                 ;;
1820         *)
1821                 cf_cv_mixedcase=yes
1822                 ;;
1823         esac
1824 else
1825         rm -f conftest CONFTEST
1826         echo test >conftest
1827         if test -f CONFTEST ; then
1828                 cf_cv_mixedcase=no
1829         else
1830                 cf_cv_mixedcase=yes
1831         fi
1832         rm -f conftest CONFTEST
1833 fi
1834 ])
1835 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
1836 ])dnl
1837 dnl ---------------------------------------------------------------------------
1838 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
1839 dnl ----------
1840 dnl Write a debug message to config.log, along with the line number in the
1841 dnl configure script.
1842 AC_DEFUN([CF_MSG_LOG],[
1843 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
1844 ])dnl
1845 dnl ---------------------------------------------------------------------------
1846 dnl CF_NCURSES_CC_CHECK version: 4 updated: 2007/07/29 10:39:05
1847 dnl -------------------
1848 dnl Check if we can compile with ncurses' header file
1849 dnl $1 is the cache variable to set
1850 dnl $2 is the header-file to include
1851 dnl $3 is the root name (ncurses or ncursesw)
1852 AC_DEFUN([CF_NCURSES_CC_CHECK],[
1853         AC_TRY_COMPILE([
1854 ]ifelse($3,ncursesw,[
1855 #define _XOPEN_SOURCE_EXTENDED
1856 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
1857 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
1858 ])[
1859 #include <$2>],[
1860 #ifdef NCURSES_VERSION
1861 ]ifelse($3,ncursesw,[
1862 #ifndef WACS_BSSB
1863         make an error
1864 #endif
1865 ])[
1866 printf("%s\n", NCURSES_VERSION);
1867 #else
1868 #ifdef __NCURSES_H
1869 printf("old\n");
1870 #else
1871         make an error
1872 #endif
1873 #endif
1874         ]
1875         ,[$1=$2]
1876         ,[$1=no])
1877 ])dnl
1878 dnl ---------------------------------------------------------------------------
1879 dnl CF_NCURSES_CONFIG version: 10 updated: 2012/10/06 08:57:51
1880 dnl -----------------
1881 dnl Tie together the configure-script macros for ncurses.
1882 dnl Prefer the "-config" script from ncurses 6.x, to simplify analysis.
1883 dnl Allow that to be overridden using the $NCURSES_CONFIG environment variable.
1884 dnl
1885 dnl $1 is the root library name (default: "ncurses")
1886 AC_DEFUN([CF_NCURSES_CONFIG],
1887 [
1888 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
1889
1890 echo "Looking for ${cf_ncuconfig_root}-config"
1891
1892 CF_ACVERSION_CHECK(2.52,
1893         [AC_CHECK_TOOLS(NCURSES_CONFIG, ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)],
1894         [AC_PATH_PROGS(NCURSES_CONFIG, ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)])
1895
1896 if test "$NCURSES_CONFIG" != none ; then
1897
1898 CPPFLAGS="$CPPFLAGS `$NCURSES_CONFIG --cflags`"
1899 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
1900
1901 # even with config script, some packages use no-override for curses.h
1902 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
1903
1904 dnl like CF_NCURSES_CPPFLAGS
1905 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
1906
1907 dnl like CF_NCURSES_LIBS
1908 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
1909 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
1910
1911 dnl like CF_NCURSES_VERSION
1912 cf_cv_ncurses_version=`$NCURSES_CONFIG --version`
1913
1914 else
1915
1916 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
1917 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
1918
1919 fi
1920 ])dnl
1921 dnl ---------------------------------------------------------------------------
1922 dnl CF_NCURSES_CPPFLAGS version: 21 updated: 2012/10/06 08:57:51
1923 dnl -------------------
1924 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
1925 dnl the CPPFLAGS variable so we can include its header.
1926 dnl
1927 dnl The header files may be installed as either curses.h, or ncurses.h (would
1928 dnl be obsolete, except that some packagers prefer this name to distinguish it
1929 dnl from a "native" curses implementation).  If not installed for overwrite,
1930 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
1931 dnl /usr/include/ncurses), but someone may have installed overwriting the
1932 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
1933 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
1934 dnl the header.
1935 dnl
1936 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
1937 dnl is already in the include-path, don't even bother with this, since we cannot
1938 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
1939 dnl
1940 dnl The optional parameter gives the root name of the library, in case it is
1941 dnl not installed as the default curses library.  That is how the
1942 dnl wide-character version of ncurses is installed.
1943 AC_DEFUN([CF_NCURSES_CPPFLAGS],
1944 [AC_REQUIRE([CF_WITH_CURSES_DIR])
1945
1946 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
1947 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
1948
1949 test -n "$cf_cv_curses_dir" && \
1950 test "$cf_cv_curses_dir" != "no" && { \
1951   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
1952 }
1953
1954 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
1955         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
1956         ( test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw ) && cf_header_list="$cf_header_list curses.h ncurses.h"
1957         for cf_header in $cf_header_list
1958         do
1959                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
1960                 test "$cf_cv_ncurses_h" != no && break
1961         done
1962 ])
1963
1964 CF_NCURSES_HEADER
1965 CF_TERM_HEADER
1966
1967 # some applications need this, but should check for NCURSES_VERSION
1968 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
1969
1970 CF_NCURSES_VERSION
1971 ])dnl
1972 dnl ---------------------------------------------------------------------------
1973 dnl CF_NCURSES_EXT_FUNCS version: 4 updated: 2012/10/06 16:39:58
1974 dnl --------------------
1975 dnl Since 2007/11/17, ncurses has defined NCURSES_EXT_FUNCS; earlier versions
1976 dnl may provide these functions.  Define the symbol if it is not defined, and
1977 dnl if it is valid.
1978 AC_DEFUN([CF_NCURSES_EXT_FUNCS],
1979 [
1980 AC_CACHE_CHECK(for ncurses extended functions,cf_cv_ncurses_ext_funcs,[
1981 AC_TRY_COMPILE([
1982 #include <${cf_cv_ncurses_header:-curses.h}>],
1983 [
1984 int x = NCURSES_EXT_FUNCS
1985 ],[cf_cv_ncurses_ext_funcs=defined],[
1986 AC_TRY_LINK([
1987 #include <${cf_cv_ncurses_header:-curses.h}>],
1988 [
1989         (void) assume_default_colors (0, 0);
1990         (void) curses_version ();
1991         (void) define_key (0, 0);
1992         (void) is_term_resized (0, 0);
1993         (void) key_defined (0);
1994         (void) keybound (0, 0);
1995         (void) keyok (0, 0);
1996         (void) resize_term (0, 0);
1997         (void) resizeterm (0, 0);
1998         (void) use_default_colors ();
1999         (void) use_extended_names (0);
2000         (void) wresize (0, 0, 0);],
2001         [cf_cv_ncurses_ext_funcs=yes],
2002         [cf_cv_ncurses_ext_funcs=no])
2003 ])
2004 ])
2005 test "$cf_cv_ncurses_ext_funcs" = yes && AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 if we have ncurses extensions])
2006 ])dnl
2007 dnl ---------------------------------------------------------------------------
2008 dnl CF_NCURSES_HEADER version: 3 updated: 2012/10/06 08:57:51
2009 dnl -----------------
2010 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
2011 dnl variations of ncurses' installs.
2012 dnl
2013 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
2014 AC_DEFUN([CF_NCURSES_HEADER],[
2015
2016 if test "$cf_cv_ncurses_h" != no ; then
2017         cf_cv_ncurses_header=$cf_cv_ncurses_h
2018 else
2019
2020 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
2021         test -n "$verbose" && echo
2022         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
2023         test -n "$verbose" && echo search path $cf_search
2024         cf_save2_CPPFLAGS="$CPPFLAGS"
2025         for cf_incdir in $cf_search
2026         do
2027                 CF_ADD_INCDIR($cf_incdir)
2028                 for cf_header in \
2029                         ncurses.h \
2030                         curses.h
2031                 do
2032                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
2033                         if test "$cf_cv_ncurses_h2" != no ; then
2034                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
2035                                 test -n "$verbose" && echo $ac_n "      ... found $ac_c" 1>&AC_FD_MSG
2036                                 break
2037                         fi
2038                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
2039                 done
2040                 CPPFLAGS="$cf_save2_CPPFLAGS"
2041                 test "$cf_cv_ncurses_h2" != no && break
2042         done
2043         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
2044         ])
2045
2046         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
2047         cf_cv_ncurses_header=`basename $cf_cv_ncurses_h2`
2048         if test `basename $cf_1st_incdir` = $cf_ncuhdr_root ; then
2049                 cf_cv_ncurses_header=$cf_ncuhdr_root/$cf_cv_ncurses_header
2050         fi
2051         CF_ADD_INCDIR($cf_1st_incdir)
2052
2053 fi
2054
2055 # Set definitions to allow ifdef'ing for ncurses.h
2056
2057 case $cf_cv_ncurses_header in # (vi
2058 *ncurses.h)
2059         AC_DEFINE(HAVE_NCURSES_H,1,[Define to 1 if we have ncurses.h])
2060         ;;
2061 esac
2062
2063 case $cf_cv_ncurses_header in # (vi
2064 ncurses/curses.h|ncurses/ncurses.h)
2065         AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Define to 1 if we have ncurses/ncurses.h])
2066         ;;
2067 ncursesw/curses.h|ncursesw/ncurses.h)
2068         AC_DEFINE(HAVE_NCURSESW_NCURSES_H,1,[Define to 1 if we have ncursesw/ncurses.h])
2069         ;;
2070 esac
2071
2072 ])dnl
2073 dnl ---------------------------------------------------------------------------
2074 dnl CF_NCURSES_LIBS version: 16 updated: 2010/11/20 17:02:38
2075 dnl ---------------
2076 dnl Look for the ncurses library.  This is a little complicated on Linux,
2077 dnl because it may be linked with the gpm (general purpose mouse) library.
2078 dnl Some distributions have gpm linked with (bsd) curses, which makes it
2079 dnl unusable with ncurses.  However, we don't want to link with gpm unless
2080 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
2081 dnl and the linker will record a dependency.
2082 dnl
2083 dnl The optional parameter gives the root name of the library, in case it is
2084 dnl not installed as the default curses library.  That is how the
2085 dnl wide-character version of ncurses is installed.
2086 AC_DEFUN([CF_NCURSES_LIBS],
2087 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
2088
2089 cf_nculib_root=ifelse($1,,ncurses,$1)
2090         # This works, except for the special case where we find gpm, but
2091         # ncurses is in a nonstandard location via $LIBS, and we really want
2092         # to link gpm.
2093 cf_ncurses_LIBS=""
2094 cf_ncurses_SAVE="$LIBS"
2095 AC_CHECK_LIB(gpm,Gpm_Open,
2096         [AC_CHECK_LIB(gpm,initscr,
2097                 [LIBS="$cf_ncurses_SAVE"],
2098                 [cf_ncurses_LIBS="-lgpm"])])
2099
2100 case $host_os in #(vi
2101 freebsd*)
2102         # This is only necessary if you are linking against an obsolete
2103         # version of ncurses (but it should do no harm, since it's static).
2104         if test "$cf_nculib_root" = ncurses ; then
2105                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
2106         fi
2107         ;;
2108 esac
2109
2110 CF_ADD_LIBS($cf_ncurses_LIBS)
2111
2112 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
2113 then
2114         CF_ADD_LIBS(-l$cf_nculib_root)
2115 else
2116         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
2117                 [#include <${cf_cv_ncurses_header:-curses.h}>],
2118                 [initscr()],
2119                 initscr)
2120 fi
2121
2122 if test -n "$cf_ncurses_LIBS" ; then
2123         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
2124         cf_ncurses_SAVE="$LIBS"
2125         for p in $cf_ncurses_LIBS ; do
2126                 q=`echo $LIBS | sed -e "s%$p %%" -e "s%$p$%%"`
2127                 if test "$q" != "$LIBS" ; then
2128                         LIBS="$q"
2129                 fi
2130         done
2131         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2132                 [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2133                 [AC_MSG_RESULT(yes)],
2134                 [AC_MSG_RESULT(no)
2135                  LIBS="$cf_ncurses_SAVE"])
2136 fi
2137
2138 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
2139 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2140 ])dnl
2141 dnl ---------------------------------------------------------------------------
2142 dnl CF_NCURSES_VERSION version: 14 updated: 2012/10/06 08:57:51
2143 dnl ------------------
2144 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
2145 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
2146 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
2147 AC_DEFUN([CF_NCURSES_VERSION],
2148 [
2149 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
2150 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
2151         cf_cv_ncurses_version=no
2152         cf_tempfile=out$$
2153         rm -f $cf_tempfile
2154         AC_TRY_RUN([
2155 #include <${cf_cv_ncurses_header:-curses.h}>
2156 #include <stdio.h>
2157 int main()
2158 {
2159         FILE *fp = fopen("$cf_tempfile", "w");
2160 #ifdef NCURSES_VERSION
2161 # ifdef NCURSES_VERSION_PATCH
2162         fprintf(fp, "%s.%d\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
2163 # else
2164         fprintf(fp, "%s\n", NCURSES_VERSION);
2165 # endif
2166 #else
2167 # ifdef __NCURSES_H
2168         fprintf(fp, "old\n");
2169 # else
2170         make an error
2171 # endif
2172 #endif
2173         ${cf_cv_main_return:-return}(0);
2174 }],[
2175         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
2176
2177         # This will not work if the preprocessor splits the line after the
2178         # Autoconf token.  The 'unproto' program does that.
2179         cat > conftest.$ac_ext <<EOF
2180 #include <${cf_cv_ncurses_header:-curses.h}>
2181 #undef Autoconf
2182 #ifdef NCURSES_VERSION
2183 Autoconf NCURSES_VERSION
2184 #else
2185 #ifdef __NCURSES_H
2186 Autoconf "old"
2187 #endif
2188 ;
2189 #endif
2190 EOF
2191         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
2192         AC_TRY_EVAL(cf_try)
2193         if test -f conftest.out ; then
2194                 cf_out=`cat conftest.out | sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%'`
2195                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
2196                 rm -f conftest.out
2197         fi
2198 ])
2199         rm -f $cf_tempfile
2200 ])
2201 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2202 ])dnl
2203 dnl ---------------------------------------------------------------------------
2204 dnl CF_NCURSES_WRAP_PREFIX version: 1 updated: 2009/03/28 16:08:10
2205 dnl ----------------------
2206 dnl Check for ncurses "wrap-prefix" used for public variables which have been
2207 dnl wrapped with a function to help with concurrency control.
2208 AC_DEFUN([CF_NCURSES_WRAP_PREFIX],
2209 [
2210 AC_MSG_CHECKING(for ncurses wrap-prefix)
2211 AC_ARG_WITH(ncurses-wrap-prefix,
2212         [  --with-ncurses-wrap-prefix naming-prefix for ncurses wrapped-variables],
2213         [NCURSES_WRAP_PREFIX=$withval],
2214         [NCURSES_WRAP_PREFIX=_nc_])
2215 AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
2216
2217 AC_SUBST(NCURSES_WRAP_PREFIX)
2218 ])
2219 dnl ---------------------------------------------------------------------------
2220 dnl CF_NETBSD_FORM_H version: 2 updated: 2012/10/06 16:39:58
2221 dnl ----------------
2222 dnl Check for NetBSD's form.h, which is incompatible with SVr4 and ncurses.
2223 dnl Some workarounds are needed in client programs to allow them to compile.
2224 AC_DEFUN([CF_NETBSD_FORM_H],[
2225 AC_CACHE_CHECK(for NetBSD form.h,cf_cv_netbsd_form_h,[
2226 AC_TRY_COMPILE([
2227 #include <${cf_cv_ncurses_header:-curses.h}>
2228 #include <form.h>
2229 ],[
2230         FORM *form;
2231         int y = current_field(form)->cursor_ypos;
2232         int x = current_field(form)->cursor_xpos;
2233 ],[cf_cv_netbsd_form_h=yes
2234 ],[cf_cv_netbsd_form_h=no])
2235 ])
2236
2237 test "$cf_cv_netbsd_form_h" = yes && AC_DEFINE(HAVE_NETBSD_FORM_H,1,[Define to 1 if we appear to be using NetBSD form.h])
2238 ])dnl
2239 dnl ---------------------------------------------------------------------------
2240 dnl CF_NETBSD_MENU_H version: 2 updated: 2012/10/06 16:39:58
2241 dnl ----------------
2242 dnl Check for NetBSD's menu.h, which is incompatible with SVr4 and ncurses.
2243 dnl Some workarounds are needed in client programs to allow them to compile.
2244 AC_DEFUN([CF_NETBSD_MENU_H],[
2245 AC_CACHE_CHECK(for NetBSD menu.h,cf_cv_netbsd_menu_h,[
2246 AC_TRY_COMPILE([
2247 #include <${cf_cv_ncurses_header:-curses.h}>
2248 #include <menu.h>
2249 ],[
2250         MENU *menu;
2251         int y = menu->max_item_width;
2252 ],[cf_cv_netbsd_menu_h=yes
2253 ],[cf_cv_netbsd_menu_h=no])
2254 ])
2255
2256 test "$cf_cv_netbsd_menu_h" = yes && AC_DEFINE(HAVE_NETBSD_MENU_H,1,[Define to 1 if we appear to be using NetBSD menu.h])
2257 ])dnl
2258 dnl ---------------------------------------------------------------------------
2259 dnl CF_NO_LEAKS_OPTION version: 5 updated: 2012/10/02 20:55:03
2260 dnl ------------------
2261 dnl see CF_WITH_NO_LEAKS
2262 AC_DEFUN([CF_NO_LEAKS_OPTION],[
2263 AC_MSG_CHECKING(if you want to use $1 for testing)
2264 AC_ARG_WITH($1,
2265         [$2],
2266         [AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
2267          $4
2268 ])
2269         : ${with_cflags:=-g}
2270         : ${with_no_leaks:=yes}
2271          with_$1=yes],
2272         [with_$1=])
2273 AC_MSG_RESULT(${with_$1:-no})
2274
2275 case .$with_cflags in #(vi
2276 .*-g*)
2277         case .$CFLAGS in #(vi
2278         .*-g*) #(vi
2279                 ;;
2280         *)
2281                 CF_ADD_CFLAGS([-g])
2282                 ;;
2283         esac
2284         ;;
2285 esac
2286 ])dnl
2287 dnl ---------------------------------------------------------------------------
2288 dnl CF_PATH_SYNTAX version: 14 updated: 2012/06/19 20:58:54
2289 dnl --------------
2290 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
2291 dnl begins with one of the prefix/exec_prefix variables, and then again if the
2292 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
2293 dnl delayed evaluation of those symbols.
2294 AC_DEFUN([CF_PATH_SYNTAX],[
2295 if test "x$prefix" != xNONE; then
2296   cf_path_syntax="$prefix"
2297 else
2298   cf_path_syntax="$ac_default_prefix"
2299 fi
2300
2301 case ".[$]$1" in #(vi
2302 .\[$]\(*\)*|.\'*\'*) #(vi
2303   ;;
2304 ..|./*|.\\*) #(vi
2305   ;;
2306 .[[a-zA-Z]]:[[\\/]]*) #(vi OS/2 EMX
2307   ;;
2308 .\[$]{*prefix}*|.\[$]{*dir}*) #(vi
2309   eval $1="[$]$1"
2310   case ".[$]$1" in #(vi
2311   .NONE/*)
2312     $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2313     ;;
2314   esac
2315   ;; #(vi
2316 .no|.NONE/*)
2317   $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2318   ;;
2319 *)
2320   ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
2321   ;;
2322 esac
2323 ])dnl
2324 dnl ---------------------------------------------------------------------------
2325 dnl CF_PDCURSES_X11 version: 13 updated: 2012/10/06 16:39:58
2326 dnl ---------------
2327 dnl Configure for PDCurses' X11 library
2328 AC_DEFUN([CF_PDCURSES_X11],[
2329 AC_REQUIRE([CF_X_ATHENA])
2330
2331 CF_ACVERSION_CHECK(2.52,
2332         [AC_CHECK_TOOLS(XCURSES_CONFIG, xcurses-config, none)],
2333         [AC_PATH_PROGS(XCURSES_CONFIG, xcurses-config, none)])
2334
2335 if test "$XCURSES_CONFIG" != none ; then
2336
2337 CPPFLAGS="$CPPFLAGS `$XCURSES_CONFIG --cflags`"
2338 CF_ADD_LIBS(`$XCURSES_CONFIG --libs`)
2339
2340 cf_cv_lib_XCurses=yes
2341
2342 else
2343
2344 LDFLAGS="$LDFLAGS $X_LIBS"
2345 CF_CHECK_CFLAGS($X_CFLAGS)
2346 AC_CHECK_LIB(X11,XOpenDisplay,
2347         [CF_ADD_LIBS(-lX11)],,
2348         [$X_PRE_LIBS $LIBS $X_EXTRA_LIBS])
2349 AC_CACHE_CHECK(for XCurses library,cf_cv_lib_XCurses,[
2350 CF_ADD_LIBS(-lXCurses)
2351 AC_TRY_LINK([
2352 #include <xcurses.h>
2353 char *XCursesProgramName = "test";
2354 ],[XCursesExit();],
2355 [cf_cv_lib_XCurses=yes],
2356 [cf_cv_lib_XCurses=no])
2357 ])
2358
2359 fi
2360
2361 if test $cf_cv_lib_XCurses = yes ; then
2362         AC_DEFINE(UNIX,1,[Define to 1 if using PDCurses on Unix])
2363         AC_DEFINE(XCURSES,1,[Define to 1 if using PDCurses on Unix])
2364         AC_CHECK_HEADER(xcurses.h, AC_DEFINE(HAVE_XCURSES,1,[Define to 1 if using PDCurses on Unix]))
2365 else
2366         AC_MSG_ERROR(Cannot link with XCurses)
2367 fi
2368 ])dnl
2369 dnl ---------------------------------------------------------------------------
2370 dnl CF_PKG_CONFIG version: 7 updated: 2011/04/29 04:53:22
2371 dnl -------------
2372 dnl Check for the package-config program, unless disabled by command-line.
2373 AC_DEFUN([CF_PKG_CONFIG],
2374 [
2375 AC_MSG_CHECKING(if you want to use pkg-config)
2376 AC_ARG_WITH(pkg-config,
2377         [  --with-pkg-config{=path} enable/disable use of pkg-config],
2378         [cf_pkg_config=$withval],
2379         [cf_pkg_config=yes])
2380 AC_MSG_RESULT($cf_pkg_config)
2381
2382 case $cf_pkg_config in #(vi
2383 no) #(vi
2384         PKG_CONFIG=none
2385         ;;
2386 yes) #(vi
2387         CF_ACVERSION_CHECK(2.52,
2388                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
2389                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
2390         ;;
2391 *)
2392         PKG_CONFIG=$withval
2393         ;;
2394 esac
2395
2396 test -z "$PKG_CONFIG" && PKG_CONFIG=none
2397 if test "$PKG_CONFIG" != none ; then
2398         CF_PATH_SYNTAX(PKG_CONFIG)
2399 fi
2400
2401 AC_SUBST(PKG_CONFIG)
2402 ])dnl
2403 dnl ---------------------------------------------------------------------------
2404 dnl CF_POSIX_C_SOURCE version: 8 updated: 2010/05/26 05:38:42
2405 dnl -----------------
2406 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
2407 dnl
2408 dnl     POSIX.1-1990                            _POSIX_SOURCE
2409 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
2410 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
2411 dnl             Bindings Option
2412 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
2413 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
2414 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
2415 dnl
2416 dnl Parameters:
2417 dnl     $1 is the nominal value for _POSIX_C_SOURCE
2418 AC_DEFUN([CF_POSIX_C_SOURCE],
2419 [
2420 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
2421
2422 cf_save_CFLAGS="$CFLAGS"
2423 cf_save_CPPFLAGS="$CPPFLAGS"
2424
2425 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
2426 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
2427
2428 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
2429         CF_MSG_LOG(if the symbol is already defined go no further)
2430         AC_TRY_COMPILE([#include <sys/types.h>],[
2431 #ifndef _POSIX_C_SOURCE
2432 make an error
2433 #endif],
2434         [cf_cv_posix_c_source=no],
2435         [cf_want_posix_source=no
2436          case .$cf_POSIX_C_SOURCE in #(vi
2437          .[[12]]??*) #(vi
2438                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2439                 ;;
2440          .2) #(vi
2441                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2442                 cf_want_posix_source=yes
2443                 ;;
2444          .*)
2445                 cf_want_posix_source=yes
2446                 ;;
2447          esac
2448          if test "$cf_want_posix_source" = yes ; then
2449                 AC_TRY_COMPILE([#include <sys/types.h>],[
2450 #ifdef _POSIX_SOURCE
2451 make an error
2452 #endif],[],
2453                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
2454          fi
2455          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
2456          CFLAGS="$cf_trim_CFLAGS"
2457          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
2458          CF_MSG_LOG(if the second compile does not leave our definition intact error)
2459          AC_TRY_COMPILE([#include <sys/types.h>],[
2460 #ifndef _POSIX_C_SOURCE
2461 make an error
2462 #endif],,
2463          [cf_cv_posix_c_source=no])
2464          CFLAGS="$cf_save_CFLAGS"
2465          CPPFLAGS="$cf_save_CPPFLAGS"
2466         ])
2467 ])
2468
2469 if test "$cf_cv_posix_c_source" != no ; then
2470         CFLAGS="$cf_trim_CFLAGS"
2471         CPPFLAGS="$cf_trim_CPPFLAGS"
2472         CF_ADD_CFLAGS($cf_cv_posix_c_source)
2473 fi
2474
2475 ])dnl
2476 dnl ---------------------------------------------------------------------------
2477 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
2478 dnl ------------
2479 dnl Append definitions and rules for the given programs to the subdirectory
2480 dnl Makefiles, and the recursion rule for the top-level Makefile.
2481 dnl
2482 dnl parameters
2483 dnl     $1 = script to run
2484 dnl     $2 = list of subdirectories
2485 dnl
2486 dnl variables
2487 dnl     $AWK
2488 AC_DEFUN([CF_PRG_RULES],
2489 [
2490 for cf_dir in $2
2491 do
2492         if test ! -d $srcdir/$cf_dir; then
2493                 continue
2494         elif test -f $srcdir/$cf_dir/programs; then
2495                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
2496         fi
2497 done
2498
2499 ])dnl
2500 dnl ---------------------------------------------------------------------------
2501 dnl CF_PROG_CC version: 3 updated: 2012/10/06 15:31:55
2502 dnl ----------
2503 dnl standard check for CC, plus followup sanity checks
2504 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
2505 AC_DEFUN([CF_PROG_CC],[
2506 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
2507 CF_GCC_VERSION
2508 CF_ACVERSION_CHECK(2.52,
2509         [AC_PROG_CC_STDC],
2510         [CF_ANSI_CC_REQD])
2511 CF_CC_ENV_FLAGS 
2512 ])dnl
2513 dnl ---------------------------------------------------------------------------
2514 dnl CF_PROG_INSTALL version: 5 updated: 2002/12/21 22:46:07
2515 dnl ---------------
2516 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
2517 dnl misc/tabset install won't work properly.  Usually this happens only when
2518 dnl using the fallback mkinstalldirs script
2519 AC_DEFUN([CF_PROG_INSTALL],
2520 [AC_PROG_INSTALL
2521 case $INSTALL in
2522 /*)
2523   ;;
2524 *)
2525   CF_DIRNAME(cf_dir,$INSTALL)
2526   test -z "$cf_dir" && cf_dir=.
2527   INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
2528   ;;
2529 esac
2530 ])dnl
2531 dnl ---------------------------------------------------------------------------
2532 dnl CF_PROG_LINT version: 2 updated: 2009/08/12 04:43:14
2533 dnl ------------
2534 AC_DEFUN([CF_PROG_LINT],
2535 [
2536 AC_CHECK_PROGS(LINT, tdlint lint alint splint lclint)
2537 AC_SUBST(LINT_OPTS)
2538 ])dnl
2539 dnl ---------------------------------------------------------------------------
2540 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
2541 dnl ----------------
2542 dnl Remove all -U and -D options that refer to the given symbol from a list
2543 dnl of C compiler options.  This works around the problem that not all
2544 dnl compilers process -U and -D options from left-to-right, so a -U option
2545 dnl cannot be used to cancel the effect of a preceding -D option.
2546 dnl
2547 dnl $1 = target (which could be the same as the source variable)
2548 dnl $2 = source (including '$')
2549 dnl $3 = symbol to remove
2550 define([CF_REMOVE_DEFINE],
2551 [
2552 $1=`echo "$2" | \
2553         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
2554                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
2555 ])dnl
2556 dnl ---------------------------------------------------------------------------
2557 dnl CF_RPATH_HACK version: 11 updated: 2013/09/01 13:02:00
2558 dnl -------------
2559 AC_DEFUN([CF_RPATH_HACK],
2560 [
2561 AC_REQUIRE([CF_LD_RPATH_OPT])
2562 AC_MSG_CHECKING(for updated LDFLAGS)
2563 if test -n "$LD_RPATH_OPT" ; then
2564         AC_MSG_RESULT(maybe)
2565
2566         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
2567         cf_rpath_list="/usr/lib /lib"
2568         if test "$cf_ldd_prog" != no
2569         then
2570                 cf_rpath_oops=
2571
2572 AC_TRY_LINK([#include <stdio.h>],
2573                 [printf("Hello");],
2574                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
2575                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
2576
2577                 # If we passed the link-test, but get a "not found" on a given library,
2578                 # this could be due to inept reconfiguration of gcc to make it only
2579                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
2580                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
2581                 # /usr/local libraries.
2582                 if test -n "$cf_rpath_oops"
2583                 then
2584                         for cf_rpath_src in $cf_rpath_oops
2585                         do
2586                                 for cf_rpath_dir in \
2587                                         /usr/local \
2588                                         /usr/pkg \
2589                                         /opt/sfw
2590                                 do
2591                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
2592                                         then
2593                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
2594                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
2595                                                 break
2596                                         fi
2597                                 done
2598                         done
2599                 fi
2600         fi
2601
2602         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
2603
2604         CF_RPATH_HACK_2(LDFLAGS)
2605         CF_RPATH_HACK_2(LIBS)
2606
2607         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
2608 else
2609         AC_MSG_RESULT(no)
2610 fi
2611 AC_SUBST(EXTRA_LDFLAGS)
2612 ])dnl
2613 dnl ---------------------------------------------------------------------------
2614 dnl CF_RPATH_HACK_2 version: 6 updated: 2010/04/17 16:31:24
2615 dnl ---------------
2616 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
2617 dnl EXTRA_LDFLAGS for each -L option found.
2618 dnl
2619 dnl $cf_rpath_list contains a list of directories to ignore.
2620 dnl
2621 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
2622 dnl      but LIBS often has misplaced -L options.
2623 AC_DEFUN([CF_RPATH_HACK_2],
2624 [
2625 CF_VERBOSE(...checking $1 [$]$1)
2626
2627 cf_rpath_dst=
2628 for cf_rpath_src in [$]$1
2629 do
2630         case $cf_rpath_src in #(vi
2631         -L*) #(vi
2632
2633                 # check if this refers to a directory which we will ignore
2634                 cf_rpath_skip=no
2635                 if test -n "$cf_rpath_list"
2636                 then
2637                         for cf_rpath_item in $cf_rpath_list
2638                         do
2639                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
2640                                 then
2641                                         cf_rpath_skip=yes
2642                                         break
2643                                 fi
2644                         done
2645                 fi
2646
2647                 if test "$cf_rpath_skip" = no
2648                 then
2649                         # transform the option
2650                         if test "$LD_RPATH_OPT" = "-R " ; then
2651                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
2652                         else
2653                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
2654                         fi
2655
2656                         # if we have not already added this, add it now
2657                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
2658                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
2659                         then
2660                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
2661                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
2662                         fi
2663                 fi
2664                 ;;
2665         esac
2666         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
2667 done
2668 $1=$cf_rpath_dst
2669
2670 CF_VERBOSE(...checked $1 [$]$1)
2671 AC_SUBST(EXTRA_LDFLAGS)
2672 ])dnl
2673 dnl ---------------------------------------------------------------------------
2674 dnl CF_SIG_ATOMIC_T version: 3 updated: 2012/10/04 20:12:20
2675 dnl ---------------
2676 dnl signal handler, but there are some gcc depedencies in that recommendation.
2677 dnl Try anyway.
2678 AC_DEFUN([CF_SIG_ATOMIC_T],
2679 [
2680 AC_MSG_CHECKING(for signal global datatype)
2681 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
2682         for cf_type in \
2683                 "volatile sig_atomic_t" \
2684                 "sig_atomic_t" \
2685                 "int"
2686         do
2687         AC_TRY_COMPILE([
2688 #include <sys/types.h>
2689 #include <signal.h>
2690 #include <stdio.h>
2691
2692 extern $cf_type x;
2693 $cf_type x;
2694 static void handler(int sig)
2695 {
2696         x = 5;
2697 }],
2698                 [signal(SIGINT, handler);
2699                  x = 1],
2700                 [cf_cv_sig_atomic_t=$cf_type],
2701                 [cf_cv_sig_atomic_t=no])
2702                 test "$cf_cv_sig_atomic_t" != no && break
2703         done
2704         ])
2705 AC_MSG_RESULT($cf_cv_sig_atomic_t)
2706 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
2707 ])dnl
2708 dnl ---------------------------------------------------------------------------
2709 dnl CF_SUBDIR_PATH version: 6 updated: 2010/04/21 06:20:50
2710 dnl --------------
2711 dnl Construct a search-list for a nonstandard header/lib-file
2712 dnl     $1 = the variable to return as result
2713 dnl     $2 = the package name
2714 dnl     $3 = the subdirectory, e.g., bin, include or lib
2715 AC_DEFUN([CF_SUBDIR_PATH],
2716 [
2717 $1=
2718
2719 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr,$prefix)
2720 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
2721 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr/local,$prefix)
2722 CF_ADD_SUBDIR_PATH($1,$2,$3,/opt,$prefix)
2723 CF_ADD_SUBDIR_PATH($1,$2,$3,[$]HOME,$prefix)
2724 ])dnl
2725 dnl ---------------------------------------------------------------------------
2726 dnl CF_SYS_TIME_SELECT version: 5 updated: 2012/10/04 05:24:07
2727 dnl ------------------
2728 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
2729 dnl older SCO configurations.
2730 AC_DEFUN([CF_SYS_TIME_SELECT],
2731 [
2732 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
2733 AC_CACHE_VAL(cf_cv_sys_time_select,[
2734 AC_TRY_COMPILE([
2735 #include <sys/types.h>
2736 #ifdef HAVE_SYS_TIME_H
2737 #include <sys/time.h>
2738 #endif
2739 #ifdef HAVE_SYS_SELECT_H
2740 #include <sys/select.h>
2741 #endif
2742 ],[],[cf_cv_sys_time_select=yes],
2743      [cf_cv_sys_time_select=no])
2744      ])
2745 AC_MSG_RESULT($cf_cv_sys_time_select)
2746 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
2747 ])dnl
2748 dnl ---------------------------------------------------------------------------
2749 dnl CF_TERM_HEADER version: 3 updated: 2012/10/06 08:57:51
2750 dnl --------------
2751 dnl Look for term.h, which is part of X/Open curses.  It defines the interface
2752 dnl to terminfo database.  Usually it is in the same include-path as curses.h,
2753 dnl but some packagers change this, breaking various applications.
2754 AC_DEFUN([CF_TERM_HEADER],[
2755 AC_CACHE_CHECK(for terminfo header, cf_cv_term_header,[
2756 case ${cf_cv_ncurses_header} in #(vi
2757 */ncurses.h|*/ncursesw.h) #(vi
2758         cf_term_header=`echo "$cf_cv_ncurses_header" | sed -e 's%ncurses[[^.]]*\.h$%term.h%'`
2759         ;;
2760 *)
2761         cf_term_header=term.h
2762         ;;
2763 esac
2764
2765 for cf_test in $cf_term_header "ncurses/term.h" "ncursesw/term.h"
2766 do
2767 AC_TRY_COMPILE([#include <stdio.h>
2768 #include <${cf_cv_ncurses_header:-curses.h}>
2769 #include <$cf_test>
2770 ],[int x = auto_left_margin],[
2771         cf_cv_term_header="$cf_test"],[
2772         cf_cv_term_header=unknown
2773         ])
2774         test "$cf_cv_term_header" != unknown && break
2775 done
2776 ])
2777
2778 # Set definitions to allow ifdef'ing to accommodate subdirectories
2779
2780 case $cf_cv_term_header in # (vi
2781 *term.h)
2782         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
2783         ;;
2784 esac
2785
2786 case $cf_cv_term_header in # (vi
2787 ncurses/term.h) #(vi
2788         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
2789         ;;
2790 ncursesw/term.h)
2791         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
2792         ;;
2793 esac
2794 ])dnl
2795 dnl ---------------------------------------------------------------------------
2796 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
2797 dnl ---------------
2798 dnl Define a top_builddir symbol, for applications that need an absolute path.
2799 AC_DEFUN([CF_TOP_BUILDDIR],
2800 [
2801 top_builddir=ifelse($1,,`pwd`,$1)
2802 AC_SUBST(top_builddir)
2803 ])dnl
2804 dnl ---------------------------------------------------------------------------
2805 dnl CF_TPUTS_PROTO version: 2 updated: 2011/04/23 19:25:50
2806 dnl --------------
2807 dnl Check for type of function-pointer passed to tputs.  Some old
2808 dnl implementations used functions that had different prototypes, making it
2809 dnl hard to compile portable programs using tputs.
2810 AC_DEFUN([CF_TPUTS_PROTO],[
2811 CF_CURSES_FUNCS(tputs)
2812 if test x$cf_cv_func_tputs = xyes
2813 then
2814         cf_done=no
2815         for cf_arg in int char
2816         do
2817                 for cf_ret in int void
2818                 do
2819                         if test $cf_ret = void
2820                         then
2821                                 cf_return="/* nothing */"
2822                         else
2823                                 cf_return="return value"
2824                         fi
2825                         AC_TRY_COMPILE([
2826 #include <${cf_cv_ncurses_header:-curses.h}>
2827 #include <$cf_cv_term_header>
2828
2829 static $cf_ret outc($cf_arg value) { $cf_return; }
2830 ],[
2831         tputs("hello", 0, outc); 
2832         ${cf_cv_main_return:-return}(0);
2833 ],[
2834                 CF_VERBOSE([prototype $cf_ret func($cf_arg value)])
2835                 cat >>confdefs.h <<EOF
2836 #define TPUTS_ARG               $cf_arg
2837 #define TPUTS_PROTO(func,value) $cf_ret func(TPUTS_ARG value)
2838 #define TPUTS_RETURN(value)     $cf_return
2839 EOF
2840                 cf_done=yes
2841                 break
2842 ])
2843                 done
2844                 test $cf_done = yes && break
2845         done
2846 fi
2847 ])dnl
2848 dnl ---------------------------------------------------------------------------
2849 dnl CF_TRIM_X_LIBS version: 2 updated: 2013/07/09 21:27:22
2850 dnl --------------
2851 dnl Trim extra base X libraries added as a workaround for inconsistent library
2852 dnl dependencies returned by "new" pkg-config files.
2853 AC_DEFUN([CF_TRIM_X_LIBS],[
2854         for cf_trim_lib in Xmu Xt X11
2855         do
2856                 case "$LIBS" in
2857                 *-l$cf_trim_lib\ *-l$cf_trim_lib*)
2858                         LIBS=`echo "$LIBS " | sed -e 's/  / /g' -e 's%-l'"$cf_trim_lib"' %%' -e 's/ $//'`
2859                         CF_VERBOSE(..trimmed $LIBS)
2860                         ;;
2861                 esac
2862         done
2863 ])
2864 dnl ---------------------------------------------------------------------------
2865 dnl CF_TRY_PKG_CONFIG version: 5 updated: 2013/07/06 21:27:06
2866 dnl -----------------
2867 dnl This is a simple wrapper to use for pkg-config, for libraries which may be
2868 dnl available in that form.
2869 dnl
2870 dnl $1 = package name
2871 dnl $2 = extra logic to use, if any, after updating CFLAGS and LIBS
2872 dnl $3 = logic to use if pkg-config does not have the package
2873 AC_DEFUN([CF_TRY_PKG_CONFIG],[
2874 AC_REQUIRE([CF_PKG_CONFIG])
2875
2876 if test "$PKG_CONFIG" != none && "$PKG_CONFIG" --exists $1; then
2877         CF_VERBOSE(found package $1)
2878         cf_pkgconfig_incs="`$PKG_CONFIG --cflags $1 2>/dev/null`"
2879         cf_pkgconfig_libs="`$PKG_CONFIG --libs   $1 2>/dev/null`"
2880         CF_VERBOSE(package $1 CFLAGS: $cf_pkgconfig_incs)
2881         CF_VERBOSE(package $1 LIBS: $cf_pkgconfig_libs)
2882         CF_ADD_CFLAGS($cf_pkgconfig_incs)
2883         CF_ADD_LIBS($cf_pkgconfig_libs)
2884         ifelse([$2],,:,[$2])
2885 else
2886         cf_pkgconfig_incs=
2887         cf_pkgconfig_libs=
2888         ifelse([$3],,:,[$3])
2889 fi
2890 ])
2891 dnl ---------------------------------------------------------------------------
2892 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
2893 dnl -------------------
2894 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
2895 dnl can define it successfully.
2896 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
2897 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
2898         AC_TRY_COMPILE([
2899 #include <stdlib.h>
2900 #include <string.h>
2901 #include <sys/types.h>
2902 ],[
2903 #ifndef _XOPEN_SOURCE
2904 make an error
2905 #endif],
2906         [cf_cv_xopen_source=no],
2907         [cf_save="$CPPFLAGS"
2908          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
2909          AC_TRY_COMPILE([
2910 #include <stdlib.h>
2911 #include <string.h>
2912 #include <sys/types.h>
2913 ],[
2914 #ifdef _XOPEN_SOURCE
2915 make an error
2916 #endif],
2917         [cf_cv_xopen_source=no],
2918         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
2919         CPPFLAGS="$cf_save"
2920         ])
2921 ])
2922
2923 if test "$cf_cv_xopen_source" != no ; then
2924         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
2925         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
2926         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
2927         CF_ADD_CFLAGS($cf_temp_xopen_source)
2928 fi
2929 ])
2930 dnl ---------------------------------------------------------------------------
2931 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
2932 dnl --------
2933 dnl Make an uppercase version of a variable
2934 dnl $1=uppercase($2)
2935 AC_DEFUN([CF_UPPER],
2936 [
2937 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
2938 ])dnl
2939 dnl ---------------------------------------------------------------------------
2940 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
2941 dnl -----------
2942 dnl Check for multibyte support, and if not found, utf8 compatibility library
2943 AC_DEFUN([CF_UTF8_LIB],
2944 [
2945 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
2946         cf_save_LIBS="$LIBS"
2947         AC_TRY_LINK([
2948 #include <stdlib.h>],[putwc(0,0);],
2949         [cf_cv_utf8_lib=yes],
2950         [CF_FIND_LINKAGE([
2951 #include <libutf8.h>],[putwc(0,0);],utf8,
2952                 [cf_cv_utf8_lib=add-on],
2953                 [cf_cv_utf8_lib=no])
2954 ])])
2955
2956 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
2957 # ncurses/ncursesw:
2958 if test "$cf_cv_utf8_lib" = "add-on" ; then
2959         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
2960         CF_ADD_INCDIR($cf_cv_header_path_utf8)
2961         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
2962         CF_ADD_LIBS($cf_cv_library_file_utf8)
2963 fi
2964 ])dnl
2965 dnl ---------------------------------------------------------------------------
2966 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
2967 dnl ----------
2968 dnl Use AC_VERBOSE w/o the warnings
2969 AC_DEFUN([CF_VERBOSE],
2970 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
2971 CF_MSG_LOG([$1])
2972 ])dnl
2973 dnl ---------------------------------------------------------------------------
2974 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
2975 dnl -------------
2976 dnl Check if type wide-character type $1 is declared, and if so, which header
2977 dnl file is needed.  The second parameter is used to set a shell variable when
2978 dnl the type is not found.  The first parameter sets a shell variable for the
2979 dnl opposite sense.
2980 AC_DEFUN([CF_WCHAR_TYPE],
2981 [
2982 # This is needed on Tru64 5.0 to declare $1
2983 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
2984 AC_TRY_COMPILE([
2985 #include <stdlib.h>
2986 #include <stdarg.h>
2987 #include <stdio.h>
2988 #ifdef HAVE_LIBUTF8_H
2989 #include <libutf8.h>
2990 #endif],
2991         [$1 state],
2992         [cf_cv_$1=no],
2993         [AC_TRY_COMPILE([
2994 #include <stdlib.h>
2995 #include <stdarg.h>
2996 #include <stdio.h>
2997 #include <wchar.h>
2998 #ifdef HAVE_LIBUTF8_H
2999 #include <libutf8.h>
3000 #endif],
3001         [$1 value],
3002         [cf_cv_$1=yes],
3003         [cf_cv_$1=unknown])])])
3004
3005 if test "$cf_cv_$1" = yes ; then
3006         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
3007         NEED_WCHAR_H=1
3008 fi
3009
3010 ifelse([$2],,,[
3011 # if we do not find $1 in either place, use substitution to provide a fallback.
3012 if test "$cf_cv_$1" = unknown ; then
3013         $2=1
3014 fi
3015 ])
3016 ifelse($3,,,[
3017 # if we find $1 in either place, use substitution to provide a fallback.
3018 if test "$cf_cv_$1" != unknown ; then
3019         $3=1
3020 fi
3021 ])
3022 ])dnl
3023 dnl ---------------------------------------------------------------------------
3024 dnl CF_WITH_CURSES_DIR version: 3 updated: 2010/11/20 17:02:38
3025 dnl ------------------
3026 dnl Wrapper for AC_ARG_WITH to specify directory under which to look for curses
3027 dnl libraries.
3028 AC_DEFUN([CF_WITH_CURSES_DIR],[
3029
3030 AC_MSG_CHECKING(for specific curses-directory)
3031 AC_ARG_WITH(curses-dir,
3032         [  --with-curses-dir=DIR   directory in which (n)curses is installed],
3033         [cf_cv_curses_dir=$withval],
3034         [cf_cv_curses_dir=no])
3035 AC_MSG_RESULT($cf_cv_curses_dir)
3036
3037 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
3038 then
3039         CF_PATH_SYNTAX(withval)
3040         if test -d "$cf_cv_curses_dir"
3041         then
3042                 CF_ADD_INCDIR($cf_cv_curses_dir/include)
3043                 CF_ADD_LIBDIR($cf_cv_curses_dir/lib)
3044         fi
3045 fi
3046 ])dnl
3047 dnl ---------------------------------------------------------------------------
3048 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
3049 dnl ----------------
3050 dnl Configure-option for dbmalloc.  The optional parameter is used to override
3051 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
3052 AC_DEFUN([CF_WITH_DBMALLOC],[
3053 CF_NO_LEAKS_OPTION(dbmalloc,
3054         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
3055         [USE_DBMALLOC])
3056
3057 if test "$with_dbmalloc" = yes ; then
3058         AC_CHECK_HEADER(dbmalloc.h,
3059                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
3060 fi
3061 ])dnl
3062 dnl ---------------------------------------------------------------------------
3063 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
3064 dnl ---------------
3065 dnl Configure-option for dmalloc.  The optional parameter is used to override
3066 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
3067 AC_DEFUN([CF_WITH_DMALLOC],[
3068 CF_NO_LEAKS_OPTION(dmalloc,
3069         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
3070         [USE_DMALLOC])
3071
3072 if test "$with_dmalloc" = yes ; then
3073         AC_CHECK_HEADER(dmalloc.h,
3074                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
3075 fi
3076 ])dnl
3077 dnl ---------------------------------------------------------------------------
3078 dnl CF_WITH_NCURSES_ETC version: 2 updated: 2012/01/13 10:49:00
3079 dnl -------------------
3080 dnl Use this macro for programs which use any variant of "curses", e.g.,
3081 dnl "ncurses", and "PDCurses".  Programs that can use curses and some unrelated
3082 dnl library (such as slang) should use a "--with-screen=XXX" option.
3083 dnl
3084 dnl This does not use AC_DEFUN, because that would tell autoconf to run each
3085 dnl of the macros inside this one - before this macro.
3086 define([CF_WITH_NCURSES_ETC],[
3087 CF_WITH_CURSES_DIR
3088
3089 cf_cv_screen=curses
3090
3091 AC_MSG_CHECKING(for specified curses library type)
3092 AC_ARG_WITH(ncursesw,
3093         [  --with-ncursesw         use wide ncurses-libraries],
3094         [cf_cv_screen=ncursesw],[
3095
3096 AC_ARG_WITH(ncurses,
3097         [  --with-ncurses          use ncurses-libraries],
3098         [cf_cv_screen=ncurses],[
3099
3100 AC_ARG_WITH(pdcurses,
3101         [  --with-pdcurses         compile/link with pdcurses X11 library],
3102         [cf_cv_screen=pdcurses],[
3103
3104 AC_ARG_WITH(curses-colr,
3105         [  --with-curses-colr      compile/link with HPUX 10.x color-curses],
3106         [cf_cv_screen=curses_colr],[
3107
3108 AC_ARG_WITH(curses-5lib,
3109         [  --with-curses-5lib      compile/link with SunOS 5lib curses],
3110         [cf_cv_screen=curses_5lib])])])])])
3111
3112 AC_MSG_RESULT($cf_cv_screen)
3113
3114 case $cf_cv_screen in #(vi
3115 curses|curses_*) #(vi
3116         CF_CURSES_CONFIG
3117         ;;
3118 ncurses) #(vi
3119         CF_NCURSES_CONFIG
3120         ;;
3121 ncursesw) #(vi
3122         CF_UTF8_LIB
3123         CF_NCURSES_CONFIG(ncursesw)
3124         ;;
3125 pdcurses)
3126         CF_PDCURSES_X11
3127         ;;
3128 esac
3129
3130 ])dnl
3131 dnl ---------------------------------------------------------------------------
3132 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
3133 dnl ----------------
3134 AC_DEFUN([CF_WITH_VALGRIND],[
3135 CF_NO_LEAKS_OPTION(valgrind,
3136         [  --with-valgrind         test: use valgrind],
3137         [USE_VALGRIND])
3138 ])dnl
3139 dnl ---------------------------------------------------------------------------
3140 dnl CF_XOPEN_CURSES version: 11 updated: 2011/01/18 18:15:30
3141 dnl ---------------
3142 dnl Test if we should define X/Open source for curses, needed on Digital Unix
3143 dnl 4.x, to see the extended functions, but breaks on IRIX 6.x.
3144 dnl
3145 dnl The getbegyx() check is needed for HPUX, which omits legacy macros such
3146 dnl as getbegy().  The latter is better design, but the former is standard.
3147 AC_DEFUN([CF_XOPEN_CURSES],
3148 [
3149 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
3150 AC_CACHE_CHECK(if we must define _XOPEN_SOURCE_EXTENDED,cf_cv_need_xopen_extension,[
3151 AC_TRY_LINK([
3152 #include <stdlib.h>
3153 #include <${cf_cv_ncurses_header:-curses.h}>],[
3154 #if defined(NCURSES_VERSION_PATCH)
3155 #if (NCURSES_VERSION_PATCH < 20100501) && (NCURSES_VERSION_PATCH >= 20100403)
3156         make an error
3157 #endif
3158 #endif
3159         long x = winnstr(stdscr, "", 0);
3160         int x1, y1;
3161         getbegyx(stdscr, y1, x1)],
3162         [cf_cv_need_xopen_extension=no],
3163         [AC_TRY_LINK([
3164 #define _XOPEN_SOURCE_EXTENDED
3165 #include <stdlib.h>
3166 #include <${cf_cv_ncurses_header:-curses.h}>],[
3167 #ifdef NCURSES_VERSION
3168         cchar_t check;
3169         int check2 = curs_set((int)sizeof(check));
3170 #endif
3171         long x = winnstr(stdscr, "", 0);
3172         int x1, y1;
3173         getbegyx(stdscr, y1, x1)],
3174         [cf_cv_need_xopen_extension=yes],
3175         [cf_cv_need_xopen_extension=unknown])])])
3176 test $cf_cv_need_xopen_extension = yes && CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED"
3177 ])dnl
3178 dnl ---------------------------------------------------------------------------
3179 dnl CF_XOPEN_SOURCE version: 45 updated: 2013/09/07 14:06:25
3180 dnl ---------------
3181 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
3182 dnl or adapt to the vendor's definitions to get equivalent functionality,
3183 dnl without losing the common non-POSIX features.
3184 dnl
3185 dnl Parameters:
3186 dnl     $1 is the nominal value for _XOPEN_SOURCE
3187 dnl     $2 is the nominal value for _POSIX_C_SOURCE
3188 AC_DEFUN([CF_XOPEN_SOURCE],[
3189 AC_REQUIRE([AC_CANONICAL_HOST])
3190
3191 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
3192 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
3193 cf_xopen_source=
3194
3195 case $host_os in #(vi
3196 aix[[4-7]]*) #(vi
3197         cf_xopen_source="-D_ALL_SOURCE"
3198         ;;
3199 cygwin|msys) #(vi
3200         cf_XOPEN_SOURCE=600
3201         ;;
3202 darwin[[0-8]].*) #(vi
3203         cf_xopen_source="-D_APPLE_C_SOURCE"
3204         ;;
3205 darwin*) #(vi
3206         cf_xopen_source="-D_DARWIN_C_SOURCE"
3207         cf_XOPEN_SOURCE=
3208         ;;
3209 freebsd*|dragonfly*) #(vi
3210         # 5.x headers associate
3211         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
3212         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
3213         cf_POSIX_C_SOURCE=200112L
3214         cf_XOPEN_SOURCE=600
3215         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
3216         ;;
3217 hpux11*) #(vi
3218         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
3219         ;;
3220 hpux*) #(vi
3221         cf_xopen_source="-D_HPUX_SOURCE"
3222         ;;
3223 irix[[56]].*) #(vi
3224         cf_xopen_source="-D_SGI_SOURCE"
3225         cf_XOPEN_SOURCE=
3226         ;;
3227 linux*|gnu*|mint*|k*bsd*-gnu) #(vi
3228         CF_GNU_SOURCE
3229         ;;
3230 mirbsd*) #(vi
3231         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
3232         cf_XOPEN_SOURCE=
3233         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
3234         ;;
3235 netbsd*) #(vi
3236         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
3237         ;;
3238 openbsd[[4-9]]*) #(vi
3239         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
3240         cf_xopen_source="-D_BSD_SOURCE"
3241         cf_XOPEN_SOURCE=600
3242         ;;
3243 openbsd*) #(vi
3244         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
3245         ;;
3246 osf[[45]]*) #(vi
3247         cf_xopen_source="-D_OSF_SOURCE"
3248         ;;
3249 nto-qnx*) #(vi
3250         cf_xopen_source="-D_QNX_SOURCE"
3251         ;;
3252 sco*) #(vi
3253         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
3254         ;;
3255 solaris2.*) #(vi
3256         cf_xopen_source="-D__EXTENSIONS__"
3257         ;;
3258 *)
3259         CF_TRY_XOPEN_SOURCE
3260         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
3261         ;;
3262 esac
3263
3264 if test -n "$cf_xopen_source" ; then
3265         CF_ADD_CFLAGS($cf_xopen_source)
3266 fi
3267
3268 dnl In anything but the default case, we may have system-specific setting
3269 dnl which is still not guaranteed to provide all of the entrypoints that
3270 dnl _XOPEN_SOURCE would yield.
3271 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
3272         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
3273         AC_TRY_COMPILE([#include <stdlib.h>],[
3274 #ifndef _XOPEN_SOURCE
3275 make an error
3276 #endif],
3277         [cf_XOPEN_SOURCE_set=yes],
3278         [cf_XOPEN_SOURCE_set=no])
3279         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
3280         if test $cf_XOPEN_SOURCE_set = yes
3281         then
3282                 AC_TRY_COMPILE([#include <stdlib.h>],[
3283 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
3284 make an error
3285 #endif],
3286                 [cf_XOPEN_SOURCE_set_ok=yes],
3287                 [cf_XOPEN_SOURCE_set_ok=no])
3288                 if test $cf_XOPEN_SOURCE_set_ok = no
3289                 then
3290                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
3291                 fi
3292         else
3293                 CF_TRY_XOPEN_SOURCE
3294         fi
3295 fi
3296 ])
3297 dnl ---------------------------------------------------------------------------
3298 dnl CF_X_ATHENA version: 21 updated: 2013/07/06 21:27:06
3299 dnl -----------
3300 dnl Check for Xaw (Athena) libraries
3301 dnl
3302 dnl Sets $cf_x_athena according to the flavor of Xaw which is used.
3303 AC_DEFUN([CF_X_ATHENA],
3304 [
3305 cf_x_athena=${cf_x_athena:-Xaw}
3306
3307 AC_MSG_CHECKING(if you want to link with Xaw 3d library)
3308 withval=
3309 AC_ARG_WITH(Xaw3d,
3310         [  --with-Xaw3d            link with Xaw 3d library])
3311 if test "$withval" = yes ; then
3312         cf_x_athena=Xaw3d
3313         AC_MSG_RESULT(yes)
3314 else
3315         AC_MSG_RESULT(no)
3316 fi
3317
3318 AC_MSG_CHECKING(if you want to link with neXT Athena library)
3319 withval=
3320 AC_ARG_WITH(neXtaw,
3321         [  --with-neXtaw           link with neXT Athena library])
3322 if test "$withval" = yes ; then
3323         cf_x_athena=neXtaw
3324         AC_MSG_RESULT(yes)
3325 else
3326         AC_MSG_RESULT(no)
3327 fi
3328
3329 AC_MSG_CHECKING(if you want to link with Athena-Plus library)
3330 withval=
3331 AC_ARG_WITH(XawPlus,
3332         [  --with-XawPlus          link with Athena-Plus library])
3333 if test "$withval" = yes ; then
3334         cf_x_athena=XawPlus
3335         AC_MSG_RESULT(yes)
3336 else
3337         AC_MSG_RESULT(no)
3338 fi
3339
3340 cf_x_athena_lib=""
3341
3342 if test "$PKG_CONFIG" != none ; then
3343         cf_athena_list=
3344         test "$cf_x_athena" = Xaw && cf_athena_list="xaw8 xaw7 xaw6"
3345         for cf_athena_pkg in \
3346                 $cf_athena_list \
3347                 ${cf_x_athena} \
3348                 ${cf_x_athena}-devel \
3349                 lib${cf_x_athena} \
3350                 lib${cf_x_athena}-devel
3351         do
3352                 CF_TRY_PKG_CONFIG($cf_athena_pkg,[
3353                         cf_x_athena_lib="$cf_pkgconfig_libs"
3354                         CF_UPPER(cf_x_athena_LIBS,HAVE_LIB_$cf_x_athena)
3355                         AC_DEFINE_UNQUOTED($cf_x_athena_LIBS)
3356
3357                         CF_TRIM_X_LIBS
3358
3359 AC_CACHE_CHECK(for usable $cf_x_athena/Xmu package,cf_cv_xaw_compat,[
3360 AC_TRY_LINK([
3361 #include <X11/Xmu/CharSet.h>
3362 ],[
3363 int check = XmuCompareISOLatin1("big", "small")
3364 ],[cf_cv_xaw_compat=yes],[cf_cv_xaw_compat=no])])
3365
3366                         if test "$cf_cv_xaw_compat" = no
3367                         then
3368                                 # workaround for broken ".pc" files...
3369                                 case "$cf_x_athena_lib" in #(vi
3370                                 *-lXmu*) #(vi
3371                                         ;;
3372                                 *)
3373                                         CF_VERBOSE(work around broken package)
3374                                         cf_save_xmu="$LIBS"
3375                                         cf_first_lib=`echo "$cf_save_xmu" | sed -e 's/^[ ][ ]*//' -e 's/ .*//'`
3376                                         CF_TRY_PKG_CONFIG(xmu,[
3377                                                         LIBS="$cf_save_xmu"
3378                                                         CF_ADD_LIB_AFTER($cf_first_lib,$cf_pkgconfig_libs)
3379                                                 ],[
3380                                                         CF_ADD_LIB_AFTER($cf_first_lib,-lXmu)
3381                                                 ])
3382                                         CF_TRIM_X_LIBS
3383                                         ;;
3384                                 esac
3385                         fi
3386
3387                         break])
3388         done
3389 fi
3390
3391 if test -z "$cf_x_athena_lib" ; then
3392         CF_X_EXT
3393         CF_X_TOOLKIT
3394         CF_X_ATHENA_CPPFLAGS($cf_x_athena)
3395         CF_X_ATHENA_LIBS($cf_x_athena)
3396 fi
3397 ])dnl
3398 dnl ---------------------------------------------------------------------------
3399 dnl CF_X_ATHENA_CPPFLAGS version: 5 updated: 2010/05/26 17:35:30
3400 dnl --------------------
3401 dnl Normally invoked by CF_X_ATHENA, with $1 set to the appropriate flavor of
3402 dnl the Athena widgets, e.g., Xaw, Xaw3d, neXtaw.
3403 AC_DEFUN([CF_X_ATHENA_CPPFLAGS],
3404 [
3405 cf_x_athena_root=ifelse([$1],,Xaw,[$1])
3406 cf_x_athena_inc=""
3407
3408 for cf_path in default \
3409         /usr/contrib/X11R6 \
3410         /usr/contrib/X11R5 \
3411         /usr/lib/X11R5 \
3412         /usr/local
3413 do
3414         if test -z "$cf_x_athena_inc" ; then
3415                 cf_save="$CPPFLAGS"
3416                 cf_test=X11/$cf_x_athena_root/SimpleMenu.h
3417                 if test $cf_path != default ; then
3418                         CPPFLAGS="$cf_save -I$cf_path/include"
3419                         AC_MSG_CHECKING(for $cf_test in $cf_path)
3420                 else
3421                         AC_MSG_CHECKING(for $cf_test)
3422                 fi
3423                 AC_TRY_COMPILE([
3424 #include <X11/Intrinsic.h>
3425 #include <$cf_test>],[],
3426                         [cf_result=yes],
3427                         [cf_result=no])
3428                 AC_MSG_RESULT($cf_result)
3429                 if test "$cf_result" = yes ; then
3430                         cf_x_athena_inc=$cf_path
3431                         break
3432                 else
3433                         CPPFLAGS="$cf_save"
3434                 fi
3435         fi
3436 done
3437
3438 if test -z "$cf_x_athena_inc" ; then
3439         AC_MSG_WARN(
3440 [Unable to successfully find Athena header files with test program])
3441 elif test "$cf_x_athena_inc" != default ; then
3442         CPPFLAGS="$CPPFLAGS -I$cf_x_athena_inc"
3443 fi
3444 ])
3445 dnl ---------------------------------------------------------------------------
3446 dnl CF_X_ATHENA_LIBS version: 12 updated: 2011/07/17 19:55:02
3447 dnl ----------------
3448 dnl Normally invoked by CF_X_ATHENA, with $1 set to the appropriate flavor of
3449 dnl the Athena widgets, e.g., Xaw, Xaw3d, neXtaw.
3450 AC_DEFUN([CF_X_ATHENA_LIBS],
3451 [AC_REQUIRE([CF_X_TOOLKIT])
3452 cf_x_athena_root=ifelse([$1],,Xaw,[$1])
3453 cf_x_athena_lib=""
3454
3455 for cf_path in default \
3456         /usr/contrib/X11R6 \
3457         /usr/contrib/X11R5 \
3458         /usr/lib/X11R5 \
3459         /usr/local
3460 do
3461         for cf_lib in \
3462                 ${cf_x_athena_root} \
3463                 ${cf_x_athena_root}7 \
3464                 ${cf_x_athena_root}6
3465         do
3466         for cf_libs in \
3467                 "-l$cf_lib -lXmu" \
3468                 "-l$cf_lib -lXpm -lXmu" \
3469                 "-l${cf_lib}_s -lXmu_s"
3470         do
3471                 if test -z "$cf_x_athena_lib" ; then
3472                         cf_save="$LIBS"
3473                         cf_test=XawSimpleMenuAddGlobalActions
3474                         if test $cf_path != default ; then
3475                                 CF_ADD_LIBS(-L$cf_path/lib $cf_libs)
3476                                 AC_MSG_CHECKING(for $cf_libs in $cf_path)
3477                         else
3478                                 CF_ADD_LIBS($cf_libs)
3479                                 AC_MSG_CHECKING(for $cf_test in $cf_libs)
3480                         fi
3481                         AC_TRY_LINK([
3482 #include <X11/Intrinsic.h>
3483 #include <X11/$cf_x_athena_root/SimpleMenu.h>
3484 ],[
3485 $cf_test((XtAppContext) 0)],
3486                                 [cf_result=yes],
3487                                 [cf_result=no])
3488                         AC_MSG_RESULT($cf_result)
3489                         if test "$cf_result" = yes ; then
3490                                 cf_x_athena_lib="$cf_libs"
3491                                 break
3492                         fi
3493                         LIBS="$cf_save"
3494                 fi
3495         done # cf_libs
3496                 test -n "$cf_x_athena_lib" && break
3497         done # cf_lib
3498 done
3499
3500 if test -z "$cf_x_athena_lib" ; then
3501         AC_MSG_ERROR(
3502 [Unable to successfully link Athena library (-l$cf_x_athena_root) with test program])
3503 fi
3504
3505 CF_UPPER(cf_x_athena_LIBS,HAVE_LIB_$cf_x_athena)
3506 AC_DEFINE_UNQUOTED($cf_x_athena_LIBS)
3507 ])
3508 dnl ---------------------------------------------------------------------------
3509 dnl CF_X_EXT version: 3 updated: 2010/06/02 05:03:05
3510 dnl --------
3511 AC_DEFUN([CF_X_EXT],[
3512 CF_TRY_PKG_CONFIG(Xext,,[
3513         AC_CHECK_LIB(Xext,XextCreateExtension,
3514                 [CF_ADD_LIB(Xext)])])
3515 ])dnl
3516 dnl ---------------------------------------------------------------------------
3517 dnl CF_X_TOOLKIT version: 21 updated: 2012/10/04 06:57:36
3518 dnl ------------
3519 dnl Check for X Toolkit libraries
3520 dnl
3521 AC_DEFUN([CF_X_TOOLKIT],
3522 [
3523 AC_REQUIRE([AC_PATH_XTRA])
3524 AC_REQUIRE([CF_CHECK_CACHE])
3525
3526 cf_have_X_LIBS=no
3527
3528 CF_TRY_PKG_CONFIG(xt,[
3529
3530         case "x$LIBS" in #(vi
3531         *-lX11*) #(vi
3532                 ;;
3533         *)
3534 # we have an "xt" package, but it may omit Xt's dependency on X11
3535 AC_CACHE_CHECK(for usable X dependency,cf_cv_xt_x11_compat,[
3536 AC_TRY_LINK([
3537 #include <X11/Xlib.h>
3538 ],[
3539         int rc1 = XDrawLine((Display*) 0, (Drawable) 0, (GC) 0, 0, 0, 0, 0);
3540         int rc2 = XClearWindow((Display*) 0, (Window) 0);
3541         int rc3 = XMoveWindow((Display*) 0, (Window) 0, 0, 0);
3542         int rc4 = XMoveResizeWindow((Display*)0, (Window)0, 0, 0, 0, 0);
3543 ],[cf_cv_xt_x11_compat=yes],[cf_cv_xt_x11_compat=no])])
3544                 if test "$cf_cv_xt_x11_compat" = no
3545                 then
3546                         CF_VERBOSE(work around broken X11 dependency)
3547                         # 2010/11/19 - good enough until a working Xt on Xcb is delivered.
3548                         CF_TRY_PKG_CONFIG(x11,,[CF_ADD_LIB_AFTER(-lXt,-lX11)])
3549                 fi
3550                 ;;
3551         esac
3552
3553 AC_CACHE_CHECK(for usable X Toolkit package,cf_cv_xt_ice_compat,[
3554 AC_TRY_LINK([
3555 #include <X11/Shell.h>
3556 ],[int num = IceConnectionNumber(0)
3557 ],[cf_cv_xt_ice_compat=yes],[cf_cv_xt_ice_compat=no])])
3558
3559         if test "$cf_cv_xt_ice_compat" = no
3560         then
3561                 # workaround for broken ".pc" files used for X Toolkit.
3562                 case "x$X_PRE_LIBS" in #(vi
3563                 *-lICE*)
3564                         case "x$LIBS" in #(vi
3565                         *-lICE*) #(vi
3566                                 ;;
3567                         *)
3568                                 CF_VERBOSE(work around broken ICE dependency)
3569                                 CF_TRY_PKG_CONFIG(ice,
3570                                         [CF_TRY_PKG_CONFIG(sm)],
3571                                         [CF_ADD_LIB_AFTER(-lXt,$X_PRE_LIBS)])
3572                                 ;;
3573                         esac
3574                         ;;
3575                 esac
3576         fi
3577
3578         cf_have_X_LIBS=yes
3579 ],[
3580
3581         LDFLAGS="$X_LIBS $LDFLAGS"
3582         CF_CHECK_CFLAGS($X_CFLAGS)
3583
3584         AC_CHECK_FUNC(XOpenDisplay,,[
3585         AC_CHECK_LIB(X11,XOpenDisplay,
3586                 [CF_ADD_LIB(X11)],,
3587                 [$X_PRE_LIBS $LIBS $X_EXTRA_LIBS])])
3588
3589         AC_CHECK_FUNC(XtAppInitialize,,[
3590         AC_CHECK_LIB(Xt, XtAppInitialize,
3591                 [AC_DEFINE(HAVE_LIBXT,1,[Define to 1 if we can compile with the Xt library])
3592                  cf_have_X_LIBS=Xt
3593                  LIBS="-lXt $X_PRE_LIBS $LIBS $X_EXTRA_LIBS"],,
3594                 [$X_PRE_LIBS $LIBS $X_EXTRA_LIBS])])
3595 ])
3596
3597 if test $cf_have_X_LIBS = no ; then
3598         AC_MSG_WARN(
3599 [Unable to successfully link X Toolkit library (-lXt) with
3600 test program.  You will have to check and add the proper libraries by hand
3601 to makefile.])
3602 fi
3603 ])dnl
3604 dnl ---------------------------------------------------------------------------
3605 dnl CF__CURSES_HEAD version: 2 updated: 2010/10/23 15:54:49
3606 dnl ---------------
3607 dnl Define a reusable chunk which includes <curses.h> and <term.h> when they
3608 dnl are both available.
3609 define([CF__CURSES_HEAD],[
3610 #ifdef HAVE_XCURSES
3611 #include <xcurses.h>
3612 char * XCursesProgramName = "test";
3613 #else
3614 #include <${cf_cv_ncurses_header:-curses.h}>
3615 #if defined(NCURSES_VERSION) && defined(HAVE_NCURSESW_TERM_H)
3616 #include <ncursesw/term.h>
3617 #elif defined(NCURSES_VERSION) && defined(HAVE_NCURSES_TERM_H)
3618 #include <ncurses/term.h>
3619 #elif defined(HAVE_TERM_H)
3620 #include <term.h>
3621 #endif
3622 #endif
3623 ])