test/aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2022,2023 Thomas E. Dickey                                *
   3 dnl Copyright 2003-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl $Id: aclocal.m4,v 1.218 2023/10/28 16:08:26 tom Exp $
  31 dnl
  32 dnl Author: Thomas E. Dickey
  33 dnl
  34 dnl Macros used in NCURSES test programs auto-configuration script.
  35 dnl
  36 dnl These macros are maintained separately from NCURSES.  The copyright on
  37 dnl this file applies to the aggregation of macros and does not affect use of
  38 dnl these macros in other applications.
  39 dnl
  40 dnl See these pages for additional information:
  41 dnl             https://invisible-island.net/autoconf/
  42 dnl             https://invisible-island.net/autoconf/my-autoconf.html
  43 dnl
  44 dnl ---------------------------------------------------------------------------
  45 dnl ---------------------------------------------------------------------------
  46 dnl AM_LANGINFO_CODESET version: 7 updated: 2023/01/11 04:05:23
  47 dnl -------------------
  48 dnl Inserted as requested by gettext 0.10.40
  49 dnl File from /usr/share/aclocal
  50 dnl codeset.m4
  51 dnl ====================
  52 dnl serial AM1
  53 dnl
  54 dnl From Bruno Haible.
  55 AC_DEFUN([AM_LANGINFO_CODESET],
  56 [
  57 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  58         [AC_TRY_LINK([
  59 $ac_includes_default
  60 #include <langinfo.h>],
  61         [char* cs = nl_langinfo(CODESET); (void)cs],
  62         am_cv_langinfo_codeset=yes,
  63         am_cv_langinfo_codeset=no)
  64         ])
  65         if test "$am_cv_langinfo_codeset" = yes; then
  66                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  67                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  68         fi
  69 ])dnl
  70 dnl ---------------------------------------------------------------------------
  71 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
  72 dnl ------------------
  73 dnl Conditionally generate script according to whether we're using a given autoconf.
  74 dnl
  75 dnl $1 = version to compare against
  76 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  77 dnl $3 = code to use if AC_ACVERSION is older than $1.
  78 define([CF_ACVERSION_CHECK],
  79 [
  80 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
  81 ifdef([m4_version_compare],
  82 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  83 [CF_ACVERSION_COMPARE(
  84 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  85 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  86 dnl ---------------------------------------------------------------------------
  87 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
  88 dnl --------------------
  89 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  90 dnl                      MAJOR2, MINOR2, TERNARY2,
  91 dnl                      PRINTABLE2, not FOUND, FOUND)
  92 define([CF_ACVERSION_COMPARE],
  93 [ifelse(builtin([eval], [$2 < $5]), 1,
  94 [ifelse([$8], , ,[$8])],
  95 [ifelse([$9], , ,[$9])])])dnl
  96 dnl ---------------------------------------------------------------------------
  97 dnl CF_ADD_CFLAGS version: 15 updated: 2020/12/31 10:54:15
  98 dnl -------------
  99 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 100 dnl $1 = flags to add
 101 dnl $2 = if given makes this macro verbose.
 102 dnl
 103 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 104 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 105 dnl confused by the quotes (which require backslashes to keep them usable).
 106 AC_DEFUN([CF_ADD_CFLAGS],
 107 [
 108 cf_fix_cppflags=no
 109 cf_new_cflags=
 110 cf_new_cppflags=
 111 cf_new_extra_cppflags=
 112
 113 for cf_add_cflags in $1
 114 do
 115 case "$cf_fix_cppflags" in
 116 (no)
 117         case "$cf_add_cflags" in
 118         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 119                 case "$cf_add_cflags" in
 120                 (-D*)
 121                         cf_tst_cflags=`echo "${cf_add_cflags}" |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 122
 123                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 124                                 && test -z "${cf_tst_cflags}" \
 125                                 && cf_fix_cppflags=yes
 126
 127                         if test "$cf_fix_cppflags" = yes ; then
 128                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 129                                 continue
 130                         elif test "${cf_tst_cflags}" = "\"'" ; then
 131                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 132                                 continue
 133                         fi
 134                         ;;
 135                 esac
 136                 case "$CPPFLAGS" in
 137                 (*$cf_add_cflags)
 138                         ;;
 139                 (*)
 140                         case "$cf_add_cflags" in
 141                         (-D*)
 142                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 143                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 144                                 ;;
 145                         esac
 146                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
 147                         ;;
 148                 esac
 149                 ;;
 150         (*)
 151                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
 152                 ;;
 153         esac
 154         ;;
 155 (yes)
 156         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 157
 158         cf_tst_cflags=`echo "${cf_add_cflags}" |sed -e 's/^[[^"]]*"'\''//'`
 159
 160         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 161                 && test -z "${cf_tst_cflags}" \
 162                 && cf_fix_cppflags=no
 163         ;;
 164 esac
 165 done
 166
 167 if test -n "$cf_new_cflags" ; then
 168         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 169         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
 170 fi
 171
 172 if test -n "$cf_new_cppflags" ; then
 173         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 174         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
 175 fi
 176
 177 if test -n "$cf_new_extra_cppflags" ; then
 178         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 179         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
 180 fi
 181
 182 AC_SUBST(EXTRA_CPPFLAGS)
 183
 184 ])dnl
 185 dnl ---------------------------------------------------------------------------
 186 dnl CF_ADD_INCDIR version: 17 updated: 2021/09/04 06:35:04
 187 dnl -------------
 188 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it is
 189 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 190 dnl but old versions (and some misinstalled ones) need that.  To make things
 191 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 192 dnl the include-path).
 193 AC_DEFUN([CF_ADD_INCDIR],
 194 [
 195 if test -n "$1" ; then
 196   for cf_add_incdir in $1
 197   do
 198         while test "$cf_add_incdir" != /usr/include
 199         do
 200           if test -d "$cf_add_incdir"
 201           then
 202                 cf_have_incdir=no
 203                 if test -n "$CFLAGS$CPPFLAGS" ; then
 204                   # a loop is needed to ensure we can add subdirs of existing dirs
 205                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 206                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 207                           cf_have_incdir=yes; break
 208                         fi
 209                   done
 210                 fi
 211
 212                 if test "$cf_have_incdir" = no ; then
 213                   if test "$cf_add_incdir" = /usr/local/include ; then
 214                         if test "$GCC" = yes
 215                         then
 216                           cf_save_CPPFLAGS=$CPPFLAGS
 217                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
 218                           AC_TRY_COMPILE([#include <stdio.h>],
 219                                   [printf("Hello")],
 220                                   [],
 221                                   [cf_have_incdir=yes])
 222                           CPPFLAGS=$cf_save_CPPFLAGS
 223                         fi
 224                   fi
 225                 fi
 226
 227                 if test "$cf_have_incdir" = no ; then
 228                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 229                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 230
 231                   cf_top_incdir=`echo "$cf_add_incdir" | sed -e 's%/include/.*$%/include%'`
 232                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 233                   cf_add_incdir="$cf_top_incdir"
 234                 else
 235                   break
 236                 fi
 237           else
 238                 break
 239           fi
 240         done
 241   done
 242 fi
 243 ])dnl
 244 dnl ---------------------------------------------------------------------------
 245 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 246 dnl ----------
 247 dnl Add a library, used to enforce consistency.
 248 dnl
 249 dnl $1 = library to add, without the "-l"
 250 dnl $2 = variable to update (default $LIBS)
 251 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 252 dnl ---------------------------------------------------------------------------
 253 dnl CF_ADD_LIBDIR version: 11 updated: 2020/12/31 20:19:42
 254 dnl -------------
 255 dnl     Adds to the library-path
 256 dnl
 257 dnl     Some machines have trouble with multiple -L options.
 258 dnl
 259 dnl $1 is the (list of) directory(s) to add
 260 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 261 dnl
 262 AC_DEFUN([CF_ADD_LIBDIR],
 263 [
 264 if test -n "$1" ; then
 265         for cf_add_libdir in $1
 266         do
 267                 if test "$cf_add_libdir" = /usr/lib ; then
 268                         :
 269                 elif test -d "$cf_add_libdir"
 270                 then
 271                         cf_have_libdir=no
 272                         if test -n "$LDFLAGS$LIBS" ; then
 273                                 # a loop is needed to ensure we can add subdirs of existing dirs
 274                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 275                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 276                                                 cf_have_libdir=yes; break
 277                                         fi
 278                                 done
 279                         fi
 280                         if test "$cf_have_libdir" = no ; then
 281                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 282                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 283                         fi
 284                 fi
 285         done
 286 fi
 287 ])dnl
 288 dnl ---------------------------------------------------------------------------
 289 dnl CF_ADD_LIBS version: 3 updated: 2019/11/02 16:47:33
 290 dnl -----------
 291 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 292 dnl prepended to an existing list, since their dependencies are assumed to
 293 dnl already exist in the list.
 294 dnl
 295 dnl $1 = libraries to add, with the "-l", etc.
 296 dnl $2 = variable to update (default $LIBS)
 297 AC_DEFUN([CF_ADD_LIBS],[
 298 cf_add_libs="[$]ifelse($2,,LIBS,[$2])"
 299 # reverse order
 300 cf_add_0lib=
 301 for cf_add_1lib in $1; do cf_add_0lib="$cf_add_1lib $cf_add_0lib"; done
 302 # filter duplicates
 303 for cf_add_1lib in $cf_add_0lib; do
 304         for cf_add_2lib in $cf_add_libs; do
 305                 if test "x$cf_add_1lib" = "x$cf_add_2lib"; then
 306                         cf_add_1lib=
 307                         break
 308                 fi
 309         done
 310         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_1lib $cf_add_libs"
 311 done
 312 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 313 ])dnl
 314 dnl ---------------------------------------------------------------------------
 315 dnl CF_ADD_LIB_AFTER version: 3 updated: 2013/07/09 21:27:22
 316 dnl ----------------
 317 dnl Add a given library after another, e.g., following the one it satisfies a
 318 dnl dependency for.
 319 dnl
 320 dnl $1 = the first library
 321 dnl $2 = its dependency
 322 AC_DEFUN([CF_ADD_LIB_AFTER],[
 323 CF_VERBOSE(...before $LIBS)
 324 LIBS=`echo "$LIBS" | sed -e "s/[[       ]][[    ]]*/ /g" -e "s%$1 %$1 $2 %" -e 's%  % %g'`
 325 CF_VERBOSE(...after  $LIBS)
 326 ])dnl
 327 dnl ---------------------------------------------------------------------------
 328 dnl CF_ADD_SUBDIR_PATH version: 5 updated: 2020/12/31 20:19:42
 329 dnl ------------------
 330 dnl Append to a search-list for a nonstandard header/lib-file
 331 dnl     $1 = the variable to return as result
 332 dnl     $2 = the package name
 333 dnl     $3 = the subdirectory, e.g., bin, include or lib
 334 dnl $4 = the directory under which we will test for subdirectories
 335 dnl $5 = a directory that we do not want $4 to match
 336 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 337 [
 338 test "x$4" != "x$5" && \
 339 test -d "$4" && \
 340 ifelse([$5],NONE,,[{ test -z "$5" || test "x$5" = xNONE || test "x$4" != "x$5"; } &&]) {
 341         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 342         test -d "$4/$3" &&          $1="[$]$1 $4/$3"
 343         test -d "$4/$3/$2" &&       $1="[$]$1 $4/$3/$2"
 344         test -d "$4/$3/$2/$3" &&    $1="[$]$1 $4/$3/$2/$3"
 345         test -d "$4/$2/$3" &&       $1="[$]$1 $4/$2/$3"
 346         test -d "$4/$2/$3/$2" &&    $1="[$]$1 $4/$2/$3/$2"
 347 }
 348 ])dnl
 349 dnl ---------------------------------------------------------------------------
 350 dnl CF_APPEND_CFLAGS version: 3 updated: 2021/09/05 17:25:40
 351 dnl ----------------
 352 dnl Use CF_ADD_CFLAGS after first checking for potential redefinitions.
 353 dnl $1 = flags to add
 354 dnl $2 = if given makes this macro verbose.
 355 define([CF_APPEND_CFLAGS],
 356 [
 357 for cf_add_cflags in $1
 358 do
 359         case "x$cf_add_cflags" in
 360         (x-[[DU]]*)
 361                 CF_REMOVE_CFLAGS($cf_add_cflags,CFLAGS,[$2])
 362                 CF_REMOVE_CFLAGS($cf_add_cflags,CPPFLAGS,[$2])
 363                 ;;
 364         esac
 365         CF_ADD_CFLAGS([$cf_add_cflags],[$2])
 366 done
 367 ])dnl
 368 dnl ---------------------------------------------------------------------------
 369 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
 370 dnl --------------
 371 dnl use this macro for appending text without introducing an extra blank at
 372 dnl the beginning
 373 define([CF_APPEND_TEXT],
 374 [
 375         test -n "[$]$1" && $1="[$]$1 "
 376         $1="[$]{$1}$2"
 377 ])dnl
 378 dnl ---------------------------------------------------------------------------
 379 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 380 dnl --------------
 381 dnl Allow user to disable a normally-on option.
 382 AC_DEFUN([CF_ARG_DISABLE],
 383 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 384 dnl ---------------------------------------------------------------------------
 385 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
 386 dnl -------------
 387 dnl Allow user to enable a normally-off option.
 388 AC_DEFUN([CF_ARG_ENABLE],
 389 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
 390 dnl ---------------------------------------------------------------------------
 391 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 392 dnl -------------
 393 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 394 dnl values.
 395 dnl
 396 dnl Parameters:
 397 dnl $1 = option name
 398 dnl $2 = help-string
 399 dnl $3 = action to perform if option is not default
 400 dnl $4 = action if perform if option is default
 401 dnl $5 = default option value (either 'yes' or 'no')
 402 AC_DEFUN([CF_ARG_OPTION],
 403 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 404         if test "$enableval" != "$5" ; then
 405 ifelse([$3],,[    :]dnl
 406 ,[    $3]) ifelse([$4],,,[
 407         else
 408                 $4])
 409         fi],[enableval=$5 ifelse([$4],,,[
 410         $4
 411 ])dnl
 412 ])])dnl
 413 dnl ---------------------------------------------------------------------------
 414 dnl CF_C11_NORETURN version: 4 updated: 2023/02/18 17:41:25
 415 dnl ---------------
 416 AC_DEFUN([CF_C11_NORETURN],
 417 [
 418 AC_MSG_CHECKING(if you want to use C11 _Noreturn feature)
 419 CF_ARG_ENABLE(stdnoreturn,
 420         [  --enable-stdnoreturn    enable C11 _Noreturn feature for diagnostics],
 421         [enable_stdnoreturn=yes],
 422         [enable_stdnoreturn=no])
 423 AC_MSG_RESULT($enable_stdnoreturn)
 424
 425 if test $enable_stdnoreturn = yes; then
 426 AC_CACHE_CHECK([for C11 _Noreturn feature], cf_cv_c11_noreturn,
 427         [AC_TRY_COMPILE([
 428 $ac_includes_default
 429 #include <stdnoreturn.h>
 430 static _Noreturn void giveup(void) { exit(0); }
 431         ],
 432         [if (feof(stdin)) giveup()],
 433         cf_cv_c11_noreturn=yes,
 434         cf_cv_c11_noreturn=no)
 435         ])
 436 else
 437         cf_cv_c11_noreturn=no,
 438 fi
 439
 440 if test "$cf_cv_c11_noreturn" = yes; then
 441         AC_DEFINE(HAVE_STDNORETURN_H, 1,[Define if <stdnoreturn.h> header is available and working])
 442         AC_DEFINE_UNQUOTED(STDC_NORETURN,_Noreturn,[Define if C11 _Noreturn keyword is supported])
 443         HAVE_STDNORETURN_H=1
 444 else
 445         HAVE_STDNORETURN_H=0
 446 fi
 447
 448 AC_SUBST(HAVE_STDNORETURN_H)
 449 AC_SUBST(STDC_NORETURN)
 450 ])dnl
 451 dnl ---------------------------------------------------------------------------
 452 dnl CF_CC_ENV_FLAGS version: 11 updated: 2023/02/20 11:15:46
 453 dnl ---------------
 454 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 455 dnl into CC.  This will not help with broken scripts that wrap the compiler
 456 dnl with options, but eliminates a more common category of user confusion.
 457 dnl
 458 dnl In particular, it addresses the problem of being able to run the C
 459 dnl preprocessor in a consistent manner.
 460 dnl
 461 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 462 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 463 dnl outweighs that limitation.
 464 AC_DEFUN([CF_CC_ENV_FLAGS],
 465 [
 466 # This should have been defined by AC_PROG_CC
 467 : "${CC:=cc}"
 468
 469 AC_MSG_CHECKING(\$CFLAGS variable)
 470 case "x$CFLAGS" in
 471 (*-[[IUD]]*)
 472         AC_MSG_RESULT(broken)
 473         AC_MSG_WARN(your environment uses the CFLAGS variable to hold CPPFLAGS options)
 474         cf_flags="$CFLAGS"
 475         CFLAGS=
 476         for cf_arg in $cf_flags
 477         do
 478                 CF_ADD_CFLAGS($cf_arg)
 479         done
 480         ;;
 481 (*)
 482         AC_MSG_RESULT(ok)
 483         ;;
 484 esac
 485
 486 AC_MSG_CHECKING(\$CC variable)
 487 case "$CC" in
 488 (*[[\ \ ]]-*)
 489         AC_MSG_RESULT(broken)
 490         AC_MSG_WARN(your environment uses the CC variable to hold CFLAGS/CPPFLAGS options)
 491         # humor him...
 492         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
 493         cf_flags=`echo "$CC" | sed -e "s%^$cf_prog%%"`
 494         CC="$cf_prog"
 495         for cf_arg in $cf_flags
 496         do
 497                 case "x$cf_arg" in
 498                 (x-[[IUDfgOW]]*)
 499                         CF_ADD_CFLAGS($cf_arg)
 500                         ;;
 501                 (*)
 502                         CC="$CC $cf_arg"
 503                         ;;
 504                 esac
 505         done
 506         CF_VERBOSE(resulting CC: '$CC')
 507         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 508         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 509         ;;
 510 (*)
 511         AC_MSG_RESULT(ok)
 512         ;;
 513 esac
 514 ])dnl
 515 dnl ---------------------------------------------------------------------------
 516 dnl CF_CHECK_CACHE version: 13 updated: 2020/12/31 10:54:15
 517 dnl --------------
 518 dnl Check if we're accidentally using a cache from a different machine.
 519 dnl Derive the system name, as a check for reusing the autoconf cache.
 520 dnl
 521 dnl If we've packaged config.guess and config.sub, run that (since it does a
 522 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 523 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 524 dnl which is useful in cross-compiles.
 525 dnl
 526 dnl Note: we would use $ac_config_sub, but that is one of the places where
 527 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 528 AC_DEFUN([CF_CHECK_CACHE],
 529 [
 530 if test -f "$srcdir/config.guess" || test -f "$ac_aux_dir/config.guess" ; then
 531         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 532         system_name="$host_os"
 533 else
 534         system_name="`(uname -s -r) 2>/dev/null`"
 535         if test -z "$system_name" ; then
 536                 system_name="`(hostname) 2>/dev/null`"
 537         fi
 538 fi
 539 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 540 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 541
 542 test -z "$system_name" && system_name="$cf_cv_system_name"
 543 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 544
 545 if test ".$system_name" != ".$cf_cv_system_name" ; then
 546         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 547         AC_MSG_ERROR("Please remove config.cache and try again.")
 548 fi
 549 ])dnl
 550 dnl ---------------------------------------------------------------------------
 551 dnl CF_CHECK_CFLAGS version: 4 updated: 2021/01/02 19:22:58
 552 dnl ---------------
 553 dnl Conditionally add to $CFLAGS and $CPPFLAGS values which are derived from
 554 dnl a build-configuration such as imake.  These have the pitfall that they
 555 dnl often contain compiler-specific options which we cannot use, mixed with
 556 dnl preprocessor options that we usually can.
 557 AC_DEFUN([CF_CHECK_CFLAGS],
 558 [
 559 CF_VERBOSE(checking additions to CFLAGS)
 560 cf_check_cflags="$CFLAGS"
 561 cf_check_cppflags="$CPPFLAGS"
 562 CF_ADD_CFLAGS($1,yes)
 563 if test "x$cf_check_cflags" != "x$CFLAGS" ; then
 564 AC_TRY_LINK([#include <stdio.h>],[printf("Hello world");],,
 565         [CF_VERBOSE(test-compile failed.  Undoing change to \$CFLAGS)
 566          if test "x$cf_check_cppflags" != "x$CPPFLAGS" ; then
 567                  CF_VERBOSE(but keeping change to \$CPPFLAGS)
 568          fi
 569          CFLAGS="$cf_check_cflags"])
 570 fi
 571 ])dnl
 572 dnl ---------------------------------------------------------------------------
 573 dnl CF_CHECK_CURSES_LIB version: 4 updated: 2021/09/05 17:25:40
 574 dnl -------------------
 575 dnl $1 = nominal library name, used also for header lookup
 576 dnl $2 = suffix to append to library name
 577 dnl $3 = function to check for using AC_CHECK_LIB
 578 dnl $4 = optional parameter list for $3
 579 AC_DEFUN([CF_CHECK_CURSES_LIB],
 580 [
 581 AC_REQUIRE([CF_PKG_CONFIG])
 582
 583 cf_have_curses_lib=no
 584
 585 : ${NCURSES_CONFIG_PKG:=none}
 586 if test "x${NCURSES_CONFIG_PKG}" = xnone; then
 587         :
 588 elif test "x${PKG_CONFIG:=none}" != xnone; then
 589         AC_MSG_CHECKING(pkg-config for $1$2)
 590         if "$PKG_CONFIG" --exists "$1$2" ; then
 591                 AC_MSG_RESULT(yes)
 592
 593                 AC_MSG_CHECKING(if the $1$2 package files work)
 594
 595                 cf_save_CFLAGS="$CFLAGS"
 596                 cf_save_CPPFLAGS="$CPPFLAGS"
 597                 cf_save_LIBS="$LIBS"
 598
 599                 CF_APPEND_CFLAGS(`$PKG_CONFIG --cflags "$1$2"`)
 600                 CF_ADD_LIBS(`$PKG_CONFIG --libs "$1$2"`)
 601
 602                 AC_TRY_LINK([#include <$1.h>],
 603                         [(void) $3 ( ]ifelse([$4],,,[[$4]])[ );],
 604                         [AC_TRY_RUN([#include <$1.h>
 605                                 int main(void)
 606                                 { (void) $3 ( ]ifelse([$4],,,[[$4]])[ ); return 0; }],
 607                                 [cf_have_curses_lib=yes],
 608                                 [cf_have_curses_lib=no],
 609                                 [cf_have_curses_lib=maybe])],
 610                         [cf_have_curses_lib=no])
 611                 AC_MSG_RESULT($cf_have_curses_lib)
 612                 test "$cf_have_curses_lib" = maybe && cf_have_curses_lib=yes
 613                 if test "$cf_have_curses_lib" = "yes"
 614                 then
 615                         CF_UPPER(cf_upper,have_lib$1)
 616                         AC_DEFINE_UNQUOTED($cf_upper,1)
 617                 else
 618                         CFLAGS="$cf_save_CFLAGS"
 619                         CPPFLAGS="$cf_save_CPPFLAGS"
 620                         LIBS="$cf_save_LIBS"
 621                 fi
 622         fi
 623 fi
 624 if test "$cf_have_curses_lib" = no; then
 625         AC_CHECK_LIB($1$2,$3,[
 626                 CF_UPPER(cf_upper,have_lib$1)
 627                 CF_ADD_LIBS(-l$1$2)
 628                 AC_DEFINE_UNQUOTED($cf_upper,1)])
 629 fi
 630 ])dnl
 631 dnl ---------------------------------------------------------------------------
 632 dnl CF_CLANG_COMPILER version: 9 updated: 2023/02/18 17:41:25
 633 dnl -----------------
 634 dnl Check if the given compiler is really clang.  clang's C driver defines
 635 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
 636 dnl not ignore some gcc options.
 637 dnl
 638 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
 639 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
 640 dnl the wrappers for gcc and g++ warnings.
 641 dnl
 642 dnl $1 = GCC (default) or GXX
 643 dnl $2 = CLANG_COMPILER (default)
 644 dnl $3 = CFLAGS (default) or CXXFLAGS
 645 AC_DEFUN([CF_CLANG_COMPILER],[
 646 ifelse([$2],,CLANG_COMPILER,[$2])=no
 647
 648 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
 649         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
 650         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
 651         AC_TRY_COMPILE([],[
 652 #ifdef __clang__
 653 #else
 654 #error __clang__ is not defined
 655 #endif
 656 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
 657 ],[])
 658         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
 659         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
 660 fi
 661
 662 CLANG_VERSION=none
 663
 664 if test "x$ifelse([$2],,CLANG_COMPILER,[$2])" = "xyes" ; then
 665         case "$CC" in
 666         (c[[1-9]][[0-9]]|*/c[[1-9]][[0-9]])
 667                 AC_MSG_WARN(replacing broken compiler alias $CC)
 668                 CFLAGS="$CFLAGS -std=`echo "$CC" | sed -e 's%.*/%%'`"
 669                 CC=clang
 670                 ;;
 671         esac
 672
 673         AC_MSG_CHECKING(version of $CC)
 674         CLANG_VERSION="`$CC --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(CLANG[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
 675         test -z "$CLANG_VERSION" && CLANG_VERSION=unknown
 676         AC_MSG_RESULT($CLANG_VERSION)
 677
 678         for cf_clang_opt in \
 679                 -Qunused-arguments \
 680                 -Wno-error=implicit-function-declaration
 681         do
 682                 AC_MSG_CHECKING(if option $cf_clang_opt works)
 683                 cf_save_CFLAGS="$CFLAGS"
 684                 CFLAGS="$CFLAGS $cf_clang_opt"
 685                 AC_TRY_LINK([
 686                         #include <stdio.h>],[
 687                         printf("hello!\\n");],[
 688                         cf_clang_optok=yes],[
 689                         cf_clang_optok=no])
 690                 AC_MSG_RESULT($cf_clang_optok)
 691                 CFLAGS="$cf_save_CFLAGS"
 692                 if test "$cf_clang_optok" = yes; then
 693                         CF_VERBOSE(adding option $cf_clang_opt)
 694                         CF_APPEND_TEXT(CFLAGS,$cf_clang_opt)
 695                 fi
 696         done
 697 fi
 698 ])
 699 dnl ---------------------------------------------------------------------------
 700 dnl CF_CONST_X_STRING version: 7 updated: 2021/06/07 17:39:17
 701 dnl -----------------
 702 dnl The X11R4-X11R6 Xt specification uses an ambiguous String type for most
 703 dnl character-strings.
 704 dnl
 705 dnl It is ambiguous because the specification accommodated the pre-ANSI
 706 dnl compilers bundled by more than one vendor in lieu of providing a standard C
 707 dnl compiler other than by costly add-ons.  Because of this, the specification
 708 dnl did not take into account the use of const for telling the compiler that
 709 dnl string literals would be in readonly memory.
 710 dnl
 711 dnl As a workaround, one could (starting with X11R5) define XTSTRINGDEFINES, to
 712 dnl let the compiler decide how to represent Xt's strings which were #define'd.
 713 dnl That does not solve the problem of using the block of Xt's strings which
 714 dnl are compiled into the library (and is less efficient than one might want).
 715 dnl
 716 dnl Xt specification 7 introduces the _CONST_X_STRING symbol which is used both
 717 dnl when compiling the library and compiling using the library, to tell the
 718 dnl compiler that String is const.
 719 AC_DEFUN([CF_CONST_X_STRING],
 720 [
 721 AC_REQUIRE([AC_PATH_XTRA])
 722
 723 CF_SAVE_XTRA_FLAGS([CF_CONST_X_STRING])
 724
 725 AC_TRY_COMPILE(
 726 [
 727 #include <stdlib.h>
 728 #include <X11/Intrinsic.h>
 729 ],
 730 [String foo = malloc(1); free((void*)foo)],[
 731
 732 AC_CACHE_CHECK(for X11/Xt const-feature,cf_cv_const_x_string,[
 733         AC_TRY_COMPILE(
 734                 [
 735 #define _CONST_X_STRING /* X11R7.8 (perhaps) */
 736 #undef  XTSTRINGDEFINES /* X11R5 and later */
 737 #include <stdlib.h>
 738 #include <X11/Intrinsic.h>
 739                 ],[String foo = malloc(1); *foo = 0],[
 740                         cf_cv_const_x_string=no
 741                 ],[
 742                         cf_cv_const_x_string=yes
 743                 ])
 744 ])
 745
 746 CF_RESTORE_XTRA_FLAGS([CF_CONST_X_STRING])
 747
 748 case "$cf_cv_const_x_string" in
 749 (no)
 750         CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
 751         ;;
 752 (*)
 753         CF_APPEND_TEXT(CPPFLAGS,-D_CONST_X_STRING)
 754         ;;
 755 esac
 756
 757 ])
 758 ])dnl
 759 dnl ---------------------------------------------------------------------------
 760 dnl CF_CURSES_ACS_MAP version: 8 updated: 2021/01/04 19:45:09
 761 dnl -----------------
 762 dnl Check for likely values of acs_map[]:
 763 AC_DEFUN([CF_CURSES_ACS_MAP],
 764 [
 765 AC_REQUIRE([CF_NCURSES_WRAP_PREFIX])dnl
 766 AC_CACHE_CHECK(for alternate character set array, cf_cv_curses_acs_map,[
 767 cf_cv_curses_acs_map=unknown
 768 for name in acs_map _acs_map __acs_map ${NCURSES_WRAP_PREFIX}acs_map
 769 do
 770 AC_TRY_LINK([
 771 #include <${cf_cv_ncurses_header:-curses.h}>
 772 ],[
 773 ${name}['k'] = ACS_PLUS
 774 ],[cf_cv_curses_acs_map=$name; break])
 775 done
 776 ])
 777
 778 test "$cf_cv_curses_acs_map" != unknown && AC_DEFINE_UNQUOTED(CURSES_ACS_ARRAY,$cf_cv_curses_acs_map,[Define as needed to override ncurses prefix _nc_])
 779 ])
 780 dnl ---------------------------------------------------------------------------
 781 dnl CF_CURSES_CHECK_DATA version: 10 updated: 2021/01/04 19:45:09
 782 dnl --------------------
 783 dnl Check if curses.h defines the given data/variable.
 784 dnl Use this after CF_NCURSES_CONFIG or CF_CURSES_CONFIG.
 785 dnl
 786 dnl $1 = data item(s) to check for
 787 dnl $2 = action on success, e.g., "break" to quit checking a series of choices
 788 AC_DEFUN([CF_CURSES_CHECK_DATA],
 789 [
 790 for cf_data in $1
 791 do
 792 AC_MSG_CHECKING(for data $cf_data declaration in ${cf_cv_ncurses_header:-curses.h})
 793
 794 AC_TRY_COMPILE(CF__CURSES_HEAD,
 795 CF__CURSES_DATA(foo,$cf_data)
 796 ,[cf_result=yes
 797 ],[cf_result=no])
 798 AC_MSG_RESULT($cf_result)
 799
 800 if test "$cf_result" = yes ; then
 801         CF_UPPER(cf_result,have_curses_data_$cf_data)
 802         AC_DEFINE_UNQUOTED($cf_result)
 803         ifelse($2,,,[$2])
 804 else
 805         AC_MSG_CHECKING(for data $cf_data in library)
 806         # BSD linkers insist on making weak linkage, but resolve at runtime.
 807         AC_TRY_RUN(CF__CURSES_HEAD
 808 [
 809 extern char $cf_data;
 810 int main(void)
 811 {
 812         ]CF__CURSES_DATA(foo,$cf_data)[
 813         ${cf_cv_main_return:-return}(foo == 0);
 814 }],[cf_result=yes
 815 ],[cf_result=no],[
 816         # cross-compiling
 817         AC_TRY_LINK(CF__CURSES_HEAD
 818 [extern char $cf_data;],[
 819         do {
 820                 ]CF__CURSES_DATA(foo,$cf_data)[
 821                 ${cf_cv_main_return:-return}(foo == 0);
 822         } while (0)
 823 ],[cf_result=yes],[cf_result=no])
 824 ])
 825         AC_MSG_RESULT($cf_result)
 826         if test "$cf_result" = yes ; then
 827                 CF_UPPER(cf_result,decl_curses_data_$cf_data)
 828                 AC_DEFINE_UNQUOTED($cf_result)
 829                 # do not exit loop here, since we prefer system's declarations
 830         fi
 831 fi
 832 done
 833 ])dnl
 834 dnl ---------------------------------------------------------------------------
 835 dnl CF_CURSES_CHECK_TYPE version: 5 updated: 2021/01/04 19:45:09
 836 dnl --------------------
 837 dnl Check if curses.h defines the given type
 838 AC_DEFUN([CF_CURSES_CHECK_TYPE],
 839 [
 840 AC_MSG_CHECKING(for type $1 in ${cf_cv_ncurses_header:-curses.h})
 841 AC_TRY_COMPILE([
 842 #ifndef _XOPEN_SOURCE_EXTENDED
 843 #define _XOPEN_SOURCE_EXTENDED
 844 #endif
 845 #include <${cf_cv_ncurses_header:-curses.h}>],[
 846 $1 foo
 847 ],cf_result=yes,cf_result=no)
 848 AC_MSG_RESULT($cf_result)
 849 if test "$cf_result" = yes ; then
 850         CF_UPPER(cf_result,have_type_$1)
 851         AC_DEFINE_UNQUOTED($cf_result,1,[Define to 1 if we have type $1])
 852 else
 853         AC_DEFINE_UNQUOTED($1,$2,[Define to appropriate type if $1 is not declared])
 854 fi
 855 ])dnl
 856 dnl ---------------------------------------------------------------------------
 857 dnl CF_CURSES_CONFIG version: 2 updated: 2006/10/29 11:06:27
 858 dnl ----------------
 859 dnl Tie together the configure-script macros for curses.  It may be ncurses,
 860 dnl but unless asked, we do not make a special search for ncurses.  However,
 861 dnl still check for the ncurses version number, for use in other macros.
 862 AC_DEFUN([CF_CURSES_CONFIG],
 863 [
 864 CF_CURSES_CPPFLAGS
 865 CF_NCURSES_VERSION
 866 CF_CURSES_LIBS
 867 ])dnl
 868 dnl ---------------------------------------------------------------------------
 869 dnl CF_CURSES_CPPFLAGS version: 14 updated: 2021/01/02 09:31:20
 870 dnl ------------------
 871 dnl Look for the curses headers.
 872 AC_DEFUN([CF_CURSES_CPPFLAGS],[
 873
 874 AC_CACHE_CHECK(for extra include directories,cf_cv_curses_incdir,[
 875 cf_cv_curses_incdir=no
 876 case "$host_os" in
 877 (hpux10.*)
 878         if test "x$cf_cv_screen" = "xcurses_colr"
 879         then
 880                 test -d /usr/include/curses_colr && \
 881                 cf_cv_curses_incdir="-I/usr/include/curses_colr"
 882         fi
 883         ;;
 884 (sunos3*|sunos4*)
 885         if test "x$cf_cv_screen" = "xcurses_5lib"
 886         then
 887                 test -d /usr/5lib && \
 888                 test -d /usr/5include && \
 889                 cf_cv_curses_incdir="-I/usr/5include"
 890         fi
 891         ;;
 892 esac
 893 ])
 894 if test "$cf_cv_curses_incdir" != no
 895 then
 896         CF_APPEND_TEXT(CPPFLAGS,$cf_cv_curses_incdir)
 897 fi
 898
 899 CF_CURSES_HEADER
 900 CF_TERM_HEADER
 901 ])dnl
 902 dnl ---------------------------------------------------------------------------
 903 dnl CF_CURSES_FUNCS version: 20 updated: 2020/12/31 20:19:42
 904 dnl ---------------
 905 dnl Curses-functions are a little complicated, since a lot of them are macros.
 906 AC_DEFUN([CF_CURSES_FUNCS],
 907 [
 908 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
 909 AC_REQUIRE([CF_XOPEN_CURSES])
 910 AC_REQUIRE([CF_CURSES_TERM_H])
 911 AC_REQUIRE([CF_CURSES_UNCTRL_H])
 912 for cf_func in $1
 913 do
 914         CF_UPPER(cf_tr_func,$cf_func)
 915         AC_MSG_CHECKING(for ${cf_func})
 916         CF_MSG_LOG(${cf_func})
 917         AC_CACHE_VAL(cf_cv_func_$cf_func,[
 918                 eval cf_result='$ac_cv_func_'$cf_func
 919                 if test ".$cf_result" != ".no"; then
 920                         AC_TRY_LINK(CF__CURSES_HEAD,
 921                         [
 922 #ifndef ${cf_func}
 923 long foo = (long)(&${cf_func});
 924 fprintf(stderr, "testing linkage of $cf_func:%p\\n", (void *)foo);
 925 if (foo + 1234L > 5678L)
 926         ${cf_cv_main_return:-return}(foo != 0);
 927 #endif
 928                         ],
 929                         [cf_result=yes],
 930                         [cf_result=no])
 931                 fi
 932                 eval 'cf_cv_func_'$cf_func'="$cf_result"'
 933         ])
 934         # use the computed/retrieved cache-value:
 935         eval 'cf_result=$cf_cv_func_'$cf_func
 936         AC_MSG_RESULT($cf_result)
 937         if test "$cf_result" != no; then
 938                 AC_DEFINE_UNQUOTED(HAVE_${cf_tr_func})
 939         fi
 940 done
 941 ])dnl
 942 dnl ---------------------------------------------------------------------------
 943 dnl CF_CURSES_HEADER version: 6 updated: 2022/12/02 20:06:52
 944 dnl ----------------
 945 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
 946 dnl variations of ncurses' installs.
 947 dnl
 948 dnl $1 = ncurses when looking for ncurses, or is empty
 949 AC_DEFUN([CF_CURSES_HEADER],[
 950 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
 951 cf_cv_ncurses_header=none
 952 for cf_header in \
 953         ncurses.h ifelse($1,,,[$1/ncurses.h]) \
 954         curses.h ifelse($1,,,[$1/curses.h]) ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
 955 do
 956 AC_TRY_COMPILE([#include <${cf_header}>],
 957         [initscr(); endwin()],
 958         [cf_cv_ncurses_header=$cf_header; break],[])
 959 done
 960 ])
 961
 962 if test "$cf_cv_ncurses_header" = none ; then
 963         AC_MSG_ERROR(No curses header-files found)
 964 fi
 965
 966 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
 967 AC_CHECK_HEADERS($cf_cv_ncurses_header)
 968 ])dnl
 969 dnl ---------------------------------------------------------------------------
 970 dnl CF_CURSES_LIBS version: 45 updated: 2022/12/02 20:06:52
 971 dnl --------------
 972 dnl Look for the curses libraries.  Older curses implementations may require
 973 dnl termcap/termlib to be linked as well.  Call CF_CURSES_CPPFLAGS first.
 974 AC_DEFUN([CF_CURSES_LIBS],[
 975
 976 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
 977 AC_MSG_CHECKING(if we have identified curses libraries)
 978 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
 979         [initscr(); endwin()],
 980         cf_result=yes,
 981         cf_result=no)
 982 AC_MSG_RESULT($cf_result)
 983
 984 if test "$cf_result" = no ; then
 985 case "$host_os" in
 986 (freebsd*)
 987         AC_CHECK_LIB(mytinfo,tgoto,[CF_ADD_LIBS(-lmytinfo)])
 988         ;;
 989 (hpux10.*)
 990         # Looking at HPUX 10.20, the Hcurses library is the oldest (1997), cur_colr
 991         # next (1998), and xcurses "newer" (2000).  There is no header file for
 992         # Hcurses; the subdirectory curses_colr has the headers (curses.h and
 993         # term.h) for cur_colr
 994         if test "x$cf_cv_screen" = "xcurses_colr"
 995         then
 996                 AC_CHECK_LIB(cur_colr,initscr,[
 997                         CF_ADD_LIBS(-lcur_colr)
 998                         ac_cv_func_initscr=yes
 999                         ],[
1000                 AC_CHECK_LIB(Hcurses,initscr,[
1001                         # HP's header uses __HP_CURSES, but user claims _HP_CURSES.
1002                         CF_ADD_LIBS(-lHcurses)
1003                         CF_APPEND_TEXT(CPPFLAGS,-D__HP_CURSES -D_HP_CURSES)
1004                         ac_cv_func_initscr=yes
1005                         ])])
1006         fi
1007         ;;
1008 (linux*)
1009         case `arch 2>/dev/null` in
1010         (x86_64)
1011                 if test -d /lib64
1012                 then
1013                         CF_ADD_LIBDIR(/lib64)
1014                 else
1015                         CF_ADD_LIBDIR(/lib)
1016                 fi
1017                 ;;
1018         (*)
1019                 CF_ADD_LIBDIR(/lib)
1020                 ;;
1021         esac
1022         ;;
1023 (sunos3*|sunos4*)
1024         if test "x$cf_cv_screen" = "xcurses_5lib"
1025         then
1026                 if test -d /usr/5lib ; then
1027                         CF_ADD_LIBDIR(/usr/5lib)
1028                         CF_ADD_LIBS(-lcurses -ltermcap)
1029                 fi
1030         fi
1031         ac_cv_func_initscr=yes
1032         ;;
1033 esac
1034
1035 if test ".$ac_cv_func_initscr" != .yes ; then
1036         cf_save_LIBS="$LIBS"
1037
1038         if test ".${cf_cv_ncurses_version:-no}" != .no
1039         then
1040                 cf_check_list="ncurses curses cursesX"
1041         else
1042                 cf_check_list="cursesX curses ncurses"
1043         fi
1044
1045         # Check for library containing tgoto.  Do this before curses library
1046         # because it may be needed to link the test-case for initscr.
1047         if test "x$cf_term_lib" = x
1048         then
1049                 AC_CHECK_FUNC(tgoto,[cf_term_lib=predefined],[
1050                         for cf_term_lib in $cf_check_list otermcap termcap tinfo termlib unknown
1051                         do
1052                                 AC_CHECK_LIB($cf_term_lib,tgoto,[
1053                                         : "${cf_nculib_root:=$cf_term_lib}"
1054                                         break
1055                                 ])
1056                         done
1057                 ])
1058         fi
1059
1060         # Check for library containing initscr
1061         test "$cf_term_lib" != predefined && test "$cf_term_lib" != unknown && LIBS="-l$cf_term_lib $cf_save_LIBS"
1062         if test "x$cf_curs_lib" = x
1063         then
1064                 for cf_curs_lib in $cf_check_list xcurses jcurses pdcurses unknown
1065                 do
1066                         LIBS="-l$cf_curs_lib $cf_save_LIBS"
1067                         if test "$cf_term_lib" = unknown || test "$cf_term_lib" = "$cf_curs_lib" ; then
1068                                 AC_MSG_CHECKING(if we can link with $cf_curs_lib library)
1069                                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
1070                                         [initscr()],
1071                                         [cf_result=yes],
1072                                         [cf_result=no])
1073                                 AC_MSG_RESULT($cf_result)
1074                                 test "$cf_result" = yes && break
1075                         elif test "$cf_curs_lib" = "$cf_term_lib" ; then
1076                                 cf_result=no
1077                         elif test "$cf_term_lib" != predefined ; then
1078                                 AC_MSG_CHECKING(if we need both $cf_curs_lib and $cf_term_lib libraries)
1079                                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
1080                                         [initscr(); endwin();],
1081                                         [cf_result=no],
1082                                         [
1083                                         LIBS="-l$cf_curs_lib -l$cf_term_lib $cf_save_LIBS"
1084                                         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
1085                                                 [initscr()],
1086                                                 [cf_result=yes],
1087                                                 [cf_result=error])
1088                                         ])
1089                                 AC_MSG_RESULT($cf_result)
1090                                 test "$cf_result" != error && break
1091                         fi
1092                 done
1093         fi
1094         test "$cf_curs_lib" = unknown && AC_MSG_ERROR(no curses library found)
1095 fi
1096 fi
1097
1098 ])dnl
1099 dnl ---------------------------------------------------------------------------
1100 dnl CF_CURSES_TERM_H version: 15 updated: 2021/01/02 09:31:20
1101 dnl ----------------
1102 dnl SVr4 curses should have term.h as well (where it puts the definitions of
1103 dnl the low-level interface).  This may not be true in old/broken implementations,
1104 dnl as well as in misconfigured systems (e.g., gcc configured for Solaris 2.4
1105 dnl running with Solaris 2.5.1).
1106 AC_DEFUN([CF_CURSES_TERM_H],
1107 [
1108 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
1109
1110 AC_CACHE_CHECK(for term.h, cf_cv_term_header,[
1111
1112 # If we found <ncurses/curses.h>, look for <ncurses/term.h>, but always look
1113 # for <term.h> if we do not find the variant.
1114
1115 cf_header_list="term.h ncurses/term.h ncursesw/term.h"
1116
1117 case "${cf_cv_ncurses_header:-curses.h}" in
1118 (*/*)
1119         cf_header_item=`echo "${cf_cv_ncurses_header:-curses.h}" | sed -e 's%\..*%%' -e 's%/.*%/%'`term.h
1120         cf_header_list="$cf_header_item $cf_header_list"
1121         ;;
1122 esac
1123
1124 for cf_header in $cf_header_list
1125 do
1126         AC_TRY_COMPILE([
1127 #include <${cf_cv_ncurses_header:-curses.h}>
1128 #include <${cf_header}>],
1129         [WINDOW *x; (void)x],
1130         [cf_cv_term_header=$cf_header
1131          break],
1132         [cf_cv_term_header=no])
1133 done
1134
1135 case "$cf_cv_term_header" in
1136 (no)
1137         # If curses is ncurses, some packagers still mess it up by trying to make
1138         # us use GNU termcap.  This handles the most common case.
1139         for cf_header in ncurses/term.h ncursesw/term.h
1140         do
1141                 AC_TRY_COMPILE([
1142 #include <${cf_cv_ncurses_header:-curses.h}>
1143 #ifdef NCURSES_VERSION
1144 #include <${cf_header}>
1145 #else
1146 make an error
1147 #endif],
1148                         [WINDOW *x; (void)x],
1149                         [cf_cv_term_header=$cf_header
1150                          break],
1151                         [cf_cv_term_header=no])
1152         done
1153         ;;
1154 esac
1155 ])
1156
1157 case "$cf_cv_term_header" in
1158 (term.h)
1159         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
1160         ;;
1161 (ncurses/term.h)
1162         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
1163         ;;
1164 (ncursesw/term.h)
1165         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
1166         ;;
1167 esac
1168 ])dnl
1169 dnl ---------------------------------------------------------------------------
1170 dnl CF_CURSES_UNCTRL_H version: 8 updated: 2021/01/02 09:31:20
1171 dnl ------------------
1172 dnl Any X/Open curses implementation must have unctrl.h, but ncurses packages
1173 dnl may put it in a subdirectory (along with ncurses' other headers, of
1174 dnl course).  Packages which put the headers in inconsistent locations are
1175 dnl broken).
1176 AC_DEFUN([CF_CURSES_UNCTRL_H],
1177 [
1178 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
1179
1180 AC_CACHE_CHECK(for unctrl.h, cf_cv_unctrl_header,[
1181
1182 # If we found <ncurses/curses.h>, look for <ncurses/unctrl.h>, but always look
1183 # for <unctrl.h> if we do not find the variant.
1184
1185 cf_header_list="unctrl.h ncurses/unctrl.h ncursesw/unctrl.h"
1186
1187 case "${cf_cv_ncurses_header:-curses.h}" in
1188 (*/*)
1189         cf_header_item=`echo "${cf_cv_ncurses_header:-curses.h}" | sed -e 's%\..*%%' -e 's%/.*%/%'`unctrl.h
1190         cf_header_list="$cf_header_item $cf_header_list"
1191         ;;
1192 esac
1193
1194 for cf_header in $cf_header_list
1195 do
1196         AC_TRY_COMPILE([
1197 #include <${cf_cv_ncurses_header:-curses.h}>
1198 #include <${cf_header}>],
1199         [WINDOW *x; (void)x],
1200         [cf_cv_unctrl_header=$cf_header
1201          break],
1202         [cf_cv_unctrl_header=no])
1203 done
1204 ])
1205
1206 case "$cf_cv_unctrl_header" in
1207 (no)
1208         AC_MSG_WARN(unctrl.h header not found)
1209         ;;
1210 esac
1211
1212 case "$cf_cv_unctrl_header" in
1213 (unctrl.h)
1214         AC_DEFINE(HAVE_UNCTRL_H,1,[Define to 1 if we have unctrl.h])
1215         ;;
1216 (ncurses/unctrl.h)
1217         AC_DEFINE(HAVE_NCURSES_UNCTRL_H,1,[Define to 1 if we have ncurses/unctrl.h])
1218         ;;
1219 (ncursesw/unctrl.h)
1220         AC_DEFINE(HAVE_NCURSESW_UNCTRL_H,1,[Define to 1 if we have ncursesw/unctrl.h])
1221         ;;
1222 esac
1223 ])dnl
1224 dnl ---------------------------------------------------------------------------
1225 dnl CF_CURSES_WACS_MAP version: 8 updated: 2021/01/04 19:45:09
1226 dnl ------------------
1227 dnl Check for likely values of wacs_map[].
1228 AC_DEFUN([CF_CURSES_WACS_MAP],
1229 [
1230 AC_CACHE_CHECK(for wide alternate character set array, cf_cv_curses_wacs_map,[
1231         cf_cv_curses_wacs_map=unknown
1232         for name in wacs_map _wacs_map __wacs_map _nc_wacs _wacs_char
1233         do
1234         AC_TRY_LINK([
1235 #ifndef _XOPEN_SOURCE_EXTENDED
1236 #define _XOPEN_SOURCE_EXTENDED
1237 #endif
1238 #include <${cf_cv_ncurses_header:-curses.h}>],
1239         [void *foo = &(${name}['k']); (void)foo],
1240         [cf_cv_curses_wacs_map=$name
1241          break])
1242         done])
1243
1244 test "$cf_cv_curses_wacs_map" != unknown && AC_DEFINE_UNQUOTED(CURSES_WACS_ARRAY,$cf_cv_curses_wacs_map,[Define to name of (n)curses wide-character array])
1245 ])dnl
1246 dnl ---------------------------------------------------------------------------
1247 dnl CF_CURSES_WACS_SYMBOLS version: 4 updated: 2021/01/04 19:45:09
1248 dnl ----------------------
1249 dnl Do a check to see if the WACS_xxx constants are defined compatibly with
1250 dnl X/Open Curses.  In particular, NetBSD's implementation of the WACS_xxx
1251 dnl constants is broken since those constants do not point to cchar_t's.
1252 AC_DEFUN([CF_CURSES_WACS_SYMBOLS],
1253 [
1254 AC_REQUIRE([CF_CURSES_WACS_MAP])
1255
1256 AC_CACHE_CHECK(for wide alternate character constants, cf_cv_curses_wacs_symbols,[
1257 cf_cv_curses_wacs_symbols=no
1258 if test "$cf_cv_curses_wacs_map" != unknown
1259 then
1260         AC_TRY_LINK([
1261 #ifndef _XOPEN_SOURCE_EXTENDED
1262 #define _XOPEN_SOURCE_EXTENDED
1263 #endif
1264 #include <${cf_cv_ncurses_header:-curses.h}>],
1265         [cchar_t *foo = WACS_PLUS;
1266          ${cf_cv_curses_wacs_map}['k'] = *WACS_PLUS; (void)foo],
1267         [cf_cv_curses_wacs_symbols=yes])
1268 else
1269         AC_TRY_LINK([
1270 #ifndef _XOPEN_SOURCE_EXTENDED
1271 #define _XOPEN_SOURCE_EXTENDED
1272 #endif
1273 #include <${cf_cv_ncurses_header:-curses.h}>],
1274         [cchar_t *foo = WACS_PLUS; (void)foo],
1275         [cf_cv_curses_wacs_symbols=yes])
1276 fi
1277 ])
1278
1279 test "$cf_cv_curses_wacs_symbols" != no && AC_DEFINE(CURSES_WACS_SYMBOLS,1,[Define to 1 if (n)curses supports wide-character WACS_ symbols])
1280 ])dnl
1281 dnl ---------------------------------------------------------------------------
1282 dnl CF_DIRNAME version: 5 updated: 2020/12/31 20:19:42
1283 dnl ----------
1284 dnl "dirname" is not portable, so we fake it with a shell script.
1285 AC_DEFUN([CF_DIRNAME],[$1=`echo "$2" | sed -e 's%/[[^/]]*$%%'`])dnl
1286 dnl ---------------------------------------------------------------------------
1287 dnl CF_DISABLE_ECHO version: 14 updated: 2021/09/04 06:35:04
1288 dnl ---------------
1289 dnl You can always use "make -n" to see the actual options, but it is hard to
1290 dnl pick out/analyze warning messages when the compile-line is long.
1291 dnl
1292 dnl Sets:
1293 dnl     ECHO_LT - symbol to control if libtool is verbose
1294 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1295 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1296 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1297 dnl     ECHO_CC - symbol to put before any "cc" line
1298 dnl
1299 AC_DEFUN([CF_DISABLE_ECHO],[
1300 AC_MSG_CHECKING(if you want to see long compiling messages)
1301 CF_ARG_DISABLE(echo,
1302         [  --disable-echo          do not display "compiling" commands],
1303         [
1304         ECHO_LT='--silent'
1305         ECHO_LD='@echo linking [$]@;'
1306         RULE_CC='@echo compiling [$]<'
1307         SHOW_CC='@echo compiling [$]@'
1308         ECHO_CC='@'
1309 ],[
1310         ECHO_LT=''
1311         ECHO_LD=''
1312         RULE_CC=''
1313         SHOW_CC=''
1314         ECHO_CC=''
1315 ])
1316 AC_MSG_RESULT($enableval)
1317 AC_SUBST(ECHO_LT)
1318 AC_SUBST(ECHO_LD)
1319 AC_SUBST(RULE_CC)
1320 AC_SUBST(SHOW_CC)
1321 AC_SUBST(ECHO_CC)
1322 ])dnl
1323 dnl ---------------------------------------------------------------------------
1324 dnl CF_DISABLE_LEAKS version: 9 updated: 2021/04/03 16:41:50
1325 dnl ----------------
1326 dnl Combine no-leak checks with the libraries or tools that are used for the
1327 dnl checks.
1328 AC_DEFUN([CF_DISABLE_LEAKS],[
1329
1330 AC_REQUIRE([CF_WITH_DMALLOC])
1331 AC_REQUIRE([CF_WITH_DBMALLOC])
1332 AC_REQUIRE([CF_WITH_VALGRIND])
1333
1334 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1335 AC_ARG_ENABLE(leaks,
1336         [  --disable-leaks         test: free permanent memory, analyze leaks],
1337         [enable_leaks=$enableval],
1338         [enable_leaks=yes])
1339 dnl with_no_leaks is more readable...
1340 if test "x$enable_leaks" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi
1341 AC_MSG_RESULT($with_no_leaks)
1342
1343 if test "$enable_leaks" = no ; then
1344         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1345         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1346 fi
1347 ])dnl
1348 dnl ---------------------------------------------------------------------------
1349 dnl CF_DISABLE_RPATH_HACK version: 3 updated: 2021/01/05 20:14:44
1350 dnl ---------------------
1351 dnl The rpath-hack makes it simpler to build programs, particularly with the
1352 dnl *BSD ports which may have essential libraries in unusual places.  But it
1353 dnl can interfere with building an executable for the base system.  Use this
1354 dnl option in that case.
1355 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1356 [
1357 AC_MSG_CHECKING(if rpath-hack should be disabled)
1358 CF_ARG_DISABLE(rpath-hack,
1359         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1360         [enable_rpath_hack=no],
1361         [enable_rpath_hack=yes])
1362 dnl TODO - drop cf_disable_rpath_hack
1363 if test "x$enable_rpath_hack" = xno; then cf_disable_rpath_hack=yes; else cf_disable_rpath_hack=no; fi
1364 AC_MSG_RESULT($cf_disable_rpath_hack)
1365
1366 if test "$enable_rpath_hack" = yes ; then
1367         CF_RPATH_HACK
1368 fi
1369 ])
1370 dnl ---------------------------------------------------------------------------
1371 dnl CF_ENABLE_STRING_HACKS version: 6 updated: 2021/01/05 19:23:48
1372 dnl ----------------------
1373 dnl On a few platforms, the compiler and/or loader nags with untruthful
1374 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1375 dnl and implying that most uses of the recommended alternatives are correct.
1376 dnl
1377 dnl Factually speaking, no one has actually counted the number of uses of these
1378 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1379 dnl instances are meaningless compared to the hundreds of millions of lines of
1380 dnl existing C code.
1381 dnl
1382 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1383 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1384 dnl standard - but evolved through phases, and older implementations are likely
1385 dnl to yield surprising results, as documented in manpages on various systems.
1386 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1387 [
1388 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1389 AC_ARG_ENABLE(string-hacks,
1390         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1391         [enable_string_hacks=$enableval],
1392         [enable_string_hacks=no])
1393 AC_MSG_RESULT($enable_string_hacks)
1394
1395 if test "x$enable_string_hacks" = "xyes"; then
1396         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1397         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1398         AC_CHECK_FUNC(strlcat,[
1399                 AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1400                 ],[
1401                 AC_CHECK_LIB(bsd,strlcat,[
1402                         CF_ADD_LIB(bsd)
1403                         AC_CHECK_HEADERS(bsd/string.h)
1404                         AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1405                         ])
1406                 ])
1407         AC_CHECK_FUNCS( strlcpy snprintf )
1408 fi
1409 ])dnl
1410 dnl ---------------------------------------------------------------------------
1411 dnl CF_ENABLE_WARNINGS version: 9 updated: 2021/01/05 19:40:50
1412 dnl ------------------
1413 dnl Configure-option to enable gcc warnings
1414 dnl
1415 dnl $1 = extra options to add, if supported
1416 dnl $2 = option for checking attributes.  By default, this is done when
1417 dnl      warnings are enabled.  For other values:
1418 dnl      yes: always do this, e.g., to use in generated library-headers
1419 dnl      no: never do this
1420 AC_DEFUN([CF_ENABLE_WARNINGS],[
1421 if test "$GCC" = yes || test "$GXX" = yes
1422 then
1423 CF_FIX_WARNINGS(CFLAGS)
1424 CF_FIX_WARNINGS(CPPFLAGS)
1425 CF_FIX_WARNINGS(LDFLAGS)
1426 AC_MSG_CHECKING(if you want to turn on gcc warnings)
1427 CF_ARG_ENABLE(warnings,
1428         [  --enable-warnings       test: turn on gcc compiler warnings],
1429         [enable_warnings=yes],
1430         [enable_warnings=no])
1431 AC_MSG_RESULT($enable_warnings)
1432 if test "$enable_warnings" = "yes"
1433 then
1434         ifelse($2,,[CF_GCC_ATTRIBUTES])
1435         CF_GCC_WARNINGS($1)
1436 fi
1437 ifelse($2,yes,[CF_GCC_ATTRIBUTES])
1438 fi
1439 ])dnl
1440 dnl ---------------------------------------------------------------------------
1441 dnl CF_FIND_LIBRARY version: 11 updated: 2021/01/02 09:31:20
1442 dnl ---------------
1443 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
1444 dnl prefer a standard location, and use -L options only if we do not find the
1445 dnl library in the standard library location(s).
1446 dnl     $1 = library name
1447 dnl     $2 = library class, usually the same as library name
1448 dnl     $3 = includes
1449 dnl     $4 = code fragment to compile/link
1450 dnl     $5 = corresponding function-name
1451 dnl     $6 = flag, nonnull if failure should not cause an error-exit
1452 dnl
1453 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
1454 dnl to use a -L option.
1455 AC_DEFUN([CF_FIND_LIBRARY],
1456 [
1457         eval 'cf_cv_have_lib_'"$1"'=no'
1458         cf_libdir=""
1459         AC_CHECK_FUNC($5,
1460                 eval 'cf_cv_have_lib_'"$1"'=yes',[
1461                 cf_save_LIBS="$LIBS"
1462                 AC_MSG_CHECKING(for $5 in -l$1)
1463                 LIBS="-l$1 $LIBS"
1464                 AC_TRY_LINK([$3],[$4],
1465                         [AC_MSG_RESULT(yes)
1466                          eval 'cf_cv_have_lib_'"$1"'=yes'
1467                         ],
1468                         [AC_MSG_RESULT(no)
1469                         CF_LIBRARY_PATH(cf_search,$2)
1470                         for cf_libdir in $cf_search
1471                         do
1472                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
1473                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
1474                                 AC_TRY_LINK([$3],[$4],
1475                                         [AC_MSG_RESULT(yes)
1476                                          eval 'cf_cv_have_lib_'"$1"'=yes'
1477                                          break],
1478                                         [AC_MSG_RESULT(no)
1479                                          LIBS="$cf_save_LIBS"])
1480                         done
1481                         ])
1482                 ])
1483 eval 'cf_found_library="[$]cf_cv_have_lib_'"$1"\"
1484 ifelse($6,,[
1485 if test "$cf_found_library" = no ; then
1486         AC_MSG_ERROR(Cannot link $1 library)
1487 fi
1488 ])
1489 ])dnl
1490 dnl ---------------------------------------------------------------------------
1491 dnl CF_FIND_LINKAGE version: 22 updated: 2020/12/31 20:19:42
1492 dnl ---------------
1493 dnl Find a library (specifically the linkage used in the code fragment),
1494 dnl searching for it if it is not already in the library path.
1495 dnl See also CF_ADD_SEARCHPATH.
1496 dnl
1497 dnl Parameters (4-on are optional):
1498 dnl     $1 = headers for library entrypoint
1499 dnl     $2 = code fragment for library entrypoint
1500 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1501 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1502 dnl     $5 = action to perform if not successful
1503 dnl     $6 = module name, if not the same as the library name
1504 dnl     $7 = extra libraries
1505 dnl
1506 dnl Sets these variables:
1507 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1508 dnl     $cf_cv_header_path_$3 - include-directory if needed
1509 dnl     $cf_cv_library_path_$3 - library-directory if needed
1510 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1511 AC_DEFUN([CF_FIND_LINKAGE],[
1512
1513 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1514 # will be set on completion of the AC_TRY_LINK below.
1515 cf_cv_header_path_$3=
1516 cf_cv_library_path_$3=
1517
1518 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1519
1520 cf_save_LIBS="$LIBS"
1521
1522 AC_TRY_LINK([$1],[$2],[
1523         cf_cv_find_linkage_$3=yes
1524         cf_cv_header_path_$3=/usr/include
1525         cf_cv_library_path_$3=/usr/lib
1526 ],[
1527
1528 LIBS="-l$3 $7 $cf_save_LIBS"
1529
1530 AC_TRY_LINK([$1],[$2],[
1531         cf_cv_find_linkage_$3=yes
1532         cf_cv_header_path_$3=/usr/include
1533         cf_cv_library_path_$3=/usr/lib
1534         cf_cv_library_file_$3="-l$3"
1535 ],[
1536         cf_cv_find_linkage_$3=no
1537         LIBS="$cf_save_LIBS"
1538
1539         CF_VERBOSE(find linkage for $3 library)
1540         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1541
1542         cf_save_CPPFLAGS="$CPPFLAGS"
1543         cf_test_CPPFLAGS="$CPPFLAGS"
1544
1545         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1546         for cf_cv_header_path_$3 in $cf_search
1547         do
1548                 if test -d "$cf_cv_header_path_$3" ; then
1549                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1550                         CPPFLAGS="$cf_save_CPPFLAGS"
1551                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
1552                         AC_TRY_COMPILE([$1],[$2],[
1553                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1554                                 cf_cv_find_linkage_$3=maybe
1555                                 cf_test_CPPFLAGS="$CPPFLAGS"
1556                                 break],[
1557                                 CPPFLAGS="$cf_save_CPPFLAGS"
1558                                 ])
1559                 fi
1560         done
1561
1562         if test "$cf_cv_find_linkage_$3" = maybe ; then
1563
1564                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1565
1566                 cf_save_LIBS="$LIBS"
1567                 cf_save_LDFLAGS="$LDFLAGS"
1568
1569                 ifelse([$6],,,[
1570                 CPPFLAGS="$cf_test_CPPFLAGS"
1571                 LIBS="-l$3 $7 $cf_save_LIBS"
1572                 AC_TRY_LINK([$1],[$2],[
1573                         CF_VERBOSE(... found $3 library in system)
1574                         cf_cv_find_linkage_$3=yes])
1575                         CPPFLAGS="$cf_save_CPPFLAGS"
1576                         LIBS="$cf_save_LIBS"
1577                         ])
1578
1579                 if test "$cf_cv_find_linkage_$3" != yes ; then
1580                         CF_LIBRARY_PATH(cf_search,$3)
1581                         for cf_cv_library_path_$3 in $cf_search
1582                         do
1583                                 if test -d "$cf_cv_library_path_$3" ; then
1584                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
1585                                         CPPFLAGS="$cf_test_CPPFLAGS"
1586                                         LIBS="-l$3 $7 $cf_save_LIBS"
1587                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1588                                         AC_TRY_LINK([$1],[$2],[
1589                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1590                                         cf_cv_find_linkage_$3=yes
1591                                         cf_cv_library_file_$3="-l$3"
1592                                         break],[
1593                                         CPPFLAGS="$cf_save_CPPFLAGS"
1594                                         LIBS="$cf_save_LIBS"
1595                                         LDFLAGS="$cf_save_LDFLAGS"
1596                                         ])
1597                                 fi
1598                         done
1599                         CPPFLAGS="$cf_save_CPPFLAGS"
1600                         LDFLAGS="$cf_save_LDFLAGS"
1601                 fi
1602
1603         else
1604                 cf_cv_find_linkage_$3=no
1605         fi
1606         ],$7)
1607 ])
1608
1609 LIBS="$cf_save_LIBS"
1610
1611 if test "$cf_cv_find_linkage_$3" = yes ; then
1612 ifelse([$4],,[
1613         CF_ADD_INCDIR($cf_cv_header_path_$3)
1614         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1615         CF_ADD_LIB($3)
1616 ],[$4])
1617 else
1618 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1619 fi
1620 ])dnl
1621 dnl ---------------------------------------------------------------------------
1622 dnl CF_FIX_WARNINGS version: 4 updated: 2021/12/16 18:22:31
1623 dnl ---------------
1624 dnl Warning flags do not belong in CFLAGS, CPPFLAGS, etc.  Any of gcc's
1625 dnl "-Werror" flags can interfere with configure-checks.  Those go into
1626 dnl EXTRA_CFLAGS.
1627 dnl
1628 dnl $1 = variable name to repair
1629 define([CF_FIX_WARNINGS],[
1630 if test "$GCC" = yes || test "$GXX" = yes
1631 then
1632         case [$]$1 in
1633         (*-Werror=*)
1634                 cf_temp_flags=
1635                 for cf_temp_scan in [$]$1
1636                 do
1637                         case "x$cf_temp_scan" in
1638                         (x-Werror=format*)
1639                                 CF_APPEND_TEXT(cf_temp_flags,$cf_temp_scan)
1640                                 ;;
1641                         (x-Werror=*)
1642                                 CF_APPEND_TEXT(EXTRA_CFLAGS,$cf_temp_scan)
1643                                 ;;
1644                         (*)
1645                                 CF_APPEND_TEXT(cf_temp_flags,$cf_temp_scan)
1646                                 ;;
1647                         esac
1648                 done
1649                 if test "x[$]$1" != "x$cf_temp_flags"
1650                 then
1651                         CF_VERBOSE(repairing $1: [$]$1)
1652                         $1="$cf_temp_flags"
1653                         CF_VERBOSE(... fixed [$]$1)
1654                         CF_VERBOSE(... extra $EXTRA_CFLAGS)
1655                 fi
1656                 ;;
1657         esac
1658 fi
1659 AC_SUBST(EXTRA_CFLAGS)
1660 ])dnl
1661 dnl ---------------------------------------------------------------------------
1662 dnl CF_FUNC_CURSES_VERSION version: 9 updated: 2023/01/05 18:06:10
1663 dnl ----------------------
1664 dnl Solaris has a data item 'curses_version', which confuses AC_CHECK_FUNCS.
1665 dnl It's a character string "SVR4", not documented.
1666 AC_DEFUN([CF_FUNC_CURSES_VERSION],
1667 [
1668 AC_CACHE_CHECK(for function curses_version, cf_cv_func_curses_version,[
1669 AC_TRY_RUN([
1670 $ac_includes_default
1671
1672 #include <${cf_cv_ncurses_header:-curses.h}>
1673
1674 int main(void)
1675 {
1676         char temp[1024];
1677         sprintf(temp, "%.999s\\n", curses_version());
1678         ${cf_cv_main_return:-return}(0);
1679 }]
1680 ,[cf_cv_func_curses_version=yes]
1681 ,[cf_cv_func_curses_version=no]
1682 ,[cf_cv_func_curses_version=unknown])
1683 rm -f core])
1684 test "$cf_cv_func_curses_version" = yes && AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 if we have curses_version function])
1685 ])
1686 dnl ---------------------------------------------------------------------------
1687 dnl CF_FUNC_GETTIME version: 2 updated: 2023/02/25 08:45:56
1688 dnl ---------------
1689 dnl Check for gettimeofday or clock_gettime.  In 2023, the former is still more
1690 dnl widely supported, but "deprecated" (2008), so we will use the latter if it
1691 dnl is available, to reduce compiler warnings.
1692 AC_DEFUN([CF_FUNC_GETTIME],[
1693 AC_CACHE_CHECK(for clock_gettime,cf_cv_func_clock_gettime,[
1694                 AC_TRY_LINK([#include <time.h>],
1695                 [struct timespec ts;
1696                 int rc = clock_gettime(CLOCK_REALTIME, &ts); (void) rc; (void)ts],
1697                 [cf_cv_func_clock_gettime=yes],
1698                 [cf_cv_func_clock_gettime=no])
1699 ])
1700
1701 if test "$cf_cv_func_clock_gettime" = yes
1702 then
1703         AC_DEFINE(HAVE_CLOCK_GETTIME,1,[Define to 1 if we have clock_gettime function])
1704 else
1705 AC_CHECK_FUNC(gettimeofday,
1706         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function]),[
1707
1708 AC_CHECK_LIB(bsd, gettimeofday,
1709         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function])
1710         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1711 fi
1712 ])dnl
1713 dnl ---------------------------------------------------------------------------
1714 dnl CF_FUNC_OPENPTY version: 6 updated: 2021/01/01 13:31:04
1715 dnl ---------------
1716 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1717 dnl "util" library as well.
1718 AC_DEFUN([CF_FUNC_OPENPTY],
1719 [
1720 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1721 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1722         cf_save_LIBS="$LIBS"
1723         test "$cf_cv_lib_util" = yes && { CF_ADD_LIB(util) }
1724         for cf_header in pty.h libutil.h util.h
1725         do
1726         AC_TRY_LINK([
1727 #include <$cf_header>
1728 ],[
1729         int x = openpty((int *)0, (int *)0, (char *)0,
1730                                    (struct termios *)0, (struct winsize *)0);
1731 ],[
1732                 cf_cv_func_openpty=$cf_header
1733                 break
1734 ],[
1735                 cf_cv_func_openpty=no
1736 ])
1737         done
1738         LIBS="$cf_save_LIBS"
1739 ])
1740 ])dnl
1741 dnl ---------------------------------------------------------------------------
1742 dnl CF_GCC_ATTRIBUTES version: 24 updated: 2021/03/20 12:00:25
1743 dnl -----------------
1744 dnl Test for availability of useful gcc __attribute__ directives to quiet
1745 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1746 dnl to documentation, unrecognized directives cause older compilers to barf.
1747 AC_DEFUN([CF_GCC_ATTRIBUTES],
1748 [AC_REQUIRE([AC_PROG_FGREP])dnl
1749 AC_REQUIRE([CF_C11_NORETURN])dnl
1750
1751 if test "$GCC" = yes || test "$GXX" = yes
1752 then
1753 cat > conftest.i <<EOF
1754 #ifndef GCC_PRINTF
1755 #define GCC_PRINTF 0
1756 #endif
1757 #ifndef GCC_SCANF
1758 #define GCC_SCANF 0
1759 #endif
1760 #ifndef GCC_NORETURN
1761 #define GCC_NORETURN /* nothing */
1762 #endif
1763 #ifndef GCC_UNUSED
1764 #define GCC_UNUSED /* nothing */
1765 #endif
1766 EOF
1767 if test "$GCC" = yes
1768 then
1769         AC_CHECKING([for $CC __attribute__ directives])
1770 cat > "conftest.$ac_ext" <<EOF
1771 #line __oline__ "${as_me:-configure}"
1772 #include <stdio.h>
1773 #include "confdefs.h"
1774 #include "conftest.h"
1775 #include "conftest.i"
1776 #if     GCC_PRINTF
1777 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1778 #else
1779 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1780 #endif
1781 #if     GCC_SCANF
1782 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1783 #else
1784 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1785 #endif
1786 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1787 extern GCC_NORETURN void oops(char *,...) GCC_PRINTFLIKE(1,2);
1788 extern GCC_NORETURN void foo(void);
1789 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { (void)argc; (void)argv; return 0; }
1790 EOF
1791         cf_printf_attribute=no
1792         cf_scanf_attribute=no
1793         for cf_attribute in scanf printf unused noreturn
1794         do
1795                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1796                 cf_directive="__attribute__(($cf_attribute))"
1797                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1798
1799                 case "$cf_attribute" in
1800                 (printf)
1801                         cf_printf_attribute=yes
1802                         cat >conftest.h <<EOF
1803 #define GCC_$cf_ATTRIBUTE 1
1804 EOF
1805                         ;;
1806                 (scanf)
1807                         cf_scanf_attribute=yes
1808                         cat >conftest.h <<EOF
1809 #define GCC_$cf_ATTRIBUTE 1
1810 EOF
1811                         ;;
1812                 (*)
1813                         cat >conftest.h <<EOF
1814 #define GCC_$cf_ATTRIBUTE $cf_directive
1815 EOF
1816                         ;;
1817                 esac
1818
1819                 if AC_TRY_EVAL(ac_compile); then
1820                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1821                         cat conftest.h >>confdefs.h
1822                         case "$cf_attribute" in
1823                         (noreturn)
1824                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1825                                 ;;
1826                         (printf)
1827                                 cf_value='/* nothing */'
1828                                 if test "$cf_printf_attribute" != no ; then
1829                                         cf_value='__attribute__((format(printf,fmt,var)))'
1830                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1831                                 fi
1832                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1833                                 ;;
1834                         (scanf)
1835                                 cf_value='/* nothing */'
1836                                 if test "$cf_scanf_attribute" != no ; then
1837                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1838                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1839                                 fi
1840                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1841                                 ;;
1842                         (unused)
1843                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1844                                 ;;
1845                         esac
1846                 fi
1847         done
1848 else
1849         ${FGREP-fgrep} define conftest.i >>confdefs.h
1850 fi
1851 rm -rf ./conftest*
1852 fi
1853 ])dnl
1854 dnl ---------------------------------------------------------------------------
1855 dnl CF_GCC_VERSION version: 9 updated: 2023/03/05 14:30:13
1856 dnl --------------
1857 dnl Find version of gcc, and (because icc/clang pretend to be gcc without being
1858 dnl compatible), attempt to determine if icc/clang is actually used.
1859 AC_DEFUN([CF_GCC_VERSION],[
1860 AC_REQUIRE([AC_PROG_CC])
1861 GCC_VERSION=none
1862 if test "$GCC" = yes ; then
1863         AC_MSG_CHECKING(version of $CC)
1864         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^[[^(]]*([[^)]][[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1865         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1866         AC_MSG_RESULT($GCC_VERSION)
1867 fi
1868 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1869 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
1870 ])dnl
1871 dnl ---------------------------------------------------------------------------
1872 dnl CF_GCC_WARNINGS version: 41 updated: 2021/01/01 16:53:59
1873 dnl ---------------
1874 dnl Check if the compiler supports useful warning options.  There's a few that
1875 dnl we don't use, simply because they're too noisy:
1876 dnl
1877 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1878 dnl     -Winline (usually not worthwhile)
1879 dnl     -Wredundant-decls (system headers make this too noisy)
1880 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1881 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1882 dnl             is enabled for ncurses using "--enable-const".
1883 dnl     -pedantic
1884 dnl
1885 dnl Parameter:
1886 dnl     $1 is an optional list of gcc warning flags that a particular
1887 dnl             application might want to use, e.g., "no-unused" for
1888 dnl             -Wno-unused
1889 dnl Special:
1890 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1891 dnl
1892 AC_DEFUN([CF_GCC_WARNINGS],
1893 [
1894 AC_REQUIRE([CF_GCC_VERSION])
1895 if test "x$have_x" = xyes; then CF_CONST_X_STRING fi
1896 cat > "conftest.$ac_ext" <<EOF
1897 #line __oline__ "${as_me:-configure}"
1898 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1899 EOF
1900 if test "$INTEL_COMPILER" = yes
1901 then
1902 # The "-wdXXX" options suppress warnings:
1903 # remark #1419: external declaration in primary source file
1904 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1905 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1906 # remark #193: zero used for undefined preprocessing identifier
1907 # remark #593: variable "curs_sb_left_arrow" was set but never used
1908 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1909 # remark #869: parameter "tw" was never referenced
1910 # remark #981: operands are evaluated in unspecified order
1911 # warning #279: controlling expression is constant
1912
1913         AC_CHECKING([for $CC warning options])
1914         cf_save_CFLAGS="$CFLAGS"
1915         EXTRA_CFLAGS="$EXTRA_CFLAGS -Wall"
1916         for cf_opt in \
1917                 wd1419 \
1918                 wd1683 \
1919                 wd1684 \
1920                 wd193 \
1921                 wd593 \
1922                 wd279 \
1923                 wd810 \
1924                 wd869 \
1925                 wd981
1926         do
1927                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1928                 if AC_TRY_EVAL(ac_compile); then
1929                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1930                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1931                 fi
1932         done
1933         CFLAGS="$cf_save_CFLAGS"
1934 elif test "$GCC" = yes && test "$GCC_VERSION" != "unknown"
1935 then
1936         AC_CHECKING([for $CC warning options])
1937         cf_save_CFLAGS="$CFLAGS"
1938         cf_warn_CONST=""
1939         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1940         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
1941         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
1942         for cf_opt in W Wall \
1943                 Wbad-function-cast \
1944                 Wcast-align \
1945                 Wcast-qual \
1946                 Wdeclaration-after-statement \
1947                 Wextra \
1948                 Winline \
1949                 Wmissing-declarations \
1950                 Wmissing-prototypes \
1951                 Wnested-externs \
1952                 Wpointer-arith \
1953                 Wshadow \
1954                 Wstrict-prototypes \
1955                 Wundef Wno-inline $cf_gcc_warnings $cf_warn_CONST $1
1956         do
1957                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1958                 if AC_TRY_EVAL(ac_compile); then
1959                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1960                         case "$cf_opt" in
1961                         (Winline)
1962                                 case "$GCC_VERSION" in
1963                                 ([[34]].*)
1964                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1965                                         continue;;
1966                                 esac
1967                                 ;;
1968                         (Wpointer-arith)
1969                                 case "$GCC_VERSION" in
1970                                 ([[12]].*)
1971                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1972                                         continue;;
1973                                 esac
1974                                 ;;
1975                         esac
1976                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1977                 fi
1978         done
1979         CFLAGS="$cf_save_CFLAGS"
1980 fi
1981 rm -rf ./conftest*
1982
1983 AC_SUBST(EXTRA_CFLAGS)
1984 ])dnl
1985 dnl ---------------------------------------------------------------------------
1986 dnl CF_GETOPT_HEADER version: 8 updated: 2021/06/19 19:16:16
1987 dnl ----------------
1988 dnl Check for getopt's variables which are commonly defined in stdlib.h,
1989 dnl unistd.h or (nonstandard) in getopt.h
1990 AC_DEFUN([CF_GETOPT_HEADER],
1991 [
1992 AC_HAVE_HEADERS(unistd.h getopt.h)
1993 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
1994 cf_cv_getopt_header=none
1995 for cf_header in stdio.h stdlib.h unistd.h getopt.h
1996 do
1997 AC_TRY_COMPILE([
1998 #include <$cf_header>],
1999 [int x = optind; char *y = optarg; (void)x; (void)y],
2000 [cf_cv_getopt_header=$cf_header
2001  break])
2002 done
2003 ])
2004 if test "$cf_cv_getopt_header" != none ; then
2005         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
2006 fi
2007 if test "$cf_cv_getopt_header" = getopt.h ; then
2008         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
2009 fi
2010 ])dnl
2011 dnl ---------------------------------------------------------------------------
2012 dnl CF_GNU_SOURCE version: 10 updated: 2018/12/10 20:09:41
2013 dnl -------------
2014 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2015 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2016 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2017 dnl since it is interwoven with GNU extensions.
2018 dnl
2019 dnl Well, yes we could work around it...
2020 dnl
2021 dnl Parameters:
2022 dnl     $1 is the nominal value for _XOPEN_SOURCE
2023 AC_DEFUN([CF_GNU_SOURCE],
2024 [
2025 cf_gnu_xopen_source=ifelse($1,,500,$1)
2026
2027 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
2028 AC_TRY_COMPILE([#include <sys/types.h>],[
2029         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
2030                 return 0;
2031         #elif __NEWLIB__ > 0 && __NEWLIB_MINOR__ >= 0
2032                 return 0;
2033         #else
2034         #       error not GNU C library
2035         #endif],
2036         [cf_cv_gnu_library=yes],
2037         [cf_cv_gnu_library=no])
2038 ])
2039
2040 if test x$cf_cv_gnu_library = xyes; then
2041
2042         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
2043         # was changed to help a little.  newlib incorporated the change about 4
2044         # years later.
2045         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
2046                 cf_save="$CPPFLAGS"
2047                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
2048                 AC_TRY_COMPILE([#include <sys/types.h>],[
2049                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
2050                                 return 0;
2051                         #elif (__NEWLIB__ == 2 && __NEWLIB_MINOR__ >= 4) || (__GLIBC__ > 3)
2052                                 return 0;
2053                         #else
2054                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
2055                         #endif],
2056                         [cf_cv_gnu_library_219=yes],
2057                         [cf_cv_gnu_library_219=no])
2058                 CPPFLAGS="$cf_save"
2059         ])
2060
2061         if test "x$cf_cv_gnu_library_219" = xyes; then
2062                 cf_save="$CPPFLAGS"
2063                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
2064                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
2065                         AC_TRY_COMPILE([
2066                                 #include <limits.h>
2067                                 #include <sys/types.h>
2068                                 ],[
2069                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
2070                                         return 0;
2071                                 #else
2072                                 #       error GNU C library is too old
2073                                 #endif],
2074                                 [cf_cv_gnu_dftsrc_219=yes],
2075                                 [cf_cv_gnu_dftsrc_219=no])
2076                         ])
2077                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
2078         else
2079                 cf_cv_gnu_dftsrc_219=maybe
2080         fi
2081
2082         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
2083
2084                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2085                 AC_TRY_COMPILE([#include <sys/types.h>],[
2086                         #ifndef _XOPEN_SOURCE
2087                         #error  expected _XOPEN_SOURCE to be defined
2088                         #endif],
2089                         [cf_cv_gnu_source=no],
2090                         [cf_save="$CPPFLAGS"
2091                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
2092                          AC_TRY_COMPILE([#include <sys/types.h>],[
2093                                 #ifdef _XOPEN_SOURCE
2094                                 #error  expected _XOPEN_SOURCE to be undefined
2095                                 #endif],
2096                                 [cf_cv_gnu_source=no],
2097                                 [cf_cv_gnu_source=yes])
2098                         CPPFLAGS="$cf_save"
2099                         ])
2100                 ])
2101
2102                 if test "$cf_cv_gnu_source" = yes
2103                 then
2104                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
2105                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
2106                         AC_TRY_COMPILE([#include <sys/types.h>],[
2107                                 #ifdef _DEFAULT_SOURCE
2108                                 #error  expected _DEFAULT_SOURCE to be undefined
2109                                 #endif],
2110                                 [cf_cv_default_source=no],
2111                                 [cf_cv_default_source=yes])
2112                         ])
2113                         if test "$cf_cv_default_source" = yes
2114                         then
2115                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
2116                         fi
2117                 fi
2118         fi
2119
2120 fi
2121 ])dnl
2122 dnl ---------------------------------------------------------------------------
2123 dnl CF_HEADER_PATH version: 15 updated: 2021/01/01 13:31:04
2124 dnl --------------
2125 dnl Construct a search-list of directories for a nonstandard header-file
2126 dnl
2127 dnl Parameters
2128 dnl     $1 = the variable to return as result
2129 dnl     $2 = the package name
2130 AC_DEFUN([CF_HEADER_PATH],
2131 [
2132 $1=
2133
2134 # collect the current set of include-directories from compiler flags
2135 cf_header_path_list=""
2136 if test -n "${CFLAGS}${CPPFLAGS}" ; then
2137         for cf_header_path in $CPPFLAGS $CFLAGS
2138         do
2139                 case "$cf_header_path" in
2140                 (-I*)
2141                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
2142                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
2143                         cf_header_path_list="$cf_header_path_list [$]$1"
2144                         ;;
2145                 esac
2146         done
2147 fi
2148
2149 # add the variations for the package we are looking for
2150 CF_SUBDIR_PATH($1,$2,include)
2151
2152 test "$includedir" != NONE && \
2153 test "$includedir" != "/usr/include" && \
2154 test -d "$includedir" && {
2155         test -d "$includedir" &&    $1="[$]$1 $includedir"
2156         test -d "$includedir/$2" && $1="[$]$1 $includedir/$2"
2157 }
2158
2159 test "$oldincludedir" != NONE && \
2160 test "$oldincludedir" != "/usr/include" && \
2161 test -d "$oldincludedir" && {
2162         test -d "$oldincludedir"    && $1="[$]$1 $oldincludedir"
2163         test -d "$oldincludedir/$2" && $1="[$]$1 $oldincludedir/$2"
2164 }
2165
2166 $1="[$]$1 $cf_header_path_list"
2167 ])dnl
2168 dnl ---------------------------------------------------------------------------
2169 dnl CF_HELP_MESSAGE version: 4 updated: 2019/12/31 08:53:54
2170 dnl ---------------
2171 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
2172 AC_DEFUN([CF_HELP_MESSAGE],
2173 [CF_ACVERSION_CHECK(2.53,[],[
2174 AC_DIVERT_HELP($1)])dnl
2175 ])dnl
2176 dnl ---------------------------------------------------------------------------
2177 dnl CF_INHERIT_SCRIPT version: 2 updated: 2003/03/01 23:50:42
2178 dnl -----------------
2179 dnl If we do not have a given script, look for it in the parent directory.
2180 AC_DEFUN([CF_INHERIT_SCRIPT],
2181 [
2182 test -f $1 || ( test -f ../$1 && cp ../$1 ./ )
2183 ])dnl
2184 dnl ---------------------------------------------------------------------------
2185 dnl CF_INSTALL_OPTS version: 3 updated: 2023/06/03 15:17:30
2186 dnl ---------------
2187 dnl prompt for/fill-in useful install-program options
2188 AC_DEFUN([CF_INSTALL_OPTS],
2189 [
2190 CF_INSTALL_OPT_S
2191 CF_INSTALL_OPT_P
2192 CF_INSTALL_OPT_O
2193 CF_INSTALL_OPT_STRIP_PROG
2194 ])dnl
2195 dnl ---------------------------------------------------------------------------
2196 dnl CF_INSTALL_OPT_O version: 3 updated: 2020/12/31 20:19:42
2197 dnl ----------------
2198 dnl Almost all "install" programs default to the current user's ownership.
2199 dnl Almost - MINIX is an exception.
2200 AC_DEFUN([CF_INSTALL_OPT_O],
2201 [
2202 AC_MSG_CHECKING(if install needs to be told about ownership)
2203 case `$ac_config_guess` in
2204 (*minix)
2205         with_install_o=yes
2206         ;;
2207 (*)
2208         with_install_o=no
2209         ;;
2210 esac
2211
2212 AC_MSG_RESULT($with_install_o)
2213 if test "x$with_install_o" = xyes
2214 then
2215         INSTALL_OPT_O="`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`"
2216 else
2217         INSTALL_OPT_O=
2218 fi
2219
2220 AC_SUBST(INSTALL_OPT_O)
2221 ])dnl
2222 dnl ---------------------------------------------------------------------------
2223 dnl CF_INSTALL_OPT_P version: 3 updated: 2021/01/01 13:31:04
2224 dnl ----------------
2225 dnl Some install-programs accept a "-p" option to preserve file modification
2226 dnl timestamps.  That can be useful as an install option, as well as a way to
2227 dnl avoid the need for ranlib after copying a static archive.
2228 AC_DEFUN([CF_INSTALL_OPT_P],
2229 [
2230 : "${INSTALL:=install}"
2231 AC_CACHE_CHECK(if install accepts -p option, cf_cv_install_p,[
2232         rm -rf ./conftest*
2233         date >conftest.in
2234         mkdir conftest.out
2235         sleep 3
2236         if $INSTALL -p conftest.in conftest.out 2>/dev/null
2237         then
2238                 if test -f conftest.out/conftest.in
2239                 then
2240                         test conftest.in -nt conftest.out/conftest.in 2>conftest.err && \
2241                         test conftest.out/conftest.in -nt conftest.in 2>conftest.err
2242                         if test -s conftest.err
2243                         then
2244                                 cf_cv_install_p=no
2245                         else
2246                                 cf_cv_install_p=yes
2247                         fi
2248                 else
2249                         cf_cv_install_p=no
2250                 fi
2251         else
2252                 cf_cv_install_p=no
2253         fi
2254         rm -rf ./conftest*
2255 ])
2256 ])dnl
2257 dnl ---------------------------------------------------------------------------
2258 dnl CF_INSTALL_OPT_S version: 3 updated: 2021/01/05 19:23:48
2259 dnl ----------------
2260 dnl By default, we should strip executables which are installed, but leave the
2261 dnl ability to suppress that for unit-testing.
2262 AC_DEFUN([CF_INSTALL_OPT_S],
2263 [
2264 AC_MSG_CHECKING(if you want to install stripped executables)
2265 CF_ARG_DISABLE(stripping,
2266         [  --disable-stripping     do not strip (debug info) installed executables],
2267         [enable_stripping=no],
2268         [enable_stripping=yes])
2269 AC_MSG_RESULT($enable_stripping)
2270
2271 if test "$enable_stripping" = yes
2272 then
2273         INSTALL_OPT_S="-s"
2274 else
2275         INSTALL_OPT_S=
2276 fi
2277 AC_SUBST(INSTALL_OPT_S)
2278 ])dnl
2279 dnl ---------------------------------------------------------------------------
2280 dnl CF_INSTALL_OPT_STRIP_PROG version: 1 updated: 2023/06/03 15:17:30
2281 dnl -------------------------
2282 dnl Provide an option for overriding the strip program used in install "-s"
2283 dnl
2284 dnl coreutils install provides a --strip-program option
2285 dnl FreeBSD uses STRIPBIN environment variable, while NetBSD and OpenBSD use
2286 dnl STRIP environment variable.  Other versions of install do not support this.
2287 AC_DEFUN([CF_INSTALL_OPT_STRIP_PROG],
2288 [
2289 AC_REQUIRE([CF_INSTALL_OPT_S])
2290 if test -n "$INSTALL_OPT_S"
2291 then
2292         AC_MSG_CHECKING(if you want to specify strip-program)
2293         AC_ARG_WITH(strip-program,
2294                 [  --with-strip-program=XX specify program to use when stripping in install],
2295                 [with_strip_program=$withval],
2296                 [with_strip_program=no])
2297         AC_MSG_RESULT($with_strip_program)
2298         if test "$with_strip_program" != no
2299         then
2300                 AC_MSG_CHECKING(if strip-program is supported with this installer)
2301                 cf_install_program=`echo "$INSTALL" | sed -e 's%[[ ]]*[[ ]]-.%%'`
2302                 check_install_strip=no
2303                 if test -f "$cf_install_program"
2304                 then
2305                         check_install_version=`"$cf_install_program" --version 2>/dev/null | head -n 1 | grep coreutils`
2306                         if test -n "$check_install_version"
2307                         then
2308                                 check_install_strip="option"
2309                         else
2310                                 for check_strip_variable in STRIPBIN STRIP
2311                                 do
2312                                         if strings "$cf_install_program" | grep "^$check_strip_variable[$]" >/dev/null
2313                                         then
2314                                                 check_install_strip="environ"
2315                                                 break
2316                                         fi
2317                                 done
2318                         fi
2319                 fi
2320                 AC_MSG_RESULT($check_install_strip)
2321                 case "$check_install_strip" in
2322                 (no)
2323                         AC_MSG_WARN($cf_install_program does not support strip program option)
2324                         with_strip_program=no
2325                         ;;
2326                 (environ)
2327                         cat >install.tmp <<-CF_EOF
2328                         #! $SHELL
2329                         STRIPBIN="$with_strip_program" \\
2330                         STRIP="$with_strip_program" \\
2331                         $INSTALL "[$]@"
2332                         CF_EOF
2333                         INSTALL="`pwd`/install.tmp"
2334                         chmod +x "$INSTALL"
2335                         CF_VERBOSE(created $INSTALL)
2336                         ;;
2337                 (option)
2338                         INSTALL_OPT_S="$INSTALL_OPT_S --strip-program=\"$with_strip_program\""
2339                         ;;
2340                 esac
2341         fi
2342 fi
2343 AC_SUBST(INSTALL_OPT_S)
2344 ])dnl
2345 dnl ---------------------------------------------------------------------------
2346 dnl CF_INTEL_COMPILER version: 9 updated: 2023/02/18 17:41:25
2347 dnl -----------------
2348 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2349 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2350 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2351 dnl
2352 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2353 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2354 dnl the wrappers for gcc and g++ warnings.
2355 dnl
2356 dnl $1 = GCC (default) or GXX
2357 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2358 dnl $3 = CFLAGS (default) or CXXFLAGS
2359 AC_DEFUN([CF_INTEL_COMPILER],[
2360 AC_REQUIRE([AC_CANONICAL_HOST])
2361 ifelse([$2],,INTEL_COMPILER,[$2])=no
2362
2363 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2364         case "$host_os" in
2365         (linux*|gnu*)
2366                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2367                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2368                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2369                 AC_TRY_COMPILE([],[
2370 #ifdef __INTEL_COMPILER
2371 #else
2372 #error __INTEL_COMPILER is not defined
2373 #endif
2374 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2375 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
2376 ],[])
2377                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2378                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2379                 ;;
2380         esac
2381 fi
2382 ])dnl
2383 dnl ---------------------------------------------------------------------------
2384 dnl CF_LD_RPATH_OPT version: 9 updated: 2021/01/01 13:31:04
2385 dnl ---------------
2386 dnl For the given system and compiler, find the compiler flags to pass to the
2387 dnl loader to use the "rpath" feature.
2388 AC_DEFUN([CF_LD_RPATH_OPT],
2389 [
2390 AC_REQUIRE([CF_CHECK_CACHE])
2391
2392 LD_RPATH_OPT=
2393 if test "x$cf_cv_enable_rpath" != xno
2394 then
2395         AC_MSG_CHECKING(for an rpath option)
2396         case "$cf_cv_system_name" in
2397         (irix*)
2398                 if test "$GCC" = yes; then
2399                         LD_RPATH_OPT="-Wl,-rpath,"
2400                 else
2401                         LD_RPATH_OPT="-rpath "
2402                 fi
2403                 ;;
2404         (linux*|gnu*|k*bsd*-gnu|freebsd*)
2405                 LD_RPATH_OPT="-Wl,-rpath,"
2406                 ;;
2407         (openbsd[[2-9]].*|mirbsd*)
2408                 LD_RPATH_OPT="-Wl,-rpath,"
2409                 ;;
2410         (dragonfly*)
2411                 LD_RPATH_OPT="-rpath "
2412                 ;;
2413         (netbsd*)
2414                 LD_RPATH_OPT="-Wl,-rpath,"
2415                 ;;
2416         (osf*|mls+*)
2417                 LD_RPATH_OPT="-rpath "
2418                 ;;
2419         (solaris2*)
2420                 LD_RPATH_OPT="-R"
2421                 ;;
2422         (*)
2423                 ;;
2424         esac
2425         AC_MSG_RESULT($LD_RPATH_OPT)
2426
2427         case "x$LD_RPATH_OPT" in
2428         (x-R*)
2429                 AC_MSG_CHECKING(if we need a space after rpath option)
2430                 cf_save_LIBS="$LIBS"
2431                 CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
2432                 AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
2433                 LIBS="$cf_save_LIBS"
2434                 AC_MSG_RESULT($cf_rpath_space)
2435                 test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
2436                 ;;
2437         esac
2438 fi
2439 ])dnl
2440 dnl ---------------------------------------------------------------------------
2441 dnl CF_LIBRARY_PATH version: 11 updated: 2021/01/01 13:31:04
2442 dnl ---------------
2443 dnl Construct a search-list of directories for a nonstandard library-file
2444 dnl
2445 dnl Parameters
2446 dnl     $1 = the variable to return as result
2447 dnl     $2 = the package name
2448 AC_DEFUN([CF_LIBRARY_PATH],
2449 [
2450 $1=
2451 cf_library_path_list=""
2452 if test -n "${LDFLAGS}${LIBS}" ; then
2453         for cf_library_path in $LDFLAGS $LIBS
2454         do
2455                 case "$cf_library_path" in
2456                 (-L*)
2457                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
2458                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
2459                         cf_library_path_list="$cf_library_path_list [$]$1"
2460                         ;;
2461                 esac
2462         done
2463 fi
2464
2465 CF_SUBDIR_PATH($1,$2,lib)
2466
2467 $1="$cf_library_path_list [$]$1"
2468 ])dnl
2469 dnl ---------------------------------------------------------------------------
2470 dnl CF_MAKE_PHONY version: 3 updated: 2021/01/08 16:08:21
2471 dnl -------------
2472 dnl Check if the make-program handles a ".PHONY" target, e.g,. a target which
2473 dnl acts as a placeholder.
2474 dnl
2475 dnl The ".PHONY" feature was proposed in 2011 here
2476 dnl     https://www.austingroupbugs.net/view.php?id=523
2477 dnl and is scheduled for release in P1003.1 Issue 8 (late 2022).
2478 dnl
2479 dnl This is not supported by SVr4 make (or SunOS 4, 4.3SD, etc), but works with
2480 dnl a few others (i.e., GNU make and the non-POSIX "BSD" make):
2481 dnl
2482 dnl + This is a GNU make feature (since April 1988, but in turn from binutils,
2483 dnl   date unspecified).
2484 dnl
2485 dnl + It was adopted in NetBSD make in June 1995.
2486 dnl
2487 dnl + The other BSD make programs are derived from the NetBSD make (and for
2488 dnl   that reason are not actually different "implementations").
2489 dnl
2490 dnl + Some features of NetBSD make were actually adapted from pmake, which
2491 dnl   began as a modified GNU make starting in 1993.
2492 dnl
2493 dnl + Version 3.8 of the dmake program in January 1992 also implemented this
2494 dnl   GNU make extension, but is less well known than the BSD make.
2495 AC_DEFUN([CF_MAKE_PHONY],[
2496 AC_CACHE_CHECK(for \".PHONY\" make-support, cf_cv_make_PHONY,[
2497         rm -rf conftest*
2498         (
2499                 mkdir conftest || exit 1
2500                 cd conftest
2501                 cat >makefile <<'CF_EOF'
2502 .PHONY: always
2503 DATA=0
2504 always: always.out
2505         @echo "** making [$]@ [$](DATA)"
2506 once: once.out
2507         @echo "** making [$]@ [$](DATA)"
2508 always.out:
2509         @echo "** making [$]@ [$](DATA)"
2510         echo [$](DATA) > [$]@
2511 once.out:
2512         @echo "** making [$]@ [$](DATA)"
2513         echo [$](DATA) > [$]@
2514 CF_EOF
2515                 for cf_data in 1 2 3
2516                 do
2517                         ${MAKE:-make} always DATA=$cf_data
2518                         ${MAKE:-make} once   DATA=$cf_data
2519                         ${MAKE:-make} -t always once
2520                         if test -f always ; then
2521                                 echo "no (case 1)" > ../conftest.tmp
2522                         elif test ! -f always.out ; then
2523                                 echo "no (case 2)" > ../conftest.tmp
2524                         elif test ! -f once.out ; then
2525                                 echo "no (case 3)" > ../conftest.tmp
2526                         elif ! cmp -s always.out once.out ; then
2527                                 echo "no (case 4)" > ../conftest.tmp
2528                                 diff always.out once.out
2529                         else
2530                                 cf_check="`cat always.out`"
2531                                 if test "x$cf_check" != "x$cf_data" ; then
2532                                         echo "no (case 5)" > ../conftest.tmp
2533                                 else
2534                                         echo yes > ../conftest.tmp
2535                                         rm -f ./*.out
2536                                         continue
2537                                 fi
2538                         fi
2539                         break
2540                 done
2541         ) >&AC_FD_CC 2>&1
2542         cf_cv_make_PHONY="`cat conftest.tmp`"
2543         rm -rf conftest*
2544 ])
2545 MAKE_NO_PHONY="#"
2546 MAKE_PHONY="#"
2547 test "x$cf_cv_make_PHONY" = xyes && MAKE_PHONY=
2548 test "x$cf_cv_make_PHONY" != xyes && MAKE_NO_PHONY=
2549 AC_SUBST(MAKE_NO_PHONY)
2550 AC_SUBST(MAKE_PHONY)
2551 ])dnl
2552 dnl ---------------------------------------------------------------------------
2553 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
2554 dnl ------------
2555 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
2556 dnl a monocase filesystem.
2557 AC_DEFUN([CF_MAKE_TAGS],[
2558 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
2559
2560 AC_CHECK_PROGS(CTAGS, exctags ctags)
2561 AC_CHECK_PROGS(ETAGS, exetags etags)
2562
2563 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
2564
2565 if test "$cf_cv_mixedcase" = yes ; then
2566         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
2567 else
2568         MAKE_UPPER_TAGS=no
2569 fi
2570
2571 if test "$MAKE_UPPER_TAGS" = yes ; then
2572         MAKE_UPPER_TAGS=
2573 else
2574         MAKE_UPPER_TAGS="#"
2575 fi
2576
2577 if test "$MAKE_LOWER_TAGS" = yes ; then
2578         MAKE_LOWER_TAGS=
2579 else
2580         MAKE_LOWER_TAGS="#"
2581 fi
2582
2583 AC_SUBST(CTAGS)
2584 AC_SUBST(ETAGS)
2585
2586 AC_SUBST(MAKE_UPPER_TAGS)
2587 AC_SUBST(MAKE_LOWER_TAGS)
2588 ])dnl
2589 dnl ---------------------------------------------------------------------------
2590 dnl CF_MATH_LIB version: 11 updated: 2022/07/27 19:01:48
2591 dnl -----------
2592 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
2593 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
2594 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
2595 AC_DEFUN([CF_MATH_LIB],
2596 [
2597 AC_CACHE_CHECK(if -lm needed for math functions,
2598         cf_cv_need_libm,[
2599         AC_TRY_LINK([
2600                 #include <stdio.h>
2601                 #include <stdlib.h>
2602                 #include <math.h>
2603         ],
2604         [double x = rand(); printf("result = %g\\n", ]ifelse([$2],,sin(x),$2)[)],
2605         [cf_cv_need_libm=no],
2606         [cf_cv_need_libm=yes])])
2607
2608 if test "$cf_cv_need_libm" = yes
2609 then
2610
2611         cf_save_LIBS="$LIBS"
2612         LIBS="$LIBS -lm"
2613         AC_CACHE_CHECK(if -lm is available for math functions,
2614         cf_cv_have_libm,[
2615         AC_TRY_LINK([
2616                 #include <stdio.h>
2617                 #include <stdlib.h>
2618                 #include <math.h>
2619         ],
2620         [double x = rand(); printf("result = %g\\n", ]ifelse([$2],,sin(x),$2)[)],
2621         [cf_cv_have_libm=yes],
2622         [cf_cv_have_libm=no])])
2623         LIBS="$cf_save_LIBS"
2624
2625         if test "$cf_cv_have_libm" = yes
2626         then
2627                 ifelse($1,,[CF_ADD_LIB(m)],[$1=-lm])
2628         fi
2629 else
2630         cf_cv_have_libm=yes
2631 fi
2632
2633 if test "$cf_cv_have_libm" = yes
2634 then
2635         AC_DEFINE(HAVE_MATH_FUNCS,1,[Define to 1 if math functions are available])
2636 fi
2637 ])
2638 dnl ---------------------------------------------------------------------------
2639 dnl CF_MIXEDCASE_FILENAMES version: 9 updated: 2021/01/01 16:53:59
2640 dnl ----------------------
2641 dnl Check if the file-system supports mixed-case filenames.  If we're able to
2642 dnl create a lowercase name and see it as uppercase, it doesn't support that.
2643 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
2644 [
2645 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
2646 if test "$cross_compiling" = yes ; then
2647         case "$target_alias" in
2648         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*|darwin*)
2649                 cf_cv_mixedcase=no
2650                 ;;
2651         (*)
2652                 cf_cv_mixedcase=yes
2653                 ;;
2654         esac
2655 else
2656         rm -f conftest CONFTEST
2657         echo test >conftest
2658         if test -f CONFTEST ; then
2659                 cf_cv_mixedcase=no
2660         else
2661                 cf_cv_mixedcase=yes
2662         fi
2663         rm -f conftest CONFTEST
2664 fi
2665 ])
2666 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
2667 ])dnl
2668 dnl ---------------------------------------------------------------------------
2669 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
2670 dnl ----------
2671 dnl Write a debug message to config.log, along with the line number in the
2672 dnl configure script.
2673 AC_DEFUN([CF_MSG_LOG],[
2674 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
2675 ])dnl
2676 dnl ---------------------------------------------------------------------------
2677 dnl CF_NCURSES_CC_CHECK version: 6 updated: 2023/02/18 17:47:58
2678 dnl -------------------
2679 dnl Check if we can compile with ncurses' header file
2680 dnl $1 is the cache variable to set
2681 dnl $2 is the header-file to include
2682 dnl $3 is the root name (ncurses or ncursesw)
2683 AC_DEFUN([CF_NCURSES_CC_CHECK],[
2684         AC_TRY_COMPILE([
2685 ]ifelse($3,ncursesw,[
2686 #define _XOPEN_SOURCE_EXTENDED
2687 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
2688 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
2689 ])[
2690 #include <$2>],[
2691 #ifdef NCURSES_VERSION
2692 ]ifelse($3,ncursesw,[
2693 #ifndef WACS_BSSB
2694         #error WACS_BSSB is not defined
2695 #endif
2696 ])[
2697 printf("%s\\n", NCURSES_VERSION);
2698 #else
2699 #ifdef __NCURSES_H
2700 printf("old\\n");
2701 #else
2702         #error __NCURSES_H is not defined
2703 #endif
2704 #endif
2705         ]
2706         ,[$1=$2]
2707         ,[$1=no])
2708 ])dnl
2709 dnl ---------------------------------------------------------------------------
2710 dnl CF_NCURSES_CONFIG version: 28 updated: 2021/08/28 15:20:37
2711 dnl -----------------
2712 dnl Tie together the configure-script macros for ncurses, preferring these in
2713 dnl order:
2714 dnl a) ".pc" files for pkg-config, using $NCURSES_CONFIG_PKG
2715 dnl b) the "-config" script from ncurses, using $NCURSES_CONFIG
2716 dnl c) just plain libraries
2717 dnl
2718 dnl $1 is the root library name (default: "ncurses")
2719 AC_DEFUN([CF_NCURSES_CONFIG],[
2720 AC_REQUIRE([CF_PKG_CONFIG])
2721 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
2722 cf_have_ncuconfig=no
2723
2724 if test "x${PKG_CONFIG:=none}" != xnone; then
2725         AC_MSG_CHECKING(pkg-config for $cf_ncuconfig_root)
2726         if "$PKG_CONFIG" --exists $cf_ncuconfig_root ; then
2727                 AC_MSG_RESULT(yes)
2728
2729                 AC_MSG_CHECKING(if the $cf_ncuconfig_root package files work)
2730                 cf_have_ncuconfig=unknown
2731
2732                 cf_save_CFLAGS="$CFLAGS"
2733                 cf_save_CPPFLAGS="$CPPFLAGS"
2734                 cf_save_LIBS="$LIBS"
2735
2736                 cf_pkg_cflags="`$PKG_CONFIG --cflags $cf_ncuconfig_root`"
2737                 cf_pkg_libs="`$PKG_CONFIG --libs $cf_ncuconfig_root`"
2738
2739                 # while -W for passing linker flags is prevalent, it is not "standard".
2740                 # At least one wrapper for c89/c99 (in Apple's xcode) has its own
2741                 # incompatible _and_ non-standard -W option which gives an error.  Work
2742                 # around that pitfall.
2743                 case "x${CC}@@${cf_pkg_libs}@${cf_pkg_cflags}" in
2744                 (x*c[[89]]9@@*-W*)
2745                         CF_ADD_CFLAGS($cf_pkg_cflags)
2746                         CF_ADD_LIBS($cf_pkg_libs)
2747
2748                         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2749                                 [initscr(); mousemask(0,0); tigetstr((char *)0);],
2750                                 [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
2751                                         int main(void)
2752                                         { const char *xx = curses_version(); return (xx == 0); }],
2753                                         [cf_test_ncuconfig=yes],
2754                                         [cf_test_ncuconfig=no],
2755                                         [cf_test_ncuconfig=maybe])],
2756                                 [cf_test_ncuconfig=no])
2757
2758                         CFLAGS="$cf_save_CFLAGS"
2759                         CPPFLAGS="$cf_save_CPPFLAGS"
2760                         LIBS="$cf_save_LIBS"
2761
2762                         if test "x$cf_test_ncuconfig" != xyes; then
2763                                 cf_temp=`echo "x$cf_pkg_cflags" | sed -e s/^x// -e 's/-W[[^     ]]*//g'`
2764                                 cf_pkg_cflags="$cf_temp"
2765                                 cf_temp=`echo "x$cf_pkg_libs" | sed -e s/^x// -e 's/-W[[^       ]]*//g'`
2766                                 cf_pkg_libs="$cf_temp"
2767                         fi
2768                         ;;
2769                 esac
2770
2771                 CF_APPEND_CFLAGS($cf_pkg_cflags)
2772                 CF_ADD_LIBS($cf_pkg_libs)
2773
2774                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2775                         [initscr(); mousemask(0,0); tigetstr((char *)0);],
2776                         [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
2777                                 int main(void)
2778                                 { const char *xx = curses_version(); return (xx == 0); }],
2779                                 [cf_have_ncuconfig=yes],
2780                                 [cf_have_ncuconfig=no],
2781                                 [cf_have_ncuconfig=maybe])],
2782                         [cf_have_ncuconfig=no])
2783                 AC_MSG_RESULT($cf_have_ncuconfig)
2784                 test "$cf_have_ncuconfig" = maybe && cf_have_ncuconfig=yes
2785                 if test "$cf_have_ncuconfig" != "yes"
2786                 then
2787                         CPPFLAGS="$cf_save_CPPFLAGS"
2788                         LIBS="$cf_save_LIBS"
2789                         NCURSES_CONFIG_PKG=none
2790                 else
2791                         AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2792                         NCURSES_CONFIG_PKG=$cf_ncuconfig_root
2793                         CF_TERM_HEADER
2794                 fi
2795
2796         else
2797                 AC_MSG_RESULT(no)
2798                 NCURSES_CONFIG_PKG=none
2799         fi
2800 else
2801         NCURSES_CONFIG_PKG=none
2802 fi
2803
2804 if test "x$cf_have_ncuconfig" = "xno"; then
2805         cf_ncurses_config="${cf_ncuconfig_root}${NCURSES_CONFIG_SUFFIX}-config"; echo "Looking for ${cf_ncurses_config}"
2806
2807         CF_ACVERSION_CHECK(2.52,
2808                 [AC_CHECK_TOOLS(NCURSES_CONFIG, ${cf_ncurses_config} ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)],
2809                 [AC_PATH_PROGS(NCURSES_CONFIG,  ${cf_ncurses_config} ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)])
2810
2811         if test "$NCURSES_CONFIG" != none ; then
2812
2813                 CF_APPEND_CFLAGS(`$NCURSES_CONFIG --cflags`)
2814                 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
2815
2816                 # even with config script, some packages use no-override for curses.h
2817                 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
2818
2819                 dnl like CF_NCURSES_CPPFLAGS
2820                 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2821
2822                 dnl like CF_NCURSES_LIBS
2823                 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
2824                 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2825
2826                 dnl like CF_NCURSES_VERSION
2827                 cf_cv_ncurses_version="`$NCURSES_CONFIG --version`"
2828
2829         else
2830
2831                 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
2832                 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
2833
2834         fi
2835 else
2836         NCURSES_CONFIG=none
2837 fi
2838 ])dnl
2839 dnl ---------------------------------------------------------------------------
2840 dnl CF_NCURSES_CPPFLAGS version: 22 updated: 2021/01/02 09:31:20
2841 dnl -------------------
2842 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
2843 dnl the CPPFLAGS variable so we can include its header.
2844 dnl
2845 dnl The header files may be installed as either curses.h, or ncurses.h (would
2846 dnl be obsolete, except that some packagers prefer this name to distinguish it
2847 dnl from a "native" curses implementation).  If not installed for overwrite,
2848 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
2849 dnl /usr/include/ncurses), but someone may have installed overwriting the
2850 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
2851 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
2852 dnl the header.
2853 dnl
2854 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
2855 dnl is already in the include-path, don't even bother with this, since we cannot
2856 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
2857 dnl
2858 dnl The optional parameter gives the root name of the library, in case it is
2859 dnl not installed as the default curses library.  That is how the
2860 dnl wide-character version of ncurses is installed.
2861 AC_DEFUN([CF_NCURSES_CPPFLAGS],
2862 [AC_REQUIRE([CF_WITH_CURSES_DIR])
2863
2864 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
2865 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
2866
2867 test -n "$cf_cv_curses_dir" && \
2868 test "$cf_cv_curses_dir" != "no" && { \
2869   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
2870 }
2871
2872 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
2873         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
2874         { test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw; } && cf_header_list="$cf_header_list curses.h ncurses.h"
2875         for cf_header in $cf_header_list
2876         do
2877                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
2878                 test "$cf_cv_ncurses_h" != no && break
2879         done
2880 ])
2881
2882 CF_NCURSES_HEADER
2883 CF_TERM_HEADER
2884
2885 # some applications need this, but should check for NCURSES_VERSION
2886 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2887
2888 CF_NCURSES_VERSION
2889 ])dnl
2890 dnl ---------------------------------------------------------------------------
2891 dnl CF_NCURSES_EXT_FUNCS version: 4 updated: 2012/10/06 16:39:58
2892 dnl --------------------
2893 dnl Since 2007/11/17, ncurses has defined NCURSES_EXT_FUNCS; earlier versions
2894 dnl may provide these functions.  Define the symbol if it is not defined, and
2895 dnl if it is valid.
2896 AC_DEFUN([CF_NCURSES_EXT_FUNCS],
2897 [
2898 AC_CACHE_CHECK(for ncurses extended functions,cf_cv_ncurses_ext_funcs,[
2899 AC_TRY_COMPILE([
2900 #include <${cf_cv_ncurses_header:-curses.h}>],
2901 [
2902 int x = NCURSES_EXT_FUNCS
2903 ],[cf_cv_ncurses_ext_funcs=defined],[
2904 AC_TRY_LINK([
2905 #include <${cf_cv_ncurses_header:-curses.h}>],
2906 [
2907         (void) assume_default_colors (0, 0);
2908         (void) curses_version ();
2909         (void) define_key (0, 0);
2910         (void) is_term_resized (0, 0);
2911         (void) key_defined (0);
2912         (void) keybound (0, 0);
2913         (void) keyok (0, 0);
2914         (void) resize_term (0, 0);
2915         (void) resizeterm (0, 0);
2916         (void) use_default_colors ();
2917         (void) use_extended_names (0);
2918         (void) wresize (0, 0, 0);],
2919         [cf_cv_ncurses_ext_funcs=yes],
2920         [cf_cv_ncurses_ext_funcs=no])
2921 ])
2922 ])
2923 test "$cf_cv_ncurses_ext_funcs" = yes && AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 if we have ncurses extensions])
2924 ])dnl
2925 dnl ---------------------------------------------------------------------------
2926 dnl CF_NCURSES_HEADER version: 7 updated: 2021/01/04 19:33:05
2927 dnl -----------------
2928 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
2929 dnl variations of ncurses' installs.
2930 dnl
2931 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
2932 AC_DEFUN([CF_NCURSES_HEADER],[
2933
2934 if test "$cf_cv_ncurses_h" != no ; then
2935         cf_cv_ncurses_header=$cf_cv_ncurses_h
2936 else
2937
2938 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
2939         test -n "$verbose" && echo
2940         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
2941         test -n "$verbose" && echo "search path $cf_search"
2942         cf_save2_CPPFLAGS="$CPPFLAGS"
2943         for cf_incdir in $cf_search
2944         do
2945                 CF_ADD_INCDIR($cf_incdir)
2946                 for cf_header in \
2947                         ncurses.h \
2948                         curses.h
2949                 do
2950                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
2951                         if test "$cf_cv_ncurses_h2" != no ; then
2952                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
2953                                 test -n "$verbose" && echo $ECHO_N "    ... found $ECHO_C" 1>&AC_FD_MSG
2954                                 break
2955                         fi
2956                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
2957                 done
2958                 CPPFLAGS="$cf_save2_CPPFLAGS"
2959                 test "$cf_cv_ncurses_h2" != no && break
2960         done
2961         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
2962         ])
2963
2964         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
2965         cf_cv_ncurses_header="`basename "$cf_cv_ncurses_h2"`"
2966         if test "`basename "$cf_1st_incdir"`" = "$cf_ncuhdr_root" ; then
2967                 cf_cv_ncurses_header="$cf_ncuhdr_root/$cf_cv_ncurses_header"
2968         fi
2969         CF_ADD_INCDIR($cf_1st_incdir)
2970
2971 fi
2972
2973 # Set definitions to allow ifdef'ing for ncurses.h
2974
2975 case "$cf_cv_ncurses_header" in
2976 (*ncurses.h)
2977         AC_DEFINE(HAVE_NCURSES_H,1,[Define to 1 if we have ncurses.h])
2978         ;;
2979 esac
2980
2981 case "$cf_cv_ncurses_header" in
2982 (ncurses/curses.h|ncurses/ncurses.h)
2983         AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Define to 1 if we have ncurses/ncurses.h])
2984         ;;
2985 (ncursesw/curses.h|ncursesw/ncurses.h)
2986         AC_DEFINE(HAVE_NCURSESW_NCURSES_H,1,[Define to 1 if we have ncursesw/ncurses.h])
2987         ;;
2988 esac
2989
2990 ])dnl
2991 dnl ---------------------------------------------------------------------------
2992 dnl CF_NCURSES_LIBS version: 21 updated: 2021/09/04 06:37:12
2993 dnl ---------------
2994 dnl Look for the ncurses library.  This is a little complicated on Linux,
2995 dnl because it may be linked with the gpm (general purpose mouse) library.
2996 dnl Some distributions have gpm linked with (bsd) curses, which makes it
2997 dnl unusable with ncurses.  However, we don't want to link with gpm unless
2998 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
2999 dnl and the linker will record a dependency.
3000 dnl
3001 dnl The optional parameter gives the root name of the library, in case it is
3002 dnl not installed as the default curses library.  That is how the
3003 dnl wide-character version of ncurses is installed.
3004 AC_DEFUN([CF_NCURSES_LIBS],
3005 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
3006
3007 cf_nculib_root=ifelse($1,,ncurses,$1)
3008         # This works, except for the special case where we find gpm, but
3009         # ncurses is in a nonstandard location via $LIBS, and we really want
3010         # to link gpm.
3011 cf_ncurses_LIBS=""
3012 cf_ncurses_SAVE="$LIBS"
3013 AC_CHECK_LIB(gpm,Gpm_Open,
3014         [AC_CHECK_LIB(gpm,initscr,
3015                 [LIBS="$cf_ncurses_SAVE"],
3016                 [cf_ncurses_LIBS="-lgpm"])])
3017
3018 case "$host_os" in
3019 (freebsd*)
3020         # This is only necessary if you are linking against an obsolete
3021         # version of ncurses (but it should do no harm, since it is static).
3022         if test "$cf_nculib_root" = ncurses ; then
3023                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
3024         fi
3025         ;;
3026 esac
3027
3028 CF_ADD_LIBS($cf_ncurses_LIBS)
3029
3030 if test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no"
3031 then
3032         CF_ADD_LIBS(-l$cf_nculib_root)
3033 else
3034         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
3035                 [#include <${cf_cv_ncurses_header:-curses.h}>],
3036                 [initscr()],
3037                 initscr)
3038 fi
3039
3040 if test -n "$cf_ncurses_LIBS" ; then
3041         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
3042         cf_ncurses_SAVE="$LIBS"
3043         for p in $cf_ncurses_LIBS ; do
3044                 q=`echo "$LIBS" | sed -e "s%$p %%" -e "s%$p$%%"`
3045                 if test "$q" != "$LIBS" ; then
3046                         LIBS="$q"
3047                 fi
3048         done
3049         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
3050                 [initscr(); mousemask(0,0); tigetstr((char *)0);],
3051                 [AC_MSG_RESULT(yes)],
3052                 [AC_MSG_RESULT(no)
3053                  LIBS="$cf_ncurses_SAVE"])
3054 fi
3055
3056 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
3057 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
3058 ])dnl
3059 dnl ---------------------------------------------------------------------------
3060 dnl CF_NCURSES_PTHREADS version: 2 updated: 2016/04/22 05:07:41
3061 dnl -------------------
3062 dnl Use this followup check to ensure that we link with pthreads if ncurses
3063 dnl uses it.
3064 AC_DEFUN([CF_NCURSES_PTHREADS],[
3065 : ${cf_nculib_root:=ifelse($1,,ncurses,$1)}
3066 AC_CHECK_LIB($cf_nculib_root,_nc_init_pthreads,
3067         cf_cv_ncurses_pthreads=yes,
3068         cf_cv_ncurses_pthreads=no)
3069 if test "$cf_cv_ncurses_pthreads" = yes
3070 then
3071         CF_ADD_LIBS(-lpthread)
3072 fi
3073 ])dnl
3074 dnl ---------------------------------------------------------------------------
3075 dnl CF_NCURSES_VERSION version: 17 updated: 2023/01/05 18:54:02
3076 dnl ------------------
3077 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
3078 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
3079 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
3080 AC_DEFUN([CF_NCURSES_VERSION],
3081 [
3082 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
3083 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
3084         cf_cv_ncurses_version=no
3085         cf_tempfile=out$$
3086         rm -f "$cf_tempfile"
3087         AC_TRY_RUN([
3088 $ac_includes_default
3089
3090 #include <${cf_cv_ncurses_header:-curses.h}>
3091
3092 int main(void)
3093 {
3094         FILE *fp = fopen("$cf_tempfile", "w");
3095 #ifdef NCURSES_VERSION
3096 # ifdef NCURSES_VERSION_PATCH
3097         fprintf(fp, "%s.%d\\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
3098 # else
3099         fprintf(fp, "%s\\n", NCURSES_VERSION);
3100 # endif
3101 #else
3102 # ifdef __NCURSES_H
3103         fprintf(fp, "old\\n");
3104 # else
3105         make an error
3106 # endif
3107 #endif
3108         ${cf_cv_main_return:-return}(0);
3109 }],[
3110         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
3111
3112         # This will not work if the preprocessor splits the line after the
3113         # Autoconf token.  The 'unproto' program does that.
3114         cat > "conftest.$ac_ext" <<EOF
3115 #include <${cf_cv_ncurses_header:-curses.h}>
3116 #undef Autoconf
3117 #ifdef NCURSES_VERSION
3118 Autoconf NCURSES_VERSION
3119 #else
3120 #ifdef __NCURSES_H
3121 Autoconf "old"
3122 #endif
3123 ;
3124 #endif
3125 EOF
3126         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
3127         AC_TRY_EVAL(cf_try)
3128         if test -f conftest.out ; then
3129                 cf_out=`sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%' conftest.out`
3130                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
3131                 rm -f conftest.out
3132         fi
3133 ])
3134         rm -f "$cf_tempfile"
3135 ])
3136 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
3137 ])dnl
3138 dnl ---------------------------------------------------------------------------
3139 dnl CF_NCURSES_WRAP_PREFIX version: 1 updated: 2009/03/28 16:08:10
3140 dnl ----------------------
3141 dnl Check for ncurses "wrap-prefix" used for public variables which have been
3142 dnl wrapped with a function to help with concurrency control.
3143 AC_DEFUN([CF_NCURSES_WRAP_PREFIX],
3144 [
3145 AC_MSG_CHECKING(for ncurses wrap-prefix)
3146 AC_ARG_WITH(ncurses-wrap-prefix,
3147         [  --with-ncurses-wrap-prefix naming-prefix for ncurses wrapped-variables],
3148         [NCURSES_WRAP_PREFIX=$withval],
3149         [NCURSES_WRAP_PREFIX=_nc_])
3150 AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
3151
3152 AC_SUBST(NCURSES_WRAP_PREFIX)
3153 ])
3154 dnl ---------------------------------------------------------------------------
3155 dnl CF_NETBSD_FORM_H version: 2 updated: 2012/10/06 16:39:58
3156 dnl ----------------
3157 dnl Check for NetBSD's form.h, which is incompatible with SVr4 and ncurses.
3158 dnl Some workarounds are needed in client programs to allow them to compile.
3159 AC_DEFUN([CF_NETBSD_FORM_H],[
3160 AC_CACHE_CHECK(for NetBSD form.h,cf_cv_netbsd_form_h,[
3161 AC_TRY_COMPILE([
3162 #include <${cf_cv_ncurses_header:-curses.h}>
3163 #include <form.h>
3164 ],[
3165         FORM *form;
3166         int y = current_field(form)->cursor_ypos;
3167         int x = current_field(form)->cursor_xpos;
3168 ],[cf_cv_netbsd_form_h=yes
3169 ],[cf_cv_netbsd_form_h=no])
3170 ])
3171
3172 test "$cf_cv_netbsd_form_h" = yes && AC_DEFINE(HAVE_NETBSD_FORM_H,1,[Define to 1 if we appear to be using NetBSD form.h])
3173 ])dnl
3174 dnl ---------------------------------------------------------------------------
3175 dnl CF_NETBSD_MENU_H version: 2 updated: 2012/10/06 16:39:58
3176 dnl ----------------
3177 dnl Check for NetBSD's menu.h, which is incompatible with SVr4 and ncurses.
3178 dnl Some workarounds are needed in client programs to allow them to compile.
3179 AC_DEFUN([CF_NETBSD_MENU_H],[
3180 AC_CACHE_CHECK(for NetBSD menu.h,cf_cv_netbsd_menu_h,[
3181 AC_TRY_COMPILE([
3182 #include <${cf_cv_ncurses_header:-curses.h}>
3183 #include <menu.h>
3184 ],[
3185         MENU *menu;
3186         int y = menu->max_item_width;
3187 ],[cf_cv_netbsd_menu_h=yes
3188 ],[cf_cv_netbsd_menu_h=no])
3189 ])
3190
3191 test "$cf_cv_netbsd_menu_h" = yes && AC_DEFINE(HAVE_NETBSD_MENU_H,1,[Define to 1 if we appear to be using NetBSD menu.h])
3192 ])dnl
3193 dnl ---------------------------------------------------------------------------
3194 dnl CF_NO_LEAKS_OPTION version: 9 updated: 2021/06/13 19:45:41
3195 dnl ------------------
3196 dnl see CF_WITH_NO_LEAKS
3197 dnl
3198 dnl $1 = option/name
3199 dnl $2 = help-text
3200 dnl $3 = symbol to define if the option is set
3201 dnl $4 = additional actions to take if the option is set
3202 AC_DEFUN([CF_NO_LEAKS_OPTION],[
3203 AC_MSG_CHECKING(if you want to use $1 for testing)
3204 AC_ARG_WITH($1,
3205         [$2],
3206         [case "x$withval" in
3207         (x|xno) ;;
3208         (*)
3209                 : "${with_cflags:=-g}"
3210                 : "${enable_leaks:=no}"
3211                 with_$1=yes
3212                 AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
3213          $4
3214 ])
3215                 ;;
3216         esac],
3217         [with_$1=])
3218 AC_MSG_RESULT(${with_$1:-no})
3219
3220 case ".$with_cflags" in
3221 (.*-g*)
3222         case .$CFLAGS in
3223         (.*-g*)
3224                 ;;
3225         (*)
3226                 CF_ADD_CFLAGS([-g])
3227                 ;;
3228         esac
3229         ;;
3230 esac
3231 ])dnl
3232 dnl ---------------------------------------------------------------------------
3233 dnl CF_PATH_SYNTAX version: 18 updated: 2020/12/31 18:40:20
3234 dnl --------------
3235 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
3236 dnl begins with one of the prefix/exec_prefix variables, and then again if the
3237 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
3238 dnl delayed evaluation of those symbols.
3239 AC_DEFUN([CF_PATH_SYNTAX],[
3240 if test "x$prefix" != xNONE; then
3241         cf_path_syntax="$prefix"
3242 else
3243         cf_path_syntax="$ac_default_prefix"
3244 fi
3245
3246 case ".[$]$1" in
3247 (.\[$]\(*\)*|.\'*\'*)
3248         ;;
3249 (..|./*|.\\*)
3250         ;;
3251 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
3252         ;;
3253 (.\[$]\{*prefix\}*|.\[$]\{*dir\}*)
3254         eval $1="[$]$1"
3255         case ".[$]$1" in
3256         (.NONE/*)
3257                 $1=`echo "[$]$1" | sed -e s%NONE%$cf_path_syntax%`
3258                 ;;
3259         esac
3260         ;;
3261 (.no|.NONE/*)
3262         $1=`echo "[$]$1" | sed -e s%NONE%$cf_path_syntax%`
3263         ;;
3264 (*)
3265         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
3266         ;;
3267 esac
3268 ])dnl
3269 dnl ---------------------------------------------------------------------------
3270 dnl CF_PDCURSES_X11 version: 15 updated: 2021/01/02 09:31:20
3271 dnl ---------------
3272 dnl Configure for PDCurses' X11 library
3273 AC_DEFUN([CF_PDCURSES_X11],[
3274 AC_REQUIRE([CF_X_ATHENA])
3275
3276 CF_ACVERSION_CHECK(2.52,
3277         [AC_CHECK_TOOLS(XCURSES_CONFIG, xcurses-config, none)],
3278         [AC_PATH_PROGS(XCURSES_CONFIG, xcurses-config, none)])
3279
3280 if test "$XCURSES_CONFIG" != none ; then
3281
3282 CF_ADD_CFLAGS(`$XCURSES_CONFIG --cflags`)
3283 CF_ADD_LIBS(`$XCURSES_CONFIG --libs`)
3284
3285 cf_cv_lib_XCurses=yes
3286
3287 else
3288
3289 LDFLAGS="$LDFLAGS $X_LIBS"
3290 CF_CHECK_CFLAGS($X_CFLAGS)
3291 AC_CHECK_LIB(X11,XOpenDisplay,
3292         [CF_ADD_LIBS(-lX11)],,
3293         [$X_PRE_LIBS $LIBS $X_EXTRA_LIBS])
3294 AC_CACHE_CHECK(for XCurses library,cf_cv_lib_XCurses,[
3295 CF_ADD_LIBS(-lXCurses)
3296 AC_TRY_LINK([
3297 #include <xcurses.h>
3298 char *XCursesProgramName = "test";
3299 ],[XCursesExit();],
3300 [cf_cv_lib_XCurses=yes],
3301 [cf_cv_lib_XCurses=no])
3302 ])
3303
3304 fi
3305
3306 if test "$cf_cv_lib_XCurses" = yes ; then
3307         AC_DEFINE(UNIX,1,[Define to 1 if using PDCurses on Unix])
3308         AC_DEFINE(XCURSES,1,[Define to 1 if using PDCurses on Unix])
3309         AC_CHECK_HEADER(xcurses.h, AC_DEFINE(HAVE_XCURSES,1,[Define to 1 if using PDCurses on Unix]))
3310 else
3311         AC_MSG_ERROR(Cannot link with XCurses)
3312 fi
3313 ])dnl
3314 dnl ---------------------------------------------------------------------------
3315 dnl CF_PKG_CONFIG version: 13 updated: 2023/10/28 11:59:01
3316 dnl -------------
3317 dnl Check for the package-config program, unless disabled by command-line.
3318 dnl
3319 dnl Sets $PKG_CONFIG to the pathname of the pkg-config program.
3320 AC_DEFUN([CF_PKG_CONFIG],
3321 [
3322 AC_MSG_CHECKING(if you want to use pkg-config)
3323 AC_ARG_WITH(pkg-config,
3324         [[  --with-pkg-config[=CMD] enable/disable use of pkg-config and its name CMD]],
3325         [cf_pkg_config=$withval],
3326         [cf_pkg_config=yes])
3327 AC_MSG_RESULT($cf_pkg_config)
3328
3329 case "$cf_pkg_config" in
3330 (no)
3331         PKG_CONFIG=none
3332         ;;
3333 (yes)
3334         CF_ACVERSION_CHECK(2.52,
3335                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
3336                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
3337         ;;
3338 (*)
3339         PKG_CONFIG=$withval
3340         ;;
3341 esac
3342
3343 test -z "$PKG_CONFIG" && PKG_CONFIG=none
3344 if test "$PKG_CONFIG" != none ; then
3345         CF_PATH_SYNTAX(PKG_CONFIG)
3346 elif test "x$cf_pkg_config" != xno ; then
3347         AC_MSG_WARN(pkg-config is not installed)
3348 fi
3349
3350 AC_SUBST(PKG_CONFIG)
3351 ])dnl
3352 dnl ---------------------------------------------------------------------------
3353 dnl CF_POSIX_C_SOURCE version: 12 updated: 2023/02/18 17:41:25
3354 dnl -----------------
3355 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
3356 dnl
3357 dnl     POSIX.1-1990                            _POSIX_SOURCE
3358 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
3359 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
3360 dnl             Bindings Option
3361 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
3362 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
3363 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
3364 dnl
3365 dnl Parameters:
3366 dnl     $1 is the nominal value for _POSIX_C_SOURCE
3367 AC_DEFUN([CF_POSIX_C_SOURCE],
3368 [AC_REQUIRE([CF_POSIX_VISIBLE])dnl
3369
3370 if test "$cf_cv_posix_visible" = no; then
3371
3372 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
3373
3374 cf_save_CFLAGS="$CFLAGS"
3375 cf_save_CPPFLAGS="$CPPFLAGS"
3376
3377 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
3378 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
3379
3380 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
3381         CF_MSG_LOG(if the symbol is already defined go no further)
3382         AC_TRY_COMPILE([#include <sys/types.h>],[
3383 #ifndef _POSIX_C_SOURCE
3384 #error _POSIX_C_SOURCE is not defined
3385 #endif],
3386         [cf_cv_posix_c_source=no],
3387         [cf_want_posix_source=no
3388          case .$cf_POSIX_C_SOURCE in
3389          (.[[12]]??*)
3390                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
3391                 ;;
3392          (.2)
3393                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
3394                 cf_want_posix_source=yes
3395                 ;;
3396          (.*)
3397                 cf_want_posix_source=yes
3398                 ;;
3399          esac
3400          if test "$cf_want_posix_source" = yes ; then
3401                 AC_TRY_COMPILE([#include <sys/types.h>],[
3402 #ifdef _POSIX_SOURCE
3403 #error _POSIX_SOURCE is defined
3404 #endif],[],
3405                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
3406          fi
3407          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
3408          CFLAGS="$cf_trim_CFLAGS"
3409          CPPFLAGS="$cf_trim_CPPFLAGS"
3410          CF_APPEND_TEXT(CPPFLAGS,$cf_cv_posix_c_source)
3411          CF_MSG_LOG(if the second compile does not leave our definition intact error)
3412          AC_TRY_COMPILE([#include <sys/types.h>],[
3413 #ifndef _POSIX_C_SOURCE
3414 #error _POSIX_C_SOURCE is not defined
3415 #endif],,
3416          [cf_cv_posix_c_source=no])
3417          CFLAGS="$cf_save_CFLAGS"
3418          CPPFLAGS="$cf_save_CPPFLAGS"
3419         ])
3420 ])
3421
3422 if test "$cf_cv_posix_c_source" != no ; then
3423         CFLAGS="$cf_trim_CFLAGS"
3424         CPPFLAGS="$cf_trim_CPPFLAGS"
3425         CF_ADD_CFLAGS($cf_cv_posix_c_source)
3426 fi
3427
3428 fi # cf_cv_posix_visible
3429
3430 ])dnl
3431 dnl ---------------------------------------------------------------------------
3432 dnl CF_POSIX_VISIBLE version: 1 updated: 2018/12/31 20:46:17
3433 dnl ----------------
3434 dnl POSIX documents test-macros which an application may set before any system
3435 dnl headers are included to make features available.
3436 dnl
3437 dnl Some BSD platforms (originally FreeBSD, but copied by a few others)
3438 dnl diverged from POSIX in 2002 by setting symbols which make all of the most
3439 dnl recent features visible in the system header files unless the application
3440 dnl overrides the corresponding test-macros.  Doing that introduces portability
3441 dnl problems.
3442 dnl
3443 dnl This macro makes a special check for the symbols used for this, to avoid a
3444 dnl conflicting definition.
3445 AC_DEFUN([CF_POSIX_VISIBLE],
3446 [
3447 AC_CACHE_CHECK(if the POSIX test-macros are already defined,cf_cv_posix_visible,[
3448 AC_TRY_COMPILE([#include <stdio.h>],[
3449 #if defined(__POSIX_VISIBLE) && ((__POSIX_VISIBLE - 0L) > 0) \
3450         && defined(__XSI_VISIBLE) && ((__XSI_VISIBLE - 0L) > 0) \
3451         && defined(__BSD_VISIBLE) && ((__BSD_VISIBLE - 0L) > 0) \
3452         && defined(__ISO_C_VISIBLE) && ((__ISO_C_VISIBLE - 0L) > 0)
3453 #error conflicting symbols found
3454 #endif
3455 ],[cf_cv_posix_visible=no],[cf_cv_posix_visible=yes])
3456 ])
3457 ])dnl
3458 dnl ---------------------------------------------------------------------------
3459 dnl CF_PRG_RULES version: 2 updated: 2021/01/01 13:31:04
3460 dnl ------------
3461 dnl Append definitions and rules for the given programs to the subdirectory
3462 dnl Makefiles, and the recursion rule for the top-level Makefile.
3463 dnl
3464 dnl parameters
3465 dnl     $1 = script to run
3466 dnl     $2 = list of subdirectories
3467 dnl
3468 dnl variables
3469 dnl     $AWK
3470 AC_DEFUN([CF_PRG_RULES],
3471 [
3472 for cf_dir in $2
3473 do
3474         if test ! -d "$srcdir/$cf_dir" ; then
3475                 continue
3476         elif test -f "$srcdir/$cf_dir/programs" ; then
3477                 $AWK -f $1 "$srcdir/$cf_dir/programs" >>$cf_dir/Makefile
3478         fi
3479 done
3480
3481 ])dnl
3482 dnl ---------------------------------------------------------------------------
3483 dnl CF_PROG_CC version: 5 updated: 2019/12/31 08:53:54
3484 dnl ----------
3485 dnl standard check for CC, plus followup sanity checks
3486 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
3487 AC_DEFUN([CF_PROG_CC],[
3488 CF_ACVERSION_CHECK(2.53,
3489         [AC_MSG_WARN(this will incorrectly handle gnatgcc choice)
3490          AC_REQUIRE([AC_PROG_CC])],
3491         [])
3492 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
3493 CF_GCC_VERSION
3494 CF_ACVERSION_CHECK(2.52,
3495         [AC_PROG_CC_STDC],
3496         [CF_ANSI_CC_REQD])
3497 CF_CC_ENV_FLAGS
3498 ])dnl
3499 dnl ---------------------------------------------------------------------------
3500 dnl CF_PROG_INSTALL version: 10 updated: 2021/01/04 19:33:05
3501 dnl ---------------
3502 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
3503 dnl misc/tabset install won't work properly.  Usually this happens only when
3504 dnl using the fallback mkinstalldirs script
3505 AC_DEFUN([CF_PROG_INSTALL],
3506 [AC_PROG_INSTALL
3507 case $INSTALL in
3508 (/*)
3509         ;;
3510 (*)
3511         CF_DIRNAME(cf_dir,$INSTALL)
3512         test -z "$cf_dir" && cf_dir=.
3513         INSTALL="`cd \"$cf_dir\" && pwd`"/"`echo "$INSTALL" | sed -e 's%^.*/%%'`"
3514         ;;
3515 esac
3516 ])dnl
3517 dnl ---------------------------------------------------------------------------
3518 dnl CF_PROG_LINT version: 5 updated: 2022/08/20 15:44:13
3519 dnl ------------
3520 AC_DEFUN([CF_PROG_LINT],
3521 [
3522 AC_CHECK_PROGS(LINT, lint cppcheck splint)
3523 case "x$LINT" in
3524 (xcppcheck|x*/cppcheck)
3525         test -z "$LINT_OPTS" && LINT_OPTS="--enable=all"
3526         ;;
3527 esac
3528 AC_SUBST(LINT_OPTS)
3529 AC_SUBST(LINT_LIBS)
3530 ])dnl
3531 dnl ---------------------------------------------------------------------------
3532 dnl CF_REMOVE_CFLAGS version: 3 updated: 2021/09/05 17:25:40
3533 dnl ----------------
3534 dnl Remove a given option from CFLAGS/CPPFLAGS
3535 dnl $1 = option to remove
3536 dnl $2 = variable to update
3537 dnl $3 = nonempty to allow verbose message
3538 define([CF_REMOVE_CFLAGS],
3539 [
3540 cf_tmp_cflag=`echo "x$1" | sed -e 's/^.//' -e 's/=.*//'`
3541 while true
3542 do
3543         cf_old_cflag=`echo "x[$]$2" | sed -e 's/^.//' -e 's/[[  ]][[    ]]*-/ -/g' -e "s%$cf_tmp_cflag\\(=[[^   ]][[^   ]]*\\)\?%%" -e 's/^[[   ]]*//' -e 's%[[ ]][[ ]]*-D% -D%g' -e 's%[[ ]][[ ]]*-I% -I%g'`
3544         test "[$]$2" != "$cf_old_cflag" || break
3545         ifelse([$3],,,[CF_VERBOSE(removing old option $1 from $2)])
3546         $2="$cf_old_cflag"
3547 done
3548 ])dnl
3549 dnl ---------------------------------------------------------------------------
3550 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
3551 dnl ----------------
3552 dnl Remove all -U and -D options that refer to the given symbol from a list
3553 dnl of C compiler options.  This works around the problem that not all
3554 dnl compilers process -U and -D options from left-to-right, so a -U option
3555 dnl cannot be used to cancel the effect of a preceding -D option.
3556 dnl
3557 dnl $1 = target (which could be the same as the source variable)
3558 dnl $2 = source (including '$')
3559 dnl $3 = symbol to remove
3560 define([CF_REMOVE_DEFINE],
3561 [
3562 $1=`echo "$2" | \
3563         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
3564                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
3565 ])dnl
3566 dnl ---------------------------------------------------------------------------
3567 dnl CF_RESTORE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:47:45
3568 dnl ---------------------
3569 dnl Restore flags saved in CF_SAVE_XTRA_FLAGS
3570 dnl $1 = name of current macro
3571 define([CF_RESTORE_XTRA_FLAGS],
3572 [
3573 LIBS="$cf_save_LIBS_$1"
3574 CFLAGS="$cf_save_CFLAGS_$1"
3575 CPPFLAGS="$cf_save_CPPFLAGS_$1"
3576 ])dnl
3577 dnl ---------------------------------------------------------------------------
3578 dnl CF_RPATH_HACK version: 13 updated: 2021/01/03 18:30:50
3579 dnl -------------
3580 AC_DEFUN([CF_RPATH_HACK],
3581 [AC_REQUIRE([AC_PROG_FGREP])dnl
3582 AC_REQUIRE([CF_LD_RPATH_OPT])dnl
3583
3584 AC_MSG_CHECKING(for updated LDFLAGS)
3585 if test -n "$LD_RPATH_OPT" ; then
3586         AC_MSG_RESULT(maybe)
3587
3588         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
3589         cf_rpath_list="/usr/lib /lib"
3590         if test "$cf_ldd_prog" != no
3591         then
3592                 cf_rpath_oops=
3593
3594 AC_TRY_LINK([#include <stdio.h>],
3595                 [printf("Hello");],
3596                 [cf_rpath_oops=`"$cf_ldd_prog" "conftest$ac_exeext" | ${FGREP-fgrep} ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
3597                  cf_rpath_list=`"$cf_ldd_prog" "conftest$ac_exeext" | ${FGREP-fgrep} / | sed -e 's%^.*[[        ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
3598
3599                 # If we passed the link-test, but get a "not found" on a given library,
3600                 # this could be due to inept reconfiguration of gcc to make it only
3601                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
3602                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
3603                 # /usr/local libraries.
3604                 if test -n "$cf_rpath_oops"
3605                 then
3606                         for cf_rpath_src in $cf_rpath_oops
3607                         do
3608                                 for cf_rpath_dir in \
3609                                         /usr/local \
3610                                         /usr/pkg \
3611                                         /opt/sfw
3612                                 do
3613                                         if test -f "$cf_rpath_dir/lib/$cf_rpath_src"
3614                                         then
3615                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
3616                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
3617                                                 break
3618                                         fi
3619                                 done
3620                         done
3621                 fi
3622         fi
3623
3624         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
3625
3626         CF_RPATH_HACK_2(LDFLAGS)
3627         CF_RPATH_HACK_2(LIBS)
3628
3629         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
3630 else
3631         AC_MSG_RESULT(no)
3632 fi
3633 AC_SUBST(EXTRA_LDFLAGS)
3634 ])dnl
3635 dnl ---------------------------------------------------------------------------
3636 dnl CF_RPATH_HACK_2 version: 8 updated: 2021/01/01 13:31:04
3637 dnl ---------------
3638 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
3639 dnl EXTRA_LDFLAGS for each -L option found.
3640 dnl
3641 dnl $cf_rpath_list contains a list of directories to ignore.
3642 dnl
3643 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
3644 dnl      but LIBS often has misplaced -L options.
3645 AC_DEFUN([CF_RPATH_HACK_2],
3646 [
3647 CF_VERBOSE(...checking $1 [$]$1)
3648
3649 cf_rpath_dst=
3650 for cf_rpath_src in [$]$1
3651 do
3652         case "$cf_rpath_src" in
3653         (-L*)
3654
3655                 # check if this refers to a directory which we will ignore
3656                 cf_rpath_skip=no
3657                 if test -n "$cf_rpath_list"
3658                 then
3659                         for cf_rpath_item in $cf_rpath_list
3660                         do
3661                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
3662                                 then
3663                                         cf_rpath_skip=yes
3664                                         break
3665                                 fi
3666                         done
3667                 fi
3668
3669                 if test "$cf_rpath_skip" = no
3670                 then
3671                         # transform the option
3672                         if test "$LD_RPATH_OPT" = "-R " ; then
3673                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
3674                         else
3675                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
3676                         fi
3677
3678                         # if we have not already added this, add it now
3679                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
3680                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
3681                         then
3682                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
3683                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
3684                         fi
3685                 fi
3686                 ;;
3687         esac
3688         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
3689 done
3690 $1=$cf_rpath_dst
3691
3692 CF_VERBOSE(...checked $1 [$]$1)
3693 AC_SUBST(EXTRA_LDFLAGS)
3694 ])dnl
3695 dnl ---------------------------------------------------------------------------
3696 dnl CF_SAVE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:46:44
3697 dnl ------------------
3698 dnl Use this macro to save CFLAGS/CPPFLAGS/LIBS before checks against X headers
3699 dnl and libraries which do not update those variables.
3700 dnl
3701 dnl $1 = name of current macro
3702 define([CF_SAVE_XTRA_FLAGS],
3703 [
3704 cf_save_LIBS_$1="$LIBS"
3705 cf_save_CFLAGS_$1="$CFLAGS"
3706 cf_save_CPPFLAGS_$1="$CPPFLAGS"
3707 LIBS="$LIBS ${X_PRE_LIBS} ${X_LIBS} ${X_EXTRA_LIBS}"
3708 for cf_X_CFLAGS in $X_CFLAGS
3709 do
3710         case "x$cf_X_CFLAGS" in
3711         x-[[IUD]]*)
3712                 CPPFLAGS="$CPPFLAGS $cf_X_CFLAGS"
3713                 ;;
3714         *)
3715                 CFLAGS="$CFLAGS $cf_X_CFLAGS"
3716                 ;;
3717         esac
3718 done
3719 ])dnl
3720 dnl ---------------------------------------------------------------------------
3721 dnl CF_SIGWINCH version: 7 updated: 2023/02/18 17:41:25
3722 dnl -----------
3723 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
3724 dnl programs need this test).
3725 dnl
3726 dnl This is really a Mac OS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
3727 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
3728 dnl winsize declaration is left alone - we may revisit this if Apple choose to
3729 dnl break that part of the interface as well.
3730 AC_DEFUN([CF_SIGWINCH],
3731 [
3732 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
3733         AC_TRY_COMPILE([
3734 #include <sys/types.h>
3735 #include <sys/signal.h>
3736 ],[int x = SIGWINCH; (void)x],
3737         [cf_cv_define_sigwinch=yes],
3738         [AC_TRY_COMPILE([
3739 #undef _XOPEN_SOURCE
3740 #undef _POSIX_SOURCE
3741 #undef _POSIX_C_SOURCE
3742 #include <sys/types.h>
3743 #include <sys/signal.h>
3744 ],[int x = SIGWINCH; (void)x],
3745         [cf_cv_define_sigwinch=maybe],
3746         [cf_cv_define_sigwinch=no])
3747 ])
3748 ])
3749
3750 if test "$cf_cv_define_sigwinch" = maybe ; then
3751 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
3752 cf_cv_fixup_sigwinch=unknown
3753 cf_sigwinch=32
3754 while test "$cf_sigwinch" != 1
3755 do
3756         AC_TRY_COMPILE([
3757 #undef _XOPEN_SOURCE
3758 #undef _POSIX_SOURCE
3759 #undef _POSIX_C_SOURCE
3760 #include <sys/types.h>
3761 #include <sys/signal.h>
3762 ],[
3763 #if SIGWINCH != $cf_sigwinch
3764 #error SIGWINCH is not $cf_sigwinch
3765 #endif
3766 int x = SIGWINCH; (void)x],
3767         [cf_cv_fixup_sigwinch=$cf_sigwinch
3768          break])
3769
3770 cf_sigwinch="`expr "$cf_sigwinch" - 1`"
3771 done
3772 ])
3773
3774         if test "$cf_cv_fixup_sigwinch" != unknown ; then
3775                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
3776         fi
3777 fi
3778 ])dnl
3779 dnl ---------------------------------------------------------------------------
3780 dnl CF_SIG_ATOMIC_T version: 5 updated: 2020/03/10 18:53:47
3781 dnl ---------------
3782 dnl signal handler, but there are some gcc dependencies in that recommendation.
3783 dnl Try anyway.
3784 AC_DEFUN([CF_SIG_ATOMIC_T],
3785 [
3786 AC_MSG_CHECKING(for signal global datatype)
3787 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
3788         for cf_type in \
3789                 "volatile sig_atomic_t" \
3790                 "sig_atomic_t" \
3791                 "int"
3792         do
3793         AC_TRY_COMPILE([
3794 #include <sys/types.h>
3795 #include <signal.h>
3796 #include <stdio.h>
3797
3798 extern $cf_type x;
3799 $cf_type x;
3800 static void handler(int sig)
3801 {
3802         (void)sig;
3803         x = 5;
3804 }],
3805                 [signal(SIGINT, handler);
3806                  x = 1],
3807                 [cf_cv_sig_atomic_t=$cf_type],
3808                 [cf_cv_sig_atomic_t=no])
3809                 test "$cf_cv_sig_atomic_t" != no && break
3810         done
3811         ])
3812 AC_MSG_RESULT($cf_cv_sig_atomic_t)
3813 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
3814 ])dnl
3815 dnl ---------------------------------------------------------------------------
3816 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
3817 dnl --------------
3818 dnl Construct a search-list for a nonstandard header/lib-file
3819 dnl     $1 = the variable to return as result
3820 dnl     $2 = the package name
3821 dnl     $3 = the subdirectory, e.g., bin, include or lib
3822 AC_DEFUN([CF_SUBDIR_PATH],
3823 [
3824 $1=
3825
3826 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
3827
3828 for cf_subdir_prefix in \
3829         /usr \
3830         /usr/local \
3831         /usr/pkg \
3832         /opt \
3833         /opt/local \
3834         [$]HOME
3835 do
3836         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
3837 done
3838 ])dnl
3839 dnl ---------------------------------------------------------------------------
3840 dnl CF_SYS_TIME_SELECT version: 6 updated: 2015/04/18 08:56:57
3841 dnl ------------------
3842 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
3843 dnl older SCO configurations.
3844 AC_DEFUN([CF_SYS_TIME_SELECT],
3845 [
3846 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
3847 AC_CACHE_VAL(cf_cv_sys_time_select,[
3848 AC_TRY_COMPILE([
3849 #include <sys/types.h>
3850 #ifdef HAVE_SYS_TIME_H
3851 #include <sys/time.h>
3852 #endif
3853 #ifdef HAVE_SYS_SELECT_H
3854 #include <sys/select.h>
3855 #endif
3856 ],[],[cf_cv_sys_time_select=yes],
3857          [cf_cv_sys_time_select=no])
3858          ])
3859 AC_MSG_RESULT($cf_cv_sys_time_select)
3860 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
3861 ])dnl
3862 dnl ---------------------------------------------------------------------------
3863 dnl CF_TERM_HEADER version: 6 updated: 2021/01/02 09:31:20
3864 dnl --------------
3865 dnl Look for term.h, which is part of X/Open curses.  It defines the interface
3866 dnl to terminfo database.  Usually it is in the same include-path as curses.h,
3867 dnl but some packagers change this, breaking various applications.
3868 AC_DEFUN([CF_TERM_HEADER],[
3869 AC_CACHE_CHECK(for terminfo header, cf_cv_term_header,[
3870 case "${cf_cv_ncurses_header}" in
3871 (*/ncurses.h|*/ncursesw.h)
3872         cf_term_header=`echo "$cf_cv_ncurses_header" | sed -e 's%ncurses[[^.]]*\.h$%term.h%'`
3873         ;;
3874 (*)
3875         cf_term_header=term.h
3876         ;;
3877 esac
3878
3879 for cf_test in $cf_term_header "ncurses/term.h" "ncursesw/term.h"
3880 do
3881 AC_TRY_COMPILE([#include <stdio.h>
3882 #include <${cf_cv_ncurses_header:-curses.h}>
3883 #include <$cf_test>
3884 ],[int x = auto_left_margin; (void)x],[
3885         cf_cv_term_header="$cf_test"],[
3886         cf_cv_term_header=unknown
3887         ])
3888         test "$cf_cv_term_header" != unknown && break
3889 done
3890 ])
3891
3892 # Set definitions to allow ifdef'ing to accommodate subdirectories
3893
3894 case "$cf_cv_term_header" in
3895 (*term.h)
3896         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
3897         ;;
3898 esac
3899
3900 case "$cf_cv_term_header" in
3901 (ncurses/term.h)
3902         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
3903         ;;
3904 (ncursesw/term.h)
3905         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
3906         ;;
3907 esac
3908 ])dnl
3909 dnl ---------------------------------------------------------------------------
3910 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
3911 dnl ---------------
3912 dnl Define a top_builddir symbol, for applications that need an absolute path.
3913 AC_DEFUN([CF_TOP_BUILDDIR],
3914 [
3915 top_builddir=ifelse($1,,`pwd`,$1)
3916 AC_SUBST(top_builddir)
3917 ])dnl
3918 dnl ---------------------------------------------------------------------------
3919 dnl CF_TPUTS_PROTO version: 4 updated: 2021/01/04 19:45:09
3920 dnl --------------
3921 dnl Check for type of function-pointer passed to tputs.  Some old
3922 dnl implementations used functions that had different prototypes, making it
3923 dnl hard to compile portable programs using tputs.
3924 AC_DEFUN([CF_TPUTS_PROTO],[
3925 CF_CURSES_FUNCS(tputs)
3926 if test "x$cf_cv_func_tputs" = xyes
3927 then
3928         cf_done=no
3929         for cf_arg in int char
3930         do
3931                 for cf_ret in int void
3932                 do
3933                         if test "$cf_ret" = void
3934                         then
3935                                 cf_return="/* nothing */"
3936                         else
3937                                 cf_return="return value"
3938                         fi
3939                         AC_TRY_COMPILE([
3940 #include <${cf_cv_ncurses_header:-curses.h}>
3941 #include <$cf_cv_term_header>
3942
3943 static $cf_ret outc($cf_arg value) { $cf_return; }
3944 ],[
3945         tputs("hello", 0, outc);
3946         ${cf_cv_main_return:-return}(0);
3947 ],[
3948                 CF_VERBOSE([prototype $cf_ret func($cf_arg value)])
3949                 cat >>confdefs.h <<EOF
3950 #define TPUTS_ARG               $cf_arg
3951 #define TPUTS_PROTO(func,value) $cf_ret func(TPUTS_ARG value)
3952 #define TPUTS_RETURN(value)     $cf_return
3953 EOF
3954                 cf_done=yes
3955                 break
3956 ])
3957                 done
3958                 test "$cf_done" = yes && break
3959         done
3960 fi
3961 ])dnl
3962 dnl ---------------------------------------------------------------------------
3963 dnl CF_TRIM_X_LIBS version: 3 updated: 2015/04/12 15:39:00
3964 dnl --------------
3965 dnl Trim extra base X libraries added as a workaround for inconsistent library
3966 dnl dependencies returned by "new" pkg-config files.
3967 AC_DEFUN([CF_TRIM_X_LIBS],[
3968         for cf_trim_lib in Xmu Xt X11
3969         do
3970                 case "$LIBS" in
3971                 (*-l$cf_trim_lib\ *-l$cf_trim_lib*)
3972                         LIBS=`echo "$LIBS " | sed -e 's/  / /g' -e 's%-l'"$cf_trim_lib"' %%' -e 's/ $//'`
3973                         CF_VERBOSE(..trimmed $LIBS)
3974                         ;;
3975                 esac
3976         done
3977 ])
3978 dnl ---------------------------------------------------------------------------
3979 dnl CF_TRY_PKG_CONFIG version: 6 updated: 2020/12/31 10:54:15
3980 dnl -----------------
3981 dnl This is a simple wrapper to use for pkg-config, for libraries which may be
3982 dnl available in that form.
3983 dnl
3984 dnl $1 = package name, which may be a shell variable
3985 dnl $2 = extra logic to use, if any, after updating CFLAGS and LIBS
3986 dnl $3 = logic to use if pkg-config does not have the package
3987 AC_DEFUN([CF_TRY_PKG_CONFIG],[
3988 AC_REQUIRE([CF_PKG_CONFIG])
3989
3990 if test "$PKG_CONFIG" != none && "$PKG_CONFIG" --exists "$1"; then
3991         CF_VERBOSE(found package $1)
3992         cf_pkgconfig_incs="`$PKG_CONFIG --cflags "$1" 2>/dev/null`"
3993         cf_pkgconfig_libs="`$PKG_CONFIG --libs   "$1" 2>/dev/null`"
3994         CF_VERBOSE(package $1 CFLAGS: $cf_pkgconfig_incs)
3995         CF_VERBOSE(package $1 LIBS: $cf_pkgconfig_libs)
3996         CF_ADD_CFLAGS($cf_pkgconfig_incs)
3997         CF_ADD_LIBS($cf_pkgconfig_libs)
3998         ifelse([$2],,:,[$2])
3999 else
4000         cf_pkgconfig_incs=
4001         cf_pkgconfig_libs=
4002         ifelse([$3],,:,[$3])
4003 fi
4004 ])
4005 dnl ---------------------------------------------------------------------------
4006 dnl CF_TRY_XOPEN_SOURCE version: 4 updated: 2022/09/10 15:16:16
4007 dnl -------------------
4008 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
4009 dnl can define it successfully.
4010 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
4011 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
4012         AC_TRY_COMPILE(CF__XOPEN_SOURCE_HEAD,CF__XOPEN_SOURCE_BODY,
4013         [cf_cv_xopen_source=no],
4014         [cf_save="$CPPFLAGS"
4015          CF_APPEND_TEXT(CPPFLAGS,-D_XOPEN_SOURCE=$cf_XOPEN_SOURCE)
4016          AC_TRY_COMPILE(CF__XOPEN_SOURCE_HEAD,CF__XOPEN_SOURCE_BODY,
4017                 [cf_cv_xopen_source=no],
4018                 [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
4019                 CPPFLAGS="$cf_save"
4020         ])
4021 ])
4022
4023 if test "$cf_cv_xopen_source" != no ; then
4024         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
4025         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
4026         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
4027         CF_APPEND_CFLAGS($cf_temp_xopen_source)
4028 fi
4029 ])
4030 dnl ---------------------------------------------------------------------------
4031 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
4032 dnl --------
4033 dnl Make an uppercase version of a variable
4034 dnl $1=uppercase($2)
4035 AC_DEFUN([CF_UPPER],
4036 [
4037 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
4038 ])dnl
4039 dnl ---------------------------------------------------------------------------
4040 dnl CF_UTF8_LIB version: 10 updated: 2023/01/11 04:05:23
4041 dnl -----------
4042 dnl Check for multibyte support, and if not found, utf8 compatibility library
4043 AC_DEFUN([CF_UTF8_LIB],
4044 [
4045 AC_HAVE_HEADERS(wchar.h)
4046 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
4047         cf_save_LIBS="$LIBS"
4048         AC_TRY_LINK([
4049 $ac_includes_default
4050 #ifdef HAVE_WCHAR_H
4051 #include <wchar.h>
4052 #endif
4053 ],[putwc(0,0);],
4054         [cf_cv_utf8_lib=yes],
4055         [CF_FIND_LINKAGE([
4056 #include <libutf8.h>],[putwc(0,0);],utf8,
4057                 [cf_cv_utf8_lib=add-on],
4058                 [cf_cv_utf8_lib=no])
4059 ])])
4060
4061 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
4062 # ncurses/ncursesw:
4063 if test "$cf_cv_utf8_lib" = "add-on" ; then
4064         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
4065         CF_ADD_INCDIR($cf_cv_header_path_utf8)
4066         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
4067         CF_ADD_LIBS($cf_cv_library_file_utf8)
4068 fi
4069 ])dnl
4070 dnl ---------------------------------------------------------------------------
4071 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
4072 dnl ----------
4073 dnl Use AC_VERBOSE w/o the warnings
4074 AC_DEFUN([CF_VERBOSE],
4075 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
4076 CF_MSG_LOG([$1])
4077 ])dnl
4078 dnl ---------------------------------------------------------------------------
4079 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
4080 dnl -------------
4081 dnl Check if type wide-character type $1 is declared, and if so, which header
4082 dnl file is needed.  The second parameter is used to set a shell variable when
4083 dnl the type is not found.  The first parameter sets a shell variable for the
4084 dnl opposite sense.
4085 AC_DEFUN([CF_WCHAR_TYPE],
4086 [
4087 # This is needed on Tru64 5.0 to declare $1
4088 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
4089 AC_TRY_COMPILE([
4090 #include <stdlib.h>
4091 #include <stdarg.h>
4092 #include <stdio.h>
4093 #ifdef HAVE_LIBUTF8_H
4094 #include <libutf8.h>
4095 #endif],
4096         [$1 state],
4097         [cf_cv_$1=no],
4098         [AC_TRY_COMPILE([
4099 #include <stdlib.h>
4100 #include <stdarg.h>
4101 #include <stdio.h>
4102 #include <wchar.h>
4103 #ifdef HAVE_LIBUTF8_H
4104 #include <libutf8.h>
4105 #endif],
4106         [$1 value],
4107         [cf_cv_$1=yes],
4108         [cf_cv_$1=unknown])])])
4109
4110 if test "$cf_cv_$1" = yes ; then
4111         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
4112         NEED_WCHAR_H=1
4113 fi
4114
4115 ifelse([$2],,,[
4116 # if we do not find $1 in either place, use substitution to provide a fallback.
4117 if test "$cf_cv_$1" = unknown ; then
4118         $2=1
4119 fi
4120 ])
4121 ifelse($3,,,[
4122 # if we find $1 in either place, use substitution to provide a fallback.
4123 if test "$cf_cv_$1" != unknown ; then
4124         $3=1
4125 fi
4126 ])
4127 ])dnl
4128 dnl ---------------------------------------------------------------------------
4129 dnl CF_WITH_CURSES_DIR version: 4 updated: 2021/01/02 19:22:58
4130 dnl ------------------
4131 dnl Wrapper for AC_ARG_WITH to specify directory under which to look for curses
4132 dnl libraries.
4133 AC_DEFUN([CF_WITH_CURSES_DIR],[
4134
4135 AC_MSG_CHECKING(for specific curses-directory)
4136 AC_ARG_WITH(curses-dir,
4137         [  --with-curses-dir=DIR   directory in which (n)curses is installed],
4138         [cf_cv_curses_dir=$withval],
4139         [cf_cv_curses_dir=no])
4140 AC_MSG_RESULT($cf_cv_curses_dir)
4141
4142 if test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no"
4143 then
4144         CF_PATH_SYNTAX(withval)
4145         if test -d "$cf_cv_curses_dir"
4146         then
4147                 CF_ADD_INCDIR($cf_cv_curses_dir/include)
4148                 CF_ADD_LIBDIR($cf_cv_curses_dir/lib)
4149         fi
4150 fi
4151 ])dnl
4152 dnl ---------------------------------------------------------------------------
4153 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
4154 dnl ----------------
4155 dnl Configure-option for dbmalloc.  The optional parameter is used to override
4156 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
4157 AC_DEFUN([CF_WITH_DBMALLOC],[
4158 CF_NO_LEAKS_OPTION(dbmalloc,
4159         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
4160         [USE_DBMALLOC])
4161
4162 if test "$with_dbmalloc" = yes ; then
4163         AC_CHECK_HEADER(dbmalloc.h,
4164                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
4165 fi
4166 ])dnl
4167 dnl ---------------------------------------------------------------------------
4168 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
4169 dnl ---------------
4170 dnl Configure-option for dmalloc.  The optional parameter is used to override
4171 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
4172 AC_DEFUN([CF_WITH_DMALLOC],[
4173 CF_NO_LEAKS_OPTION(dmalloc,
4174         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
4175         [USE_DMALLOC])
4176
4177 if test "$with_dmalloc" = yes ; then
4178         AC_CHECK_HEADER(dmalloc.h,
4179                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
4180 fi
4181 ])dnl
4182 dnl ---------------------------------------------------------------------------
4183 dnl CF_WITH_LIB_BASENAME version: 1 updated: 2020/03/07 20:05:14
4184 dnl --------------------
4185 dnl Allow for overriding the basename of a library, i.e., the part to which
4186 dnl prefixes/suffixes are attached.
4187 dnl
4188 dnl $1 = variable to set
4189 dnl $2 = option name
4190 dnl $3 = default basename for library, if omitted use $2
4191 AC_DEFUN([CF_WITH_LIB_BASENAME],
4192 [
4193 AC_MSG_CHECKING(for desired basename for $2 library)
4194 AC_ARG_WITH($2-libname,
4195         [  --with-$2-libname=XXX override ifelse($3,,$2,$3) basename of library],
4196         [with_lib_basename=$withval],
4197         [with_lib_basename=ifelse($3,,$2,$3)])
4198 $1="$with_lib_basename"
4199
4200 case "x[$]$1" in
4201 (x|xno|xnone|xyes)
4202         $1=ifelse($3,,$2,$3)
4203         ;;
4204 (*)
4205         ;;
4206 esac
4207
4208 AC_MSG_RESULT([$]$1)
4209 AC_SUBST($1)
4210 ])dnl
4211 dnl ---------------------------------------------------------------------------
4212 dnl CF_WITH_NCURSES_ETC version: 6 updated: 2023/01/16 10:10:06
4213 dnl -------------------
4214 dnl Use this macro for programs which use any variant of "curses", e.g.,
4215 dnl "ncurses", and "PDCurses".  Programs that can use curses and some unrelated
4216 dnl library (such as slang) should use a "--with-screen=XXX" option.
4217 dnl
4218 dnl This does not use AC_DEFUN, because that would tell autoconf to run each
4219 dnl of the macros inside this one - before this macro.
4220 define([CF_WITH_NCURSES_ETC],[
4221 CF_WITH_CURSES_DIR
4222
4223 cf_cv_screen=curses
4224
4225 AC_MSG_CHECKING(for specified curses library type)
4226 AC_ARG_WITH(screen,
4227         [  --with-screen=XXX       use specified curses-libraries],
4228         [cf_cv_screen=$withval],[
4229
4230 AC_ARG_WITH(ncursesw,
4231         [  --with-ncursesw         use wide ncurses-libraries],
4232         [cf_cv_screen=ncursesw],[
4233
4234 AC_ARG_WITH(ncurses,
4235         [  --with-ncurses          use ncurses-libraries],
4236         [cf_cv_screen=ncurses],[
4237
4238 AC_ARG_WITH(pdcurses,
4239         [  --with-pdcurses         compile/link with pdcurses X11 library],
4240         [cf_cv_screen=pdcurses],[
4241
4242 AC_ARG_WITH(curses-colr,
4243         [  --with-curses-colr      compile/link with HPUX 10.x color-curses],
4244         [cf_cv_screen=curses_colr],[
4245
4246 AC_ARG_WITH(curses-5lib,
4247         [  --with-curses-5lib      compile/link with SunOS 5lib curses],
4248         [cf_cv_screen=curses_5lib])])])])])])
4249
4250 AC_MSG_RESULT($cf_cv_screen)
4251
4252 case $cf_cv_screen in
4253 (curses|curses_*)
4254         CF_CURSES_CONFIG
4255         ;;
4256 (ncursesw*)
4257         CF_UTF8_LIB
4258         CF_NCURSES_CONFIG($cf_cv_screen)
4259         ;;
4260 (ncurses*)
4261         CF_NCURSES_CONFIG($cf_cv_screen)
4262         ;;
4263 (pdcurses)
4264         CF_PDCURSES_X11
4265         ;;
4266 (*)
4267         AC_MSG_ERROR(unexpected screen-value: $cf_cv_screen)
4268         ;;
4269 esac
4270
4271 CF_NCURSES_PTHREADS($cf_cv_screen)
4272 AC_SUBST(cf_cv_screen)
4273
4274 ])dnl
4275 dnl ---------------------------------------------------------------------------
4276 dnl CF_WITH_SCREEN_PDCURSES version: 1 updated: 2020/08/28 16:56:27
4277 dnl -----------------------
4278 dnl Call this macro before CF_ENABLE_WARNINGS for configure scripts which use
4279 dnl the "--with-screen=pdcurses" selection.  Doing that allows the configure
4280 dnl script to search for the X11/Xt header files to declare (or not) the
4281 dnl symbol needed to enable "const" in those header files.  If that configure
4282 dnl option is not used, then those checks are unnecessary.
4283 AC_DEFUN([CF_WITH_SCREEN_PDCURSES],[
4284 AC_PROVIDE([AC_PATH_XTRA])
4285 AC_PROVIDE([AC_PATH_X])
4286 if test -n "$with_screen" && test "x$with_screen" = "xpdcurses"
4287 then
4288         AC_PATH_X
4289         AC_PATH_XTRA
4290 fi
4291 ])dnl
4292 dnl ---------------------------------------------------------------------------
4293 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
4294 dnl ----------------
4295 AC_DEFUN([CF_WITH_VALGRIND],[
4296 CF_NO_LEAKS_OPTION(valgrind,
4297         [  --with-valgrind         test: use valgrind],
4298         [USE_VALGRIND])
4299 ])dnl
4300 dnl ---------------------------------------------------------------------------
4301 dnl CF_WITH_X11_RGB version: 3 updated: 2023/10/28 11:59:01
4302 dnl ---------------
4303 dnl Handle configure option "--with-x11-rgb", setting these shell
4304 dnl variables:
4305 dnl
4306 dnl $RGB_PATH is the option value, used for finding the X11 rgb file.
4307 dnl $no_x11_rgb is a "#" (comment) if "--without-x11-rgb" is given.
4308 dnl
4309 dnl Most Linux's use this:
4310 dnl     /usr/share/X11/rgb.txt
4311 dnl Debian uses this:
4312 dnl     /etc/X11/rgb.txt
4313 dnl DragonFlyBSD ports uses this:
4314 dnl     /usr/pkg/lib/X11/rgb.txt
4315 dnl FreeBSD ports use these:
4316 dnl     /usr/local/lib/X11/rgb.txt
4317 dnl     /usr/local/share/X11/rgb.txt
4318 dnl Mandriva has these:
4319 dnl     /usr/lib/X11/rgb.txt
4320 dnl     /usr/lib64/X11/rgb.txt
4321 dnl NetBSD has these
4322 dnl     /usr/X11R7/lib/X11/rgb.txt
4323 dnl OpenSolaris uses
4324 dnl     32-bit:
4325 dnl     /usr/X11/etc/X11/rgb.txt
4326 dnl     /usr/X11/share/X11/rgb.txt
4327 dnl     /usr/X11/lib/X11/rgb.txt
4328 dnl OSX uses
4329 dnl             /opt/local/share/X11/rgb.txt (MacPorts)
4330 dnl             /opt/X11/share/X11/rgb.txt (non-ports)
4331 dnl     64-bit:
4332 dnl     /usr/X11/etc/X11/rgb.txt
4333 dnl     /usr/X11/share/X11/rgb.txt (perhaps)
4334 dnl     /usr/X11/lib/amd64/X11/rgb.txt
4335 dnl Solaris10 uses (in this order):
4336 dnl     /usr/openwin/lib/X11/rgb.txt
4337 dnl     /usr/X11/lib/X11/rgb.txt
4338 AC_DEFUN([CF_WITH_X11_RGB],[
4339 AC_MSG_CHECKING(for X11 rgb file)
4340 AC_ARG_WITH(x11-rgb,
4341         [  --with-x11-rgb=FILE     obtain X11 color definitions from FILE (default: EPREFIX/lib/X11/rgb.txt)],
4342         [RGB_PATH=$withval],
4343         [RGB_PATH=auto])
4344
4345 if test "x[$]RGB_PATH" = xauto
4346 then
4347         RGB_PATH='${exec_prefix}/lib/X11/rgb.txt'
4348         for cf_path in \
4349                 /opt/local/share/X11/rgb.txt \
4350                 /opt/X11/share/X11/rgb.txt \
4351                 /usr/share/X11/rgb.txt \
4352                 /usr/X11/share/X11/rgb.txt \
4353                 /usr/X11/lib/X11/rgb.txt \
4354                 /usr/lib/X11/rgb.txt \
4355                 /etc/X11/rgb.txt \
4356                 /usr/pkg/lib/X11/rgb.txt \
4357                 /usr/X11R7/lib/X11/rgb.txt \
4358                 /usr/X11R6/lib/X11/rgb.txt \
4359                 /usr/X11R5/lib/X11/rgb.txt \
4360                 /usr/X11R4/lib/X11/rgb.txt \
4361                 /usr/local/lib/X11/rgb.txt \
4362                 /usr/local/share/X11/rgb.txt \
4363                 /usr/lib64/X11/rgb.txt
4364         do
4365                 if test -f "$cf_path" ; then
4366                         RGB_PATH="$cf_path"
4367                         break
4368                 fi
4369         done
4370 else
4371         cf_path=$RGB_PATH
4372         CF_PATH_SYNTAX(cf_path)
4373 fi
4374
4375 AC_MSG_RESULT($RGB_PATH)
4376 AC_SUBST(RGB_PATH)
4377 AC_DEFINE_UNQUOTED(RGB_PATH,"$cf_path",[Define to the full pathname of rgb.txt])
4378
4379 no_x11_rgb=
4380 if test "$RGB_PATH" = no
4381 then
4382         no_x11_rgb="#"
4383 fi
4384 AC_SUBST(no_x11_rgb)
4385 ])dnl
4386 dnl ---------------------------------------------------------------------------
4387 dnl CF_XOPEN_CURSES version: 18 updated: 2023/01/11 04:05:23
4388 dnl ---------------
4389 dnl Test if we should define X/Open source for curses, needed on Digital Unix
4390 dnl 4.x, to see the extended functions, but breaks on IRIX 6.x.
4391 dnl
4392 dnl The getbegyx() check is needed for HPUX, which omits legacy macros such
4393 dnl as getbegy().  The latter is better design, but the former is standard.
4394 AC_DEFUN([CF_XOPEN_CURSES],
4395 [
4396 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
4397 AC_CACHE_CHECK(definition to turn on extended curses functions,cf_cv_need_xopen_extension,[
4398 cf_cv_need_xopen_extension=unknown
4399 AC_TRY_LINK([
4400 $ac_includes_default
4401 #include <${cf_cv_ncurses_header:-curses.h}>],[
4402 #if defined(NCURSES_VERSION_PATCH)
4403 #if (NCURSES_VERSION_PATCH < 20100501) && (NCURSES_VERSION_PATCH >= 20100403)
4404         make an error
4405 #endif
4406 #endif
4407 #ifdef NCURSES_WIDECHAR
4408 make an error   /* prefer to fall-through on the second checks */
4409 #endif
4410         cchar_t check;
4411         int check2 = curs_set((int)sizeof(check));
4412         long x = winnstr(stdscr, "", 0);
4413         int x1, y1;
4414         (void)check2;
4415         getbegyx(stdscr, y1, x1);
4416         (void)x;
4417         (void)y1;
4418         (void)x1;
4419         ],
4420         [cf_cv_need_xopen_extension=none],
4421         [
4422         for cf_try_xopen_extension in _XOPEN_SOURCE_EXTENDED NCURSES_WIDECHAR
4423         do
4424                 AC_TRY_LINK([
4425 #define $cf_try_xopen_extension 1
4426 $ac_includes_default
4427 #include <${cf_cv_ncurses_header:-curses.h}>],[
4428                 cchar_t check;
4429                 int check2 = curs_set((int)sizeof(check));
4430                 long x = winnstr(stdscr, "", 0);
4431                 int x1, y1;
4432                 getbegyx(stdscr, y1, x1);
4433                 (void)check2;
4434                 (void)x;
4435                 (void)y1;
4436                 (void)x1;
4437                 ],
4438                 [cf_cv_need_xopen_extension=$cf_try_xopen_extension; break])
4439         done
4440         ])
4441 ])
4442
4443 case "$cf_cv_need_xopen_extension" in
4444 (*_*)
4445         CF_APPEND_TEXT(CPPFLAGS,-D$cf_cv_need_xopen_extension)
4446         ;;
4447 esac
4448
4449 ])dnl
4450 dnl ---------------------------------------------------------------------------
4451 dnl CF_XOPEN_SOURCE version: 67 updated: 2023/09/06 18:55:27
4452 dnl ---------------
4453 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
4454 dnl or adapt to the vendor's definitions to get equivalent functionality,
4455 dnl without losing the common non-POSIX features.
4456 dnl
4457 dnl Parameters:
4458 dnl     $1 is the nominal value for _XOPEN_SOURCE
4459 dnl     $2 is the nominal value for _POSIX_C_SOURCE
4460 dnl
4461 dnl The default case prefers _XOPEN_SOURCE over _POSIX_C_SOURCE if the
4462 dnl implementation predefines it, because X/Open and most implementations agree
4463 dnl that the latter is a legacy or "aligned" value.
4464 dnl
4465 dnl Because _XOPEN_SOURCE is preferred, if defining _POSIX_C_SOURCE turns
4466 dnl that off, then refrain from setting _POSIX_C_SOURCE explicitly.
4467 dnl
4468 dnl References:
4469 dnl https://pubs.opengroup.org/onlinepubs/007904975/functions/xsh_chap02_02.html
4470 dnl https://docs.oracle.com/cd/E19253-01/816-5175/standards-5/index.html
4471 dnl https://www.gnu.org/software/libc/manual/html_node/Feature-Test-Macros.html
4472 AC_DEFUN([CF_XOPEN_SOURCE],[
4473 AC_REQUIRE([AC_CANONICAL_HOST])
4474 AC_REQUIRE([CF_POSIX_VISIBLE])
4475
4476 if test "$cf_cv_posix_visible" = no; then
4477
4478 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
4479 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
4480 cf_xopen_source=
4481
4482 case "$host_os" in
4483 (aix[[4-7]]*)
4484         cf_xopen_source="-D_ALL_SOURCE"
4485         ;;
4486 (darwin[[0-8]].*)
4487         cf_xopen_source="-D_APPLE_C_SOURCE"
4488         ;;
4489 (darwin*)
4490         cf_xopen_source="-D_DARWIN_C_SOURCE"
4491         cf_XOPEN_SOURCE=
4492         ;;
4493 (freebsd*|dragonfly*|midnightbsd*)
4494         # 5.x headers associate
4495         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
4496         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
4497         cf_POSIX_C_SOURCE=200112L
4498         cf_XOPEN_SOURCE=600
4499         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
4500         ;;
4501 (hpux11*)
4502         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
4503         ;;
4504 (hpux*)
4505         cf_xopen_source="-D_HPUX_SOURCE"
4506         ;;
4507 (irix[[56]].*)
4508         cf_xopen_source="-D_SGI_SOURCE"
4509         cf_XOPEN_SOURCE=
4510         ;;
4511 (linux*gnu|linux*gnuabi64|linux*gnuabin32|linux*gnueabi|linux*gnueabihf|linux*gnux32|uclinux*|gnu*|mint*|k*bsd*-gnu|cygwin|msys|mingw*|linux*uclibc)
4512         CF_GNU_SOURCE($cf_XOPEN_SOURCE)
4513         ;;
4514 (minix*)
4515         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
4516         ;;
4517 (mirbsd*)
4518         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
4519         cf_XOPEN_SOURCE=
4520         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
4521         ;;
4522 (netbsd*)
4523         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
4524         ;;
4525 (openbsd[[6-9]]*)
4526         # OpenBSD 6.x has broken locale support, both compile-time and runtime.
4527         # see https://www.mail-archive.com/bugs@openbsd.org/msg13200.html
4528         # Abusing the conformance level is a workaround.
4529         AC_MSG_WARN(this system does not provide usable locale support)
4530         cf_xopen_source="-D_BSD_SOURCE"
4531         cf_XOPEN_SOURCE=700
4532         ;;
4533 (openbsd[[4-5]]*)
4534         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
4535         cf_xopen_source="-D_BSD_SOURCE"
4536         cf_XOPEN_SOURCE=600
4537         ;;
4538 (openbsd*)
4539         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
4540         ;;
4541 (osf[[45]]*)
4542         cf_xopen_source="-D_OSF_SOURCE"
4543         ;;
4544 (nto-qnx*)
4545         cf_xopen_source="-D_QNX_SOURCE"
4546         ;;
4547 (sco*)
4548         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
4549         ;;
4550 (solaris2.*)
4551         cf_xopen_source="-D__EXTENSIONS__"
4552         cf_cv_xopen_source=broken
4553         ;;
4554 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
4555         cf_XOPEN_SOURCE=
4556         cf_POSIX_C_SOURCE=
4557         ;;
4558 (*)
4559         CF_TRY_XOPEN_SOURCE
4560         cf_save_xopen_cppflags="$CPPFLAGS"
4561         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
4562         # Some of these niche implementations use copy/paste, double-check...
4563         if test "$cf_cv_xopen_source" = no ; then
4564                 CF_VERBOSE(checking if _POSIX_C_SOURCE interferes with _XOPEN_SOURCE)
4565                 AC_TRY_COMPILE(CF__XOPEN_SOURCE_HEAD,CF__XOPEN_SOURCE_BODY,,[
4566                         AC_MSG_WARN(_POSIX_C_SOURCE definition is not usable)
4567                         CPPFLAGS="$cf_save_xopen_cppflags"])
4568         fi
4569         ;;
4570 esac
4571
4572 if test -n "$cf_xopen_source" ; then
4573         CF_APPEND_CFLAGS($cf_xopen_source,true)
4574 fi
4575
4576 dnl In anything but the default case, we may have system-specific setting
4577 dnl which is still not guaranteed to provide all of the entrypoints that
4578 dnl _XOPEN_SOURCE would yield.
4579 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
4580         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
4581         AC_TRY_COMPILE([#include <stdlib.h>],[
4582 #ifndef _XOPEN_SOURCE
4583 #error _XOPEN_SOURCE is not defined
4584 #endif],
4585         [cf_XOPEN_SOURCE_set=yes],
4586         [cf_XOPEN_SOURCE_set=no])
4587         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
4588         if test "$cf_XOPEN_SOURCE_set" = yes
4589         then
4590                 AC_TRY_COMPILE([#include <stdlib.h>],[
4591 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
4592 #error (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
4593 #endif],
4594                 [cf_XOPEN_SOURCE_set_ok=yes],
4595                 [cf_XOPEN_SOURCE_set_ok=no])
4596                 if test "$cf_XOPEN_SOURCE_set_ok" = no
4597                 then
4598                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
4599                 fi
4600         else
4601                 CF_TRY_XOPEN_SOURCE
4602         fi
4603 fi
4604 fi # cf_cv_posix_visible
4605 ])
4606 dnl ---------------------------------------------------------------------------
4607 dnl CF_X_ATHENA version: 25 updated: 2023/01/11 04:05:23
4608 dnl -----------
4609 dnl Check for Xaw (Athena) libraries
4610 dnl
4611 dnl Sets $cf_x_athena according to the flavor of Xaw which is used.
4612 AC_DEFUN([CF_X_ATHENA],
4613 [
4614 cf_x_athena=${cf_x_athena:-Xaw}
4615
4616 AC_MSG_CHECKING(if you want to link with Xaw 3d library)
4617 withval=
4618 AC_ARG_WITH(Xaw3d,
4619         [  --with-Xaw3d            link with Xaw 3d library])
4620 if test "$withval" = yes ; then
4621         cf_x_athena=Xaw3d
4622         AC_MSG_RESULT(yes)
4623 else
4624         AC_MSG_RESULT(no)
4625 fi
4626
4627 AC_MSG_CHECKING(if you want to link with Xaw 3d xft library)
4628 withval=
4629 AC_ARG_WITH(Xaw3dxft,
4630         [  --with-Xaw3dxft         link with Xaw 3d xft library])
4631 if test "$withval" = yes ; then
4632         cf_x_athena=Xaw3dxft
4633         AC_MSG_RESULT(yes)
4634 else
4635         AC_MSG_RESULT(no)
4636 fi
4637
4638 AC_MSG_CHECKING(if you want to link with neXT Athena library)
4639 withval=
4640 AC_ARG_WITH(neXtaw,
4641         [  --with-neXtaw           link with neXT Athena library])
4642 if test "$withval" = yes ; then
4643         cf_x_athena=neXtaw
4644         AC_MSG_RESULT(yes)
4645 else
4646         AC_MSG_RESULT(no)
4647 fi
4648
4649 AC_MSG_CHECKING(if you want to link with Athena-Plus library)
4650 withval=
4651 AC_ARG_WITH(XawPlus,
4652         [  --with-XawPlus          link with Athena-Plus library])
4653 if test "$withval" = yes ; then
4654         cf_x_athena=XawPlus
4655         AC_MSG_RESULT(yes)
4656 else
4657         AC_MSG_RESULT(no)
4658 fi
4659
4660 cf_x_athena_lib=""
4661
4662 if test "$PKG_CONFIG" != none ; then
4663         cf_athena_list=
4664         test "$cf_x_athena" = Xaw && cf_athena_list="xaw8 xaw7 xaw6"
4665         for cf_athena_pkg in \
4666                 $cf_athena_list \
4667                 ${cf_x_athena} \
4668                 ${cf_x_athena}-devel \
4669                 lib${cf_x_athena} \
4670                 lib${cf_x_athena}-devel
4671         do
4672                 CF_TRY_PKG_CONFIG($cf_athena_pkg,[
4673                         cf_x_athena_lib="$cf_pkgconfig_libs"
4674                         CF_UPPER(cf_x_athena_LIBS,HAVE_LIB_$cf_x_athena)
4675                         AC_DEFINE_UNQUOTED($cf_x_athena_LIBS)
4676
4677                         CF_TRIM_X_LIBS
4678
4679 AC_CACHE_CHECK(for usable $cf_x_athena/Xmu package,cf_cv_xaw_compat,[
4680 AC_TRY_LINK([
4681 $ac_includes_default
4682 #include <X11/Xmu/CharSet.h>
4683 ],[
4684 int check = XmuCompareISOLatin1("big", "small");
4685 (void)check;
4686 ],[cf_cv_xaw_compat=yes],[cf_cv_xaw_compat=no])])
4687
4688                         if test "$cf_cv_xaw_compat" = no
4689                         then
4690                                 # workaround for broken ".pc" files...
4691                                 case "$cf_x_athena_lib" in
4692                                 (*-lXmu*)
4693                                         ;;
4694                                 (*)
4695                                         CF_VERBOSE(work around broken package)
4696                                         cf_save_xmu="$LIBS"
4697                                         cf_first_lib=`echo "$cf_save_xmu" | sed -e 's/^[ ][ ]*//' -e 's/ .*//'`
4698                                         CF_TRY_PKG_CONFIG(xmu,[
4699                                                         LIBS="$cf_save_xmu"
4700                                                         CF_ADD_LIB_AFTER($cf_first_lib,$cf_pkgconfig_libs)
4701                                                 ],[
4702                                                         CF_ADD_LIB_AFTER($cf_first_lib,-lXmu)
4703                                                 ])
4704                                         CF_TRIM_X_LIBS
4705                                         ;;
4706                                 esac
4707                         fi
4708
4709                         break])
4710         done
4711 fi
4712
4713 if test -z "$cf_x_athena_lib" ; then
4714         CF_X_EXT
4715         CF_X_TOOLKIT
4716         CF_X_ATHENA_CPPFLAGS($cf_x_athena)
4717         CF_X_ATHENA_LIBS($cf_x_athena)
4718 fi
4719 ])dnl
4720 dnl ---------------------------------------------------------------------------
4721 dnl CF_X_ATHENA_CPPFLAGS version: 9 updated: 2020/12/31 10:54:15
4722 dnl --------------------
4723 dnl Normally invoked by CF_X_ATHENA, with $1 set to the appropriate flavor of
4724 dnl the Athena widgets, e.g., Xaw, Xaw3d, neXtaw.
4725 AC_DEFUN([CF_X_ATHENA_CPPFLAGS],
4726 [
4727 AC_REQUIRE([AC_PATH_XTRA])
4728 cf_x_athena_root=ifelse([$1],,Xaw,[$1])
4729 cf_x_athena_inc=""
4730
4731 for cf_path in default \
4732         /usr/contrib/X11R6 \
4733         /usr/contrib/X11R5 \
4734         /usr/lib/X11R5 \
4735         /usr/local
4736 do
4737         if test -z "$cf_x_athena_inc" ; then
4738                 CF_SAVE_XTRA_FLAGS([CF_X_ATHENA_CPPFLAGS])
4739                 cf_test=X11/$cf_x_athena_root/SimpleMenu.h
4740                 if test "$cf_path" != default ; then
4741                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_path/include)
4742                         AC_MSG_CHECKING(for $cf_test in $cf_path)
4743                 else
4744                         AC_MSG_CHECKING(for $cf_test)
4745                 fi
4746                 AC_TRY_COMPILE([
4747 #include <X11/Intrinsic.h>
4748 #include <$cf_test>],[],
4749                         [cf_result=yes],
4750                         [cf_result=no])
4751                 AC_MSG_RESULT($cf_result)
4752                 CF_RESTORE_XTRA_FLAGS([CF_X_ATHENA_CPPFLAGS])
4753                 if test "$cf_result" = yes ; then
4754                         test "$cf_path"  = default && cf_x_athena_inc=default
4755                         test "$cf_path" != default && cf_x_athena_inc="$cf_path/include"
4756                         break
4757                 fi
4758         fi
4759 done
4760
4761 if test -z "$cf_x_athena_inc" ; then
4762         AC_MSG_WARN([Unable to find Athena header files])
4763 elif test "$cf_x_athena_inc" != default ; then
4764         CF_APPEND_TEXT(CPPFLAGS,-I$cf_x_athena_inc)
4765 fi
4766 ])
4767 dnl ---------------------------------------------------------------------------
4768 dnl CF_X_ATHENA_LIBS version: 14 updated: 2023/01/11 04:05:23
4769 dnl ----------------
4770 dnl Normally invoked by CF_X_ATHENA, with $1 set to the appropriate flavor of
4771 dnl the Athena widgets, e.g., Xaw, Xaw3d, neXtaw.
4772 AC_DEFUN([CF_X_ATHENA_LIBS],
4773 [AC_REQUIRE([CF_X_TOOLKIT])
4774 cf_x_athena_root=ifelse([$1],,Xaw,[$1])
4775 cf_x_athena_lib=""
4776
4777 for cf_path in default \
4778         /usr/contrib/X11R6 \
4779         /usr/contrib/X11R5 \
4780         /usr/lib/X11R5 \
4781         /usr/local
4782 do
4783         for cf_lib in \
4784                 ${cf_x_athena_root} \
4785                 ${cf_x_athena_root}7 \
4786                 ${cf_x_athena_root}6
4787         do
4788         for cf_libs in \
4789                 "-l$cf_lib -lXmu" \
4790                 "-l$cf_lib -lXpm -lXmu" \
4791                 "-l${cf_lib}_s -lXmu_s"
4792         do
4793                 test -n "$cf_x_athena_lib" && break
4794
4795                 CF_SAVE_XTRA_FLAGS([CF_X_ATHENA_LIBS])
4796                 cf_test=XawSimpleMenuAddGlobalActions
4797                 test "$cf_path" != default && cf_libs="-L$cf_path/lib $cf_libs"
4798                 CF_ADD_LIBS($cf_libs)
4799                 AC_MSG_CHECKING(for $cf_test in $cf_libs)
4800                 AC_TRY_LINK([
4801 $ac_includes_default
4802 #include <X11/Intrinsic.h>
4803 #include <X11/$cf_x_athena_root/SimpleMenu.h>
4804 ],[
4805 $cf_test((XtAppContext) 0)],
4806                         [cf_result=yes],
4807                         [cf_result=no])
4808                 AC_MSG_RESULT($cf_result)
4809                 CF_RESTORE_XTRA_FLAGS([CF_X_ATHENA_LIBS])
4810
4811                 if test "$cf_result" = yes ; then
4812                         cf_x_athena_lib="$cf_libs"
4813                         break
4814                 fi
4815         done # cf_libs
4816                 test -n "$cf_x_athena_lib" && break
4817         done # cf_lib
4818 done
4819
4820 if test -z "$cf_x_athena_lib" ; then
4821         AC_MSG_ERROR(
4822 [Unable to successfully link Athena library (-l$cf_x_athena_root) with test program])
4823 fi
4824
4825 CF_ADD_LIBS($cf_x_athena_lib)
4826 CF_UPPER(cf_x_athena_LIBS,HAVE_LIB_$cf_x_athena)
4827 AC_DEFINE_UNQUOTED($cf_x_athena_LIBS)
4828 ])
4829 dnl ---------------------------------------------------------------------------
4830 dnl CF_X_EXT version: 3 updated: 2010/06/02 05:03:05
4831 dnl --------
4832 AC_DEFUN([CF_X_EXT],[
4833 CF_TRY_PKG_CONFIG(Xext,,[
4834         AC_CHECK_LIB(Xext,XextCreateExtension,
4835                 [CF_ADD_LIB(Xext)])])
4836 ])dnl
4837 dnl ---------------------------------------------------------------------------
4838 dnl CF_X_TOOLKIT version: 27 updated: 2023/01/11 04:05:23
4839 dnl ------------
4840 dnl Check for X Toolkit libraries
4841 AC_DEFUN([CF_X_TOOLKIT],
4842 [
4843 AC_REQUIRE([AC_PATH_XTRA])
4844 AC_REQUIRE([CF_CHECK_CACHE])
4845
4846 # OSX is schizoid about who owns /usr/X11 (old) versus /opt/X11 (new) (and
4847 # in some cases has installed dummy files in the former, other cases replaced
4848 # it with a link to the new location).  This complicates the configure script.
4849 # Check for that pitfall, and recover using pkg-config
4850 #
4851 # If none of these are set, the configuration is almost certainly broken.
4852 if test -z "${X_CFLAGS}${X_PRE_LIBS}${X_LIBS}${X_EXTRA_LIBS}"
4853 then
4854         CF_TRY_PKG_CONFIG(x11,,[AC_MSG_WARN(unable to find X11 library)])
4855         CF_TRY_PKG_CONFIG(ice,,[AC_MSG_WARN(unable to find ICE library)])
4856         CF_TRY_PKG_CONFIG(sm,,[AC_MSG_WARN(unable to find SM library)])
4857         CF_TRY_PKG_CONFIG(xt,,[AC_MSG_WARN(unable to find Xt library)])
4858 else
4859         LIBS="$X_PRE_LIBS $LIBS $X_EXTRA_LIBS"
4860 fi
4861
4862 cf_have_X_LIBS=no
4863
4864 CF_TRY_PKG_CONFIG(xt,[
4865
4866         case "x$LIBS" in
4867         (*-lX11*)
4868                 ;;
4869         (*)
4870 # we have an "xt" package, but it may omit Xt's dependency on X11
4871 AC_CACHE_CHECK(for usable X dependency,cf_cv_xt_x11_compat,[
4872 AC_TRY_LINK([
4873 $ac_includes_default
4874 #include <X11/Xlib.h>
4875 ],[
4876         int rc1 = XDrawLine((Display*) 0, (Drawable) 0, (GC) 0, 0, 0, 0, 0);
4877         int rc2 = XClearWindow((Display*) 0, (Window) 0);
4878         int rc3 = XMoveWindow((Display*) 0, (Window) 0, 0, 0);
4879         int rc4 = XMoveResizeWindow((Display*)0, (Window)0, 0, 0, 0, 0);
4880 ],[cf_cv_xt_x11_compat=yes],[cf_cv_xt_x11_compat=no])])
4881                 if test "$cf_cv_xt_x11_compat" = no
4882                 then
4883                         CF_VERBOSE(work around broken X11 dependency)
4884                         # 2010/11/19 - good enough until a working Xt on Xcb is delivered.
4885                         CF_TRY_PKG_CONFIG(x11,,[CF_ADD_LIB_AFTER(-lXt,-lX11)])
4886                 fi
4887                 ;;
4888         esac
4889
4890 AC_CACHE_CHECK(for usable X Toolkit package,cf_cv_xt_ice_compat,[
4891 AC_TRY_LINK([
4892 $ac_includes_default
4893 #include <X11/Shell.h>
4894 ],[int num = IceConnectionNumber(0); (void) num
4895 ],[cf_cv_xt_ice_compat=yes],[cf_cv_xt_ice_compat=no])])
4896
4897         if test "$cf_cv_xt_ice_compat" = no
4898         then
4899                 # workaround for broken ".pc" files used for X Toolkit.
4900                 case "x$X_PRE_LIBS" in
4901                 (*-lICE*)
4902                         case "x$LIBS" in
4903                         (*-lICE*)
4904                                 ;;
4905                         (*)
4906                                 CF_VERBOSE(work around broken ICE dependency)
4907                                 CF_TRY_PKG_CONFIG(ice,
4908                                         [CF_TRY_PKG_CONFIG(sm)],
4909                                         [CF_ADD_LIB_AFTER(-lXt,$X_PRE_LIBS)])
4910                                 ;;
4911                         esac
4912                         ;;
4913                 esac
4914         fi
4915
4916         cf_have_X_LIBS=yes
4917 ],[
4918
4919         LDFLAGS="$X_LIBS $LDFLAGS"
4920         CF_CHECK_CFLAGS($X_CFLAGS)
4921
4922         AC_CHECK_FUNC(XOpenDisplay,,[
4923         AC_CHECK_LIB(X11,XOpenDisplay,
4924                 [CF_ADD_LIB(X11)])])
4925
4926         AC_CHECK_FUNC(XtAppInitialize,,[
4927         AC_CHECK_LIB(Xt, XtAppInitialize,
4928                 [AC_DEFINE(HAVE_LIBXT,1,[Define to 1 if we can compile with the Xt library])
4929                  cf_have_X_LIBS=Xt
4930                  LIBS="-lXt $LIBS"])])
4931 ])
4932
4933 if test "$cf_have_X_LIBS" = no ; then
4934         AC_MSG_WARN(
4935 [Unable to successfully link X Toolkit library (-lXt) with
4936 test program.  You will have to check and add the proper libraries by hand
4937 to makefile.])
4938 fi
4939 ])dnl
4940 dnl ---------------------------------------------------------------------------
4941 dnl CF__CURSES_DATA version: 3 updated: 2021/01/04 19:45:09
4942 dnl ---------------
4943 dnl Attempt to make a copy of a curses data item.  This is needed in the
4944 dnl check-data configure tests when using ncurses, because the symbol may be
4945 dnl actually a function return-value.  That could happen if the linker is
4946 dnl broken (does not resolve data-only references), or if ncurses is configured
4947 dnl to support re-entrant code.
4948 dnl $1 = target
4949 dnl $2 = source
4950 define([CF__CURSES_DATA],[
4951 #if defined($2) && ((defined(NCURSES_WRAPPED_VAR) && (NCURSES_VERSION_PATCH < 20200208)) || defined(NCURSES_BROKEN_LINKER) || defined(NCURSES_REENTRANT))
4952         const void *$1 = (const void *)($2);
4953 #else
4954         const void *$1 = &($2);
4955 #endif
4956         fprintf(stderr, "testing linkage of $2:%p\\n", (const void *)$1);
4957 ])dnl
4958 dnl ---------------------------------------------------------------------------
4959 dnl CF__CURSES_HEAD version: 2 updated: 2010/10/23 15:54:49
4960 dnl ---------------
4961 dnl Define a reusable chunk which includes <curses.h> and <term.h> when they
4962 dnl are both available.
4963 define([CF__CURSES_HEAD],[
4964 #ifdef HAVE_XCURSES
4965 #include <xcurses.h>
4966 char * XCursesProgramName = "test";
4967 #else
4968 #include <${cf_cv_ncurses_header:-curses.h}>
4969 #if defined(NCURSES_VERSION) && defined(HAVE_NCURSESW_TERM_H)
4970 #include <ncursesw/term.h>
4971 #elif defined(NCURSES_VERSION) && defined(HAVE_NCURSES_TERM_H)
4972 #include <ncurses/term.h>
4973 #elif defined(HAVE_TERM_H)
4974 #include <term.h>
4975 #endif
4976 #endif
4977 ])
4978 dnl ---------------------------------------------------------------------------
4979 dnl CF__XOPEN_SOURCE_BODY version: 2 updated: 2023/02/18 17:41:25
4980 dnl ---------------------
4981 dnl body of test when test-compiling for _XOPEN_SOURCE check
4982 define([CF__XOPEN_SOURCE_BODY],
4983 [
4984 #ifndef _XOPEN_SOURCE
4985 #error _XOPEN_SOURCE is not defined
4986 #endif
4987 ])
4988 dnl ---------------------------------------------------------------------------
4989 dnl CF__XOPEN_SOURCE_HEAD version: 2 updated: 2023/02/18 17:41:25
4990 dnl ---------------------
4991 dnl headers to include when test-compiling for _XOPEN_SOURCE check
4992 define([CF__XOPEN_SOURCE_HEAD],
4993 [
4994 $ac_includes_default
4995 ])